source: main/trunk/greenstone2/common-src/indexers/lucene-gs/winMake.bat@ 24746

@echo off

set LUCENEHOME=.

rem ---- Where to put class files ----
set JAVACLASSDIR=classes
set JAVACLASSDIR3=classes3

rem ---- Name and location of java programs ----
set JAVAC="%JAVA_HOME%\bin\javac"
set JAVAH="%JAVA_HOME%\bin\javah"
set JAVA="%JAVA_HOME%\bin\java"
set JAVADOC="%JAVA_HOME%\bin\javadoc"
set JAR="%JAVA_HOME%\bin\jar"

set JAVACOPTIONS=-deprecation -g -O

set LUCENE_JAR=.\lib\lucene-core-2.3.2.jar
set MYCLASSPATH=%LUCENE_JAR%;%JAVACLASSDIR%

set LUCENE3_JAR=.\lib\lucene-core-3.3.0.jar
set MYCLASSPATH3=%LUCENE3_JAR%;%JAVACLASSDIR3%

if "%DEBUG%" == "" (
  set MAKE_VARS=DEBUG=0
) else (
  set MAKE_VARS=DEBUG=%DEBUG%
)

if ""%1"" == """" goto all
if ""%1"" == ""all"" goto all
if ""%1"" == ""install"" goto install
if ""%1"" == ""clean"" goto clean

:unknown
    echo Error: Unrecognized argument %1.
    goto done

:all
    if not exist %JAVACLASSDIR% mkdir %JAVACLASSDIR%
    echo Compiling Greenstone Lucene version 2.x Java classes ...
    %JAVAC% -d %JAVACLASSDIR% -classpath %MYCLASSPATH% %JAVACOPTIONS% -sourcepath src src\org\greenstone\LuceneWrapper\*.java
    cd %JAVACLASSDIR%
    %JAR% xf ..\%LUCENE_JAR%
    cd ..
    %JAR% cf LuceneWrapper.jar -C %JAVACLASSDIR% .

    if not exist %JAVACLASSDIR3% mkdir %JAVACLASSDIR3%
    echo Compiling Greenstone Lucene version 3.x Java classes ...
    %JAVAC% -d %JAVACLASSDIR3% -classpath %MYCLASSPATH3% %JAVACOPTIONS% -sourcepath src src\org\greenstone\LuceneWrapper3\*.java
    cd %JAVACLASSDIR3%
    %JAR% xf ..\%LUCENE3_JAR%
    cd ..
    %JAR% cf LuceneWrapper3.jar -C %JAVACLASSDIR3% .
    goto done

:install
    goto done

:clean
    echo Cleaning up Greenstone Lucene ...
    if exist %JAVACLASSDIR% rmdir /S /Q %JAVACLASSDIR%
        if exist LuceneWrapper.jar del LuceneWrapper.jar
    if exist %JAVACLASSDIR3% rmdir /S /Q %JAVACLASSDIR3%
        if exist LuceneWrapper3.jar del LuceneWrapper3.jar
    goto done 

:done