source: greenstone3/${branch.path}/gs3-server.bat@ 14688

@echo off

set SERVERLANG=en

:: -------- Run the Greenstone 3 Server --------

:: This script must be run from within the directory in which it lives
if exist gs3-server.bat goto start
    if "%SERVERLANG%" == "en" echo This script must be run from the directory in which it resides.
    if "%SERVERLANG%" == "es" echo Este gui¢n deber  ejecutarse desde el directorio en el que reside.
    if "%SERVERLANG%" == "fr" echo Ce script doit ˆtre ex‚cut‚ 
 partir du r‚pertoire dans lequel il se trouve.
    if "%SERVERLANG%" == "ru" echo â®â áªà š¯â €®«Š¥­ ¡ëâì ¢§ï⠚§ €šà ¥ªâ®à šš, ¢ ª®â®à ®© ®­ à  á¯®«®Š¥­
    goto exit

:start
if "%OS%" == "Windows_NT" goto findGSDL
    :: Invoke a new command processor to ensure there's enough environment space
    if "%1" == "Second" goto findGSDL
        command /E:2048 /C %0 Second %1 %2 %3 %4 %5 %6 %7 %8 %9
        goto done

:findGSDL
echo.
if "%SERVERLANG%" == "en" echo Greenstone3 Server
if "%SERVERLANG%" == "en" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%SERVERLANG%" == "en" echo This program comes with ABSOLUTELY NO WARRANTY; for details see LICENSE.txt
if "%SERVERLANG%" == "en" echo This is free software, and you are welcome to redistribute it

echo.
::  ---- Determine GSDL3HOME ----
set GSDL3PATH=

:: Some users may set the above line manually
 if not "%GSDL3PATH%" == "" goto prepGSDL

 :: The default location is the current directory
 set GSDL3PATH=.

 :: If it is set, use the GSDLHOME environment variable
  if "%GSDL3SRCHOME%" == "" goto prepGSDL
  set GSDL3PATH=%GSDL3SRCHOME%

:prepGSDL
:: Setup Greenstone, unless it has already been done
if not "%GSDL3SRCHOME%" == "" goto doneGSDL
   call "%GSDL3PATH%\gs3-setup.bat" SetEnv > nul

:doneGSDL
:: GSDL3PATH is no longer needed, since GSDL3SRCHOME should now be set
set GSDL3PATH=

:findJava
:: ---- Check Java exists ----
set JAVAPATH=

:: Some users may set the above line manually
if not "%JAVAPATH%" == "" goto testJava

:: If it is set, use the JAVA_HOME environment variable
 if not "%JAVA_HOME%" == "" goto javahome

:: Check if Java is on the search path
 echo %PATH%| winutil\which.exe java.exe | winutil\setvar.exe JAVAPATH > setjava.bat
 call setjava.bat
 del setjava.bat
 if not "%JAVAPATH%" == "" goto testJava

    :: Still haven't found anything, so try looking in the registry (gulp!)
    type nul > jdk.reg
    regedit /E jdk.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit"
    type jdk.reg > jdk.txt
    del jdk.reg
    type nul > jre.reg
    regedit /E jre.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Runtime Environment"
    type jre.reg > jre.txt
    del jre.reg

    winutil\findjava.exe jdk.txt jre.txt | winutil\setvar.exe JAVAPATH > setjava.bat
    del jdk.txt
    del jre.txt
    call setjava.bat
    del setjava.bat

   :: If nothing was found in the registry, we're stuck
   if "%JAVAPATH%" == "" goto noJava

   set JAVAPATH=%JAVAPATH%\bin
   goto testJava

:javahome
    set JAVAPATH=%JAVA_HOME%\bin

:testJava
:: Check that a Java executable has been found
  if "%SERVERLANG%" == "en" echo Checking Java: %JAVAPATH%
  if "%SERVERLANG%" == "es" echo Revisando Java: %JAVAPATH%
  if "%SERVERLANG%" == "fr" echo V‚rification de Java: %JAVAPATH%
  if "%SERVERLANG%" == "ru" echo à ®¢¥à ª  Java: %JAVAPATH%
  if exist "%JAVAPATH%\java.exe" goto checkServer

:noJava
 echo.
    if "%SERVERLANG%" == "en" echo Failed to locate an appropriate version of Java. You must install a
    if "%SERVERLANG%" == "en" echo Java Runtime Environment (version 1.4 or greater) before running the
    if "%SERVERLANG%" == "en" echo Greenstone3 Server.
    goto exit

:checkServer
::---- Check that the server program has been compiled ----
if exist "server.jar" goto runServer
if "%SERVERLANG%" == "en" echo "You need to compile the code before running the server"
goto exit

:runServer
echo Running the Greenstone Server
:: -Xms32M          To set minimum memory
:: -Xmx32M          To set maximum memory
:: -verbose:gc      To set garbage collection messages
:: -Xincgc          For incremental garbage collection
:: -Xprof           Function call profiling
:: -Xloggc:<file>   Write garbage collection log

"%JAVAPATH%\java" -cp "%CLASSPATH%" org.greenstone.server.Server "%GSDL3SRCHOME%"

:exit

:done
:: ---- Clean up ----
set JAVAPATH=