root/main/trunk/greenstone2/perllib/gssql.pm @ 32560

Revision 32560, 23.9 KB (checked in by ak19, 11 months ago)

gssql constructor accepts a verbosity parameter

Line 
1###########################################################################
2#
3# gssql.pm -- DBI for SQL related utility functions used by
4# GreenstoneSQLPlugout and hereafter by GreenstoneSQLPlugin too.
5# A component of the Greenstone digital library software
6# from the New Zealand Digital Library Project at the
7# University of Waikato, New Zealand.
8#
9# Copyright (C) 1999 New Zealand Digital Library Project
10#
11# This program is free software; you can redistribute it and/or modify
12# it under the terms of the GNU General Public License as published by
13# the Free Software Foundation; either version 2 of the License, or
14# (at your option) any later version.
15#
16# This program is distributed in the hope that it will be useful,
17# but WITHOUT ANY WARRANTY; without even the implied warranty of
18# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
19# GNU General Public License for more details.
20#
21# You should have received a copy of the GNU General Public License
22# along with this program; if not, write to the Free Software
23# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
24#
25###########################################################################
26
27package gssql;
28
29use strict;
30no strict 'refs';
31no strict 'subs';
32
33use DBI; # the central package for this module used by GreenstoneSQL Plugout and Plugin
34
35# Need params_map keys:
36# - collection_name
37# - db_encoding (db content encoding) - MySQL can set this at server, db, table levels. For MySQL
38# we set the enc during connect at server level. Not sure whether other DB's support it at the
39# same levels.
40
41# For connection to MySQL, need:
42#  - db_driver, db_client_user, db_client_pwd, db_host, (db_port not used at present)
43# So these will be parameterised, but in a hashmap, for just the connect method.
44
45# Parameterise (one or more methods may use them):
46# - build_mode (like removeold)
47# - db_name (which is the GS3 sitename)
48
49# TODO: add infrastructure for db_port, AutoCommit etc
50# For port, see https://stackoverflow.com/questions/2248665/perl-script-to-connect-to-mysql-server-port-3307
51
52sub new
53{
54 
55    my $class = shift(@_);
56   
57    my ($params_map) = @_;
58   
59    # library_url: to be specified on the cmdline if not using a GS-included web server
60    # the GSDL_LIBRARY_URL env var is useful when running cmdline buildcol.pl in the linux package manager versions of GS3
61   
62    # https://stackoverflow.com/questions/7083453/copying-a-hashref-in-perl
63    # Making a shallow copy works, and can handle unknown params:
64    #my $self = $params_map;
65
66    # but being explicit for class params needed for MySQL:
67    my $self = {
68    'collection_name' => $params_map->{'collection_name'},
69    'verbosity' => $params_map->{'verbosity'} || 1
70    };
71
72    # (My)SQL doesn't like tables with - (hyphens) in their names
73    my $coll_name = $params_map->{'collection_name'};
74    $coll_name =~ s/-/_/g;
75    $self->{'tablename_prefix'} = $coll_name;
76
77    # The db_encoding option is presently not passed in to this constructor as parameter.
78    # Placed here to indicate it's sort of optional.
79    # Since docxml are all in utf8, the contents of the GS SQL database should be too,
80    # So making utf8 the hidden default at present.
81    $self->{'db_encoding'} = $params_map->{'db_encoding'} || "utf8";
82   
83    return bless($self, $class);
84}
85
86
87#################################
88
89# Database access related functions
90# http://g2pc1.bu.edu/~qzpeng/manual/MySQL%20Commands.htm
91# https://www.guru99.com/insert-into.html
92
93# TODO Q: What on cancelling a build: delete table? But what if it was a rebuild and the rebuild is cancelled (not the original build)?
94# Do we create a copy of the orig database as backup, then start populating current db, and if cancelled, delete current db and RENAME backup table to current?
95# https://stackoverflow.com/questions/3280006/duplicating-a-mysql-table-indexes-and-data
96# BUT what if the table is HUGE? (Think of a collection with millions of docs.) Huge overhead in copying?
97# The alternative is we just quit on cancel, but then: cancel could leave the table in a partial committed state, with no way of rolling back.
98# Unless they do a full rebuild, which will recreate the table from scratch?
99# SOLUTION-> rollback transaction on error, see https://www.effectiveperlprogramming.com/2010/07/set-custom-dbi-error-handlers/
100# But then should set AutoCommit to off on connection, and remember to commit every time
101
102#################
103# Database functions that use the perl DBI module (with the DBD driver module for mysql)
104#################
105
106################### BASIC DB OPERATIONS ##################
107
108# THE NEW DB FUNCTIONS
109# NOTE: FULLTEXT is a reserved keyword in (My)SQL. So we can't name a table or any of its columns "fulltext".
110# https://dev.mysql.com/doc/refman/5.5/en/keywords.html
111
112# TODO: Consider AutoCommit status (and Autocommit off allowing commit or rollback for GS coll build cancel) later
113
114# TODO: where should the defaults for these params be, here or in GS-SQLPlugin/Plugout?
115sub connect_to_db {
116    my $self= shift (@_);
117    my ($params_map) = @_;
118    # For proper utf8 support in MySQL, encoding should be 'utf8mb4' as 'utf8' is insufficient
119    my $db_enc = "utf8mb4" if $self->{'db_encoding'} eq "utf8";
120
121    # these are the params for connecting to MySQL
122    my $db_driver = $params_map->{'db_driver'} || "mysql";
123    my $db_user = $params_map->{'db_client_user'} || "root";
124    my $db_pwd = $params_map->{'db_client_pwd'}; # even if undef, we'll see a sensible error message
125                                           # when connect fails
126    my $db_host = $params_map->{'db_host'} || "127.0.0.1";
127    # localhost doesn't work for us, but 127.0.0.1 works
128    # https://metacpan.org/pod/DBD::mysql
129    # "The hostname, if not specified or specified as '' or 'localhost', will default to a MySQL server
130    # running on the local machine using the default for the UNIX socket. To connect to a MySQL server
131    # on the local machine via TCP, you must specify the loopback IP address (127.0.0.1) as the host."
132    #my $connect_str = "dbi:$db_driver:database=$db_name;host=$db_host";
133    my $connect_str = "dbi:$db_driver:host=$db_host"; # don't provide db - allows checking the db exists later when loading the db
134
135    if($self->{'verbosity'}) {
136    print STDERR "Away to make connection to $db_driver database with:\n";
137    print STDERR " - hostname $db_host; username: $db_user";
138    print STDERR "; and the password provided" if $db_pwd;
139    print STDERR "\nAssuming the mysql server has been started with: --character_set_server=utf8mb4\n" if $db_driver eq "mysql";
140    }
141   
142    my $dbh = DBI->connect("$connect_str", $db_user, $db_pwd,
143               {
144                   ShowErrorStatement => 1, # more informative as DBI will append failed SQL stmt to error message
145                   PrintError => 1, # on by default, but being explicit
146                   RaiseError => 0, # off by default, but being explicit
147                   AutoCommit => 1, # on by default, but being explicit
148                   mysql_enable_utf8mb4 => 1 # tells MySQL to use UTF-8 for communication and tells DBD::mysql to decode the data, see https://stackoverflow.com/questions/46727362/perl-mysql-utf8mb4-issue-possible-bug
149               });
150
151    if(!$dbh) {
152    # NOTE, despite handle dbh being undefined, error code will be in DBI->err (note caps)
153    return 0;   
154    }
155
156    # set encoding https://metacpan.org/pod/DBD::mysql
157    # https://dev.mysql.com/doc/refman/5.7/en/charset.html
158    # https://dev.mysql.com/doc/refman/5.7/en/charset-conversion.html
159    # Setting the encoding at db server level: $dbh->do("set NAMES '" . $db_enc . "'");
160    # HOWEVER:
161    # It turned out insufficient setting the encoding to utf8, as that only supports utf8 chars that
162    # need up to 3 bytes. We may need up to 4 bytes per utf8 character, e.g. chars with macron,
163    # and for that, we need the encoding to be set to utf8mb4.
164    # To set up a MySQL db to use utf8mb4 requires configuration on the server side too.
165    # https://stackoverflow.com/questions/10957238/incorrect-string-value-when-trying-to-insert-utf-8-into-mysql-via-jdbc
166    # https://stackoverflow.com/questions/46727362/perl-mysql-utf8mb4-issue-possible-bug
167    # To set up the db for utf8mb4, therefore,
168    # the MySQL server needs to be configured for that char encoding by running the server as:
169    # mysql-5.7.23-linux-glibc2.12-x86_64/bin>./mysqld_safe --datadir=/Scratch/ak19/mysql/data --character_set_server=utf8mb4
170    # AND when connecting to the server, we can can either set mysql_enable_utf8mb4 => 1
171    # as a connection option
172    # OR we need to do both "set NAMES utf8mb4" AND "$dbh->{mysql_enable_utf8mb4} = 1;" after connecting
173    #
174    # Search results for DBI Set Names imply the "SET NAMES '<enc>'" command is mysql specific too,
175    # so setting the mysql specific option during connection above as "mysql_enable_utf8mb4 => 1"
176    # is no more objectionable. It has the advantage of cutting out the 2 extra lines of doing
177    # set NAMES '<enc>' and $dbh->{mysql_enable_utf8mb4} = 1 here.
178    # These lines may be preferred if more db_driver options are to be supported in future:
179    # then a separate method called set_db_encoding($enc) can work out what db_driver we're using
180    # and if mysql and enc=utfy, then it can do the following whereas it will issue other do stmts
181    # for other db_drivers, see https://www.perlmonks.org/?node_id=259456:
182   
183    #my $stmt = "set NAMES '" . $db_enc . "'";
184    #$dbh->do($stmt) || warn("Unable to set charset encoding at db server level to: " . $db_enc . "\n"); # tells MySQL to use UTF-8 for communication
185    #$dbh->{mysql_enable_utf8mb4} = 1; # tells DBD::mysql to decode the data
186   
187    # if we're here, then connection succeeded, store handle
188    $self->{'db_handle'} = $dbh;
189    return 1;
190}
191
192# will attempt to load the specified db and the <coll>_metadata and <coll>_fulltxt for this
193# collection, or create any of these (db, tables) that don't yet exist. At the end
194# it will have loaded the requested database (in MySQL: "use <db>;")
195sub load_db_and_tables {
196    my $self= shift (@_);
197    my ($db_name, $build_mode) = @_;
198    my $dbh = $self->{'db_handle'};
199   
200    print STDERR "Attempting to use database $db_name\n" if($self->{'verbosity'});
201   
202    # perl DBI switch database: https://www.perlmonks.org/?node_id=995434
203    # do() returns undef on error.
204    # connection succeeded, try to load our database. If that didn't work, attempt to create db
205    my $success = $dbh->do("use $db_name");
206   
207    if(!$success && $dbh->err == 1049) { # "Unknown database" error has code 1049 (mysql only?) meaning db doesn't exist yet
208
209    print STDERR "Database $db_name didn't exist, creating it and the tables for the current collection...\n" if($self->{'verbosity'});
210   
211    # attempt to create the db and its tables
212    $self->create_db($db_name) || return 0;
213
214    print STDERR "   Created database $db_name\n" if($self->{'verbosity'} > 1);
215   
216    # once more attempt to use db, now that it exists
217    $dbh->do("use $db_name") || return 0;
218    #$dbh->do("use localsite") or die "Error (code" . $dbh->err ."): " . $dbh->errstr . "\n";
219
220    # attempt to create tables in current db
221    $self->create_metadata_table() || return 0;
222    $self->create_fulltext_table() || return 0;
223
224    $success = 1;
225    }
226    elsif($success) { # database existed and loaded successfully, but
227    # before proceeding check that the current collection's tables exist
228
229    print STDERR "@@@ DATABASE $db_name EXISTED\n" if($self->{'verbosity'} > 2);
230   
231
232    # build_mode can be removeold or incremental. We only do something special on removeold:
233    # deleting the existing tables for this collection and recreating empty ones
234    if($build_mode eq "removeold") {
235        print STDERR "   Building with removeold option set, so deleting current collection's tables if they exist\n" if($self->{'verbosity'});
236        $self->delete_collection_tables();
237    }
238
239    # use existing tables if any
240    # attempt to create tables in current db   
241    if($build_mode eq "removeold" || !$self->table_exists($self->get_metadata_table_name())) {
242        $self->create_metadata_table() || return 0;
243    } else {
244        print STDERR "@@@ Meta table exists\n" if($self->{'verbosity'} > 2);
245    }
246    if($build_mode eq "removeold" || !$self->table_exists($self->get_fulltext_table_name())) {
247        $self->create_fulltext_table() || return 0;
248    } else {
249        print STDERR "@@@ Fulltxt table exists\n" if($self->{'verbosity'} > 2);
250    }
251   
252    }
253   
254    return $success; # could still return 0, if database failed to load with an error code != 1049
255}
256
257# GreenstoneSQLPlugin calls this method to load an existing db.
258# This will terminate if the db does not exist. Unlike load_db_and_tables() above, used by
259# GreenstoneSQLPlugout, this method will not attempt to create the requested db (nor its tables)
260# TODO: GS SQLPlugin is called before GS SQLPlugout and attempts to use_db() - called in plugin's
261# init() method. This will fail if the db does not exist. Ideally want the gssqlplugin only called
262# during buildcol.pl
263sub use_db {
264    my $self= shift (@_);
265    my ($db_name) = @_;
266    my $dbh = $self->{'db_handle'};
267
268    print STDERR "Loading database $db_name\n" if($self->{'verbosity'} > 1);
269   
270    # perl DBI switch database: https://www.perlmonks.org/?node_id=995434
271    # do() returns undef on error.
272    # connection succeeded, try to load our database. If that didn't work, attempt to create db
273    return $dbh->do("use $db_name") || warn();
274}
275
276# disconnect from db - https://metacpan.org/pod/DBI#disconnect
277# TODO: make sure to have committed or rolled back before disconnect
278# and that you've call finish() on statement handles if any fetch remnants remain
279sub disconnect_from_db {
280    my $self= shift (@_);   
281    my $dbh = $self->{'db_handle'};
282
283    # make sure any active stmt handles are finished
284    # NO: "When all the data has been fetched from a SELECT statement, the driver will automatically call finish for you. So you should not call it explicitly except when you know that you've not fetched all the data from a statement handle and the handle won't be destroyed soon."
285   
286    #$meta_sth = $self->{'metadata_prepared_insert_statement_handle'};
287    #$txt_sth = $self->{'fulltxt_prepared_insert_statement_handle'};
288    #$meta_sth->finish() if($meta_sth);
289    #$txt_sth->finish() if($txt_sth);
290
291    print STDERR "Disconnecting from database\n" if($self->{'verbosity'} > 1);
292   
293    my $rc = $dbh->disconnect or warn $dbh->errstr; # The handle is of little use after disconnecting. Possibly PrintError already prints a warning and this duplicates it?
294    return $rc;
295}
296
297sub create_db {
298    my $self= shift (@_);
299    my ($db_name) = @_;
300    my $dbh = $self->{'db_handle'};
301   
302    # https://stackoverflow.com/questions/5025768/how-can-i-create-a-mysql-database-from-a-perl-script
303    return $dbh->do("create database $db_name"); # do() will return undef on fail, https://metacpan.org/pod/DBI#do
304}
305
306
307sub create_metadata_table {
308    my $self= shift (@_);
309    my $dbh = $self->{'db_handle'};
310   
311    my $table_name = $self->get_metadata_table_name();
312    print STDERR "   Creating table $table_name\n" if($self->{'verbosity'} > 1);
313   
314    # If using an auto incremented primary key:
315    my $stmt = "CREATE TABLE $table_name (id INT NOT NULL AUTO_INCREMENT, did VARCHAR(63) NOT NULL, sid VARCHAR(63) NOT NULL, metaname VARCHAR(127) NOT NULL, metavalue VARCHAR(1023) NOT NULL, PRIMARY KEY(id));";
316    return $dbh->do($stmt);
317}
318
319# TODO: Investigate: https://dev.mysql.com/doc/search/?d=10&p=1&q=FULLTEXT
320# 12.9.1 Natural Language Full-Text Searches
321# to see whether we have to index the 'fulltxt' column of the 'fulltext' tables
322# or let user edit this file, or add it as another option
323sub create_fulltext_table {
324    my $self= shift (@_);
325    my $dbh = $self->{'db_handle'};
326   
327    my $table_name = $self->get_fulltext_table_name();
328    print STDERR "   Creating table $table_name\n" if($self->{'verbosity'} > 1);
329   
330    # If using an auto incremented primary key:
331    my $stmt = "CREATE TABLE $table_name (id INT NOT NULL AUTO_INCREMENT, did VARCHAR(63) NOT NULL, sid VARCHAR(63) NOT NULL, fulltxt LONGTEXT, PRIMARY KEY(id));";
332    return $dbh->do($stmt);
333
334}
335
336# "IF EXISTS is used to prevent an error from occurring if the database does not exist. ... DROP DATABASE returns the number of tables that were removed. The DROP DATABASE statement removes from the given database directory those files and directories that MySQL itself may create during normal operation.Jun 20, 2012"
337# MySQL 8.0 Reference Manual :: 13.1.22 DROP DATABASE Syntax
338# https://dev.mysql.com/doc/en/drop-database.html
339sub delete_collection_tables {
340    my $self= shift (@_);
341    my $dbh = $self->{'db_handle'};
342   
343    # drop table <tablename>
344    my $table = $self->get_metadata_table_name();
345    if($self->table_exists($table)) {
346    $dbh->do("drop table $table") || warn("@@@ Couldn't delete $table");
347    }
348    $table = $self->get_fulltext_table_name();
349    if($self->table_exists($table)) {
350    $dbh->do("drop table $table") || warn("@@@ Couldn't delete $table");
351    }
352}
353
354# Don't call this: it will delete the meta and full text tables for ALL collections in $db_name (localsite by default)!
355# This method is just here for debugging (for testing creating a database when there is none)
356sub _delete_database {
357    my $self= shift (@_);
358    my ($db_name) = @_;
359    my $dbh = $self->{'db_handle'};
360
361    print STDERR "!!! Deleting database $db_name\n" if($self->{'verbosity'});
362   
363    # "drop database dbname"
364    $dbh->do("drop database $db_name") || return 0;
365
366    return 1;
367}
368
369
370########################### DB STATEMENTS ###########################
371
372# USEFUL: https://metacpan.org/pod/DBI
373# "Many methods have an optional \%attr parameter which can be used to pass information to the driver implementing the method. Except where specifically documented, the \%attr parameter can only be used to pass driver specific hints. In general, you can ignore \%attr parameters or pass it as undef."
374
375
376# https://www.guru99.com/insert-into.html
377# and https://dev.mysql.com/doc/refman/8.0/en/example-auto-increment.html
378#     for inserting multiple rows at once
379# https://www.perlmonks.org/bare/?node_id=316183
380# https://metacpan.org/pod/DBI#do
381# https://www.quora.com/What-is-the-difference-between-prepare-and-do-statements-in-Perl-while-we-make-a-connection-to-the-database-for-executing-the-query
382# https://docstore.mik.ua/orelly/linux/dbi/ch05_05.htm
383
384# https://metacpan.org/pod/DBI#performance
385# 'The q{...} style quoting used in this example avoids clashing with quotes that may be used in the SQL statement. Use the double-quote like qq{...} operator if you want to interpolate variables into the string. See "Quote and Quote-like Operators" in perlop for more details.'
386sub prepare_insert_metadata_row_stmthandle {
387    my $self = shift (@_);   
388    #my ($did, $sid, $metaname, $metavalue) = @_;
389    my $dbh = $self->{'db_handle'};
390   
391    my $tablename = $self->get_metadata_table_name();
392
393    #my $stmt = "INSERT INTO $tablename (did, sid, metaname, metavalue) VALUES ('$did', '$sid', '$metaname', '$metavalue');"; # ?, ?, ?, ?
394
395    # using qq{} since we want $tablename placeholder to be filled in
396    # returns Statement Handle object!
397    my $sth = $dbh->prepare(qq{INSERT INTO $tablename (did, sid, metaname, metavalue) VALUES (?, ?, ?, ?)}) || warn("Could not prepare insert statement for metadata table\n");
398
399    print STDERR "@@@@ Prepared meta insert statement: ".$sth->{'Statement'}."\n" if($self->{'verbosity'} > 2);
400   
401    return $sth;
402}
403
404sub prepare_insert_fulltxt_row_stmthandle {
405    my $self = shift (@_);
406    #my ($did, $sid, $fulltext) = @_;
407    my $dbh = $self->{'db_handle'};
408   
409    my $tablename = $self->get_fulltext_table_name();
410
411    #my $stmt = "INSERT INTO $tablename (did, sid, fulltxt) VALUES ('$did', '$sid', '$fulltext');"; ?, ?, ?
412
413    # using qq{} since we want $tablename placeholder to be filled in
414    # returns Statement Handle object!
415    my $sth = $dbh->prepare(qq{INSERT INTO $tablename (did, sid, fulltxt) VALUES (?, ?, ?)}) || warn("Could not prepare insert statement for fulltxt table\n");
416   
417    print STDERR "@@@@ Prepared fulltext insert statement: ".$sth->{'Statement'}."\n" if($self->{'verbosity'} > 2);
418   
419    return $sth;
420}
421
422
423## The 2 select statements used by GreenstoneSQLPlugin
424
425# Returns the statement handle that prepared and executed
426# a "SELECT * FROM <COLL>_metadata WHERE did = $oid" SQL statement.
427# Caller can call fetchrow_array() on returned statement handle, $sth
428# Have to use prepare() and execute() instead of do() since do() does
429# not allow for fetching result set thereafter:
430# do(): "This method  is typically most useful for non-SELECT statements that either cannot be prepared in advance (due to a limitation of the driver) or do not need to be executed repeatedly. It should not be used for SELECT statements because it does not return a statement handle (so you can't fetch any data)." https://metacpan.org/pod/release/TIMB/DBI-1.634_50/DBI.pm#do
431sub select_from_metatable_matching_docid {
432    my $self= shift (@_);
433    my ($oid) = @_;
434   
435    my $dbh = $self->{'db_handle'};
436    my $meta_table = $self->get_metadata_table_name();
437   
438    my $sth = $dbh->prepare(qq{SELECT * FROM $meta_table WHERE did = ?});
439    $sth->execute( $oid ); # will print msg on fail
440   
441    return $sth; # caller can call fetchrow_array() on returned statement handle, sth
442}
443
444# Returns the statement handle that prepared and executed
445# a "SELECT * FROM <COLL>_metadata WHERE did = $oid" SQL statement.
446# Caller can call fetchrow_array() on returned statement handle, $sth
447sub select_from_texttable_matching_docid {
448    my $self= shift (@_);
449    my ($oid) = @_;
450   
451    my $dbh = $self->{'db_handle'};
452    my $fulltxt_table = $self->get_fulltext_table_name();
453   
454    my $sth = $dbh->prepare(qq{SELECT * FROM $fulltxt_table WHERE did = ?});
455    $sth->execute( $oid ); # will print msg on fail
456   
457    return $sth; # caller can call fetchrow_array() on returned statement handle, sth
458}
459
460# delete all records in metatable with specified docid
461# https://www.tutorialspoint.com/mysql/mysql-delete-query.htm
462# DELETE FROM table_name [WHERE Clause]
463# see example under 'do' at https://metacpan.org/pod/release/TIMB/DBI-1.634_50/DBI.pm
464sub delete_recs_from_metatable_with_docid {
465    my $self= shift (@_);
466    my ($oid) = @_;
467   
468    my $dbh = $self->{'db_handle'};
469    my $meta_table = $self->get_metadata_table_name();
470   
471    #my $rows_deleted =
472    $dbh->do(qq{DELETE FROM $meta_table WHERE did = ?}, undef, $oid)
473    or warn $dbh->errstr;
474}
475
476# delete all records in metatable with specified docid
477sub delete_recs_from_texttable_with_docid {
478    my $self= shift (@_);
479    my ($oid) = @_;
480   
481    my $dbh = $self->{'db_handle'};   
482    my $fulltxt_table = $self->get_fulltext_table_name();
483   
484    $dbh->do(qq{DELETE FROM $fulltxt_table WHERE did = ?}, undef, $oid)
485    or warn $dbh->errstr;
486}
487
488# Can call this after connection succeeded to get the database handle, dbh,
489# if any specific DB operation (SQL statement, create/delete)
490# needs to be executed that is not already provided as a method of this class.
491sub get_db_handle {
492    my $self= shift (@_);
493    return $self->{'db_handle'};
494}
495
496################ HELPER METHODS ##############
497
498# More basic helper methods
499sub get_metadata_table_name {
500    my $self= shift (@_);
501    my $table_name = $self->{'tablename_prefix'} . "_metadata";
502    return $table_name;
503}
504
505# FULLTEXT is a reserved keyword in (My)SQL. https://dev.mysql.com/doc/refman/5.5/en/keywords.html
506# So we can't name a table or any of its columns "fulltext". We use "fulltxt" instead.
507sub get_fulltext_table_name {
508    my $self= shift (@_);
509    my $table_name = $self->{'tablename_prefix'} . "_fulltxt";
510    return $table_name;
511}
512
513
514# I can get my version of table_exists to work, but it's not so ideal
515# Interesting that MySQL has non-standard command to CREATE TABLE IF NOT EXISTS and DROP TABLE IF EXISTS,
516# see https://www.perlmonks.org/bare/?node=DBI%20Recipes
517#    The page further has a table_exists function that could work with proper comparison
518# TODO Q: Couldn't get the first solution at https://www.perlmonks.org/bare/?node_id=500050 to work though
519sub table_exists {
520    my $self = shift (@_);
521    my $dbh = $self->{'db_handle'};
522    my ($table_name) = @_;
523
524    my @table_list = $dbh->tables;
525    #my $tables_str = @table_list[0];
526    foreach my $table (@table_list) {
527    return 1 if ($table =~ m/$table_name/);
528    }
529    return 0;
530}
531
5321;
Note: See TracBrowser for help on using the browser.