root/main/trunk/greenstone2/perllib/gssql.pm @ 32563

Revision 32563, 23.4 KB (checked in by ak19, 9 months ago)

1. Overhaul of GreenstoneSQLPlugs to handle removeold and incremental delete correctly. And now code also automatically handles 'non-incremental delete' (see mention in ArchivesInfPlugin?). The new version no longer does lazy loading for getting the sql db connection in the GS SQL Plugin, as now the connection needs to be active since the start of the plugin to run SQL delete statements on remove_old. So the db connection code for the GS SQL plugin has moved back into its init() method. Lots of changes to gssql.pm (and some flow on effects to the GS SQL Plugout) as when database tables exist and need to be created have changed. 2. Undoing most of the changes of changeset 32555 since we're doing incremental delete and removeold differently and in the correct way now when using the GreenstoneSQLPlugs.

Line 
1###########################################################################
2#
3# gssql.pm -- DBI for SQL related utility functions used by
4# GreenstoneSQLPlugout and hereafter by GreenstoneSQLPlugin too.
5# A component of the Greenstone digital library software
6# from the New Zealand Digital Library Project at the
7# University of Waikato, New Zealand.
8#
9# Copyright (C) 1999 New Zealand Digital Library Project
10#
11# This program is free software; you can redistribute it and/or modify
12# it under the terms of the GNU General Public License as published by
13# the Free Software Foundation; either version 2 of the License, or
14# (at your option) any later version.
15#
16# This program is distributed in the hope that it will be useful,
17# but WITHOUT ANY WARRANTY; without even the implied warranty of
18# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
19# GNU General Public License for more details.
20#
21# You should have received a copy of the GNU General Public License
22# along with this program; if not, write to the Free Software
23# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
24#
25###########################################################################
26
27package gssql;
28
29use strict;
30no strict 'refs';
31no strict 'subs';
32
33use DBI; # the central package for this module used by GreenstoneSQL Plugout and Plugin
34
35# Need params_map keys:
36# - collection_name
37# - db_encoding (db content encoding) - MySQL can set this at server, db, table levels. For MySQL
38# we set the enc during connect at server level. Not sure whether other DB's support it at the
39# same levels.
40
41# For connection to MySQL, need:
42#  - db_driver, db_client_user, db_client_pwd, db_host, (db_port not used at present)
43# So these will be parameterised, but in a hashmap, for just the connect method.
44
45# Parameterise (one or more methods may use them):
46# - db_name (which is the GS3 sitename)
47
48# TODO: add infrastructure for db_port, AutoCommit etc
49# For port, see https://stackoverflow.com/questions/2248665/perl-script-to-connect-to-mysql-server-port-3307
50
51sub new
52
53    my $class = shift(@_);
54   
55    my ($params_map) = @_;
56   
57    # library_url: to be specified on the cmdline if not using a GS-included web server
58    # the GSDL_LIBRARY_URL env var is useful when running cmdline buildcol.pl in the linux package manager versions of GS3
59   
60    # https://stackoverflow.com/questions/7083453/copying-a-hashref-in-perl
61    # Making a shallow copy works, and can handle unknown params:
62    #my $self = $params_map;
63
64    # but being explicit for class params needed for MySQL:
65    my $self = {
66    'collection_name' => $params_map->{'collection_name'},
67    'verbosity' => $params_map->{'verbosity'} || 1
68    };
69
70    # The db_encoding option is presently not passed in to this constructor as parameter.
71    # Placed here to indicate it's sort of optional.
72    # Since docxml are all in utf8, the contents of the GS SQL database should be too,
73    # So making utf8 the hidden default at present.
74    $self->{'db_encoding'} = $params_map->{'db_encoding'} || "utf8";
75   
76    $self = bless($self, $class);   
77
78    $self->{'tablename_prefix'} = $self->sanitize_name($params_map->{'collection_name'});
79   
80    return $self;
81}
82
83
84#################################
85
86# Database access related functions
87# http://g2pc1.bu.edu/~qzpeng/manual/MySQL%20Commands.htm
88# https://www.guru99.com/insert-into.html
89
90# TODO Q: What on cancelling a build: delete table? But what if it was a rebuild and the rebuild is cancelled (not the original build)?
91# Do we create a copy of the orig database as backup, then start populating current db, and if cancelled, delete current db and RENAME backup table to current?
92# https://stackoverflow.com/questions/3280006/duplicating-a-mysql-table-indexes-and-data
93# BUT what if the table is HUGE? (Think of a collection with millions of docs.) Huge overhead in copying?
94# The alternative is we just quit on cancel, but then: cancel could leave the table in a partial committed state, with no way of rolling back.
95# Unless they do a full rebuild, which will recreate the table from scratch?
96# SOLUTION-> rollback transaction on error, see https://www.effectiveperlprogramming.com/2010/07/set-custom-dbi-error-handlers/
97# But then should set AutoCommit to off on connection, and remember to commit every time
98
99#################
100# Database functions that use the perl DBI module (with the DBD driver module for mysql)
101#################
102
103################### BASIC DB OPERATIONS ##################
104
105# THE NEW DB FUNCTIONS
106# NOTE: FULLTEXT is a reserved keyword in (My)SQL. So we can't name a table or any of its columns "fulltext".
107# https://dev.mysql.com/doc/refman/5.5/en/keywords.html
108
109# TODO: Consider AutoCommit status (and Autocommit off allowing commit or rollback for GS coll build cancel) later
110
111# TODO: where should the defaults for these params be, here or in GS-SQLPlugin/Plugout?
112sub connect_to_db {
113    my $self= shift (@_);
114    my ($params_map) = @_;
115    # For proper utf8 support in MySQL, encoding should be 'utf8mb4' as 'utf8' is insufficient
116    my $db_enc = "utf8mb4" if $self->{'db_encoding'} eq "utf8";
117
118    # these are the params for connecting to MySQL
119    my $db_driver = $params_map->{'db_driver'} || "mysql";
120    my $db_user = $params_map->{'db_client_user'} || "root";
121    my $db_pwd = $params_map->{'db_client_pwd'}; # even if undef, we'll see a sensible error message
122                                           # when connect fails
123    my $db_host = $params_map->{'db_host'} || "127.0.0.1";
124    # localhost doesn't work for us, but 127.0.0.1 works
125    # https://metacpan.org/pod/DBD::mysql
126    # "The hostname, if not specified or specified as '' or 'localhost', will default to a MySQL server
127    # running on the local machine using the default for the UNIX socket. To connect to a MySQL server
128    # on the local machine via TCP, you must specify the loopback IP address (127.0.0.1) as the host."
129    #my $connect_str = "dbi:$db_driver:database=$db_name;host=$db_host";
130    my $connect_str = "dbi:$db_driver:host=$db_host"; # don't provide db - allows checking the db exists later when loading the db
131
132    if($self->{'verbosity'}) {
133    print STDERR "Away to make connection to $db_driver database with:\n";
134    print STDERR " - hostname $db_host; username: $db_user";
135    print STDERR "; and the provided password" if $db_pwd;
136    print STDERR "\nAssuming the mysql server has been started with: --character_set_server=utf8mb4\n" if $db_driver eq "mysql";
137    }
138   
139    my $dbh = DBI->connect("$connect_str", $db_user, $db_pwd,
140               {
141                   ShowErrorStatement => 1, # more informative as DBI will append failed SQL stmt to error message
142                   PrintError => 1, # on by default, but being explicit
143                   RaiseError => 0, # off by default, but being explicit
144                   AutoCommit => 1, # on by default, but being explicit
145                   mysql_enable_utf8mb4 => 1 # tells MySQL to use UTF-8 for communication and tells DBD::mysql to decode the data, see https://stackoverflow.com/questions/46727362/perl-mysql-utf8mb4-issue-possible-bug
146               });
147
148    if(!$dbh) {
149    # NOTE, despite handle dbh being undefined, error code will be in DBI->err (note caps)
150    return 0;   
151    }
152
153    # set encoding https://metacpan.org/pod/DBD::mysql
154    # https://dev.mysql.com/doc/refman/5.7/en/charset.html
155    # https://dev.mysql.com/doc/refman/5.7/en/charset-conversion.html
156    # Setting the encoding at db server level: $dbh->do("set NAMES '" . $db_enc . "'");
157    # HOWEVER:
158    # It turned out insufficient setting the encoding to utf8, as that only supports utf8 chars that
159    # need up to 3 bytes. We may need up to 4 bytes per utf8 character, e.g. chars with macron,
160    # and for that, we need the encoding to be set to utf8mb4.
161    # To set up a MySQL db to use utf8mb4 requires configuration on the server side too.
162    # https://stackoverflow.com/questions/10957238/incorrect-string-value-when-trying-to-insert-utf-8-into-mysql-via-jdbc
163    # https://stackoverflow.com/questions/46727362/perl-mysql-utf8mb4-issue-possible-bug
164    # To set up the db for utf8mb4, therefore,
165    # the MySQL server needs to be configured for that char encoding by running the server as:
166    # mysql-5.7.23-linux-glibc2.12-x86_64/bin>./mysqld_safe --datadir=/Scratch/ak19/mysql/data --character_set_server=utf8mb4
167    # AND when connecting to the server, we can can either set mysql_enable_utf8mb4 => 1
168    # as a connection option
169    # OR we need to do both "set NAMES utf8mb4" AND "$dbh->{mysql_enable_utf8mb4} = 1;" after connecting
170    #
171    # Search results for DBI Set Names imply the "SET NAMES '<enc>'" command is mysql specific too,
172    # so setting the mysql specific option during connection above as "mysql_enable_utf8mb4 => 1"
173    # is no more objectionable. It has the advantage of cutting out the 2 extra lines of doing
174    # set NAMES '<enc>' and $dbh->{mysql_enable_utf8mb4} = 1 here.
175    # These lines may be preferred if more db_driver options are to be supported in future:
176    # then a separate method called set_db_encoding($enc) can work out what db_driver we're using
177    # and if mysql and enc=utfy, then it can do the following whereas it will issue other do stmts
178    # for other db_drivers, see https://www.perlmonks.org/?node_id=259456:
179   
180    #my $stmt = "set NAMES '" . $db_enc . "'";
181    #$dbh->do($stmt) || warn("Unable to set charset encoding at db server level to: " . $db_enc . "\n"); # tells MySQL to use UTF-8 for communication
182    #$dbh->{mysql_enable_utf8mb4} = 1; # tells DBD::mysql to decode the data
183   
184    # if we're here, then connection succeeded, store handle
185    $self->{'db_handle'} = $dbh;
186    return 1;
187}
188
189# Load the designated database, i.e. 'use <dbname>;'.
190# If the database doesn't yet exist, creates it and loads it.
191# (Don't create the collection's tables yet, though)
192# At the end it will have loaded the requested database (in MySQL: "use <db>;") on success.
193# As usual, returns success or failure value that can be evaluated in a boolean context.
194sub use_db {
195    my $self= shift (@_);
196    my ($db_name) = @_;
197    my $dbh = $self->{'db_handle'};
198    $db_name = $self->sanitize_name($db_name);
199   
200    print STDERR "Attempting to use database $db_name\n" if($self->{'verbosity'});
201   
202    # perl DBI switch database: https://www.perlmonks.org/?node_id=995434
203    # do() returns undef on error.
204    # connection succeeded, try to load our database. If that didn't work, attempt to create db
205    my $success = $dbh->do("use $db_name");
206   
207    if(!$success && $dbh->err == 1049) { # "Unknown database" error has code 1049 (mysql only?) meaning db doesn't exist yet
208
209    print STDERR "Database $db_name didn't exist, creating it along with the tables for the current collection...\n" if($self->{'verbosity'});
210   
211    # attempt to create the db and its tables
212    $self->create_db($db_name) || return 0;
213
214    print STDERR "   Created database $db_name\n" if($self->{'verbosity'} > 1);
215   
216    # once more attempt to use db, now that it exists
217    $dbh->do("use $db_name") || return 0;
218    #$dbh->do("use $db_name") or die "Error (code" . $dbh->err ."): " . $dbh->errstr . "\n";
219
220    $success = 1;
221    }
222    elsif($success) { # database existed and loaded successfully, but
223    # before proceeding check that the current collection's tables exist
224
225    print STDERR "@@@ DATABASE $db_name EXISTED\n" if($self->{'verbosity'} > 2);
226    }
227   
228    return $success; # could still return 0, if database failed to load with an error code != 1049
229}
230
231# We should already have done "use <database>;" if this gets called.
232# Just load this collection's metatable
233sub ensure_meta_table_exists {
234    my $self = shift (@_);
235   
236    my $tablename = $self->get_metadata_table_name();
237    if(!$self->table_exists($tablename)) {
238    #print STDERR "   Creating metadata table $tablename\n" if($self->{'verbosity'} > 1);
239    $self->create_metadata_table() || return 0;
240    } else {
241    print STDERR "@@@ Meta table exists\n" if($self->{'verbosity'} > 2);
242    }
243    return 1;
244}
245
246# We should already have done "use <database>;" if this gets called.
247# Just load this collection's metatable
248sub ensure_fulltxt_table_exists {
249    my $self = shift (@_);
250   
251    my $tablename = $self->get_fulltext_table_name();   
252    if(!$self->table_exists($tablename)) {
253    #print STDERR "   Creating fulltxt table $tablename\n" if($self->{'verbosity'} > 1);
254    $self->create_fulltext_table() || return 0;
255    } else {
256    print STDERR "@@@ Fulltxt table exists\n" if($self->{'verbosity'} > 2);
257    }
258    return 1;
259}
260
261# disconnect from db - https://metacpan.org/pod/DBI#disconnect
262# TODO: make sure to have committed or rolled back before disconnect
263# and that you've call finish() on statement handles if any fetch remnants remain
264sub disconnect_from_db {
265    my $self= shift (@_);   
266    my $dbh = $self->{'db_handle'};
267
268    # make sure any active stmt handles are finished
269    # NO: "When all the data has been fetched from a SELECT statement, the driver will automatically call finish for you. So you should not call it explicitly except when you know that you've not fetched all the data from a statement handle and the handle won't be destroyed soon."
270   
271    #$meta_sth = $self->{'metadata_prepared_insert_statement_handle'};
272    #$txt_sth = $self->{'fulltxt_prepared_insert_statement_handle'};
273    #$meta_sth->finish() if($meta_sth);
274    #$txt_sth->finish() if($txt_sth);
275
276    print STDERR "Disconnecting from database\n" if($self->{'verbosity'} > 1);
277   
278    my $rc = $dbh->disconnect or warn $dbh->errstr; # The handle is of little use after disconnecting. Possibly PrintError already prints a warning and this duplicates it?
279    return $rc;
280}
281
282sub create_db {
283    my $self= shift (@_);
284    my ($db_name) = @_;
285    my $dbh = $self->{'db_handle'};
286    $db_name = $self->sanitize_name($db_name);
287   
288    # https://stackoverflow.com/questions/5025768/how-can-i-create-a-mysql-database-from-a-perl-script
289    return $dbh->do("create database $db_name"); # do() will return undef on fail, https://metacpan.org/pod/DBI#do
290}
291
292
293sub create_metadata_table {
294    my $self= shift (@_);
295    my $dbh = $self->{'db_handle'};
296   
297    my $table_name = $self->get_metadata_table_name();
298    print STDERR "   Creating table $table_name\n" if($self->{'verbosity'} > 1);
299   
300    # If using an auto incremented primary key:
301    my $stmt = "CREATE TABLE $table_name (id INT NOT NULL AUTO_INCREMENT, did VARCHAR(63) NOT NULL, sid VARCHAR(63) NOT NULL, metaname VARCHAR(127) NOT NULL, metavalue VARCHAR(1023) NOT NULL, PRIMARY KEY(id));";
302    return $dbh->do($stmt);
303}
304
305# TODO: Investigate: https://dev.mysql.com/doc/search/?d=10&p=1&q=FULLTEXT
306# 12.9.1 Natural Language Full-Text Searches
307# to see whether we have to index the 'fulltxt' column of the 'fulltext' tables
308# or let user edit this file, or add it as another option
309sub create_fulltext_table {
310    my $self= shift (@_);
311    my $dbh = $self->{'db_handle'};
312   
313    my $table_name = $self->get_fulltext_table_name();
314    print STDERR "   Creating table $table_name\n" if($self->{'verbosity'} > 1);
315   
316    # If using an auto incremented primary key:
317    my $stmt = "CREATE TABLE $table_name (id INT NOT NULL AUTO_INCREMENT, did VARCHAR(63) NOT NULL, sid VARCHAR(63) NOT NULL, fulltxt LONGTEXT, PRIMARY KEY(id));";
318    return $dbh->do($stmt);
319
320}
321
322# "IF EXISTS is used to prevent an error from occurring if the database does not exist. ... DROP DATABASE returns the number of tables that were removed. The DROP DATABASE statement removes from the given database directory those files and directories that MySQL itself may create during normal operation.Jun 20, 2012"
323# MySQL 8.0 Reference Manual :: 13.1.22 DROP DATABASE Syntax
324# https://dev.mysql.com/doc/en/drop-database.html
325sub delete_collection_tables {
326    my $self= shift (@_);
327    my $dbh = $self->{'db_handle'};
328   
329    # drop table <tablename>
330    my $table = $self->get_metadata_table_name();
331    if($self->table_exists($table)) {
332    $dbh->do("drop table $table") || warn("@@@ Couldn't delete $table");
333    }
334    $table = $self->get_fulltext_table_name();
335    if($self->table_exists($table)) {
336    $dbh->do("drop table $table") || warn("@@@ Couldn't delete $table");
337    }
338}
339
340# Don't call this: it will delete the meta and full text tables for ALL collections in $db_name (localsite by default)!
341# This method is just here for debugging (for testing creating a database when there is none)
342sub _delete_database {
343    my $self= shift (@_);
344    my ($db_name) = @_;
345    my $dbh = $self->{'db_handle'};
346    $db_name = $self->sanitize_name($db_name);
347   
348    print STDERR "!!! Deleting database $db_name\n" if($self->{'verbosity'});
349   
350    # "drop database dbname"
351    $dbh->do("drop database $db_name") || return 0;
352
353    return 1;
354}
355
356
357########################### DB STATEMENTS ###########################
358
359# USEFUL: https://metacpan.org/pod/DBI
360# "Many methods have an optional \%attr parameter which can be used to pass information to the driver implementing the method. Except where specifically documented, the \%attr parameter can only be used to pass driver specific hints. In general, you can ignore \%attr parameters or pass it as undef."
361
362
363# https://www.guru99.com/insert-into.html
364# and https://dev.mysql.com/doc/refman/8.0/en/example-auto-increment.html
365#     for inserting multiple rows at once
366# https://www.perlmonks.org/bare/?node_id=316183
367# https://metacpan.org/pod/DBI#do
368# https://www.quora.com/What-is-the-difference-between-prepare-and-do-statements-in-Perl-while-we-make-a-connection-to-the-database-for-executing-the-query
369# https://docstore.mik.ua/orelly/linux/dbi/ch05_05.htm
370
371# https://metacpan.org/pod/DBI#performance
372# 'The q{...} style quoting used in this example avoids clashing with quotes that may be used in the SQL statement. Use the double-quote like qq{...} operator if you want to interpolate variables into the string. See "Quote and Quote-like Operators" in perlop for more details.'
373sub prepare_insert_metadata_row_stmthandle {
374    my $self = shift (@_);   
375    #my ($did, $sid, $metaname, $metavalue) = @_;
376    my $dbh = $self->{'db_handle'};
377   
378    my $tablename = $self->get_metadata_table_name();
379
380    #my $stmt = "INSERT INTO $tablename (did, sid, metaname, metavalue) VALUES ('$did', '$sid', '$metaname', '$metavalue');"; # ?, ?, ?, ?
381
382    # using qq{} since we want $tablename placeholder to be filled in
383    # returns Statement Handle object!
384    my $sth = $dbh->prepare(qq{INSERT INTO $tablename (did, sid, metaname, metavalue) VALUES (?, ?, ?, ?)}) || warn("Could not prepare insert statement for metadata table\n");
385
386    print STDERR "@@@@ Prepared meta insert statement: ".$sth->{'Statement'}."\n" if($self->{'verbosity'} > 2);
387   
388    return $sth;
389}
390
391sub prepare_insert_fulltxt_row_stmthandle {
392    my $self = shift (@_);
393    #my ($did, $sid, $fulltext) = @_;
394    my $dbh = $self->{'db_handle'};
395   
396    my $tablename = $self->get_fulltext_table_name();
397
398    #my $stmt = "INSERT INTO $tablename (did, sid, fulltxt) VALUES ('$did', '$sid', '$fulltext');"; ?, ?, ?
399
400    # using qq{} since we want $tablename placeholder to be filled in
401    # returns Statement Handle object!
402    my $sth = $dbh->prepare(qq{INSERT INTO $tablename (did, sid, fulltxt) VALUES (?, ?, ?)}) || warn("Could not prepare insert statement for fulltxt table\n");
403   
404    print STDERR "@@@@ Prepared fulltext insert statement: ".$sth->{'Statement'}."\n" if($self->{'verbosity'} > 2);
405   
406    return $sth;
407}
408
409
410## The 2 select statements used by GreenstoneSQLPlugin
411
412# Returns the statement handle that prepared and executed
413# a "SELECT * FROM <COLL>_metadata WHERE did = $oid" SQL statement.
414# Caller can call fetchrow_array() on returned statement handle, $sth
415# Have to use prepare() and execute() instead of do() since do() does
416# not allow for fetching result set thereafter:
417# do(): "This method  is typically most useful for non-SELECT statements that either cannot be prepared in advance (due to a limitation of the driver) or do not need to be executed repeatedly. It should not be used for SELECT statements because it does not return a statement handle (so you can't fetch any data)." https://metacpan.org/pod/release/TIMB/DBI-1.634_50/DBI.pm#do
418sub select_from_metatable_matching_docid {
419    my $self= shift (@_);
420    my ($oid) = @_;
421   
422    my $dbh = $self->{'db_handle'};
423    my $meta_table = $self->get_metadata_table_name();
424   
425    my $sth = $dbh->prepare(qq{SELECT * FROM $meta_table WHERE did = ?});
426    $sth->execute( $oid ); # will print msg on fail
427   
428    return $sth; # caller can call fetchrow_array() on returned statement handle, sth
429}
430
431# Returns the statement handle that prepared and executed
432# a "SELECT * FROM <COLL>_metadata WHERE did = $oid" SQL statement.
433# Caller can call fetchrow_array() on returned statement handle, $sth
434sub select_from_texttable_matching_docid {
435    my $self= shift (@_);
436    my ($oid) = @_;
437   
438    my $dbh = $self->{'db_handle'};
439    my $fulltxt_table = $self->get_fulltext_table_name();
440   
441    my $sth = $dbh->prepare(qq{SELECT * FROM $fulltxt_table WHERE did = ?});
442    $sth->execute( $oid ); # will print msg on fail
443   
444    return $sth; # caller can call fetchrow_array() on returned statement handle, sth
445}
446
447# delete all records in metatable with specified docid
448# https://www.tutorialspoint.com/mysql/mysql-delete-query.htm
449# DELETE FROM table_name [WHERE Clause]
450# see example under 'do' at https://metacpan.org/pod/release/TIMB/DBI-1.634_50/DBI.pm
451sub delete_recs_from_metatable_with_docid {
452    my $self= shift (@_);
453    my ($oid) = @_;
454   
455    my $dbh = $self->{'db_handle'};
456    my $meta_table = $self->get_metadata_table_name();
457   
458    #my $rows_deleted =
459    $dbh->do(qq{DELETE FROM $meta_table WHERE did = ?}, undef, $oid)
460    or warn $dbh->errstr;
461}
462
463# delete all records in metatable with specified docid
464sub delete_recs_from_texttable_with_docid {
465    my $self= shift (@_);
466    my ($oid) = @_;
467   
468    my $dbh = $self->{'db_handle'};   
469    my $fulltxt_table = $self->get_fulltext_table_name();
470   
471    $dbh->do(qq{DELETE FROM $fulltxt_table WHERE did = ?}, undef, $oid)
472    or warn $dbh->errstr;
473}
474
475# Can call this after connection succeeded to get the database handle, dbh,
476# if any specific DB operation (SQL statement, create/delete)
477# needs to be executed that is not already provided as a method of this class.
478sub get_db_handle {
479    my $self= shift (@_);
480    return $self->{'db_handle'};
481}
482
483################ HELPER METHODS ##############
484
485# More basic helper methods
486sub get_metadata_table_name {
487    my $self= shift (@_);
488    my $table_name = $self->{'tablename_prefix'} . "_metadata";
489    return $table_name;
490}
491
492# FULLTEXT is a reserved keyword in (My)SQL. https://dev.mysql.com/doc/refman/5.5/en/keywords.html
493# So we can't name a table or any of its columns "fulltext". We use "fulltxt" instead.
494sub get_fulltext_table_name {
495    my $self= shift (@_);
496    my $table_name = $self->{'tablename_prefix'} . "_fulltxt";
497    return $table_name;
498}
499
500# Attempt to make sure the name parameter (for db or table name) is acceptable syntax
501# for the db in question, e.g. for mysql. For example, (My)SQL doesn't like tables or
502# databases with '-' (hyphens) in their names
503sub sanitize_name {
504    my $self= shift (@_);
505    my ($name) = @_;
506    $name =~ s/-/_/g;
507    return $name;
508}
509
510
511# I can get my version of table_exists to work, but it's not so ideal
512# Interesting that MySQL has non-standard command to CREATE TABLE IF NOT EXISTS and DROP TABLE IF EXISTS,
513# see https://www.perlmonks.org/bare/?node=DBI%20Recipes
514#    The page further has a table_exists function that could work with proper comparison
515# TODO Q: Couldn't get the first solution at https://www.perlmonks.org/bare/?node_id=500050 to work though
516sub table_exists {
517    my $self = shift (@_);
518    my $dbh = $self->{'db_handle'};
519    my ($table_name) = @_;
520
521    my @table_list = $dbh->tables;
522    #my $tables_str = @table_list[0];
523    foreach my $table (@table_list) {
524    return 1 if ($table =~ m/$table_name/);
525    }
526    return 0;
527}
528
5291;
Note: See TracBrowser for help on using the browser.