@echo off
set GLILANG=en


::  -------- Run the Greenstone Librarian Interface --------

:: This script must be run from within the directory in which it lives
if exist gli.bat goto start
    if "%GLILANG%" == "en" echo This script must be run from the directory in which it resides.
    if "%GLILANG%" == "es" echo Este guiвn deberа ejecutarse desde el directorio en el que reside.
    if "%GLILANG%" == "fr" echo Ce script doit Иtre exВcutВ Е partir du rВpertoire dans lequel il se trouve.
    if "%GLILANG%" == "ru" echo Этот скрипт должен быть взят из директории, в которой он расположен
    goto exit

:start
if "%OS%" == "Windows_NT" goto findGSDL
    :: Invoke a new command processor to ensure there's enough environment space
    if "%1" == "Second" goto findGSDL
        command /E:2048 /C %0 Second %1 %2 %3 %4 %5 %6 %7 %8 %9
        goto done

:findGSDL
echo.
if "%GLILANG%" == "en" echo Greenstone Librarian Interface (GLI)
if "%GLILANG%" == "en" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%GLILANG%" == "en" echo GLI comes with ABSOLUTELY NO WARRANTY; for details see LICENSE.txt
if "%GLILANG%" == "en" echo This is free software, and you are welcome to redistribute it

if "%GLILANG%" == "es" echo Interfaz de la Biblioteca Digital Greenstone (Greenstone Librarian Interface - GLI)
if "%GLILANG%" == "es" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%GLILANG%" == "es" echo La Interfaz de la Biblioteca Digital Greenstone NO INCLUYE ABSOLUTAMENTE NINGUNA GARANT╓A.
if "%GLILANG%" == "es" echo Para mayor informaciвn vea los tВrminos de la licencia en LICENSE.txt
if "%GLILANG%" == "es" echo Este es un software abierto, por lo que lo invitamos a que lo distribuya de forma gratuita

if "%GLILANG%" == "fr" echo Interface du BibliothВcaire Greenstone (Greenstone Librarian Interface - GLI)
if "%GLILANG%" == "fr" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%GLILANG%" == "fr" echo GLI est fourni sans AUCUNE GARANTIE; pour des dВtails, voir LICENSE.txt
if "%GLILANG%" == "fr" echo Ceci est un logiciel libre, et vous Иtes invitВ Е le redistribuer

if "%GLILANG%" == "ru" echo Библиотечный интерфейс Greenstone (Greenstone Librarian Interface - GLI)
if "%GLILANG%" == "ru" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%GLILANG%" == "ru" echo БИГ не дает АБСОЛЮТНО НИКАКИХ ГАРАНТИЙ; детали см. в тексте LICENSE.TXT
if "%GLILANG%" == "ru" echo Это - свободно распространяемое программное обеспечение и Вы можете распространять его

echo.
::  ---- Determine GSDLHOME ----
set GSDLPATH=

:: Some users may set the above line manually
if not "%GSDLPATH%" == "" goto testGSDL

    :: The default location for the GLI is a subdirectory of Greenstone
    set GSDLPATH=..

    :: If it is set, use the GSDLHOME environment variable 
    if "%GSDLHOME%" == "" goto testGSDL
	set GSDLPATH=%GSDLHOME%

:testGSDL
:: Check that the Greenstone installation looks OK
if "%GLILANG%" == "en" echo Checking GSDL: %GSDLPATH%
if "%GLILANG%" == "es" echo Revisando GSDL: %GSDLPATH%
if "%GLILANG%" == "fr" echo VВrification de GSDL: %GSDLPATH%
if "%GLILANG%" == "ru" echo Проверка GSDL: %GSDLPATH%
if exist "%GSDLPATH%\setup.bat" goto prepGSDL
    echo.
    if "%GLILANG%" == "en" echo The Greenstone installation could not be found, or is incomplete.
    if "%GLILANG%" == "en" echo Try reinstalling Greenstone then running this script again.

    if "%GLILANG%" == "es" echo No se pudo encontrar la instalaciвn de Greenstone o estа incompleta.
    if "%GLILANG%" == "es" echo Trate de reinstalar Greenstone y a continuaciвn ejecute nuevamente este guiвn.

    if "%GLILANG%" == "fr" echo L'installation de Greenstone est introuvable ou incomplКte. Essayez
    if "%GLILANG%" == "fr" echo de rВinstaller Greenstone et exВcutez ce script Е nouveau.

    if "%GLILANG%" == "ru" echo Инсталляция Greenstone не была найдена или она неполна. Попробуйте повторно
    if "%GLILANG%" == "ru" echo установить Greenstone, а затем ввести этот скрипт снова.
    goto exit

:prepGSDL
:: Setup Greenstone, unless it has already been done
if not "%GSDLHOME%" == "" goto doneGSDL
    call "%GSDLPATH%\setup.bat" SetEnv > nul

:doneGSDL
:: GSDLPATH is no longer needed, since GSDLHOME should now be set
set GSDLPATH=
:: test writability of GSDLHOME
@call "%GSDLHOME%\bin\script\checkwritability.bat"


:findPerl
::  ---- Check Perl exists ----
set PERLPATH=

:: Some users may set the above line manually
if not "%PERLPATH%" == "" goto testPerl

    :: Check if Perl is on the search path
    echo %PATH%| winutil\which.exe perl.exe | winutil\setvar.exe PERLPATH > %SystemRoot%\Temp\setperl.bat
    call %SystemRoot%\Temp\setperl.bat
    del %SystemRoot%\Temp\setperl.bat
    if not "%PERLPATH%" == "" goto testPerl

    :: If not, try GSDLHOME\bin\windows\perl\bin
    if exist "%GSDLHOME%\bin\windows\perl\bin\perl.exe" goto gsdlPerl

    :: Still haven't found anything, so try looking in the registry (gulp!)
    type nul > %SystemRoot%\Temp\perl.reg
    regedit /E %SystemRoot%\Temp\perl.reg "HKEY_LOCAL_MACHINE\SOFTWARE\Perl"
    type %SystemRoot%\Temp\perl.reg > %SystemRoot%\Temp\perl.txt
    del %SystemRoot%\Temp\perl.reg

    winutil\findperl.exe %SystemRoot%\Temp\perl.txt | winutil\setvar.exe PERLPATH > %SystemRoot%\Temp\setperl.bat
    del %SystemRoot%\Temp\perl.txt
    call %SystemRoot%\Temp\setperl.bat
    del %SystemRoot%\Temp\setperl.bat

    :: If nothing was found in the registry, we're stuck
    if "%PERLPATH%" == "" goto noPerl

    goto testPerl

:gsdlPerl
    set PERLPATH=%GSDLHOME%\bin\windows\perl\bin

:testPerl
:: Check that a Perl executable has been found
if "%GLILANG%" == "en" echo Checking Perl: %PERLPATH%
if "%GLILANG%" == "es" echo Revisando Perl: %PERLPATH%
if "%GLILANG%" == "fr" echo VВrification de Perl: %PERLPATH%
if "%GLILANG%" == "ru" echo Проверка Perl: %PERLPATH%
if exist "%PERLPATH%\perl.exe" goto findJava

:noPerl
    echo.
    if "%GLILANG%" == "en" echo The Greenstone Librarian Interface requires perl in order to operate,
    if "%GLILANG%" == "en" echo but perl could not be detected on your system. Please ensure that perl
    if "%GLILANG%" == "en" echo is installed and is on your search path, then rerun this script.

    if "%GLILANG%" == "es" echo La Interfaz de la Biblioteca Digital Greenstone requiere Perl para poder
    if "%GLILANG%" == "es" echo operar, pero Вste no aparece en su sistema. Por favor asegгrese de
    if "%GLILANG%" == "es" echo que Perl estа instalado y se encuentra en su ruta de bгsqueda.
    if "%GLILANG%" == "es" echo A continuaciвn ejecute nuevamente este guiвn.

    if "%GLILANG%" == "fr" echo Greenstone Librarian Interface nВcessite perl pour son fonctionnement,
    if "%GLILANG%" == "fr" echo mais perl n'a pas pu Иtre dВtectВ dans votre systКme. Veuillez vous 
    if "%GLILANG%" == "fr" echo assurer que perl est installВ et est spВcifiВ dans votre chemin de 
    if "%GLILANG%" == "fr" echo recherche, puis redВmarrez ce script.

    if "%GLILANG%" == "ru" echo Библиотечный интерфейс Greenstone требует Perl, чтобы иметь возможность
    if "%GLILANG%" == "ru" echo работать, но Perl не был в вашей системе. Пожалуйста, подтвердите,
    if "%GLILANG%" == "ru" echo что Perl установлен и находится на вашем пути поиска, затем
    if "%GLILANG%" == "ru" echo повторновведите этот скрипт.
    goto exit


:findJava
:: ---- Check Java exists ----
set JAVAPATH=

:: Some users may set the above line manually
if not "%JAVAPATH%" == "" goto testJava

    :: If it is set, use the JAVA_HOME environment variable
    if not "%JAVA_HOME%" == "" goto javahome

    :: Check if Java is on the search path
    echo %PATH%| winutil\which.exe java.exe | winutil\setvar.exe JAVAPATH > %SystemRoot%\Temp\setjava.bat
    call %SystemRoot%\Temp\setjava.bat
    del %SystemRoot%\Temp\setjava.bat
    if not "%JAVAPATH%" == "" goto testJava

    :: Still haven't found anything, so try looking in the registry (gulp!)
    type nul > %SystemRoot%\Temp\jdk.reg
    regedit /E %SystemRoot%\Temp\jdk.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit"
    type %SystemRoot%\Temp\jdk.reg > %SystemRoot%\Temp\jdk.txt
    del %SystemRoot%\Temp\jdk.reg
    type nul > %SystemRoot%\Temp\jre.reg
    regedit /E %SystemRoot%\Temp\jre.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Runtime Environment"
    type %SystemRoot%\Temp\jre.reg > %SystemRoot%\Temp\jre.txt
    del %SystemRoot%\Temp\jre.reg

    winutil\findjava.exe %SystemRoot%\Temp\jdk.txt %SystemRoot%\Temp\jre.txt | winutil\setvar.exe JAVAPATH > %SystemRoot%\Temp\setjava.bat
    del %SystemRoot%\Temp\jdk.txt
    del %SystemRoot%\Temp\jre.txt
    call %SystemRoot%\Temp\setjava.bat
    del %SystemRoot%\Temp\setjava.bat

    :: If nothing was found in the registry, we're stuck
    if "%JAVAPATH%" == "" goto noJava

    set JAVAPATH=%JAVAPATH%\bin
    goto testJava

:javahome
    set JAVAPATH=%JAVA_HOME%\bin

:testJava
:: Check that a Java executable has been found
if "%GLILANG%" == "en" echo Checking Java: %JAVAPATH%
if "%GLILANG%" == "es" echo Revisando Java: %JAVAPATH%
if "%GLILANG%" == "fr" echo VВrification de Java: %JAVAPATH%
if "%GLILANG%" == "ru" echo Проверка Java: %JAVAPATH%
if exist "%JAVAPATH%\java.exe" goto checkGLI

:noJava
    echo.
    if "%GLILANG%" == "en" echo Failed to locate an appropriate version of Java. You must install a
    if "%GLILANG%" == "en" echo Java Runtime Environment (version 1.4 or greater) before running the
    if "%GLILANG%" == "en" echo Greenstone Librarian Interface.

    if "%GLILANG%" == "es" echo No se pudo localizar una versiвn apropiada de Java. Usted deberа
    if "%GLILANG%" == "es" echo instalar un Ambiente de Ejecuciвn Java (versiвn 1.4 o superior)
    if "%GLILANG%" == "es" echo antes de correr la Interfaz de la Biblioteca Digital Greenstone.

    if "%GLILANG%" == "fr" echo Une version adВquate de Java n'a pas pu Иtre localisВe. Vous devez
    if "%GLILANG%" == "fr" echo installer un Java Runtime Environment (version 1.4 ou supВrieur)
    if "%GLILANG%" == "fr" echo avant de dВmarrer Greenstone Librarian Interface.

    if "%GLILANG%" == "ru" echo Не удалось определить местонахождение соответствующей версии Java.
    if "%GLILANG%" == "ru" echo Вы должны установить Java Runtime Environment (версию 1.4 или выше) перед вводом
    if "%GLILANG%" == "ru" echo библиотечного интерфейса Greenstone.
    goto exit


:checkGLI
:: ---- Check that the GLI has been compiled ----
if exist "classes/org/greenstone/gatherer/Gatherer.class" goto runGLI
if exist "GLI.jar" goto runGLI
    echo.
    if "%GLILANG%" == "en" echo You need to compile the Greenstone Librarian Interface (using makegli.bat)
    if "%GLILANG%" == "en" echo before running this script.

    if "%GLILANG%" == "es" echo Usted necesita compilar la Interfaz de la Biblioteca Digital Greenstone
    if "%GLILANG%" == "es" echo (por medio de makegli.bat) antes de ejecutar este guiвn.

    if "%GLILANG%" == "fr" echo Vous devez compiler le Greenstone Interface (en utilisant makegli.bat)
    if "%GLILANG%" == "fr" echo avant d'exВcuter ce script.

    if "%GLILANG%" == "ru" echo Вы должны компилировать библиотечный интерфейс Greenstone (используя makegli.bat)
    if "%GLILANG%" == "ru" echo перед вводом этого скрипта
    goto exit


:runGLI
:: ---- Finally, run the GLI ----
echo.

if "%GLILANG%" == "en" echo Running the Greenstone Librarian Interface...
if "%GLILANG%" == "es" echo Ejecutando la Interfaz de la Biblioteca Digital Greenstone...
if "%GLILANG%" == "fr" echo ExВcution de Greenstone Librarian Interface
if "%GLILANG%" == "ru" echo Текущий библиотечный интерфейс Greenstone...

:: -Xms32M          To set minimum memory
:: -Xmx32M          To set maximum memory
:: -verbose:gc      To set garbage collection messages
:: -Xincgc          For incremental garbage collection
:: -Xprof           Function call profiling
:: -Xloggc:<file>   Write garbage collection log

if exist "%GSDLHOME%\server.exe" goto localLib 

:webLib
    "%JAVAPATH%\java" -Xmx128M -cp classes/;GLI.jar;lib/apache.jar;lib/qfslib.jar org.greenstone.gatherer.GathererProg -gsdl %GSDLHOME% -gsdlos %GSDLOS% -perl %PERLPATH% %1 %2 %3 %4 %5 %6 %7 %8 %9

    if ERRORLEVEL 2 goto webLib

    if "%GLILANG%" == "en" echo Done!
    if "%GLILANG%" == "es" echo нHecho!
    if "%GLILANG%" == "fr" echo TerminВ!
    if "%GLILANG%" == "ru" echo Выполнено!
    goto done

:localLib
    "%JAVAPATH%\java" -Xmx128M -cp classes/;GLI.jar;lib/apache.jar;lib/qfslib.jar org.greenstone.gatherer.GathererProg -gsdl %GSDLHOME% -gsdlos %GSDLOS% -perl %PERLPATH% -local_library %GSDLHOME%\server.exe %1 %2 %3 %4 %5 %6 %7 %8 %9

    if ERRORLEVEL 2 goto localLib

    if "%GLILANG%" == "en" echo Done!
    if "%GLILANG%" == "es" echo нHecho!
    if "%GLILANG%" == "fr" echo TerminВ!
    if "%GLILANG%" == "ru" echo Выполнено!
    goto done

:exit
echo.
pause

:done
:: ---- Clean up ----
set PERLPATH=
set JAVAPATH=