@echo off
set GLILANG=en


::  -------- Generate documentation for the Greenstone Librarian Interface --------

:: This script must be run from within the directory in which it lives
if exist document.bat goto findJavadoc
    if "%GLILANG%" == "en" echo This script must be run from the directory in which it resides.
    if "%GLILANG%" == "es" echo Este guiвn deberа ejecutarse desde el directorio en el que reside.
    if "%GLILANG%" == "fr" echo Ce script doit Иtre exВcutВ Е partir du rВpertoire dans lequel il se trouve.
    if "%GLILANG%" == "ru" echo Этот скрипт должен быть взят из директории, в которой он расположен
    goto exit


:findJavadoc
:: ---- Check Javadoc exists ----
set JAVADOCPATH=

:: Some users may set the above line manually
if not "%JAVADOCPATH%" == "" goto testJavadoc

    :: If it is set, use the JAVA_HOME environment variable
    if not "%JAVA_HOME%" == "" goto javahome

    :: Check if Javadoc is on the search path
    echo %PATH%| winutil\which javadoc.exe | winutil\setvar JAVADOCPATH > setjavadoc.bat
    call setjavadoc.bat
    del setjavadoc.bat
    if not "%JAVADOCPATH%" == "" goto testJavadoc

    :: Still haven't found anything, so try looking in the registry (gulp!)
    type nul > jdk.reg
    regedit /E jdk.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit"
    type jdk.reg > jdk.txt
    del jdk.reg

    winutil\findjava jdk.txt | winutil\setvar JAVADOCPATH > setjavadoc.bat
    del jdk.txt
    call setjavadoc.bat
    del setjavadoc.bat

    :: If nothing was found in the registry, we're stuck
    if "%JAVADOCPATH%" == "" goto noJavadoc

    set JAVADOCPATH=%JAVADOCPATH%\bin
    goto testJavadoc

:javahome
    set JAVADOCPATH=%JAVA_HOME%\bin

:testJavadoc
:: Check that a Javadoc executable has been found
if "%GLILANG%" == "en" echo Checking Javadoc: %JAVADOCPATH%
if "%GLILANG%" == "es" echo Revisando Javadoc: %JAVADOCPATH%
if "%GLILANG%" == "fr" echo VВrification de Javadoc: %JAVADOCPATH%
if "%GLILANG%" == "ru" echo Проверка Javadoc: %JAVADOCPATH%
if exist "%JAVADOCPATH%\javadoc.exe" goto docGLI

:noJavadoc
    echo.
    if "%GLILANG%" == "en" echo Failed to locate an appropriate version of Javadoc. You must install a
    if "%GLILANG%" == "en" echo Java Development Kit (version 1.4 or greater) before generating the
    if "%GLILANG%" == "en" echo documentation for the Greenstone Librarian Interface.

    if "%GLILANG%" == "es" echo No se pudo localizar una versiвn apropiada de Javadoc. Usted deberа
    if "%GLILANG%" == "es" echo instalar un Kit de Desarrollo de Software Java (versiвn 1.4 o superior)
    if "%GLILANG%" == "es" echo antes de generar la documentaciвn para la Interfaz de la Biblioteca
    if "%GLILANG%" == "es" echo Digital Greenstone.

    if "%GLILANG%" == "fr" echo Une version appropriВe de Javadoc n'a pas pu Иtre localisВe. Vous devez
    if "%GLILANG%" == "fr" echo installer un Kit de DВveloppement Java (version 1.4 ou supВrieure) avant
    if "%GLILANG%" == "fr" echo de produire la documentation de Greenstone Librarian Interface.

    if "%GLILANG%" == "ru" echo Не удалось определить местонахождение соответствующей версии Javadoc.
    if "%GLILANG%" == "ru" echo Вы должны инсталлировать Java Development Kit (версия 1.4 или выше)
    if "%GLILANG%" == "ru" echo прежде, чем генерировать документацию для библиотечного
    if "%GLILANG%" == "ru" echo интерфейса Greenstone.
    goto exit


:docGLI
:: ---- Document the GLI ----
echo.
if "%GLILANG%" == "en" echo Generating documentation for the Greenstone Librarian Interface...
if "%GLILANG%" == "es" echo Generando documentaciвn para la Interfaz de la Biblioteca Digital Greenstone...
if "%GLILANG%" == "fr" echo Production de documentation pour la Greenstone Librarian Interface
if "%GLILANG%" == "ru" echo Генерирование документации для библиотечного интерфейса Greenstone

"%JAVADOCPATH%\javadoc.exe" -classpath classes/ -sourcepath src/ -source 1.4 -author -breakiterator -d docs/ -group "Gatherer v2.3" org.greenstone.gatherer:org.greenstone.gatherer.checklist:org.greenstone.gatherer.collection:org.greenstone.gatherer.feedback:org.greenstone.gatherer.file:org.greenstone.gatherer.gui:org.greenstone.gatherer.gui.browser:org.greenstone.gatherer.gui.combobox:org.greenstone.gatherer.gui.messages:org.greenstone.gatherer.gui.metaaudit:org.greenstone.gatherer.gui.table:org.greenstone.gatherer.gui.tree:org.greenstone.gatherer.help:org.greenstone.gatherer.sarm:org.greenstone.gatherer.shell:org.greenstone.gatherer.util -group "Collection Design Module" org.greenstone.gatherer.cdm:org.greenstone.gatherer.cdm.custom -group "Metadata Set Manager" org.greenstone.gatherer.msm:org.greenstone.gatherer.msm.parsers -group "Value Tree Controls" org.greenstone.gatherer.valuetree -private -splitindex -version   org.greenstone.gatherer org.greenstone.gatherer.checklist org.greenstone.gatherer.collection org.greenstone.gatherer.feedback org.greenstone.gatherer.file org.greenstone.gatherer.gui org.greenstone.gatherer.gui.browser org.greenstone.gatherer.gui.combobox org.greenstone.gatherer.gui.messages org.greenstone.gatherer.gui.metaaudit org.greenstone.gatherer.gui.table org.greenstone.gatherer.gui.tree org.greenstone.gatherer.help org.greenstone.gatherer.sarm org.greenstone.gatherer.shell org.greenstone.gatherer.util org.greenstone.gatherer.cdm org.greenstone.gatherer.cdm.custom org.greenstone.gatherer.msm org.greenstone.gatherer.msm.parsers org.greenstone.gatherer.valuetree 

if "%GLILANG%" == "en" echo Done!
if "%GLILANG%" == "es" echo нHecho!
if "%GLILANG%" == "fr" echo TerminВ!
if "%GLILANG%" == "ru" echo Выполнено!

:exit
echo.
pause

:: ---- Clean up ----
set JAVADOCPATH=