@echo off

set java_min_version=1.4.0_00

if exist gs3-setup.bat goto start
  echo This script must be run from within the Greenstone 3 home directory
  goto exit

:start
:: ---- Set some relevant environment variables ----

:: this is the default
:: greenstone3 (%GSDL3SRCHOME%)
:: +-- web (%GSDLHOME%)
:: +-- packages
::      +-- tomcat (%TOMCAT_HOME%)
::      +-- ant (%ANT_HOME%)

:: set GSDLSRCHOME to the current directory
cd | winutil\setvar.exe GSDL3SRCHOME > %TMP%\setgsdl3.bat
call %TMP%\setgsdl3.bat
del %TMP%\setgsdl3.bat

:: set GSDLHOME to the 'web' subdirectory
set GSDL3HOME=%GSDL3SRCHOME%\web

:: change if using external tomcat or ant
set TOMCAT_HOME=%GSDL3SRCHOME%\packages\tomcat
set ANT_HOME=%GSDL3SRCHOME%\packages\ant

:: other important environment variables
set GSDLOS=windows

:: ---- Set the CLASSPATH and PATH environment variables ----
if "%GS_CP_SET%" == "yes" goto skipSetCp
set CLASSPATH=%CLASSPATH%;.;%GSDL3HOME%\WEB-INF\classes;%GSDL3SRCHOME%\resources\java;%GSDL3SRCHOME%\server.jar;%GSDL3HOME%\WEB-INF\lib\cp.jar;%GSDL3SRCHOME%\lib\jni\cp.jar;%GSDL3SRCHOME%\build\cp.jar;%GSDL3SRCHOME%\lib\java\cp.jar;%GSDL3SRCHOME%\admin\cp.jar;
set PATH=%PATH%;%GSDL3SRCHOME%\bin;%GSDL3SRCHOME%\bin\script;%GSDL3SRCHOME%\lib\jni;%ANT_HOME%\bin

:: a little dynamic set cp stuff
if exist %TMP%\setcp.bat del %TMP%\setcp.bat
for %%j in ("%TOMCAT_HOME%"\common\endorsed\*.jar) do echo set CLASSPATH=%%CLASSPATH%%;%%j>> %TMP%\setcp.bat
if exist %TMP%\setcp.bat call %TMP%\setcp.bat
if exist %TMP%\setcp.bat del %TMP%\setcp.bat

set GS_CP_SET=yes
:skipSetCp

:: ---- Search for java ----
bin\search4j.exe -p "%CD%\packages\jre" -m %java_min_version% | winutil\setvar.exe _JRE_HOME > %TMP%\set_jre_home.bat
call %TMP%\set_jre_home.bat
del %TMP%\set_jre_home.bat

echo %_JRE_HOME%\bin\java.exe | winutil\setvar.exe RUNJAVA > %TMP%\setrunjava.bat
call %TMP%\setrunjava.bat
del %TMP%\setrunjava.bat

if "%JRE_HOME%" == "" set JRE_HOME=%_JRE_HOME%

echo GSDL3SRCHOME : %GSDL3SRCHOME%
echo GSDL3HOME    : %GSDL3HOME%
echo JAVA         : %RUNJAVA%