source: main/trunk/greenstone2/cgi-bin/talkback-transfer.pl@ 23145

#!/usr/bin/perl -w

use strict;

use LWP::UserAgent;
use HTTP::Request::Common;

use CGI::Carp qw(fatalsToBrowser); 
use CGI; 

eval('require "./gsdlCGI.pm"');
if ($@)
{
    print STDOUT "Content-type:text/plain\n\n";
    print STDOUT "ERROR: $@\n";
    exit 0;
}


sub get_infodb_type
{
    my ($opt_site,$collect_home,$collect) = @_;

    my $out = "STDERR";

    $collect = &colcfg::use_collection($opt_site, $collect, $collect_home);

    if ($collect eq "") {
    print STDERR "Error: failed to find collection $collect in $collect_home\n";
    print STDOUT "Content-type:text/plain\n\n";
    print STDOUT "ERROR: Failed to find collection $collect\n";
    exit 0;
    
    }

    # Read in the collection configuration file.
    my ($config_filename, $gs_mode) = &colcfg::get_collect_cfg_name($out);
    my $collectcfg = &colcfg::read_collection_cfg ($config_filename, $gs_mode);

    return $collectcfg->{'infodbtype'};
}


sub oid_to_docxml_filename
{
    my ($opt_site,$collect_home,$collect,$docid) = @_;

    my $infodb_type = get_infodb_type($opt_site,$collect_home,$collect);

    # Obtain the collect and archives dir    
    my $archives_dir = &util::filename_cat($collect_home,$collect,"archives");

    # Obtain the doc.xml path for the specified docID
    my $arcinfo_doc_filename 
    = &dbutil::get_infodb_file_path($infodb_type, "archiveinf-doc", 
                    $archives_dir);
    my $doc_rec_string 
    = &dbutil::read_infodb_entry($infodb_type, $arcinfo_doc_filename, 
                     $docid);
    my $doc_rec = &dbutil::convert_infodb_string_to_hash($doc_rec_string);    
    my $doc_xml_file = $doc_rec->{'doc-file'}->[0];
    
    # The $doc_xml_file is relative to the archives, so now let's get the 
    # full path
    my $doc_xml_filename = &util::filename_cat($archives_dir,$doc_xml_file);

    return $doc_xml_filename;
}

sub main
{
    # Setup greenstone Perl include paths so additional packages can be found
    my $gsdl_cgi = gsdlCGI->new(); 
    $gsdl_cgi->setup_gsdl();

    my $gsdl_home = $gsdl_cgi->get_gsdl_home();
    my $collect_home = &util::filename_cat($gsdl_home,"collect");

    require dbutil;
    require talkback;
    require colcfg;

    my $oid     = $gsdl_cgi->param('oid');
    my $collect = $gsdl_cgi->param('collect');
    my $site    = $gsdl_cgi->param('site');

    # sanity check
    if (!defined $oid || !defined $collect) {
    print STDOUT "Content-type:text/plain\n\n";
    print STDOUT "ERROR: Malformed CGI argments.  Need to specify 'oid' and 'collect'\n";
    exit 0;
    }

    my $uniq_prefix = "$collect-$oid";

    my $docxml_filename = oid_to_docxml_filename($site,$collect_home,$collect,$oid);

    my $talktoUploadURL = $gsdl_cgi->param('talktoUpload');

    my $browser = LWP::UserAgent->new(agent => 'Perl File Upload');

    my $response = $browser->post(
       $talktoUploadURL,
       [ 'yes_upload'   => '1',
         'process'      => '1',
         'oid'          => $oid,
         'collect'      => $collect,
         'uploadedfile' => [$docxml_filename, "$uniq_prefix-doc.xml"] 
         ],
       'Content_Type' => 'form-data'
      );

    if ($response->is_success) {
    print "Content-type:text/html\n\n";
    print $response->content;
    }
    else {
    print $response->error_as_HTML;
    }

}

main();