source: gsdl/trunk/perllib/classify.pm@ 18520

Last change on this file since 18520 was 18520, checked in by davidb, 15 years ago

The variable $next_classify_num used to be global to the file. This was tied up and made a local variable, however some non-standard classifiers need to access this. Have made it a 'our' variable to keep things tidy, but still allow external access to its value from classifiers.
  • Property svn:keywords set to Author Date Id Revision
File size: 13.1 KB
Line 
1###########################################################################
2#
3# classify.pm --
4# A component of the Greenstone digital library software
5# from the New Zealand Digital Library Project at the
6# University of Waikato, New Zealand.
7#
8# Copyright (C) 1999 New Zealand Digital Library Project
9#
10# This program is free software; you can redistribute it and/or modify
11# it under the terms of the GNU General Public License as published by
12# the Free Software Foundation; either version 2 of the License, or
13# (at your option) any later version.
14#
15# This program is distributed in the hope that it will be useful,
16# but WITHOUT ANY WARRANTY; without even the implied warranty of
17# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18# GNU General Public License for more details.
19#
20# You should have received a copy of the GNU General Public License
21# along with this program; if not, write to the Free Software
22# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
23#
24###########################################################################
25
26# functions to handle classifiers
27
28package classify;
29
30require util;
31require AllList;
32
33use dbutil;
34use gsprintf;
35use strict; no strict 'subs';
36
37
38sub gsprintf
39{
40 return &gsprintf::gsprintf(@_);
41}
42
43
44sub load_classifier_for_info {
45 my ($classifier) = shift @_;
46
47 # find the classifier
48 my $customclassname;
49 if (defined($ENV{'GSDLCOLLECTION'}))
50 {
51 $customclassname = &util::filename_cat($ENV{'GSDLCOLLECTDIR'}, "custom", $ENV{'GSDLCOLLECTION'},
52 "perllib", "classify", "${classifier}.pm");
53 }
54 my $colclassname = &util::filename_cat($ENV{'GSDLCOLLECTDIR'}, "perllib", "classify", "${classifier}.pm");
55 my $mainclassname = &util::filename_cat($ENV{'GSDLHOME'}, "perllib", "classify", "${classifier}.pm");
56
57 if (defined($customclassname) && -e $customclassname) { require $customclassname; }
58 elsif (-e $colclassname) { require $colclassname; }
59 elsif (-e $mainclassname) { require $mainclassname; }
60 else {
61 &gsprintf(STDERR, "{classify.could_not_find_classifier}\n", $classifier) && die "\n";
62 }
63 my ($classobj);
64 my $options = "-gsdlinfo";
65 eval ("\$classobj = new \$classifier([],[$options])");
66 die "$@" if $@;
67
68 return $classobj;
69}
70
71sub load_classifiers {
72 my ($classify_list, $build_dir, $outhandle) = @_;
73 my @classify_objects = ();
74 my $classify_number = 1;
75
76 my $colclassdir = &util::filename_cat($ENV{'GSDLCOLLECTDIR'},"perllib/classify");
77 unshift (@INC, $colclassdir);
78
79 foreach my $classifyoption (@$classify_list) {
80
81 # get the classifier name
82 my $classname = shift @$classifyoption;
83 next unless defined $classname;
84
85 # find the classifier
86 my $customclassname = &util::filename_cat($ENV{'GSDLCOLLECTDIR'}, "custom", $ENV{'GSDLCOLLECTION'},
87 "perllib", "classify", "${classname}.pm");
88 my $colclassname = &util::filename_cat($ENV{'GSDLCOLLECTDIR'}, "perllib", "classify", "${classname}.pm");
89 my $mainclassname = &util::filename_cat($ENV{'GSDLHOME'}, "perllib", "classify", "${classname}.pm");
90
91 if (-e $customclassname) { require $customclassname; }
92 elsif (-e $colclassname) { require $colclassname; }
93 elsif (-e $mainclassname) { require $mainclassname; }
94 else { &gsprintf(STDERR, "{classify.could_not_find_classifier}\n", $classname) && die "\n";
95 # die "ERROR - couldn't find classifier \"$classname\"\n";
96 }
97
98 # create the classify object
99 my ($classobj);
100
101 my @newoptions;
102
103 # do these first so they can be overriden by user supplied options
104 push @newoptions, "-builddir", "$build_dir" if ($build_dir);
105 push @newoptions, "-outhandle", "$outhandle" if ($outhandle);
106 push @newoptions, "-verbosity", "2";
107
108 # backwards compatability hack: if the classifier options are
109 # in "x=y" format, convert them to parsearg ("-x y") format.
110 my ($opt, $key, $value);
111 foreach $opt (@$classifyoption) {
112 # if ($opt =~ /^(\w+)=(.*)$/) {
113 # push @newoptions, "-$1", $2;
114 # } else {
115 push @newoptions, $opt;
116 #}
117 }
118
119 map { $_ = "\"$_\""; } @newoptions;
120 my $options .= join (",", @newoptions);
121
122
123 eval ("\$classobj = new \$classname([],[$options])");
124 die "$@" if $@;
125
126 $classobj->set_number($classify_number);
127 $classify_number ++;
128
129 # add this object to the list
130 push (@classify_objects, $classobj);
131 }
132
133 my ($classobj);
134 eval ("\$classobj = new AllList()");
135 die "$@" if $@;
136 push (@classify_objects, $classobj);
137
138 return \@classify_objects;
139}
140
141# init_classifiers resets all the classifiers and readys them to process
142# the documents.
143sub init_classifiers {
144 my ($classifiers) = @_;
145
146 foreach my $classobj (@$classifiers) {
147 $classobj->init();
148 }
149}
150
151
152
153# takes a hashref containing the metadata for an infodb entry, and extracts
154# the childrens numbers (from the 'contains' entry).
155# assumes format is ".1;".2;".3
156sub get_children {
157 my ($doc_db_hash) = @_;
158
159 my $children = undef;
160
161 my $contains = $doc_db_hash->{'contains'};
162 if (defined ($contains)) {
163 $contains =~ s/\@$//; #remove trailing @
164 $contains =~ s/^\"\.//; #remove initial ".
165 @$children = split /\;\"\./, $contains;
166 }
167
168 return $children;
169}
170
171
172sub recurse_sections {
173 my ($doc_obj, $children, $parentoid, $parentsection, $database_recs) = @_;
174
175 return if (!defined $children);
176
177 foreach my $child (sort { $a <=> $b} @$children) {
178 $doc_obj->create_named_section("$parentsection.$child");
179 my $doc_db_rec = $database_recs->{"$parentoid.$child"};
180 my $doc_db_hash = db_rec_to_hash($doc_db_rec);
181
182 # get child's children
183 my $newchildren = &get_children($doc_db_hash);
184
185 # add content for current section
186 add_section_content($doc_obj, "$parentsection.$child", $doc_db_hash);
187
188 # process all the children if there are any
189 if (defined ($newchildren))
190 {
191 recurse_sections($doc_obj, $newchildren, "$parentoid.$child",
192 "$parentsection.$child", $database_recs);
193 }
194 }
195}
196
197
198sub add_section_content {
199 my ($doc_obj, $cursection, $doc_db_hash) = @_;
200
201 foreach my $key (keys %$doc_db_hash) {
202 #don't need to store these metadata
203 next if $key =~ /(thistype|childtype|contains|docnum|doctype|classifytype)/i;
204 # but do want things like hastxt and archivedir
205 my @items = split /@/, $doc_db_hash->{$key};
206 # metadata is all from gdbm so should already be in utf8
207 map {$doc_obj->add_utf8_metadata ($cursection, $key, $_); } @items;
208
209 }
210}
211
212
213# gets all the metadata from an infodb entry, and puts it into a hashref
214sub db_rec_to_hash {
215
216 my ($gdb_str_ref) = @_;
217
218 my $hashref = {};
219
220 my @entries = split(/\n/, $gdb_str_ref);
221 foreach my $entry (@entries) {
222 my($key, $value) = ($entry =~ /^<([^>]*)>(.*?)$/ );
223 $hashref->{$key} .= '@' if defined $hashref->{$key};
224 $hashref->{$key} .= $value;
225
226 }
227
228 return $hashref;
229}
230
231
232sub reconstruct_doc_objs_metadata
233{
234 my $infodb_type = shift(@_);
235 my $infodb_file_path = shift(@_);
236
237 my %database_recs;
238 &dbutil::read_infodb_file($infodb_type, $infodb_file_path, \%database_recs);
239
240 # dig out top level doc sections
241 my %top_sections = ();
242 my %top_docnums = ();
243 foreach my $key ( keys %database_recs )
244 {
245 my $md_rec = $database_recs{$key};
246 my $md_hash = db_rec_to_hash($md_rec);
247
248 if ((defined $md_hash->{'doctype'}) && ($md_hash->{'doctype'} eq "doc")) {
249 next if ($key =~ m/\./);
250 $top_sections{$key} = $md_hash;
251 $top_docnums{$key} = $md_hash->{'docnum'};
252 }
253 }
254
255 # for greenstone document objects based on metadata in database file
256 my @all_docs = ();
257 # we need to make sure the documents were processed in the same order as
258 # before, so sort based on their docnums
259 foreach my $oid ( sort { $top_docnums{$a} <=> $top_docnums{$b} } keys %top_sections )
260 {
261 my $doc_db_hash = $top_sections{$oid};
262
263 my $doc_obj = new doc();
264 $doc_obj->set_OID($oid);
265 my $top = $doc_obj->get_top_section();
266 add_section_content ($doc_obj, $top, $doc_db_hash);
267 my $children = &get_children($doc_db_hash);
268 recurse_sections($doc_obj, $children, $oid, $top, \%database_recs);
269
270 push(@all_docs,$doc_obj);
271 }
272
273 return \@all_docs;
274}
275
276
277
278
279
280# classify_doc lets each of the classifiers classify a document
281sub classify_doc {
282 my ($classifiers, $doc_obj, $edit_mode) = @_;
283
284 foreach my $classobj (@$classifiers) {
285 my $title = $classobj->{'title'};
286 $classobj->classify($doc_obj,$edit_mode);
287 }
288}
289
290
291our $next_classify_num = 1;
292
293# output_classify_info outputs all the info needed for the classification
294# to the database
295sub output_classify_info
296{
297 my ($classifiers, $infodb_type, $infodb_handle, $remove_empty_classifications, $gli) = @_;
298
299 $gli = 0 unless defined $gli;
300
301 # create a classification containing all the info
302 my $classifyinfo = { 'classifyOID'=> 'browse',
303 'contains' => [] };
304
305 # get each of the classifications
306 foreach my $classifier (@$classifiers)
307 {
308 my $classifier_info = $classifier->get_classify_info($gli);
309 $classifier_info->{'classifyOID'} = "CL$next_classify_num" unless defined($classifier_info->{'classifyOID'});
310 print STDERR "*** outputting information for classifier: $classifier_info->{'classifyOID'}\n";
311
312 push(@{$classifyinfo->{'contains'}}, $classifier_info);
313 $next_classify_num++;
314 }
315
316 &print_classify_info($infodb_type, $infodb_handle, $classifyinfo, "", $remove_empty_classifications);
317}
318
319
320sub print_classify_info
321{
322 my ($infodb_type, $infodb_handle, $classifyinfo, $OID, $remove_empty_classifications) = @_;
323
324 $OID =~ s/^\.+//; # just for good luck
325
326 # book information is printed elsewhere
327 return if (defined ($classifyinfo->{'OID'}));
328
329 # don't want empty classifications
330 return if (&check_contents ($classifyinfo, $remove_empty_classifications) == 0 && $remove_empty_classifications);
331
332 $OID = $classifyinfo->{'classifyOID'} if defined ($classifyinfo->{'classifyOID'});
333
334 my %classify_infodb = ();
335 $classify_infodb{"doctype"} = [ "classify" ];
336 $classify_infodb{"hastxt"} = [ "0" ];
337 $classify_infodb{"childtype"} = [ $classifyinfo->{'childtype'} ]
338 if defined $classifyinfo->{'childtype'};
339 $classify_infodb{"Title"} = [ $classifyinfo->{'Title'} ]
340 if defined $classifyinfo->{'Title'};
341 $classify_infodb{"numleafdocs"} = [ $classifyinfo->{'numleafdocs'} ]
342 if defined $classifyinfo->{'numleafdocs'};
343 $classify_infodb{"thistype"} = [ $classifyinfo->{'thistype'} ]
344 if defined $classifyinfo->{'thistype'};
345 $classify_infodb{"parameters"} = [ $classifyinfo->{'parameters'} ]
346 if defined $classifyinfo->{'parameters'};
347 $classify_infodb{"supportsmemberof"} = [ $classifyinfo->{'supportsmemberof'} ]
348 if defined $classifyinfo->{'supportsmemberof'};
349
350 my $contains_text = "";
351 my $mdoffset_text = "";
352
353 my $next_subOID = 1;
354 my $first = 1;
355 foreach my $tempinfo (@{$classifyinfo->{'contains'}}) {
356 # empty contents were made undefined by clean_contents()
357 next unless defined $tempinfo;
358
359 if (!defined ($tempinfo->{'classifyOID'}) ||
360 $tempinfo->{'classifyOID'} ne "oai") {
361 $contains_text .= ";" unless $first;
362 }
363 $mdoffset_text .= ";" unless $first;
364 $first = 0;
365
366 if (defined ($tempinfo->{'classifyOID'}))
367 {
368 if ($tempinfo->{'classifyOID'} ne "oai")
369 {
370 $contains_text .= $tempinfo->{'classifyOID'};
371 }
372
373 &print_classify_info ($infodb_type, $infodb_handle, $tempinfo, $tempinfo->{'classifyOID'},
374 $remove_empty_classifications);
375 }
376 elsif (defined ($tempinfo->{'OID'}))
377 {
378 $contains_text .= $tempinfo->{'OID'};
379 $mdoffset_text .= $tempinfo->{'offset'} if (defined ($tempinfo->{'offset'}));
380 }
381 else
382 {
383 # Supress having top-level node in Collage classifier
384 # so no bookshelf icon appears, top-level, along with the
385 # applet
386 if (!defined ($tempinfo->{'Title'}) || $tempinfo->{'Title'} ne "Collage")
387 {
388 $contains_text .= "\".$next_subOID";
389 }
390
391 &print_classify_info ($infodb_type, $infodb_handle, $tempinfo, "$OID.$next_subOID",
392 $remove_empty_classifications);
393 $next_subOID++;
394 }
395 }
396
397 $classify_infodb{"contains"} = [ $contains_text ];
398 $classify_infodb{"mdtype"} = [ $classifyinfo->{'mdtype'} ]
399 if defined $classifyinfo->{'mdtype'};
400 $classify_infodb{"mdoffset"} = [ $mdoffset_text ]
401 if ($mdoffset_text !~ m/^;+$/);
402
403 &dbutil::write_infodb_entry($infodb_type, $infodb_handle, $OID, \%classify_infodb);
404}
405
406
407sub check_contents {
408 my ($classifyinfo,$remove_empty_classifications) = @_;
409 $remove_empty_classifications = 0 unless ($remove_empty_classifications);
410 my $num_leaf_docs = 0;
411 my $sub_num_leaf_docs = 0;
412
413 return $classifyinfo->{'numleafdocs'} if (defined $classifyinfo->{'numleafdocs'});
414
415 foreach my $content (@{$classifyinfo->{'contains'}}) {
416 if (defined $content->{'OID'}) {
417 # found a book
418 $num_leaf_docs ++;
419 } elsif (($sub_num_leaf_docs = &check_contents ($content,$remove_empty_classifications)) > 0) {
420 # there's a book somewhere below
421 $num_leaf_docs += $sub_num_leaf_docs;
422 } else {
423 if ($remove_empty_classifications){
424 # section contains no books so we want to remove
425 # it from its parents contents
426 $content = undef;
427 }
428 }
429 }
430
431 $classifyinfo->{'numleafdocs'} = $num_leaf_docs;
432 return $num_leaf_docs;
433}
434
4351;
Note: See TracBrowser for help on using the repository browser.