source: main/trunk/greenstone2/perllib/inexport.pm@ 27482

Last change on this file since 27482 was 27482, checked in by jmt12, 11 years ago

Replace slash replacement regexs with a call the FileUtils::sanitizePath() which does a much better job of preserving file protocols
  • Property svn:executable set to *
File size: 44.5 KB
Line 
1###########################################################################
2#
3# inexport.pm -- useful class to support import.pl and export.pl
4# A component of the Greenstone digital library software
5# from the New Zealand Digital Library Project at the
6# University of Waikato, New Zealand.
7#
8# Copyright (C) 1999 New Zealand Digital Library Project
9#
10# This program is free software; you can redistribute it and/or modify
11# it under the terms of the GNU General Public License as published by
12# the Free Software Foundation; either version 2 of the License, or
13# (at your option) any later version.
14#
15# This program is distributed in the hope that it will be useful,
16# but WITHOUT ANY WARRANTY; without even the implied warranty of
17# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18# GNU General Public License for more details.
19#
20# You should have received a copy of the GNU General Public License
21# along with this program; if not, write to the Free Software
22# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
23#
24###########################################################################
25
26package inexport;
27
28use strict;
29
30no strict 'refs'; # allow filehandles to be variables and vice versa
31no strict 'subs'; # allow barewords (eg STDERR) as function arguments
32
33use arcinfo;
34use colcfg;
35use dbutil;
36use doc;
37use plugin;
38use plugout;
39use manifest;
40use inexport;
41use util;
42use scriptutil;
43use FileHandle;
44use gsprintf 'gsprintf';
45use printusage;
46use parse2;
47
48use File::Basename;
49
50sub new
51{
52 my $class = shift (@_);
53 my ($mode,$argv,$options,$opt_listall_options) = @_;
54
55 my $self = { 'xml' => 0, 'mode' => $mode };
56
57 # general options available to all plugins
58 my $arguments = $options->{'args'};
59 my $intArgLeftinAfterParsing = parse2::parse($argv,$arguments,$self,"allow_extra_options");
60 # Parse returns -1 if something has gone wrong
61 if ($intArgLeftinAfterParsing == -1)
62 {
63 &PrintUsage::print_txt_usage($options, "{import.params}");
64 die "\n";
65 }
66
67 my $language = $self->{'language'};
68 # If $language has been specified, load the appropriate resource bundle
69 # (Otherwise, the default resource bundle will be loaded automatically)
70 if ($language && $language =~ /\S/) {
71 &gsprintf::load_language_specific_resource_bundle($language);
72 }
73
74 if ($self->{'listall'}) {
75 if ($self->{'xml'}) {
76 &PrintUsage::print_xml_usage($opt_listall_options);
77 }
78 else
79 {
80 &PrintUsage::print_txt_usage($opt_listall_options,"{export.params}");
81 }
82 die "\n";
83 }
84
85
86 if ($self->{'xml'}) {
87 &PrintUsage::print_xml_usage($options);
88 print "\n";
89 return bless $self, $class;
90 }
91
92 if ($self->{'gli'}) { # the gli wants strings to be in UTF-8
93 &gsprintf::output_strings_in_UTF8;
94 }
95
96 # now check that we had exactly one leftover arg, which should be
97 # the collection name. We don't want to do this earlier, cos
98 # -xml arg doesn't need a collection name
99 # Or if the user specified -h, then we output the usage also
100
101 if ($intArgLeftinAfterParsing != 1 || (@$argv && $argv->[0] =~ /^\-+h/))
102 {
103 &PrintUsage::print_txt_usage($options, "{import.params}");
104 die "\n";
105 }
106
107 $self->{'close_out'} = 0;
108 my $out = $self->{'out'};
109 if ($out !~ /^(STDERR|STDOUT)$/i) {
110 open (OUT, ">$out") ||
111 (&gsprintf(STDERR, "{common.cannot_open_output_file}: $!\n", $out) && die);
112 $out = 'inexport::OUT';
113 $self->{'close_out'} = 1;
114 }
115 $out->autoflush(1);
116 $self->{'out'} = $out;
117
118 # @ARGV should be only one item, the name of the collection
119 $self->{'collection'} = shift @$argv;
120
121 # Unless otherwise stated all manifests are considered version 1---where
122 # they act more like an advanced process expression---as compared to newer
123 # manifest files that act as an explicit (and exhaustive) list of files to
124 # process [jmt12]
125 $self->{'manifest_version'} = 1;
126
127 return bless $self, $class;
128}
129
130# Simplified version of the contstructor for use with CGI scripts
131sub newCGI
132{
133 my $class = shift (@_);
134 my ($mode,$collect,$gsdl_cgi,$opt_site) = @_;
135
136 my $self = { 'xml' => 0, 'mode' => $mode };
137
138 $self->{'out'} = STDERR;
139
140 if (defined $gsdl_cgi) {
141 $self->{'site'} = $opt_site;
142 my $collect_dir = $gsdl_cgi->get_collection_dir($opt_site);
143 $self->{'collectdir'} = $collect_dir;
144 }
145 else {
146 $self->{'site'} = "";
147 $self->{'collectdir'} = &FileUtils::filenameConcatenate($ENV{'GSDLHOME'},"collect");
148 }
149 $self->{'faillog'} = "";
150
151 $self->{'collection'} = $collect;
152
153 return bless $self, $class;
154}
155sub get_collection
156{
157 my $self = shift @_;
158
159 return $self->{'collection'};
160}
161
162
163sub read_collection_cfg
164{
165 my $self = shift @_;
166 my ($collection,$options) = @_;
167
168 my $collectdir = $self->{'collectdir'};
169 my $site = $self->{'site'};
170 my $out = $self->{'out'};
171
172 if (($collection = &colcfg::use_collection($site, $collection, $collectdir)) eq "") {
173 &PrintUsage::print_txt_usage($options, "{import.params}");
174 die "\n";
175 }
176
177 # set gs_version 2/3
178 $self->{'gs_version'} = "2";
179 if ((defined $site) && ($site ne "")) {
180 # gs3
181 $self->{'gs_version'} = "3";
182 }
183
184 # add collection's perllib dir into include path in
185 # case we have collection specific modules
186 &util::augmentINC(&FileUtils::filenameConcatenate($ENV{'GSDLCOLLECTDIR'}, 'perllib'));
187
188 # check that we can open the faillog
189 my $faillog = $self->{'faillog'};
190 if ($faillog eq "") {
191 $faillog = &FileUtils::filenameConcatenate($ENV{'GSDLCOLLECTDIR'}, "etc", "fail.log");
192 }
193 open (FAILLOG, ">$faillog") ||
194 (&gsprintf(STDERR, "{import.cannot_open_fail_log}\n", $faillog) && die);
195
196
197 my $faillogname = $faillog;
198 $faillog = 'inexport::FAILLOG';
199 $faillog->autoflush(1);
200 $self->{'faillog'} = $faillog;
201 $self->{'faillogname'} = $faillogname;
202 $self->{'close_faillog'} = 1;
203
204 # Read in the collection configuration file.
205 my $gs_mode = "gs".$self->{'gs_version'}; #gs2 or gs3
206 my $config_filename = &colcfg::get_collect_cfg_name($out, $gs_mode);
207 my $collectcfg = &colcfg::read_collection_cfg ($config_filename, $gs_mode);
208
209 return ($config_filename,$collectcfg);
210}
211
212sub set_collection_options
213{
214 my $self = shift @_;
215 my ($collectcfg) = @_;
216
217 my $inexport_mode = $self->{'mode'};
218
219 my $verbosity = $self->{'verbosity'};
220 my $debug = $self->{'debug'};
221 my $importdir = $self->{'importdir'};
222 my $archivedir = $self->{'archivedir'} || $self->{'exportdir'} || "";
223 my $out = $self->{'out'};
224
225 # If the infodbtype value wasn't defined in the collect.cfg file, use the default
226 if (!defined($collectcfg->{'infodbtype'}))
227 {
228 $collectcfg->{'infodbtype'} = &dbutil::get_default_infodb_type();
229 }
230 if ($collectcfg->{'infodbtype'} eq "gdbm-txtgz") {
231 # we can't use the text version for archives dbs.
232 $collectcfg->{'infodbtype'} = "gdbm";
233 }
234
235 if (defined $collectcfg->{'importdir'} && $importdir eq "") {
236 $importdir = $collectcfg->{'importdir'};
237 }
238 if (defined $collectcfg->{'archivedir'} && $archivedir eq "") {
239 $archivedir = $collectcfg->{'archivedir'};
240 }
241 # fill in the default import and archives directories if none
242 # were supplied, turn all \ into / and remove trailing /
243 if ($importdir eq "")
244 {
245 $importdir = &FileUtils::filenameConcatenate($ENV{'GSDLCOLLECTDIR'}, "import");
246 }
247 else
248 {
249 # Don't do this - it kills protocol prefixes
250 #$importdir =~ s/[\\\/]+/\//g;
251 #$importdir =~ s/\/$//;
252 # Do this instead
253 &FileUtils::sanitizePath($importdir);
254 }
255 if (!&FileUtils::directoryExists($importdir))
256 {
257 &gsprintf($out, "{import.no_import_dir}\n\n", $importdir);
258 die "\n";
259 }
260 $self->{'importdir'} = $importdir;
261
262 if ($archivedir eq "") {
263 if ($inexport_mode eq "import") {
264 $archivedir = &FileUtils::filenameConcatenate($ENV{'GSDLCOLLECTDIR'}, "archives");
265 }
266 elsif ($inexport_mode eq "export") {
267 $archivedir = &FileUtils::filenameConcatenate($ENV{'GSDLCOLLECTDIR'}, "export");
268 }
269 else {
270 print STDERR "Warning: Unrecognized import/export mode '$inexport_mode'\n";
271 print STDERR " Defaulting to 'archives' for file output\n";
272 $archivedir = &FileUtils::filenameConcatenate($ENV{'GSDLCOLLECTDIR'}, "archives");
273 }
274 }
275
276 $archivedir = &FileUtils::sanitizePath($archivedir)
277 #$archivedir =~ s/[\\\/]+/\//g;
278 #$archivedir =~ s/\/$//;
279 $self->{'archivedir'} = $archivedir;
280
281 if ($verbosity !~ /\d+/) {
282 if (defined $collectcfg->{'verbosity'} && $collectcfg->{'verbosity'} =~ /\d+/) {
283 $verbosity = $collectcfg->{'verbosity'};
284 } else {
285 $verbosity = 2; # the default
286 }
287 }
288 $self->{'verbosity'} = $verbosity;
289
290 if (defined $collectcfg->{'manifest'} && $self->{'manifest'} eq "") {
291 $self->{'manifest'} = $collectcfg->{'manifest'};
292 }
293
294 if (defined $collectcfg->{'gzip'} && !$self->{'gzip'}) {
295 if ($collectcfg->{'gzip'} =~ /^true$/i) {
296 $self->{'gzip'} = 1;
297 }
298 }
299
300 if ($self->{'maxdocs'} !~ /\-?\d+/) {
301 if (defined $collectcfg->{'maxdocs'} && $collectcfg->{'maxdocs'} =~ /\-?\d+/) {
302 $self->{'maxdocs'} = $collectcfg->{'maxdocs'};
303 } else {
304 $self->{'maxdocs'} = -1; # the default
305 }
306 }
307
308 if ((defined $self->{'groupsize'}) && ($self->{'groupsize'} == 1)) {
309 if (defined $collectcfg->{'groupsize'} && $collectcfg->{'groupsize'} =~ /\d+/) {
310 $self->{'groupsize'} = $collectcfg->{'groupsize'};
311 }
312 }
313
314 if (!defined $self->{'OIDtype'}
315 || ($self->{'OIDtype'} !~ /^(hash|hash_on_full_filename|incremental|assigned|filename|dirname|full_filename)$/ )) {
316 # OIDtype was either not defined on the command-line, or if it was not one of the recognized values
317 if (defined $collectcfg->{'OIDtype'}
318 && $collectcfg->{'OIDtype'} =~ /^(hash|hash_on_full_filename|incremental|assigned|filename|dirname|full_filename)$/) {
319 $self->{'OIDtype'} = $collectcfg->{'OIDtype'};
320 } else {
321 $self->{'OIDtype'} = "hash"; # the default
322 }
323 }
324
325 if ((!defined $self->{'OIDmetadata'}) || ($self->{'OIDmetadata'} eq "")) {
326 if (defined $collectcfg->{'OIDmetadata'}) {
327 $self->{'OIDmetadata'} = $collectcfg->{'OIDmetadata'};
328 } else {
329 $self->{'OIDmetadata'} = "dc.Identifier"; # the default
330 }
331 }
332
333 my $sortmeta = $self->{'sortmeta'};
334 if (defined $collectcfg->{'sortmeta'} && (!defined $sortmeta || $sortmeta eq "")) {
335 $sortmeta = $collectcfg->{'sortmeta'};
336 }
337 # sortmeta cannot be used with group size
338 $sortmeta = undef unless defined $sortmeta && $sortmeta =~ /\S/;
339 if (defined $sortmeta && $self->{'groupsize'} > 1) {
340 &gsprintf($out, "{import.cannot_sort}\n\n");
341 $sortmeta = undef;
342 }
343 $self->{'sortmeta'} = $sortmeta;
344
345 if (defined $collectcfg->{'removeprefix'} && $self->{'removeprefix'} eq "") {
346 $self->{'removeprefix'} = $collectcfg->{'removeprefix'};
347 }
348
349 if (defined $collectcfg->{'removesuffix'} && $self->{'removesuffix'} eq "") {
350 $self->{'removesuffix'} = $collectcfg->{'removesuffix'};
351 }
352 if (defined $collectcfg->{'debug'} && $collectcfg->{'debug'} =~ /^true$/i) {
353 $self->{'debug'} = 1;
354 }
355 if (defined $collectcfg->{'gli'} && $collectcfg->{'gli'} =~ /^true$/i) {
356 $self->{'gli'} = 1;
357 }
358 $self->{'gli'} = 0 unless defined $self->{'gli'};
359
360 # check keepold and removeold
361 my $checkdir = ($inexport_mode eq "import") ? "archives" : "export";
362
363 my ($removeold, $keepold, $incremental, $incremental_mode)
364 = &scriptutil::check_removeold_and_keepold($self->{'removeold'}, $self->{'keepold'},
365 $self->{'incremental'}, $checkdir,
366 $collectcfg);
367
368 $self->{'removeold'} = $removeold;
369 $self->{'keepold'} = $keepold;
370 $self->{'incremental'} = $incremental;
371 $self->{'incremental_mode'} = $incremental_mode;
372
373 # Since this wasted my morning, let's at least warn a user that manifest
374 # files now *only* work if keepold is set [jmt12]
375 if ($self->{'manifest'} && !$self->{'keepold'})
376 {
377 print STDERR "Warning: -manifest flag should not be specified without also setting -keepold or -incremental\n";
378 }
379}
380
381sub process_files
382{
383 my $self = shift @_;
384 my ($config_filename,$collectcfg) = @_;
385
386 my $inexport_mode = $self->{'mode'};
387
388 my $verbosity = $self->{'verbosity'};
389 my $debug = $self->{'debug'};
390
391 my $importdir = $self->{'importdir'};
392 my $archivedir = $self->{'archivedir'} || $self->{'exportdir'};
393
394 my $incremental = $self->{'incremental'};
395 my $incremental_mode = $self->{'incremental_mode'};
396
397 my $gs_version = $self->{'gs_version'};
398
399 my $removeold = $self->{'removeold'};
400 my $keepold = $self->{'keepold'};
401
402 my $saveas = $self->{'saveas'};
403 my $OIDtype = $self->{'OIDtype'};
404 my $OIDmetadata = $self->{'OIDmetadata'};
405
406 my $out = $self->{'out'};
407 my $faillog = $self->{'faillog'};
408
409 my $maxdocs = $self->{'maxdocs'};
410 my $gzip = $self->{'gzip'};
411 my $groupsize = $self->{'groupsize'};
412 my $sortmeta = $self->{'sortmeta'};
413
414 my $removeprefix = $self->{'removeprefix'};
415 my $removesuffix = $self->{'removesuffix'};
416
417 my $gli = $self->{'gli'};
418
419 # related to export
420 my $xsltfile = $self->{'xsltfile'};
421 my $group_marc = $self->{'group_marc'};
422 my $mapping_file = $self->{'mapping_file'};
423 my $xslt_mets = $self->{'xslt_mets'};
424 my $xslt_txt = $self->{'xslt_txt'};
425 my $fedora_namespace = $self->{'fedora_namespace'};
426 my $metadata_prefix = $self->{'metadata_prefix'};
427
428 if ($inexport_mode eq "import") {
429 print STDERR "<Import>\n" if $gli;
430 }
431 else {
432 print STDERR "<export>\n" if $gli;
433 }
434
435 my $manifest_lookup = new manifest($collectcfg->{'infodbtype'},$archivedir);
436 if ($self->{'manifest'} ne "") {
437 my $manifest_filename = $self->{'manifest'};
438
439 if (!&FileUtils::isFilenameAbsolute($manifest_filename)) {
440 $manifest_filename = &FileUtils::filenameConcatenate($ENV{'GSDLCOLLECTDIR'}, $manifest_filename);
441 }
442
443 $self->{'manifest'} = &FileUtils::sanitizePath($self->{'manifest'});
444 #$self->{'manifest'} =~ s/[\\\/]+/\//g;
445 #$self->{'manifest'} =~ s/\/$//;
446
447 $manifest_lookup->parse($manifest_filename);
448
449 # manifests may now include a version number [jmt12]
450 $self->{'manifest_version'} = $manifest_lookup->get_version();
451 }
452
453 my $manifest = $self->{'manifest'};
454
455 # load all the plugins
456 my $plugins = [];
457 if (defined $collectcfg->{'plugin'}) {
458 $plugins = $collectcfg->{'plugin'};
459 }
460
461 my $plugin_incr_mode = $incremental_mode;
462 if ($manifest ne "") {
463 # if we have a manifest file, then we pretend we are fully incremental for plugins
464 $plugin_incr_mode = "all";
465 }
466 #some global options for the plugins
467 my @global_opts = ();
468
469 my $pluginfo = &plugin::load_plugins ($plugins, $verbosity, $out, $faillog, \@global_opts, $plugin_incr_mode, $gs_version);
470 if (scalar(@$pluginfo) == 0) {
471 &gsprintf($out, "{import.no_plugins_loaded}\n");
472 die "\n";
473 }
474
475 # remove the old contents of the archives directory (and tmp
476 # directory) if needed
477
478 if ($removeold) {
479 if (&FileUtils::directoryExists($archivedir)) {
480 &gsprintf($out, "{import.removing_archives}\n");
481 &FileUtils::removeFilesRecursive($archivedir);
482 }
483 my $tmpdir = &FileUtils::filenameConcatenate($ENV{'GSDLCOLLECTDIR'}, "tmp");
484 $tmpdir =~ s/[\\\/]+/\//g;
485 $tmpdir =~ s/\/$//;
486 if (&FileUtils::directoryExists($tmpdir)) {
487 &gsprintf($out, "{import.removing_tmpdir}\n");
488 &FileUtils::removeFilesRecursive($tmpdir);
489 }
490 }
491
492 # create the archives dir if needed
493 &FileUtils::makeAllDirectories($archivedir);
494
495 # read the archive information file
496
497 # BACKWARDS COMPATIBILITY: Just in case there are old .ldb/.bdb files (won't do anything for other infodbtypes)
498 &util::rename_ldb_or_bdb_file(&FileUtils::filenameConcatenate($archivedir, "archiveinf-doc"));
499 &util::rename_ldb_or_bdb_file(&FileUtils::filenameConcatenate($archivedir, "archiveinf-src"));
500
501 # When we make these initial calls to determine the archive information doc
502 # and src databases we pass through a '1' to indicate this is the first
503 # time we are referring to these databases. When using dynamic dbutils
504 # (available in extensions) this indicates to some database types (for
505 # example, persistent servers) that this is a good time to perform any
506 # one time initialization. The argument has no effect on vanilla dbutils
507 # [jmt12]
508 my $perform_firsttime_init = 1;
509 my $arcinfo_doc_filename = &dbutil::get_infodb_file_path($collectcfg->{'infodbtype'}, "archiveinf-doc", $archivedir, $perform_firsttime_init);
510 my $arcinfo_src_filename = &dbutil::get_infodb_file_path($collectcfg->{'infodbtype'}, "archiveinf-src", $archivedir, $perform_firsttime_init);
511
512 my $archive_info = new arcinfo ($collectcfg->{'infodbtype'});
513 $archive_info->load_info ($arcinfo_doc_filename);
514
515 if ($manifest eq "") {
516 # Load in list of files in import folder from last import (if present)
517 $archive_info->load_prev_import_filelist ($arcinfo_src_filename);
518 }
519
520 ####Use Plugout####
521 my $plugout;
522
523 if ($inexport_mode eq "import") {
524 if (defined $collectcfg->{'plugout'}) {
525 # If a plugout was specified in the collect.cfg file, assume it is sensible
526 # We can't check the name because it could be anything, if it is a custom plugout
527 $plugout = $collectcfg->{'plugout'};
528 }
529 else{
530 if ($saveas !~ /^(GreenstoneXML|GreenstoneMETS)$/) {
531 push @$plugout,"GreenstoneXMLPlugout";
532 }
533 else{
534 push @$plugout,$saveas."Plugout";
535 }
536 }
537 }
538 else {
539 if (defined $collectcfg->{'plugout'} && $collectcfg->{'plugout'} =~ /^(.*METS|DSpace|MARCXML)Plugout/) {
540 $plugout = $collectcfg->{'plugout'};
541 }
542 else{
543 if ($saveas !~ /^(GreenstoneMETS|FedoraMETS|DSpace|MARCXML)$/) {
544 push @$plugout,"GreenstoneMETSPlugout";
545 }
546 else{
547 push @$plugout,$saveas."Plugout";
548 }
549 }
550 }
551
552 my $plugout_name = $plugout->[0];
553
554 push @$plugout,("-output_info",$archive_info) if (defined $archive_info);
555 push @$plugout,("-verbosity",$verbosity) if (defined $verbosity);
556 push @$plugout,("-debug") if ($debug);
557 push @$plugout,("-group_size",$groupsize) if (defined $groupsize);
558 push @$plugout,("-gzip_output") if ($gzip);
559 push @$plugout,("-output_handle",$out) if (defined $out);
560
561 push @$plugout,("-xslt_file",$xsltfile) if (defined $xsltfile && $xsltfile ne "");
562
563 if ($plugout_name =~ m/^MARCXMLPlugout$/) {
564 push @$plugout,("-group") if ($group_marc);
565 push @$plugout,("-mapping_file",$mapping_file) if (defined $mapping_file && $mapping_file ne "");
566 }
567 if ($plugout_name =~ m/^.*METSPlugout$/) {
568 push @$plugout,("-xslt_mets",$xslt_mets) if (defined $xslt_mets && $xslt_mets ne "");
569 push @$plugout,("-xslt_txt",$xslt_txt) if (defined $xslt_txt && $xslt_txt ne "");
570 }
571
572 if ($plugout_name eq "FedoraMETSPlugout") {
573 push @$plugout,("-fedora_namespace",$fedora_namespace) if (defined $fedora_namespace && $fedora_namespace ne "");
574 }
575
576 if ($plugout_name eq "DSpacePlugout") {
577 push @$plugout,("-metadata_prefix",$metadata_prefix) if (defined $metadata_prefix && $metadata_prefix ne "");
578 }
579
580 my $processor = &plugout::load_plugout($plugout);
581 $processor->setoutputdir ($archivedir);
582 $processor->set_sortmeta ($sortmeta, $removeprefix, $removesuffix) if defined $sortmeta;
583
584 $processor->set_OIDtype ($OIDtype, $OIDmetadata);
585
586 &plugin::begin($pluginfo, $importdir, $processor, $maxdocs, $gli);
587
588 if ($removeold) {
589 # occasionally, plugins may want to do something on remove
590 # old, eg pharos image indexing
591 &plugin::remove_all($pluginfo, $importdir, $processor, $maxdocs, $gli);
592 }
593
594 # process the import directory
595 my $block_hash = {};
596 $block_hash->{'new_files'} = {};
597 $block_hash->{'reindex_files'} = {};
598 # all of these are set somewhere else, so it's more readable to define them
599 # here [jmt12]
600 $block_hash->{'all_files'} = {};
601 $block_hash->{'deleted_files'} = {};
602 $block_hash->{'file_blocks'} = {};
603 $block_hash->{'metadata_files'} = {};
604 $block_hash->{'shared_fileroot'} = '';
605 # a new flag so we can tell we had a manifest way down in the plugins
606 # [jmt12]
607 $block_hash->{'manifest'} = 'false';
608 my $metadata = {};
609
610 # global blocking pass may set up some metadata
611 # - when we have a newer manifest file we don't do this -unless- the
612 # collection configuration indicates this collection contains complex
613 # (inherited) metadata [jmt12]
614 if ($manifest eq '' || (defined $collectcfg->{'complexmeta'} && $collectcfg->{'complexmeta'} eq 'true'))
615 {
616 &plugin::file_block_read($pluginfo, $importdir, "", $block_hash, $metadata, $gli);
617 }
618 else
619 {
620 print STDERR "Skipping global file scan due to manifest and complexmeta configuration\n";
621 }
622
623 if ($manifest ne "") {
624
625 # mark that we are using a manifest - information that might be needed
626 # down in plugins (for instance DirectoryPlugin)
627 $block_hash->{'manifest'} = $self->{'manifest_version'};
628
629 #
630 # 1. Process delete files first
631 #
632 my @deleted_files = keys %{$manifest_lookup->{'delete'}};
633 my @full_deleted_files = ();
634
635 # ensure all filenames are absolute
636 foreach my $df (@deleted_files) {
637 my $full_df =
638 (&FileUtils::isFilenameAbsolute($df))
639 ? $df
640 : &FileUtils::filenameConcatenate($importdir,$df);
641
642 if (-d $full_df) {
643 &add_dir_contents_to_list($full_df, \@full_deleted_files);
644 } else {
645 push(@full_deleted_files,$full_df);
646 }
647 }
648
649 &plugin::remove_some($pluginfo, $collectcfg->{'infodbtype'}, $archivedir, \@full_deleted_files);
650 mark_docs_for_deletion($archive_info,{},
651 \@full_deleted_files,
652 $archivedir, $verbosity, "delete");
653
654
655 #
656 # 2. Now files for reindexing
657 #
658
659 my @reindex_files = keys %{$manifest_lookup->{'reindex'}};
660 my @full_reindex_files = ();
661 # ensure all filenames are absolute
662 foreach my $rf (@reindex_files) {
663 my $full_rf =
664 (&FileUtils::isFilenameAbsolute($rf))
665 ? $rf
666 : &FileUtils::filenameConcatenate($importdir,$rf);
667
668 if (-d $full_rf) {
669 &add_dir_contents_to_list($full_rf, \@full_reindex_files);
670 } else {
671 push(@full_reindex_files,$full_rf);
672 }
673 }
674
675 &plugin::remove_some($pluginfo, $collectcfg->{'infodbtype'}, $archivedir, \@full_reindex_files);
676 mark_docs_for_deletion($archive_info,{},\@full_reindex_files, $archivedir,$verbosity, "reindex");
677
678 # And now to ensure the new version of the file processed by
679 # appropriate plugin, we need to add it to block_hash reindex list
680 foreach my $full_rf (@full_reindex_files) {
681 $block_hash->{'reindex_files'}->{$full_rf} = 1;
682 }
683
684
685 #
686 # 3. Now finally any new files - add to block_hash new_files list
687 #
688
689 my @new_files = keys %{$manifest_lookup->{'index'}};
690 my @full_new_files = ();
691
692 foreach my $nf (@new_files) {
693 # ensure filename is absolute
694 my $full_nf =
695 (&FileUtils::isFilenameAbsolute($nf))
696 ? $nf
697 : &FileUtils::filenameConcatenate($importdir,$nf);
698
699 if (-d $full_nf) {
700 &add_dir_contents_to_list($full_nf, \@full_new_files);
701 } else {
702 push(@full_new_files,$full_nf);
703 }
704 }
705
706 my $arcinfo_src_filename = &dbutil::get_infodb_file_path($collectcfg->{'infodbtype'}, "archiveinf-src", $archivedir);
707 # need to check this file exists before trying to read it - in the past
708 # it wasn't possible to have a manifest unless keepold was also set so
709 # you were pretty much guarenteed arcinfo existed
710 # [jmt12]
711 # @todo &FileUtils::fileExists($arcinfo_src_filename) [jmt12]
712 if (-e $arcinfo_src_filename)
713 {
714 my $arcinfodb_map = {};
715 &dbutil::read_infodb_file($collectcfg->{'infodbtype'}, $arcinfo_src_filename, $arcinfodb_map);
716 foreach my $f (@full_new_files) {
717 # check that we haven't seen it already
718 if (defined $arcinfodb_map->{$f}) {
719 # TODO make better warning
720 print STDERR "Warning: $f already in src archive, \n";
721 } else {
722 $block_hash->{'new_files'}->{$f} = 1;
723 }
724 }
725
726 undef $arcinfodb_map;
727 }
728 # no existing files - so we can just add all the files [jmt12]
729 else
730 {
731 foreach my $f (@full_new_files)
732 {
733 $block_hash->{'new_files'}->{$f} = 1;
734 }
735 }
736
737 # If we are not using complex inherited metadata (and thus have skipped
738 # the global file scan) we need to at least check for a matching
739 # metadata.xml for the files being indexed/reindexed
740 # - unless we are using the newer version of Manifests, which are treated
741 # verbatim, and should have a metadata element for metadata files (so
742 # we can explicitly process metadata files other than metadata.xml)
743 # [jmt12]
744 if ($self->{'manifest_version'} < 1 && (!defined $collectcfg->{'complexmeta'} || $collectcfg->{'complexmeta'} ne 'true'))
745 {
746 my @all_files_to_import = (keys %{$block_hash->{'reindex_files'}}, keys %{$block_hash->{'new_files'}});
747 foreach my $file_to_import (@all_files_to_import)
748 {
749 my $metadata_xml_path = $file_to_import;
750 $metadata_xml_path =~ s/[^\\\/]*$/metadata.xml/;
751 if (&FileUtils::fileExists($metadata_xml_path))
752 {
753 &plugin::file_block_read($pluginfo, '', $metadata_xml_path, $block_hash, $metadata, $gli);
754 }
755 }
756 }
757
758 # new version manifest files explicitly list metadata files to be
759 # processed (ignoring complexmeta if set)
760 # [jmt12]
761 if ($self->{'manifest_version'} > 1)
762 {
763 # Process metadata files
764 foreach my $file_to_import (keys %{$block_hash->{'reindex_files'}}, keys %{$block_hash->{'new_files'}})
765 {
766 $self->perform_process_files($manifest, $pluginfo, '', $file_to_import, $block_hash, $metadata, $processor, $maxdocs);
767 }
768 }
769 }
770 else {
771 # if incremental, we read through the import folder to see whats changed.
772
773 if ($incremental || $incremental_mode eq "onlyadd") {
774 prime_doc_oid_count($archivedir);
775
776 # Can now work out which files were new, already existed, and have
777 # been deleted
778
779 new_vs_old_import_diff($archive_info,$block_hash,$importdir,
780 $archivedir,$verbosity,$incremental_mode);
781
782 my @new_files = sort keys %{$block_hash->{'new_files'}};
783 if (scalar(@new_files>0)) {
784 print STDERR "New files and modified metadata files since last import:\n ";
785 print STDERR join("\n ",@new_files), "\n";
786 }
787
788 if ($incremental) {
789 # only look for deletions if we are truely incremental
790 my @deleted_files = sort keys %{$block_hash->{'deleted_files'}};
791 # Filter out any in gsdl/tmp area
792 my @filtered_deleted_files = ();
793 my $gsdl_tmp_area = &FileUtils::filenameConcatenate($ENV{'GSDLHOME'}, "tmp");
794 my $collect_tmp_area = &FileUtils::filenameConcatenate($ENV{'GSDLCOLLECTDIR'}, "tmp");
795 $gsdl_tmp_area = &util::filename_to_regex($gsdl_tmp_area);
796 $collect_tmp_area = &util::filename_to_regex($collect_tmp_area);
797
798 foreach my $df (@deleted_files) {
799 next if ($df =~ m/^$gsdl_tmp_area/);
800 next if ($df =~ m/^$collect_tmp_area/);
801
802 push(@filtered_deleted_files,$df);
803 }
804
805
806 @deleted_files = @filtered_deleted_files;
807
808 if (scalar(@deleted_files)>0) {
809 print STDERR "Files deleted since last import:\n ";
810 print STDERR join("\n ",@deleted_files), "\n";
811
812
813 &plugin::remove_some($pluginfo, $collectcfg->{'infodbtype'}, $archivedir, \@deleted_files);
814
815 mark_docs_for_deletion($archive_info,$block_hash,\@deleted_files, $archivedir,$verbosity, "delete");
816 }
817
818 my @reindex_files = sort keys %{$block_hash->{'reindex_files'}};
819
820 if (scalar(@reindex_files)>0) {
821 print STDERR "Files to reindex since last import:\n ";
822 print STDERR join("\n ",@reindex_files), "\n";
823 &plugin::remove_some($pluginfo, $collectcfg->{'infodbtype'}, $archivedir, \@reindex_files);
824 mark_docs_for_deletion($archive_info,$block_hash,\@reindex_files, $archivedir,$verbosity, "reindex");
825 }
826
827 }
828 }
829 }
830
831 # Check for existence of the file that's to contain earliestDateStamp in archivesdir
832 # Do nothing if the file already exists (file exists on incremental build).
833 # If the file doesn't exist, as happens on full build, create it and write out the current datestamp into it
834 # In buildcol, read the file's contents and set the earliestdateStamp in GS2's build.cfg / GS3's buildconfig.xml
835 # In doc.pm have set_oaiLastModified similar to set_lastmodified, and create the doc fields
836 # oailastmodified and oailastmodifieddate
837 my $earliestDatestampFile = &FileUtils::filenameConcatenate($archivedir, "earliestDatestamp");
838 if (!-f $earliestDatestampFile && -d $archivedir) {
839 my $current_time_in_seconds = time; # in seconds
840
841 if(open(FOUT, ">$earliestDatestampFile")) {
842 # || (&gsprintf(STDERR, "{common.cannot_open}: $!\n", $earliestDatestampFile) && die);
843 print FOUT $current_time_in_seconds;
844 close(FOUT);
845 }
846 else {
847 &gsprintf(STDERR, "{import.cannot_write_earliestdatestamp}\n", $earliestDatestampFile);
848 }
849
850 }
851
852
853 $self->perform_process_files($manifest, $pluginfo, $importdir, '', $block_hash, $metadata, $processor, $maxdocs);
854
855 if ($saveas eq "FedoraMETS") {
856 # create collection "doc obj" for Fedora that contains
857 # collection-level metadata
858
859 my $doc_obj = new doc($config_filename,"nonindexed_doc","none");
860 $doc_obj->set_OID("collection");
861
862 my $col_name = undef;
863 my $col_meta = $collectcfg->{'collectionmeta'};
864
865 if (defined $col_meta) {
866 store_collectionmeta($col_meta,"collectionname",$doc_obj); # in GS3 this is a collection's name
867 store_collectionmeta($col_meta,"collectionextra",$doc_obj); # in GS3 this is a collection's description
868 }
869 $processor->process($doc_obj);
870 }
871
872 &plugin::end($pluginfo, $processor);
873
874 &plugin::deinit($pluginfo, $processor);
875
876 # Store the value of OIDCount (used in doc.pm) so it can be
877 # restored correctly to this value on an incremental build
878 # - this OIDcount file should only be generated for numerical oids [jmt12]
879 if ($self->{'OIDtype'} eq 'incremental')
880 {
881 store_doc_oid_count($archivedir);
882 }
883
884 # write out the archive information file
885 $processor->close_file_output() if (defined $groupsize) && ($groupsize > 1);
886 $processor->close_group_output() if $processor->is_group();
887
888 # for backwards compatability with archvies.inf file
889 if ($arcinfo_doc_filename =~ m/(contents)|(\.inf)$/) {
890 $archive_info->save_info($arcinfo_doc_filename);
891 }
892 else {
893 $archive_info->save_revinfo_db($arcinfo_src_filename);
894 }
895
896 return $pluginfo;
897}
898
899# @function perform_process_files()
900# while process_files() above prepares the system to import files this is the
901# function that actually initiates the plugin pipeline to process the files.
902# This function the therefore be overridden in subclasses of inexport.pm should
903# they wish to do different or further processing
904# @author jmt12
905sub perform_process_files
906{
907 my $self = shift(@_);
908 my ($manifest, $pluginfo, $importdir, $file_to_import, $block_hash, $metadata, $processor, $maxdocs) = @_;
909 my $gli = $self->{'gli'};
910 # specific file to process - via manifest version 2+
911 if ($file_to_import ne '')
912 {
913 &plugin::read ($pluginfo, '', $file_to_import, $block_hash, $metadata, $processor, $maxdocs, 0, $gli);
914 }
915 # global file scan - if we are using a new version manifest, files would have
916 # been read above. Older manifests use extra settings in the $block_hash to
917 # control what is imported, while non-manifest imports use a regular
918 # $block_hash (so obeying process_exp and block_exp) [jmt12]
919 elsif ($manifest eq '' || $self->{'manifest_version'} < 1)
920 {
921 &plugin::read ($pluginfo, $importdir, '', $block_hash, $metadata, $processor, $maxdocs, 0, $gli);
922 }
923 else
924 {
925 print STDERR "Skipping perform_process_files() due to manifest presence and version\n";
926 }
927}
928# perform_process_files()
929
930# @function generate_statistics()
931sub generate_statistics
932{
933 my $self = shift @_;
934 my ($pluginfo) = @_;
935
936 my $inexport_mode = $self->{'mode'};
937 my $out = $self->{'out'};
938 my $faillogname = $self->{'faillogname'};
939 my $gli = $self->{'gli'};
940
941 &gsprintf($out, "\n");
942 &gsprintf($out, "*********************************************\n");
943 &gsprintf($out, "{$inexport_mode.complete}\n");
944 &gsprintf($out, "*********************************************\n");
945
946 &plugin::write_stats($pluginfo, 'STDERR', $faillogname, $gli);
947}
948# generate_statistics()
949
950
951# @function deinit()
952# Close down any file handles that we opened (and hence are responsible for
953# closing
954sub deinit
955{
956 my $self = shift(@_);
957 close OUT if $self->{'close_out'};
958 close FAILLOG if $self->{'close_faillog'};
959}
960# deinit()
961
962
963sub store_collectionmeta
964{
965 my ($collectionmeta,$field,$doc_obj) = @_;
966
967 my $section = $doc_obj->get_top_section();
968
969 my $field_hash = $collectionmeta->{$field};
970
971 foreach my $k (keys %$field_hash)
972 {
973 my $val = $field_hash->{$k};
974
975 ### print STDERR "*** $k = $field_hash->{$k}\n";
976
977 my $md_label = "ex.$field";
978
979
980 if ($k =~ m/^\[l=(.*?)\]$/)
981 {
982
983 my $md_suffix = $1;
984 $md_label .= "^$md_suffix";
985 }
986
987
988 $doc_obj->add_utf8_metadata($section,$md_label, $val);
989
990 # see collConfigxml.pm: GS2's "collectionextra" is called "description" in GS3,
991 # while "collectionname" in GS2 is called "name" in GS3.
992 # Variable $nameMap variable in collConfigxml.pm maps between GS2 and GS3
993 if (($md_label eq "ex.collectionname^en") || ($md_label eq "ex.collectionname"))
994 {
995 $doc_obj->add_utf8_metadata($section,"dc.Title", $val);
996 }
997
998 }
999}
1000
1001
1002sub oid_count_file {
1003 my ($archivedir) = @_;
1004 return &FileUtils::filenameConcatenate($archivedir, "OIDcount");
1005}
1006
1007
1008sub prime_doc_oid_count
1009{
1010 my ($archivedir) = @_;
1011 my $oid_count_filename = &oid_count_file($archivedir);
1012
1013 if (-e $oid_count_filename) {
1014 if (open(OIDIN,"<$oid_count_filename")) {
1015 my $OIDcount = <OIDIN>;
1016 chomp $OIDcount;
1017 close(OIDIN);
1018
1019 $doc::OIDcount = $OIDcount;
1020 }
1021 else {
1022 &gsprintf(STDERR, "{import.cannot_read_OIDcount}\n", $oid_count_filename);
1023 }
1024 }
1025
1026}
1027
1028sub store_doc_oid_count
1029{
1030 # Use the file "OIDcount" in the archives directory to record
1031 # what value doc.pm got up to
1032
1033 my ($archivedir) = @_;
1034 my $oid_count_filename = &oid_count_file($archivedir);
1035
1036 # @todo $oidout = &FileUtils::openFileDescriptor($oid_count_filename, 'w') [jmt12]
1037 if (open(OIDOUT,">$oid_count_filename")) {
1038 print OIDOUT $doc::OIDcount, "\n";
1039
1040 close(OIDOUT);
1041 }
1042 else {
1043 &gsprintf(STDERR, "{import.cannot_write_OIDcount}\n", $oid_count_filename);
1044 }
1045}
1046
1047
1048
1049sub new_vs_old_import_diff
1050{
1051 my ($archive_info,$block_hash,$importdir,$archivedir,$verbosity,$incremental_mode) = @_;
1052
1053 # Get the infodbtype value for this collection from the arcinfo object
1054 my $infodbtype = $archive_info->{'infodbtype'};
1055
1056 # in this method, we want to know if metadata files are modified or not.
1057 my $arcinfo_doc_filename = &dbutil::get_infodb_file_path($infodbtype, "archiveinf-doc", $archivedir);
1058
1059 my $archiveinf_timestamp = -M $arcinfo_doc_filename;
1060
1061 # First convert all files to absolute form
1062 # This is to support the situation where the import folder is not
1063 # the default
1064
1065 my $prev_all_files = $archive_info->{'prev_import_filelist'};
1066 my $full_prev_all_files = {};
1067
1068 foreach my $prev_file (keys %$prev_all_files) {
1069
1070 if (!&FileUtils::isFilenameAbsolute($prev_file)) {
1071 my $full_prev_file = &FileUtils::filenameConcatenate($ENV{'GSDLCOLLECTDIR'},$prev_file);
1072 $full_prev_all_files->{$full_prev_file} = $prev_file;
1073 }
1074 else {
1075 $full_prev_all_files->{$prev_file} = $prev_file;
1076 }
1077 }
1078
1079
1080 # Figure out which are the new files, existing files and so
1081 # by implication the files from the previous import that are not
1082 # there any more => mark them for deletion
1083 foreach my $curr_file (keys %{$block_hash->{'all_files'}}) {
1084
1085 my $full_curr_file = $curr_file;
1086
1087 # entry in 'all_files' is moved to either 'existing_files',
1088 # 'deleted_files', 'new_files', or 'new_or_modified_metadata_files'
1089
1090 if (!&FileUtils::isFilenameAbsolute($curr_file)) {
1091 # add in import dir to make absolute
1092 $full_curr_file = &FileUtils::filenameConcatenate($importdir,$curr_file);
1093 }
1094
1095 # figure out if new file or not
1096 if (defined $full_prev_all_files->{$full_curr_file}) {
1097 # delete it so that only files that need deleting are left
1098 delete $full_prev_all_files->{$full_curr_file};
1099
1100 # had it before. is it a metadata file?
1101 if ($block_hash->{'metadata_files'}->{$full_curr_file}) {
1102
1103 # is it modified??
1104 if (-M $full_curr_file < $archiveinf_timestamp) {
1105 print STDERR "*** Detected a *modified metadata* file: $full_curr_file\n" if $verbosity >= 2;
1106 # its newer than last build
1107 $block_hash->{'new_or_modified_metadata_files'}->{$full_curr_file} = 1;
1108 }
1109 }
1110 else {
1111 if ($incremental_mode eq "all") {
1112
1113 # had it before
1114 $block_hash->{'existing_files'}->{$full_curr_file} = 1;
1115
1116 }
1117 else {
1118 # Warning in "onlyadd" mode, but had it before!
1119 print STDERR "Warning: File $full_curr_file previously imported.\n";
1120 print STDERR " Treating as new file\n";
1121
1122 $block_hash->{'new_files'}->{$full_curr_file} = 1;
1123
1124 }
1125 }
1126 }
1127 else {
1128 if ($block_hash->{'metadata_files'}->{$full_curr_file}) {
1129 # the new file is the special sort of file greenstone uses
1130 # to attach metadata to src documents
1131 # i.e metadata.xml
1132 # (but note, the filename used is not constrained in
1133 # Greenstone to always be this)
1134
1135 print STDERR "*** Detected *new* metadata file: $full_curr_file\n" if $verbosity >= 2;
1136 $block_hash->{'new_or_modified_metadata_files'}->{$full_curr_file} = 1;
1137 }
1138 else {
1139 $block_hash->{'new_files'}->{$full_curr_file} = 1;
1140 }
1141 }
1142
1143
1144 delete $block_hash->{'all_files'}->{$curr_file};
1145 }
1146
1147
1148
1149
1150 # Deal with complication of new or modified metadata files by forcing
1151 # everything from this point down in the file hierarchy to
1152 # be freshly imported.
1153 #
1154 # This may mean files that have not changed are reindexed, but does
1155 # guarantee by the end of processing all new metadata is correctly
1156 # associated with the relevant document(s).
1157
1158 foreach my $new_mdf (keys %{$block_hash->{'new_or_modified_metadata_files'}}) {
1159 my ($fileroot,$situated_dir,$ext) = fileparse($new_mdf, "\\.[^\\.]+\$");
1160
1161 $situated_dir =~ s/[\\\/]+$//; # remove tailing slashes
1162 $situated_dir = &util::filename_to_regex($situated_dir); # need to escape windows slash \ and brackets in regular expression
1163
1164 # Go through existing_files, and mark anything that is contained
1165 # within 'situated_dir' to be reindexed (in case some of the metadata
1166 # attaches to one of these files)
1167
1168 my $reindex_files = [];
1169
1170 foreach my $existing_f (keys %{$block_hash->{'existing_files'}}) {
1171
1172 if ($existing_f =~ m/^$situated_dir/) {
1173
1174 print STDERR "**** Existing file $existing_f\nis located within\n$situated_dir\n";
1175
1176 push(@$reindex_files,$existing_f);
1177 $block_hash->{'reindex_files'}->{$existing_f} = 1;
1178 delete $block_hash->{'existing_files'}->{$existing_f};
1179
1180 }
1181 }
1182
1183 # metadata file needs to be in new_files list so parsed by MetadataXMLPlug
1184 # (or equivalent)
1185 $block_hash->{'new_files'}->{$new_mdf} = 1;
1186
1187 }
1188
1189 # go through remaining existing files and work out what has changed and needs to be reindexed.
1190 my @existing_files = sort keys %{$block_hash->{'existing_files'}};
1191
1192 my $reindex_files = [];
1193
1194 foreach my $existing_filename (@existing_files) {
1195 if (-M $existing_filename < $archiveinf_timestamp) {
1196 # file is newer than last build
1197
1198 my $existing_file = $existing_filename;
1199 #my $collectdir = &FileUtils::filenameConcatenate($ENV{'GSDLCOLLECTDIR'});
1200
1201 #my $collectdir_resafe = &util::filename_to_regex($collectdir);
1202 #$existing_file =~ s/^$collectdir_resafe(\\|\/)?//;
1203
1204 print STDERR "**** Reindexing existing file: $existing_file\n";
1205
1206 push(@$reindex_files,$existing_file);
1207 $block_hash->{'reindex_files'}->{$existing_filename} = 1;
1208 }
1209
1210 }
1211
1212
1213 # By this point full_prev_all_files contains the files
1214 # mentioned in archiveinf-src.db but are not in the 'import'
1215 # folder (or whatever was specified through -importdir ...)
1216
1217 # This list can contain files that were created in the 'tmp' or
1218 # 'cache' areas (such as screen-size and thumbnail images).
1219 #
1220 # In building the final list of files to delete, we test to see if
1221 # it exists on the filesystem and if it does (unusual for a "normal"
1222 # file in import, but possible in the case of 'tmp' files),
1223 # supress it from going into the final list
1224
1225 my $collectdir = $ENV{'GSDLCOLLECTDIR'};
1226
1227 my @deleted_files = values %$full_prev_all_files;
1228 map { my $curr_file = $_;
1229 my $full_curr_file = $curr_file;
1230
1231 if (!&FileUtils::isFilenameAbsolute($curr_file)) {
1232 # add in import dir to make absolute
1233
1234 $full_curr_file = &FileUtils::filenameConcatenate($collectdir,$curr_file);
1235 }
1236
1237
1238 if (!-e $full_curr_file) {
1239 $block_hash->{'deleted_files'}->{$curr_file} = 1;
1240 }
1241 } @deleted_files;
1242
1243
1244
1245}
1246
1247
1248# this is used to delete "deleted" docs, and to remove old versions of "changed" docs
1249# $mode is 'delete' or 'reindex'
1250sub mark_docs_for_deletion
1251{
1252 my ($archive_info,$block_hash,$deleted_files,$archivedir,$verbosity,$mode) = @_;
1253
1254 my $mode_text = "deleted from index";
1255 if ($mode eq "reindex") {
1256 $mode_text = "reindexed";
1257 }
1258
1259 # Get the infodbtype value for this collection from the arcinfo object
1260 my $infodbtype = $archive_info->{'infodbtype'};
1261
1262 my $arcinfo_doc_filename = &dbutil::get_infodb_file_path($infodbtype, "archiveinf-doc", $archivedir);
1263 my $arcinfo_src_filename = &dbutil::get_infodb_file_path($infodbtype, "archiveinf-src", $archivedir);
1264
1265
1266 # record files marked for deletion in arcinfo
1267 foreach my $file (@$deleted_files) {
1268 # use 'archiveinf-src' info database file to look up all the OIDs
1269 # that this file is used in (note in most cases, it's just one OID)
1270
1271 my $src_rec = &dbutil::read_infodb_entry($infodbtype, $arcinfo_src_filename, $file);
1272 my $oids = $src_rec->{'oid'};
1273 my $file_record_deleted = 0;
1274
1275 # delete the src record
1276 my $src_infodb_file_handle = &dbutil::open_infodb_write_handle($infodbtype, $arcinfo_src_filename, "append");
1277 &dbutil::delete_infodb_entry($infodbtype, $src_infodb_file_handle, $file);
1278 &dbutil::close_infodb_write_handle($infodbtype, $src_infodb_file_handle);
1279
1280
1281 foreach my $oid (@$oids) {
1282
1283 # find the source doc (the primary file that becomes this oid)
1284 my $doc_rec = &dbutil::read_infodb_entry($infodbtype, $arcinfo_doc_filename, $oid);
1285 my $doc_source_file = $doc_rec->{'src-file'}->[0];
1286 if (!&util::filename_is_absolute($doc_source_file)) {
1287 $doc_source_file = &FileUtils::filenameConcatenate($ENV{'GSDLCOLLECTDIR'},$doc_source_file);
1288 }
1289
1290 if ($doc_source_file ne $file) {
1291 # its an associated or metadata file
1292
1293 # mark source doc for reimport as one of its assoc files has changed or deleted
1294 $block_hash->{'reindex_files'}->{$doc_source_file} = 1;
1295
1296 }
1297 my $curr_status = $archive_info->get_status_info($oid);
1298 if (defined($curr_status) && (($curr_status ne "D"))) {
1299 if ($verbosity>1) {
1300 print STDERR "$oid ($doc_source_file) marked to be $mode_text on next buildcol.pl\n";
1301 }
1302 # mark oid for deletion (it will be deleted or reimported)
1303 $archive_info->set_status_info($oid,"D");
1304 my $val = &dbutil::read_infodb_rawentry($infodbtype, $arcinfo_doc_filename, $oid);
1305 $val =~ s/^<index-status>(.*)$/<index-status>D/m;
1306
1307 my $val_rec = &dbutil::convert_infodb_string_to_hash($val);
1308 my $doc_infodb_file_handle = &dbutil::open_infodb_write_handle($infodbtype, $arcinfo_doc_filename, "append");
1309
1310 &dbutil::write_infodb_entry($infodbtype, $doc_infodb_file_handle, $oid, $val_rec);
1311 &dbutil::close_infodb_write_handle($infodbtype, $doc_infodb_file_handle);
1312 }
1313 }
1314
1315 }
1316
1317 # now go through and check that we haven't marked any primary
1318 # files for reindex (because their associated files have
1319 # changed/deleted) when they have been deleted themselves. only in
1320 # delete mode.
1321
1322 if ($mode eq "delete") {
1323 foreach my $file (@$deleted_files) {
1324 if (defined $block_hash->{'reindex_files'}->{$file}) {
1325 delete $block_hash->{'reindex_files'}->{$file};
1326 }
1327 }
1328 }
1329
1330
1331}
1332
1333sub add_dir_contents_to_list {
1334
1335 my ($dirname, $list) = @_;
1336
1337 # Recur over directory contents.
1338 my (@dir, $subfile);
1339
1340 # find all the files in the directory
1341 if (!opendir (DIR, $dirname)) {
1342 print STDERR "inexport: WARNING - couldn't read directory $dirname\n";
1343 return -1; # error in processing
1344 }
1345 @dir = readdir (DIR);
1346 closedir (DIR);
1347
1348 for (my $i = 0; $i < scalar(@dir); $i++) {
1349 my $subfile = $dir[$i];
1350 next if ($subfile =~ m/^\.\.?$/);
1351 next if ($subfile =~ /^\.svn$/);
1352 my $full_file = &FileUtils::filenameConcatenate($dirname, $subfile);
1353 if (-d $full_file) {
1354 &add_dir_contents_to_list($full_file, $list);
1355 } else {
1356 push (@$list, $full_file);
1357 }
1358 }
1359
1360}
1361
1362
13631;
Note: See TracBrowser for help on using the repository browser.