source: extensions/gsdl-video/trunk/CASCADE-MAKE.bat@ 18996

@echo off
pushd "%CD%"
CD /D "%~dp0"

if "x%GSDLHOME%" == "x" (
  REM This extension needs to have the main GSDL setup.bat sourced

  echo Greenstone environment variable GSDLHOME not set.
  echo Have you sourced the main installation\'s setup file, e.g. setup.bat?
  goto ErrorExitNeg1 
)

if not exist "%GSDLHOME%\apache-httpd" (
  REM ... and it also needs to have been configured with --enable-apache-httpd
  REM This is because the entension needs to add mod_flvx to the web server

  echo Could not find the directory "%GSDLHOME%\apache-httpd"
  echo Has the main Greenstone been configure for this? 
  echo e.g. nmake /f win32.mak APACHE_HTTPD=1 [... other options]
  exit ErrorExitNeg1
)


REM call cascade-make/bin/script/test-setup.bat
call cascade-make/lib/cascade-lib.bat

:: Guaranteed that GSDLOS has now been set


for /D %%d IN ("%GSDLOS%") do (
  if not exist "%GEXTVIDEO_INSTALLED%\%%d" (
    echo Creating %GEXTVIDEO_INSTALLED%\%%d
    mkdir "%GEXTVIDEO_INSTALLED%\%%d"
  )
)

set dirlist=build-srcpack runtime-srcpack
if exist "devel-srcpack" (
  set dirlist=%dirlist% devel-srcpack
)

for /D %%d IN (%dirlist%) do (
  echo Running %%d\CASCADE-MAKE.bat %*

  (cd %%d && call CASCADE-MAKE.bat %* && cd ..)
  
  if not ERRORLEVEL 0 (
    echo Error encountered running %%d\CASCADE-MAKE.bat
    goto ErrorExitPos1
  )
)


if  "%install%" == "1" (
  type NOTES.txt
)
goto End

:ErrorExitNeg1
set ERRORLEVEL=-1
goto End

:ErrorExitPos1
set ERRORLEVEL=1
goto End

:End

popd