source: gsdl/trunk/perllib/dbutil.pm@ 15725

###########################################################################
#
# dbutil.pm -- utility functions for writing to different databases
# Copyright (C) 2008  DL Consulting Ltd
#
# A component of the Greenstone digital library software
# from the New Zealand Digital Library Project at the 
# University of Waikato, New Zealand.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
###########################################################################

package dbutil;

use strict;


sub get_infodb_file_path
{
    my $infodb_type = shift(@_);
    my $collection_name = shift(@_);
    my $infodb_directory_path = shift(@_);

    if ($infodb_type eq "sqlite")
    {
    return &get_infodb_file_path_sqlite($collection_name, $infodb_directory_path);
    }

    # Use GDBM if the infodb type is empty or not one of the values above
    return &get_infodb_file_path_gdbm($collection_name, $infodb_directory_path);
}


sub open_infodb_write_handle
{
    my $infodb_type = shift(@_);
    my $infodb_file_path = shift(@_);

    if ($infodb_type eq "sqlite")
    {
    return &open_infodb_write_handle_sqlite($infodb_file_path);
    }

    # Use GDBM if the infodb type is empty or not one of the values above
    return &open_infodb_write_handle_gdbm($infodb_file_path);
}


sub read_infodb_file
{
    my $infodb_type = shift(@_);
    my $infodb_file_path = shift(@_);
    my $infodb_map = shift(@_);

    &read_infodb_file_gdbm($infodb_file_path, $infodb_map);
}


sub write_infodb_entry
{
    my $infodb_type = shift(@_);
    my $infodb_handle = shift(@_);
    my $infodb_key = shift(@_);
    my $infodb_map = shift(@_);

    if ($infodb_type eq "sqlite")
    {
    return &write_infodb_entry_sqlite($infodb_handle, $infodb_key, $infodb_map);
    }

    # Use GDBM if the infodb type is empty or not one of the values above
    return &write_infodb_entry_gdbm($infodb_handle, $infodb_key, $infodb_map);
}



# ----------------------------------------------------------------------------------------
#   GDBM FUNCTIONS
# ----------------------------------------------------------------------------------------

sub get_infodb_file_path_gdbm
{
    my $collection_name = shift(@_);
    my $infodb_directory_path = shift(@_);

    my $infodb_file_extension = (&util::is_little_endian() ? ".ldb" : ".bdb");
    my $infodb_file_name = &util::get_dirsep_tail($collection_name) . $infodb_file_extension;
    return &util::filename_cat($infodb_directory_path, $infodb_file_name);
}


sub open_infodb_write_handle_gdbm
{
    my $infodb_file_path = shift(@_);

    my $txt2db_exe = &util::filename_cat("$ENV{'GSDLHOME'}/bin/$ENV{'GSDLOS'}", "txt2db" . &util::get_os_exe());
    my $infodb_file_handle = undef;
    if (!-e "$txt2db_exe" || !open($infodb_file_handle, "| $txt2db_exe \"$infodb_file_path\""))
    {
    return undef;
    }

    return $infodb_file_handle;
}


sub read_infodb_file_gdbm
{
    my $infodb_file_path = shift(@_);
    my $infodb_map = shift(@_);

    open (PIPEIN, "db2txt \"$infodb_file_path\" |") || die "couldn't open pipe from db2txt\n";
    my $infodb_line = "";
    my $infodb_key = "";
    my $infodb_value = "";
    while (defined ($infodb_line = <PIPEIN>))
    {
    if ($infodb_line =~ /^\[([^\]]+)\]$/)
    {
        $infodb_key = $1;
    }
    elsif ($infodb_line =~ /^-{70}$/)
    {
        $infodb_map->{$infodb_key} = $infodb_value;
        $infodb_key = "";
        $infodb_value = "";
    }
    else
    {
        $infodb_value .= $infodb_line;
    }
    }

    close (PIPEIN);
}

    
sub write_infodb_entry_gdbm
{
    my $infodb_handle = shift(@_);
    my $infodb_key = shift(@_);
    my $infodb_map = shift(@_);

    print $infodb_handle "[$infodb_key]\n";
    foreach my $infodb_value_key (keys(%$infodb_map))
    {
    foreach my $infodb_value (@{$infodb_map->{$infodb_value_key}})
    {
        if ($infodb_value =~ /-{70,}/)
        {
        # if value contains 70 or more hyphens in a row we need to escape them
        # to prevent txt2db from treating them as a separator
        $infodb_value =~ s/-/&\#045;/gi;
        }
        print $infodb_handle "<$infodb_value_key>" . $infodb_value . "\n";
    }
    }
    print $infodb_handle '-' x 70, "\n";
}



# ----------------------------------------------------------------------------------------
#   SQLITE FUNCTIONS
# ----------------------------------------------------------------------------------------

sub get_infodb_file_path_sqlite
{
    my $collection_name = shift(@_);
    my $infodb_directory_path = shift(@_);

    my $infodb_file_extension = ".db";
    my $infodb_file_name = &util::get_dirsep_tail($collection_name) . $infodb_file_extension;
    return &util::filename_cat($infodb_directory_path, $infodb_file_name);
}


sub open_infodb_write_handle_sqlite
{
    my $infodb_file_path = shift(@_);

    my $sqlite3_exe = &util::filename_cat("$ENV{'GSDLHOME'}/bin/$ENV{'GSDLOS'}", "sqlite3" . &util::get_os_exe());
    my $infodb_file_handle = undef;
    if (!-e "$sqlite3_exe" || !open($infodb_file_handle, "| $sqlite3_exe \"$infodb_file_path\""))
    {
    return undef;
    }

    print $infodb_file_handle "CREATE TABLE data (key TEXT, value TEXT, PRIMARY KEY(key));\n";

    return $infodb_file_handle;
}


sub write_infodb_entry_sqlite
{
    my $infodb_handle = shift(@_);
    my $infodb_key = shift(@_);
    my $infodb_map = shift(@_);

    my $infodb_entry_value = "";
    foreach my $infodb_value_key (keys(%$infodb_map))
    {
    foreach my $infodb_value (@{$infodb_map->{$infodb_value_key}})
    {
        $infodb_entry_value .= "<$infodb_value_key>" . $infodb_value . "\n";
    }
    }

    # Escape any single quotes in the value
    $infodb_entry_value =~ s/\'/\'\'/g;

    print $infodb_handle "DELETE FROM data WHERE key='" . $infodb_key . "';\n";
    print $infodb_handle "INSERT INTO data (key, value) VALUES ('" . $infodb_key . "', '" . $infodb_entry_value . "');\n";
}


1;