source: main/trunk/gli/makejar.bat@ 24768

echo off
pushd "%CD%"
CD /D "%~dp0"
set GLILANG=en

:: This script must be run from within the directory in which it lives
if exist makejar.bat goto findJar
    if "%GLILANG%" == "en" echo This script must be run from the directory in which it resides.
    if "%GLILANG%" == "es" echo Este gui¢n deber  ejecutarse desde el directorio en el que reside.
    if "%GLILANG%" == "fr" echo Ce script doit ˆtre ex‚cut‚ …
 partir du r‚pertoire dans lequel il se trouve.
    if "%GLILANG%" == "ru" echo â®â áªàš¯â €®«Š¥­ ¡ëâì ¢§ïâ š§ €šà¥ªâ®àšš, ¢ ª®â®à®© ®­ à ᯮ«®Š¥­
    goto exit




:findJar
:: ---- Check jar exists ----
set JARPATH=

:: Some users may set the above line manually
if not "%JARPATH%" == "" goto testJar

    :: If it is set, use the JAVA_HOME environment variable
    if not "%JAVA_HOME%" == "" goto javahome

    :: Check if jar is on the search path
    echo %PATH%| winutil\which.exe jar.exe | winutil\setvar.exe JARPATH > setjar.bat
    call setjar.bat
    del setjar.bat
    if not "%JARPATH%" == "" goto testJar

    :: Still haven't found anything, so try looking in the registry (gulp!)
    type nul > jdk.reg
    regedit /E jdk.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit"
    type jdk.reg > jdk.txt
    del jdk.reg

    winutil\findjava.exe jdk.txt | winutil\setvar.exe JARPATH > setjar.bat
    del jdk.txt
    call setjar.bat
    del setjar.bat

    :: If nothing was found in the registry, we're stuck
    if "%JARPATH%" == "" goto noJar

    set JARPATH=%JARPATH%\bin
    goto testJar

:javahome
    set JARPATH=%JAVA_HOME%\bin

:testJar
:: Check that a jar executable has been found
if "%GLILANG%" == "en" echo Checking jar: %JARPATH%
if "%GLILANG%" == "es" echo Revisando jar: %JARPATH%
if "%GLILANG%" == "fr" echo V‚rification de jar: %JARPATH%
if "%GLILANG%" == "ru" echo à®¢¥àª  jar: %JARPATH%
if exist "%JARPATH%\jar.exe" goto checkCompile

:noJar
    echo.
    if "%GLILANG%" == "en" echo Failed to locate an appropriate version of jar. You must install a
    if "%GLILANG%" == "en" echo Java Development Kit (version 1.4 or greater) before compiling the
    if "%GLILANG%" == "en" echo Greenstone Librarian Interface.

    if "%GLILANG%" == "es" echo No se pudo localizar una versi¢n apropiada de jar. Usted deber 
    if "%GLILANG%" == "es" echo instalar un Kit de Desarrollo de Software Java (versi¢n 1.4 o superior)
    if "%GLILANG%" == "es" echo antes de generar la documentaci¢n para la Interfaz de la Biblioteca
    if "%GLILANG%" == "es" echo Digital Greenstone.

    if "%GLILANG%" == "fr" echo Une version appropri‚e de jar n'a pas pu ˆtre localis‚e. Vous devez
    if "%GLILANG%" == "fr" echo installer un Kit de D‚veloppement Java (version 1.4 ou sup‚rieure) 
    if "%GLILANG%" == "fr" echo avant de produire la documentation de Greenstone Librarian Interface.

    if "%GLILANG%" == "ru" echo ¥ 〠«®áì ®¯à¥€¥«šâì ¬¥áâ®­ 宊€¥­š¥ ᮮ⢥âáâ¢ãî饩 ¢¥àášš jar.
    if "%GLILANG%" == "ru" echo ‚ë €®«Š­ë š­áâ ««šà®¢ âì Java Development Kit (¢¥àášï 1.4 š«š ¢ëè¥)
    if "%GLILANG%" == "ru" echo ¯à¥Š€¥, 祬 £¥­¥àšà®¢ âì €®ªã¬¥­â æšî €«ï ¡š¡«š®â¥ç­®£®
    if "%GLILANG%" == "ru" echo š­â¥àä¥©á  Greenstone.
    goto exit



:checkCompile
:: Check that the GLI has been compiled 
if exist classes\org\greenstone\gatherer\GathererProg.class goto makeJar
    if "%GLILANG%" == "es"  (
    echo Usted necesita compilar la Interfaz de la Biblioteca Digital Greenstone
    echo ^(por medio de makegli.sh^) antes de ejecutar este guión.
    )
    if "%GLILANG%" == "fr" (
    echo Vous devez compiler le Greenstone Interface ^(en utilisant makegli.sh^)
    echo avant d'exécuter ce script.
    )
    if "%GLILANG%" == "ru" (
    echo ÷Ù ÄÏÌÖÎÙ ËÏÍÐÉÌÉÒÏ×ÁÔØ ÂÉÂÌÉÏÔÅÞÎÙÊ ÉÎÔÅÒÆÅÊÓ Greenstone
    echo ^(ÉÓÐÏÌØÚÕÑ makegli.sh^) ÐÅÒÅÄ ××ÏÄÏÍ ÜÔÏÇÏ ÓËÒÉÐÔÁ
    )
    if "%GLILANG%" == "en" (
    echo You need to compile the Greenstone Librarian Interface ^(using makegli.sh^)
    echo before running this script.
    )
    goto exit
fi


:makeJar
:: All the GLI class files and supporting libraries are put into the "jar" directory.
:: Running programs (or commands) with start /wait will wait for each program in turn to finish.
:: This is needed when unjarring org (com and de) pkgs below, else it doesn't exist upon moving.
:: We still need to give it a couple of seconds, so adding in the 1 second ping call for this.
:: See http://www.computerhope.com/forum/index.php?topic=83771.0 and
:: http://stackoverflow.com/questions/4317020/windows-batch-sleep
echo Assuming that Java code is freshly compiled...

if NOT exist jar (
  mkdir jar

  cd lib
  start "" /wait /b "%JARPATH%\jar" xf apache.jar com 
  start "" /wait /b "%JARPATH%\jar" xf apache.jar org
  start "" /wait /b "%JARPATH%\jar" xf qfslib.jar de
  PING -n 2 127.0.0.1>nul 
  
  move com ..\jar\com     >NUL
  move de ..\jar\de       >NUL
  move org ..\jar\org     >NUL

  cd ..
)

:: Copy the latest version of the GLI classes into the jar directory
if exist jar\org\greenstone (
  rmdir /q /s jar\org\greenstone
)
xcopy /i /e /q classes\org\greenstone jar\org\greenstone

:: Some of the things to go into the JAR file are optional, and may not exist
set optional=
if exist collect.zip (
    set optional=%optional% collect.zip
)

:: Recreate the metadata.zip file (contains the GLI metadata directory)
if exist metadata.zip (
  del /f metadata.zip
)
winutil\zip.exe -r metadata.zip metadata >NUL

:: Jar everything up
"%JARPATH%\jar" cf GLI.jar .java.policy metadata.zip %optional% help -C classes dictionary.properties -C classes dictionary_es.properties -C classes dictionary_fr.properties -C classes dictionary_ru.properties -C classes feedback.properties -C classes images -C classes xml -C jar com -C jar de -C jar org

:: Tidy up
del /f metadata.zip

:: Generate the GLIServer.jar file for remote building
"%JARPATH%\jar" cf GLIServer.jar -C classes org/greenstone/gatherer/remote

:: ---- Make signed JAR file for the applet, if desired ----
if  (%1) == (-sign) (

    if not exist appletstore (
      "%JARPATH%\keytool" -genkey -alias privateKey -keystore appletstore -storepass greenstone
    )

    if exist SignedGatherer.jar del /f SignedGatherer.jar
    if exist appletpasswd (
      echo Using jarsigner to make signed jar file ...
      "%JARPATH%\jarsigner" -keystore appletstore -signedjar SignedGatherer.jar GLI.jar privateKey < appletpasswd >NUL 2>NUL
      echo ... done.
    ) ELSE (
      "%JARPATH%\jarsigner" -keystore appletstore -signedjar SignedGatherer.jar GLI.jar privateKey
    )
    echo Installing SignedGatherer in ..\bin\java
    move SignedGatherer.jar ..\bin\java\SignedGatherer.jar
)
:exit

popd