root/main/trunk/greenstone2/perllib/gssql.pm @ 32558

Revision 32558, 23.1 KB (checked in by ak19, 10 months ago)

Breadcrumbs on connection and some further helpful messages.

Line 
1###########################################################################
2#
3# gssql.pm -- DBI for SQL related utility functions used by
4# GreenstoneSQLPlugout and hereafter by GreenstoneSQLPlugin too.
5# A component of the Greenstone digital library software
6# from the New Zealand Digital Library Project at the
7# University of Waikato, New Zealand.
8#
9# Copyright (C) 1999 New Zealand Digital Library Project
10#
11# This program is free software; you can redistribute it and/or modify
12# it under the terms of the GNU General Public License as published by
13# the Free Software Foundation; either version 2 of the License, or
14# (at your option) any later version.
15#
16# This program is distributed in the hope that it will be useful,
17# but WITHOUT ANY WARRANTY; without even the implied warranty of
18# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
19# GNU General Public License for more details.
20#
21# You should have received a copy of the GNU General Public License
22# along with this program; if not, write to the Free Software
23# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
24#
25###########################################################################
26
27package gssql;
28
29use strict;
30no strict 'refs';
31no strict 'subs';
32
33use DBI; # the central package for this module used by GreenstoneSQL Plugout and Plugin
34
35# Need params_map keys:
36# - collection_name
37# - db_encoding (db content encoding) - MySQL can set this at server, db, table levels. For MySQL
38# we set the enc during connect at server level. Not sure whether other DB's support it at the
39# same levels.
40
41# For connection to MySQL, need:
42#  - db_driver, db_client_user, db_client_pwd, db_host, (db_port not used at present)
43# So these will be parameterised, but in a hashmap, for just the connect method.
44
45# Parameterise (one or more methods may use them):
46# - build_mode (like removeold)
47# - db_name (which is the GS3 sitename)
48
49# TODO: add infrastructure for db_port, AutoCommit etc
50# For port, see https://stackoverflow.com/questions/2248665/perl-script-to-connect-to-mysql-server-port-3307
51
52sub new
53{
54 
55    my $class = shift(@_);
56   
57    my ($params_map) = @_;
58   
59    # library_url: to be specified on the cmdline if not using a GS-included web server
60    # the GSDL_LIBRARY_URL env var is useful when running cmdline buildcol.pl in the linux package manager versions of GS3
61   
62    # https://stackoverflow.com/questions/7083453/copying-a-hashref-in-perl
63    # Making a shallow copy works, and can handle unknown params:
64    #my $self = $params_map;
65
66    # but being explicit for class params needed for MySQL:
67    my $self = {
68    'collection_name' => $params_map->{'collection_name'},
69    'db_encoding' => $params_map->{'db_encoding'}
70    };
71
72    # (My)SQL doesn't like tables with - (hyphens) in their names
73    my $coll_name = $params_map->{'collection_name'};
74    $coll_name =~ s/-/_/g;
75    $self->{'tablename_prefix'} = $coll_name;
76
77    return bless($self, $class);
78}
79
80
81#################################
82
83# Database access related functions
84# http://g2pc1.bu.edu/~qzpeng/manual/MySQL%20Commands.htm
85# https://www.guru99.com/insert-into.html
86
87# TODO Q: What on cancelling a build: delete table? But what if it was a rebuild and the rebuild is cancelled (not the original build)?
88# Do we create a copy of the orig database as backup, then start populating current db, and if cancelled, delete current db and RENAME backup table to current?
89# https://stackoverflow.com/questions/3280006/duplicating-a-mysql-table-indexes-and-data
90# BUT what if the table is HUGE? (Think of a collection with millions of docs.) Huge overhead in copying?
91# The alternative is we just quit on cancel, but then: cancel could leave the table in a partial committed state, with no way of rolling back.
92# Unless they do a full rebuild, which will recreate the table from scratch?
93# SOLUTION-> rollback transaction on error, see https://www.effectiveperlprogramming.com/2010/07/set-custom-dbi-error-handlers/
94# But then should set AutoCommit to off on connection, and remember to commit every time
95
96#################
97# Database functions that use the perl DBI module (with the DBD driver module for mysql)
98#################
99
100################### BASIC DB OPERATIONS ##################
101
102# THE NEW DB FUNCTIONS
103# NOTE: FULLTEXT is a reserved keyword in (My)SQL. So we can't name a table or any of its columns "fulltext".
104# https://dev.mysql.com/doc/refman/5.5/en/keywords.html
105
106# TODO: Consider AutoCommit status (and Autocommit off allowing commit or rollback for GS coll build cancel) later
107
108# TODO: where should the defaults for these params be, here or in GS-SQLPlugin/Plugout?
109sub connect_to_db {
110    my $self= shift (@_);
111    my ($params_map) = @_;
112    #my $db_enc = $self->{'db_encoding'} || "utf8";
113    my $db_enc = "utf8mb4";
114
115    # these are the params for connecting to MySQL
116    my $db_driver = $params_map->{'db_driver'} || "mysql";
117    my $db_user = $params_map->{'db_client_user'} || "root";
118    my $db_pwd = $params_map->{'db_client_pwd'}; # even if undef, we'll see a sensible error message
119                                           # when connect fails
120    my $db_host = $params_map->{'db_host'} || "127.0.0.1";
121    # localhost doesn't work for us, but 127.0.0.1 works
122    # https://metacpan.org/pod/DBD::mysql
123    # "The hostname, if not specified or specified as '' or 'localhost', will default to a MySQL server
124    # running on the local machine using the default for the UNIX socket. To connect to a MySQL server
125    # on the local machine via TCP, you must specify the loopback IP address (127.0.0.1) as the host."
126    #my $connect_str = "dbi:$db_driver:database=$db_name;host=$db_host";
127    my $connect_str = "dbi:$db_driver:host=$db_host"; # don't provide db - allows checking the db exists later when loading the db
128
129    print STDERR "Away to make connection to $db_driver database with:\n";
130    print STDERR " - hostname $db_host; username: $db_user";
131    print STDERR "; and the password provided" if $db_pwd;
132    print STDERR "Assuming the mysql server has been started with --character_set_server=utf8mb4" if $db_driver eq "mysql";
133   
134    my $dbh = DBI->connect("$connect_str", $db_user, $db_pwd,
135               {
136                   ShowErrorStatement => 1, # more informative as DBI will append failed SQL stmt to error message
137                   PrintError => 1, # on by default, but being explicit
138                   RaiseError => 0, # off by default, but being explicit
139                   AutoCommit => 1, # on by default, but being explicit
140                   mysql_enable_utf8mb4 => 1 # tells MySQL to use UTF-8 for communication and tells DBD::mysql to decode the data, see https://stackoverflow.com/questions/46727362/perl-mysql-utf8mb4-issue-possible-bug
141               });
142
143    if(!$dbh) {
144    # NOTE, despite handle dbh being undefined, error code will be in DBI->err (note caps)
145    return 0;   
146    }
147
148    # set encoding https://metacpan.org/pod/DBD::mysql
149    # https://dev.mysql.com/doc/refman/5.7/en/charset.html
150    # https://dev.mysql.com/doc/refman/5.7/en/charset-conversion.html
151    # Setting the encoding at db server level: $dbh->do("set NAMES '" . $db_enc . "'");
152    # HOWEVER:
153    # It turned out insufficient setting the encoding to utf8, as that only supports utf8 chars that
154    # need up to 3 bytes. We may need up to 4 bytes per utf8 character, e.g. chars with macron,
155    # and for that, we need the encoding to be set to utf8mb4.
156    # To set up a MySQL db to use utf8mb4 requires configuration on the server side too.
157    # https://stackoverflow.com/questions/10957238/incorrect-string-value-when-trying-to-insert-utf-8-into-mysql-via-jdbc
158    # https://stackoverflow.com/questions/46727362/perl-mysql-utf8mb4-issue-possible-bug
159    # To set up the db for utf8mb4, therefore,
160    # the MySQL server needs to be configured for that char encoding by running the server as:
161    # mysql-5.7.23-linux-glibc2.12-x86_64/bin>./mysqld_safe --datadir=/Scratch/ak19/mysql/data --character_set_server=utf8mb4
162    # AND when connecting to the server, we can can either set mysql_enable_utf8mb4 => 1
163    # as a connection option
164    # OR we need to do both "set NAMES utf8mb4" AND "$dbh->{mysql_enable_utf8mb4} = 1;" after connecting
165    #
166    # Search results for DBI Set Names imply the "SET NAMES '<enc>'" command is mysql specific too,
167    # so setting the mysql specific option during connection above as "mysql_enable_utf8mb4 => 1"
168    # is no more objectionable. It has the advantage of cutting out the 2 extra lines of doing
169    # set NAMES '<enc>' and $dbh->{mysql_enable_utf8mb4} = 1 here.
170    # These lines may be preferred if more db_driver options are to be supported in future:
171    # then a separate method called set_db_encoding($enc) can work out what db_driver we're using
172    # and if mysql and enc=utfy, then it can do the following whereas it will issue other do stmts
173    # for other db_drivers, see https://www.perlmonks.org/?node_id=259456:
174   
175    #my $stmt = "set NAMES '" . $db_enc . "'";
176    #$dbh->do($stmt) || warn("Unable to set charset encoding at db server level to: " . $db_enc . "\n"); # tells MySQL to use UTF-8 for communication
177    #$dbh->{mysql_enable_utf8mb4} = 1; # tells DBD::mysql to decode the data
178   
179    # if we're here, then connection succeeded, store handle
180    $self->{'db_handle'} = $dbh;
181    return 1;
182}
183
184# will attempt to load the specified db and the <coll>_metadata and <coll>_fulltxt for this
185# collection, or create any of these (db, tables) that don't yet exist. At the end
186# it will have loaded the requested database (in MySQL: "use <db>;")
187sub load_db_and_tables {
188    my $self= shift (@_);
189    my ($db_name, $build_mode) = @_;
190    my $dbh = $self->{'db_handle'};
191   
192    print STDERR "Attempting to use database $db_name\n";
193   
194    # perl DBI switch database: https://www.perlmonks.org/?node_id=995434
195    # do() returns undef on error.
196    # connection succeeded, try to load our database. If that didn't work, attempt to create db
197    my $success = $dbh->do("use $db_name");
198   
199    if(!$success && $dbh->err == 1049) { # "Unknown database" error has code 1049 (mysql only?) meaning db doesn't exist yet
200
201    print STDERR "Database $db_name didn't exist, creating it and tables for the current collection...\n";
202   
203    # attempt to create the db and its tables
204    $self->create_db($db_name) || return 0;
205
206    print STDERR "   Created database $db_name\n";
207   
208    # once more attempt to use db, now that it exists
209    $dbh->do("use $db_name") || return 0;
210    #$dbh->do("use localsite") or die "Error (code" . $dbh->err ."): " . $dbh->errstr . "\n";
211
212    # attempt to create tables in current db
213    $self->create_metadata_table() || return 0;
214    $self->create_fulltext_table() || return 0;
215
216    $success = 1;
217    }
218    elsif($success) { # database existed and loaded successfully, but
219    # before proceeding check that the current collection's tables exist
220
221    print STDERR "@@@ DATABASE $db_name EXISTED\n";
222   
223
224    # build_mode can be removeold or incremental. We only do something special on removeold:
225    # deleting the existing tables for this collection and recreating empty ones
226    if($build_mode eq "removeold") {
227        print STDERR "   Building with removeold option set, so deleting current collection's tables if they exist\n";
228        $self->delete_collection_tables();
229    }
230
231    # use existing tables if any
232    # attempt to create tables in current db   
233    if($build_mode eq "removeold" || !$self->table_exists($self->get_metadata_table_name())) {
234        $self->create_metadata_table() || return 0;
235    } else {
236        print STDERR "@@@ Meta table exists\n";
237    }
238    if($build_mode eq "removeold" || !$self->table_exists($self->get_fulltext_table_name())) {
239        $self->create_fulltext_table() || return 0;
240    } else {
241        print STDERR "@@@ Fulltxt table exists\n";
242    }
243   
244    }
245   
246    return $success; # could still return 0, if database failed to load with an error code != 1049
247}
248
249# GreenstoneSQLPlugin calls this method to load an existing db.
250# This will terminate if the db does not exist. Unlike load_db_and_tables() above, used by
251# GreenstoneSQLPlugout, this method will not attempt to create the requested db (nor its tables)
252# TODO: GS SQLPlugin is called before GS SQLPlugout and attempts to use_db() - called in plugin's
253# init() method. This will fail if the db does not exist. Ideally want the gssqlplugin only called
254# during buildcol.pl
255sub use_db {
256    my $self= shift (@_);
257    my ($db_name) = @_;
258    my $dbh = $self->{'db_handle'};
259
260    print STDERR "Loading database $db_name\n";
261   
262    # perl DBI switch database: https://www.perlmonks.org/?node_id=995434
263    # do() returns undef on error.
264    # connection succeeded, try to load our database. If that didn't work, attempt to create db
265    return $dbh->do("use $db_name") || warn();
266}
267
268# disconnect from db - https://metacpan.org/pod/DBI#disconnect
269# TODO: make sure to have committed or rolled back before disconnect
270# and that you've call finish() on statement handles if any fetch remnants remain
271sub disconnect_from_db {
272    my $self= shift (@_);   
273    my $dbh = $self->{'db_handle'};
274
275    # make sure any active stmt handles are finished
276    # NO: "When all the data has been fetched from a SELECT statement, the driver will automatically call finish for you. So you should not call it explicitly except when you know that you've not fetched all the data from a statement handle and the handle won't be destroyed soon."
277   
278    #$meta_sth = $self->{'metadata_prepared_insert_statement_handle'};
279    #$txt_sth = $self->{'fulltxt_prepared_insert_statement_handle'};
280    #$meta_sth->finish() if($meta_sth);
281    #$txt_sth->finish() if($txt_sth);
282
283    print STDERR "Disconnecting from database\n";
284   
285    my $rc = $dbh->disconnect or warn $dbh->errstr; # The handle is of little use after disconnecting. Possibly PrintError already prints a warning and this duplicates it?
286    return $rc;
287}
288
289sub create_db {
290    my $self= shift (@_);
291    my ($db_name) = @_;
292    my $dbh = $self->{'db_handle'};
293   
294    # https://stackoverflow.com/questions/5025768/how-can-i-create-a-mysql-database-from-a-perl-script
295    return $dbh->do("create database $db_name"); # do() will return undef on fail, https://metacpan.org/pod/DBI#do
296}
297
298
299sub create_metadata_table {
300    my $self= shift (@_);
301    my $dbh = $self->{'db_handle'};
302   
303    my $table_name = $self->get_metadata_table_name();
304    print STDERR "   Creating table $table_name\n";
305   
306    # If using an auto incremented primary key:
307    my $stmt = "CREATE TABLE $table_name (id INT NOT NULL AUTO_INCREMENT, did VARCHAR(63) NOT NULL, sid VARCHAR(63) NOT NULL, metaname VARCHAR(127) NOT NULL, metavalue VARCHAR(1023) NOT NULL, PRIMARY KEY(id));";
308    return $dbh->do($stmt);
309}
310
311# TODO: Investigate: https://dev.mysql.com/doc/search/?d=10&p=1&q=FULLTEXT
312# 12.9.1 Natural Language Full-Text Searches
313# to see whether we have to index the 'fulltxt' column of the 'fulltext' tables
314# or let user edit this file, or add it as another option
315sub create_fulltext_table {
316    my $self= shift (@_);
317    my $dbh = $self->{'db_handle'};
318   
319    my $table_name = $self->get_fulltext_table_name();
320    print STDERR "   Creating table $table_name\n";
321   
322    # If using an auto incremented primary key:
323    my $stmt = "CREATE TABLE $table_name (id INT NOT NULL AUTO_INCREMENT, did VARCHAR(63) NOT NULL, sid VARCHAR(63) NOT NULL, fulltxt LONGTEXT, PRIMARY KEY(id));";
324    return $dbh->do($stmt);
325
326}
327
328# "IF EXISTS is used to prevent an error from occurring if the database does not exist. ... DROP DATABASE returns the number of tables that were removed. The DROP DATABASE statement removes from the given database directory those files and directories that MySQL itself may create during normal operation.Jun 20, 2012"
329# MySQL 8.0 Reference Manual :: 13.1.22 DROP DATABASE Syntax
330# https://dev.mysql.com/doc/en/drop-database.html
331sub delete_collection_tables {
332    my $self= shift (@_);
333    my $dbh = $self->{'db_handle'};
334   
335    # drop table <tablename>
336    my $table = $self->get_metadata_table_name();
337    if($self->table_exists($table)) {
338    $dbh->do("drop table $table") || warn("@@@ Couldn't delete $table");
339    }
340    $table = $self->get_fulltext_table_name();
341    if($self->table_exists($table)) {
342    $dbh->do("drop table $table") || warn("@@@ Couldn't delete $table");
343    }
344}
345
346# Don't call this: it will delete the meta and full text tables for ALL collections in $db_name (localsite by default)!
347# This method is just here for debugging (for testing creating a database when there is none)
348sub _delete_database {
349    my $self= shift (@_);
350    my ($db_name) = @_;
351    my $dbh = $self->{'db_handle'};
352
353    print STDERR "!!! Deleting database $db_name\n";
354   
355    # "drop database dbname"
356    $dbh->do("drop database $db_name") || return 0;
357
358    return 1;
359}
360
361
362########################### DB STATEMENTS ###########################
363
364# USEFUL: https://metacpan.org/pod/DBI
365# "Many methods have an optional \%attr parameter which can be used to pass information to the driver implementing the method. Except where specifically documented, the \%attr parameter can only be used to pass driver specific hints. In general, you can ignore \%attr parameters or pass it as undef."
366
367
368# https://www.guru99.com/insert-into.html
369# and https://dev.mysql.com/doc/refman/8.0/en/example-auto-increment.html
370#     for inserting multiple rows at once
371# https://www.perlmonks.org/bare/?node_id=316183
372# https://metacpan.org/pod/DBI#do
373# https://www.quora.com/What-is-the-difference-between-prepare-and-do-statements-in-Perl-while-we-make-a-connection-to-the-database-for-executing-the-query
374# https://docstore.mik.ua/orelly/linux/dbi/ch05_05.htm
375
376# https://metacpan.org/pod/DBI#performance
377# 'The q{...} style quoting used in this example avoids clashing with quotes that may be used in the SQL statement. Use the double-quote like qq{...} operator if you want to interpolate variables into the string. See "Quote and Quote-like Operators" in perlop for more details.'
378sub prepare_insert_metadata_row_stmthandle {
379    my $self = shift (@_);   
380    #my ($did, $sid, $metaname, $metavalue) = @_;
381    my $dbh = $self->{'db_handle'};
382   
383    my $tablename = $self->get_metadata_table_name();
384
385    #my $stmt = "INSERT INTO $tablename (did, sid, metaname, metavalue) VALUES ('$did', '$sid', '$metaname', '$metavalue');"; # ?, ?, ?, ?
386
387    # using qq{} since we want $tablename placeholder to be filled in
388    # returns Statement Handle object!
389    my $sth = $dbh->prepare(qq{INSERT INTO $tablename (did, sid, metaname, metavalue) VALUES (?, ?, ?, ?)}) || warn("Could not prepare insert statement for metadata table\n");
390
391    print STDERR "@@@@ Prepared meta insert statement: ".$sth->{'Statement'}."\n";
392   
393    return $sth;
394}
395
396sub prepare_insert_fulltxt_row_stmthandle {
397    my $self = shift (@_);
398    #my ($did, $sid, $fulltext) = @_;
399    my $dbh = $self->{'db_handle'};
400   
401    my $tablename = $self->get_fulltext_table_name();
402
403    #my $stmt = "INSERT INTO $tablename (did, sid, fulltxt) VALUES ('$did', '$sid', '$fulltext');"; ?, ?, ?
404
405    # using qq{} since we want $tablename placeholder to be filled in
406    # returns Statement Handle object!
407    my $sth = $dbh->prepare(qq{INSERT INTO $tablename (did, sid, fulltxt) VALUES (?, ?, ?)}) || warn("Could not prepare insert statement for fulltxt table\n");
408   
409    print STDERR "@@@@ Prepared fulltext insert statement: ".$sth->{'Statement'}."\n";
410   
411    return $sth;
412}
413
414
415## The 2 select statements used by GreenstoneSQLPlugin
416
417# Returns the statement handle that prepared and executed
418# a "SELECT * FROM <COLL>_metadata WHERE did = $oid" SQL statement.
419# Caller can call fetchrow_array() on returned statement handle, $sth
420# Have to use prepare() and execute() instead of do() since do() does
421# not allow for fetching result set thereafter:
422# do(): "This method  is typically most useful for non-SELECT statements that either cannot be prepared in advance (due to a limitation of the driver) or do not need to be executed repeatedly. It should not be used for SELECT statements because it does not return a statement handle (so you can't fetch any data)." https://metacpan.org/pod/release/TIMB/DBI-1.634_50/DBI.pm#do
423sub select_from_metatable_matching_docid {
424    my $self= shift (@_);
425    my ($oid) = @_;
426   
427    my $dbh = $self->{'db_handle'};
428    my $meta_table = $self->get_metadata_table_name();
429   
430    my $sth = $dbh->prepare(qq{SELECT * FROM $meta_table WHERE did = ?});
431    $sth->execute( $oid ); # will print msg on fail
432   
433    return $sth; # caller can call fetchrow_array() on returned statement handle, sth
434}
435
436# Returns the statement handle that prepared and executed
437# a "SELECT * FROM <COLL>_metadata WHERE did = $oid" SQL statement.
438# Caller can call fetchrow_array() on returned statement handle, $sth
439sub select_from_texttable_matching_docid {
440    my $self= shift (@_);
441    my ($oid) = @_;
442   
443    my $dbh = $self->{'db_handle'};
444    my $fulltxt_table = $self->get_fulltext_table_name();
445   
446    my $sth = $dbh->prepare(qq{SELECT * FROM $fulltxt_table WHERE did = ?});
447    $sth->execute( $oid ); # will print msg on fail
448   
449    return $sth; # caller can call fetchrow_array() on returned statement handle, sth
450}
451
452# delete all records in metatable with specified docid
453# https://www.tutorialspoint.com/mysql/mysql-delete-query.htm
454# DELETE FROM table_name [WHERE Clause]
455# see example under 'do' at https://metacpan.org/pod/release/TIMB/DBI-1.634_50/DBI.pm
456sub delete_recs_from_metatable_with_docid {
457    my $self= shift (@_);
458    my ($oid) = @_;
459   
460    my $dbh = $self->{'db_handle'};
461    my $meta_table = $self->get_metadata_table_name();
462   
463    #my $rows_deleted =
464    $dbh->do(qq{DELETE FROM $meta_table WHERE did = ?}, undef, $oid)
465    or warn $dbh->errstr;
466}
467
468# delete all records in metatable with specified docid
469sub delete_recs_from_texttable_with_docid {
470    my $self= shift (@_);
471    my ($oid) = @_;
472   
473    my $dbh = $self->{'db_handle'};   
474    my $fulltxt_table = $self->get_fulltext_table_name();
475   
476    $dbh->do(qq{DELETE FROM $fulltxt_table WHERE did = ?}, undef, $oid)
477    or warn $dbh->errstr;
478}
479
480# Can call this after connection succeeded to get the database handle, dbh,
481# if any specific DB operation (SQL statement, create/delete)
482# needs to be executed that is not already provided as a method of this class.
483sub get_db_handle {
484    my $self= shift (@_);
485    return $self->{'db_handle'};
486}
487
488################ HELPER METHODS ##############
489
490# More basic helper methods
491sub get_metadata_table_name {
492    my $self= shift (@_);
493    my $table_name = $self->{'tablename_prefix'} . "_metadata";
494    return $table_name;
495}
496
497# FULLTEXT is a reserved keyword in (My)SQL. https://dev.mysql.com/doc/refman/5.5/en/keywords.html
498# So we can't name a table or any of its columns "fulltext". We use "fulltxt" instead.
499sub get_fulltext_table_name {
500    my $self= shift (@_);
501    my $table_name = $self->{'tablename_prefix'} . "_fulltxt";
502    return $table_name;
503}
504
505
506# I can get my version of table_exists to work, but it's not so ideal
507# Interesting that MySQL has non-standard command to CREATE TABLE IF NOT EXISTS and DROP TABLE IF EXISTS,
508# see https://www.perlmonks.org/bare/?node=DBI%20Recipes
509#    The page further has a table_exists function that could work with proper comparison
510# TODO Q: Couldn't get the first solution at https://www.perlmonks.org/bare/?node_id=500050 to work though
511sub table_exists {
512    my $self = shift (@_);
513    my $dbh = $self->{'db_handle'};
514    my ($table_name) = @_;
515
516    my @table_list = $dbh->tables;
517    #my $tables_str = @table_list[0];
518    foreach my $table (@table_list) {
519    return 1 if ($table =~ m/$table_name/);
520    }
521    return 0;
522}
523
5241;
Note: See TracBrowser for help on using the browser.