source: documentation/trunk/tutorials/generate-html.bat@ 30229

@echo off

:: Usage: generate-html.bat [<gs-major-version-number]
:: The optional parameter major version number, which can be 2 or 3, will be assumed to be (Greenstone) "2" if none is provided
if not "%GSDLHOME%" == "" goto generate

echo You must run 'setup' in the top level folder of your Greenstone installation before running this script
echo Usage: $0 [gs-major-version-number=2]
goto exit

:generate:
setlocal
set top_dir=%CD%
set source_dir=%CD%\xml-source
set processing_dir=%CD%\processing
set output_dir=%CD%\html
set tmp_dir=%CD%\tmp
if not exist "%output_dir%" mkdir %output_dir%
if not exist "%tmp_dir%" mkdir %tmp_dir%
cd ..
cd shared
set shared_dir=%CD%
cd %output_dir%


set GSDL_OR_GSDL3SRC_HOME=%GSDLHOME%
:: this environment variable varies for GS3, where GLI is located in GSDL3SRCHOME (GS3) and not in GSDLHOME (gs2build)
if not "%GSDL3SRCHOME%" == "" if exist "%GSDL3SRCHOME%" (   
    set GSDL_OR_GSDL3SRC_HOME=%GSDL3SRCHOME%
)

set CLASSPATH=%shared_dir%;%GSDLHOME%\gli;%GSDL_OR_GSDL3SRC_HOME%\gli\classes;%GSDLHOME%\perllib;%shared_dir%\xalan.jar;%GSDL_OR_GSDL3SRC_HOME%\web\WEB-INF\classes

:: preprocess-tut-xml.xsl removes all the non-matching MajorVersion tags first
:: This needs to be done in a separate pass, to ensure NumberedItems nested in  
:: MajorVersion tags preserve their numbering. 
echo "processing top level index"
java -cp "%CLASSPATH%" -DGSDLHOME="%GSDLHOME%" -DGSDL3SRCHOME="%GSDL3SRCHOME%" ApplyXSLT "en" "%processing_dir%\preprocess-tut-xml.xsl"  "%source_dir%\tutorial_en.xml" %* > "%tmp_dir%\tutorial_en.xml"
java -cp "%CLASSPATH%" -DGSDLHOME="%GSDLHOME%" -DGSDL3SRCHOME="%GSDL3SRCHOME%" ApplyXSLT "en" "%processing_dir%\xml-to-top-index.xsl"  "%tmp_dir%\tutorial_en.xml" %* > "%output_dir%\index.html"

echo "generating wiki index page"
java -cp "%CLASSPATH%" -DGSDLHOME="%GSDLHOME%" -DGSDL3SRCHOME="%GSDL3SRCHOME%" ApplyXSLT "en" "%processing_dir%\xml-to-wiki-index.xsl" "%tmp_dir%\tutorial_en.xml" %* > "%output_dir%\wiki-index.txt"


for %%G IN (en,fr,ru,es) do (
if not exist "%output_dir%\%%G" mkdir "%output_dir%\%%G"

echo "processing %%G version"
cd %output_dir%\%%G

if not "%%G" == "en" java -cp "%CLASSPATH%" -DGSDLHOME="%GSDLHOME%" -DGSDL3SRCHOME="%GSDL3SRCHOME%" ApplyXSLT %%G "%processing_dir%\preprocess-tut-xml.xsl" "%source_dir%\tutorial_%%G.xml" %* > "%tmp_dir%\tutorial_%%G.xml"

java -cp "%CLASSPATH%" -DGSDLHOME="%GSDLHOME%" -DGSDL3SRCHOME="%GSDL3SRCHOME%" ApplyXSLT %%G "%processing_dir%\xml-to-index.xsl" "%tmp_dir%\tutorial_%%G.xml" %* > "index.html"
java -cp "%CLASSPATH%" -DGSDLHOME="%GSDLHOME%" -DGSDL3SRCHOME="%GSDL3SRCHOME%" ApplyXSLT %%G "%processing_dir%\xml-to-one-html.xsl" "%tmp_dir%\tutorial_%%G.xml" %* > "all_tutorials.html"
java -cp "%CLASSPATH%" -DGSDLHOME="%GSDLHOME%" -DGSDL3SRCHOME="%GSDL3SRCHOME%" ApplyXSLT %%G "%processing_dir%\xml-to-many-html.xsl" "%tmp_dir%\tutorial_%%G.xml" %* | perl -S "%GSDL_OR_GSDL3SRC_HOME%\gli\help\splithelpdocument.pl"
cd ..
)

endlocal

:exit: