source: gli/trunk/findjava.bat@ 19922

@echo off

:: Environment Variables passed in: _VERSION, GLILANG and 
:: possibly also GSDLHOME and/or GSDL3SRCHOME.
:: As a result of executing this script, the JAVA_EXECUTABLE variable 
:: will be set, but only if Perl was found.

:findJava

:: We will already be in the correct folder (GLI folder), which would
:: contain a compiled up search4j.exe if this GLI is part of an installation.
:: If search4j.exe is not there, then it means this is an SVN checkout. 
:: In such a case, it's up to the user checking things out to ensure JAVA_HOME
:: is set and moreover points to the correct version of the Java.

set DISPLAY_MIN_VERSION=1.4
set MIN_VERSION=1.4.0_00
set SEARCH4J_EXECUTABLE=search4j.exe
if exist %SEARCH4J_EXECUTABLE% goto setJexec
if "%_VERSION%" == "" goto tryJava
    :: else we look for a compiled version of search4j in a GS installation
    if "%_VERSION%" == "2" (
        set SEARCH4J_EXECUTABLE=%GSDLHOME%\bin\windows\search4j.exe
        set HINT=%GSDLHOME%\packages\jre
    )
        if "%_VERSION%" == "3" (
        set SEARCH4J_EXECUTABLE=%GSDL3SRCHOME%\bin\search4j.exe
        set HINT=%GSDL3SRCHOME%\packages\jre
    )
    if not exist "%SEARCH4J_EXECUTABLE%" goto tryJava

:setJexec    
    "%SEARCH4J_EXECUTABLE%" -e -m "%MIN_VERSION%" -p "%HINT%" | winutil\setvar.exe JAVA_EXECUTABLE > %TMP%\set_java_executable.bat
    call "%TMP%\set_java_executable.bat"
    del "%TMP%\set_java_executable.bat"
    
    if "%JAVA_EXECUTABLE%" == "" goto noJava
    echo Java:
    echo %JAVA_EXECUTABLE%
    echo.

:: found java, JAVA_EXECUTABLE env var set, can exit this script
    goto exit

:tryJava
if "%JAVA_HOME%" == "" goto noJava
if not exist "%JAVA_HOME%\bin\java.exe" goto noJava
    if "%GLILANG%" == "en" (
        echo.
        echo ***************************************************************************
            echo WARNING: 
        echo Found a JAVA_HOME at %JAVA_HOME%. Attempting to use this.
        echo However, you need to have a Java %DISPLAY_MIN_VERSION% or higher installed.
        echo ***************************************************************************
        echo.
    )
    :: Try to use this version
    set JAVA_EXECUTABLE=%JAVA_HOME%\bin\java
    goto exit

:noJava
    echo.
    if "%GLILANG%" == "en" (
        echo Failed to locate an appropriate version of Java. You must install a
            echo Java Runtime Environment ^(version %DISPLAY_MIN_VERSION% or greater^) before running the
            echo Greenstone Librarian Interface.
    )

    if "%GLILANG%" == "es" (
        echo No se pudo localizar una versi¢n apropiada de Java. Usted deber 
            echo instalar un Ambiente de Ejecuci¢n Java ^(versi¢n %DISPLAY_MIN_VERSION% o superior^)
            echo antes de correr la Interfaz de la Biblioteca Digital Greenstone.
    )

    if "%GLILANG%" == "fr" (
        echo Une version ad?quate de Java n'a pas pu ?tre localis?e. Vous devez
            echo installer un Java Runtime Environment ^(version %DISPLAY_MIN_VERSION% ou sup?rieur^)
            echo avant de d?marrer Greenstone Librarian Interface.
    )

    if "%GLILANG%" == "ru" (
        echo ¥ 〠«®áì ®¯à¥€¥«šâì ¬¥áâ®­ 宊€¥­š¥ ᮮ⢥âáâ¢ãî饩 ¢¥àᚚ Java.
            echo ?ë €®«Š­ë ãáâ ­®¢šâì Java Runtime Environment ^(¢¥àášî %DISPLAY_MIN_VERSION% š«š ¢ëè¥^) ¯¥à¥€ ¢¢®€®¬
            echo ¡š¡«š®â¥ç­®£® š­â¥àä¥©á  Greenstone.
    )
    goto exit

:exit
set SEARCH4J_EXECUTABLE=
set MIN_VERSION=
set DISPLAY_MIN_VERSION=