root/main/trunk/greenstone2/perllib/plugins/BasePlugin.pm @ 22215

Revision 22215, 37.1 KB (checked in by kjdon, 10 years ago)

added store_original_file option, used for eg Text, HTML plugins to store the source file as an associated file so that it can be referred to when serving over OAI

  • Property svn:keywords set to Author Date Id Revision
Line 
1###########################################################################
2#
3# BasePlugin.pm -- base class for all the import plugins
4# A component of the Greenstone digital library software
5# from the New Zealand Digital Library Project at the
6# University of Waikato, New Zealand.
7#
8# Copyright (C) 1999-2005 New Zealand Digital Library Project
9#
10# This program is free software; you can redistribute it and/or modify
11# it under the terms of the GNU General Public License as published by
12# the Free Software Foundation; either version 2 of the License, or
13# (at your option) any later version.
14#
15# This program is distributed in the hope that it will be useful,
16# but WITHOUT ANY WARRANTY; without even the implied warranty of
17# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
18# GNU General Public License for more details.
19#
20# You should have received a copy of the GNU General Public License
21# along with this program; if not, write to the Free Software
22# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
23#
24###########################################################################
25
26package BasePlugin;
27
28use strict;
29no strict 'subs';
30no strict 'refs'; # allow filehandles to be variables and viceversa
31
32use File::Basename;
33
34use encodings;
35use unicode;
36use textcat;
37use doc;
38use ghtml;
39use gsprintf 'gsprintf';
40
41use PrintInfo;
42
43BEGIN {
44    @BasePlugin::ISA = ( 'PrintInfo' );
45}
46
47# the different methods that can be applied when renaming
48# imported documents and their associated files
49our $file_rename_method_list =
50    [ { 'name' => "url",
51    'desc' => "{BasePlugin.rename_method.url}" },
52      { 'name' => "base64",
53    'desc' => "{BasePlugin.rename_method.base64}" },
54      { 'name' => "none",
55    'desc' => "{BasePlugin.rename_method.none}",
56    'hiddengli' => "yes" } ];
57
58our $encoding_list =
59    [ { 'name' => "ascii",
60    'desc' => "{BasePlugin.encoding.ascii}" },
61      { 'name' => "utf8",
62    'desc' => "{BasePlugin.encoding.utf8}" },
63      { 'name' => "unicode",
64    'desc' => "{BasePlugin.encoding.unicode}" } ];
65     
66
67my $e = $encodings::encodings;
68foreach my $enc (sort {$e->{$a}->{'name'} cmp $e->{$b}->{'name'}} keys (%$e))
69{
70    my $hashEncode =
71    {'name' => $enc,
72     'desc' => $e->{$enc}->{'name'}};
73   
74    push(@{$encoding_list},$hashEncode);
75}
76
77our $encoding_plus_auto_list =
78    [ { 'name' => "auto",
79    'desc' => "{BasePlugin.filename_encoding.auto}" },
80       { 'name' => "auto-language-analysis",
81    'desc' => "{BasePlugin.filename_encoding.auto_language_analysis}" }, # textcat
82      { 'name' => "auto-filesystem-encoding",
83    'desc' => "{BasePlugin.filename_encoding.auto_filesystem_encoding}" }, # locale
84      { 'name' => "auto-fl",
85    'desc' => "{BasePlugin.filename_encoding.auto_fl}" }, # locale followed by textcat
86      { 'name' => "auto-lf",
87    'desc' => "{BasePlugin.filename_encoding.auto_lf}" } ]; # texcat followed by locale
88
89push(@{$encoding_plus_auto_list},@{$encoding_list});
90
91our $oidtype_list =
92    [ { 'name' => "auto",
93    'desc' => "{BasePlugin.OIDtype.auto}" },
94      { 'name' => "hash",
95        'desc' => "{import.OIDtype.hash}" },
96      { 'name' => "assigned",
97        'desc' => "{import.OIDtype.assigned}" },
98      { 'name' => "incremental",
99        'desc' => "{import.OIDtype.incremental}" },
100      { 'name' => "dirname",
101        'desc' => "{import.OIDtype.dirname}" } ];
102
103my $arguments =
104    [ { 'name' => "process_exp",
105    'desc' => "{BasePlugin.process_exp}",
106    'type' => "regexp",
107    'deft' => "",
108    'reqd' => "no" },
109      { 'name' => "no_blocking",
110    'desc' => "{BasePlugin.no_blocking}",
111    'type' => "flag",
112    'reqd' => "no"},
113      { 'name' => "block_exp",
114    'desc' => "{BasePlugin.block_exp}",
115    'type' => "regexp",
116    'deft' => "",
117    'reqd' => "no" },
118      { 'name' => "store_original_file",
119    'desc' => "{BasePlugin.store_original_file}",
120    'type' => "flag",
121    'reqd' => "no" },
122      { 'name' => "associate_ext",
123    'desc' => "{BasePlugin.associate_ext}",
124    'type' => "string",
125    'reqd' => "no" },
126      { 'name' => "associate_tail_re",
127    'desc' => "{BasePlugin.associate_tail_re}",
128    'type' => "string",
129    'reqd' => "no" },
130      { 'name' => "OIDtype",
131    'desc' => "{import.OIDtype}",
132    'type' => "enum",
133    'list' => $oidtype_list,
134    # leave default empty so we can tell if its been set or not - if not set will use option from import.pl
135    'deft' => "auto",
136    'reqd' => "no" },
137      { 'name' => "OIDmetadata",
138    'desc' => "{import.OIDmetadata}",
139    'type' => "metadata",
140    'deft' => "dc.Identifier",
141    'reqd' => "no" },     
142#      { 'name' => "use_as_doc_identifier",
143#   'desc' => "{BasePlugin.use_as_doc_identifier}",
144#   'type' => "string",
145#   'reqd' => "no" ,
146#   'deft' => "" } ,
147      { 'name' => "no_cover_image",
148    'desc' => "{BasePlugin.no_cover_image}",
149    'type' => "flag",
150    'reqd' => "no" },
151      { 'name' => "filename_encoding",
152    'desc' => "{BasePlugin.filename_encoding}",
153    'type' => "enum",
154    'deft' => "auto",
155    'list' => $encoding_plus_auto_list,
156    'reqd' => "no" },
157      { 'name' => "smart_block",
158        'desc' => "{common.deprecated}. {BasePlugin.smart_block}",
159        'type' => "flag",
160        'reqd' => "no",
161    'hiddengli' => "yes" }, # deprecated, but leave in for old collections
162      { 'name' => "file_rename_method",
163    'desc' => "{BasePlugin.file_rename_method}",
164    'type' => "enum",
165    'deft' => &get_default_file_rename_method(), # by default rename imported files and assoc files using this encoding
166    'list' => $file_rename_method_list,
167    'reqd' => "no"
168      }
169     
170      ];
171
172
173my $options = { 'name'     => "BasePlugin",
174        'desc'     => "{BasePlugin.desc}",
175        'abstract' => "yes",
176        'inherits' => "no",
177        'args'     => $arguments };
178
179sub new {
180
181    my ($class) = shift (@_);
182    my ($pluginlist,$inputargs,$hashArgOptLists,$auxiliary) = @_;
183    push(@$pluginlist, $class);
184
185    push(@{$hashArgOptLists->{"ArgList"}},@{$arguments});
186    push(@{$hashArgOptLists->{"OptList"}},$options);
187
188    my $self = new PrintInfo($pluginlist, $inputargs, $hashArgOptLists,$auxiliary);
189   
190    if ($self->{'info_only'}) {
191        # don't worry about any options etc
192        return bless $self, $class;
193    }
194
195    if ($self->{'smart_block'}) {
196    print STDERR "WARNING: -smart_block option has been deprecated and is no longer useful\n";
197    }
198    $self->{'smart_block'} = undef;
199
200    my $plugin_name = (defined $pluginlist->[0]) ? $pluginlist->[0] : $class;
201    $self->{'plugin_type'} = $plugin_name;
202
203    # remove ex. from OIDmetadata
204    $self->{'OIDmetadata'} =~ s/^ex\.// if defined $self->{'OIDmetadata'};
205    $self->{'num_processed'} = 0;
206    $self->{'num_not_processed'} = 0;
207    $self->{'num_blocked'} = 0;
208    $self->{'num_archives'} = 0;
209    $self->{'cover_image'} = 1; # cover image is on by default
210    $self->{'cover_image'} = 0 if ($self->{'no_cover_image'});
211    $self->{'can_process_directories'} = 0;
212    #$self->{'option_list'} = $hashArgOptLists->{"OptList"};
213   
214    my $associate_ext = $self->{'associate_ext'};
215    if ((defined $associate_ext) && ($associate_ext ne "")) {
216
217    my $associate_tail_re = $self->{'associate_tail_re'};
218    if ((defined $associate_tail_re) && ($associate_tail_re ne "")) {
219        my $outhandle = $self->{'outhandle'};
220        print $outhandle "Warning: can only specify 'associate_ext' or 'associate_tail_re'\n";
221        print $outhandle "         defaulting to 'associate_tail_re'\n";
222    }
223    else {
224        my @exts = split(/,/,$associate_ext);
225
226        my @exts_bracketed = map { $_ = "(?:\\.$_)" } @exts;
227        my $associate_tail_re = join("|",@exts_bracketed);
228        $self->{'associate_tail_re'} = $associate_tail_re;
229    }
230
231    delete $self->{'associate_ext'};
232    }
233
234    return bless $self, $class;
235
236}
237
238sub merge_inheritance
239{
240    my $self = {};
241    my @child_selfs = @_;
242
243    foreach my $child_self (@child_selfs) {
244    foreach my $key (keys %$child_self) {
245        if (defined $self->{$key}) {
246        if ($self->{$key} ne $child_self->{$key}) {
247#           print STDERR "Warning: Conflicting value in multiple inheritance for '$key'\n";
248#           print STDERR "Existing stored value = $self->{$key}\n";
249#           print STDERR "New (child) value     = $child_self->{$key}\n";
250#           print STDERR "Keeping existing value\n";
251            # Existing value seems to be option specified in collect.cfg
252
253            ### $self->{$key} = $child_self->{$key};
254           
255        }
256        else {
257##          print STDERR "****Info: Value $self->{$key} for $key already defined through multiple inheritance as the same value\n";
258        }
259
260        }
261        else {
262        $self->{$key} = $child_self->{$key};
263        }
264    }
265    }
266
267    return $self;   
268}
269
270# initialize BasePlugin options
271# if init() is overridden in a sub-class, remember to call BasePlugin::init()
272sub init {
273    my $self = shift (@_);
274    my ($verbosity, $outhandle, $failhandle) = @_;
275
276    # verbosity is passed through from the processor
277    $self->{'verbosity'} = $verbosity;
278
279    # as are the outhandle and failhandle
280    $self->{'outhandle'} = $outhandle if defined $outhandle;
281    $self->{'failhandle'} = $failhandle;
282#    $self->SUPER::init(@_);
283   
284    # set process_exp and block_exp to defaults unless they were
285    # explicitly set
286
287    if ((!$self->is_recursive()) and
288    (!defined $self->{'process_exp'}) || ($self->{'process_exp'} eq "")) {
289
290    $self->{'process_exp'} = $self->get_default_process_exp ();
291    if ($self->{'process_exp'} eq "") {
292        warn ref($self) . " Warning: Non-recursive plugin has no process_exp\n";
293    }
294    }
295
296    if ((!defined $self->{'block_exp'}) || ($self->{'block_exp'} eq "")) {
297    $self->{'block_exp'} = $self->get_default_block_exp ();
298    }
299
300}
301
302sub begin {
303    my $self = shift (@_);
304    my ($pluginfo, $base_dir, $processor, $maxdocs) = @_;
305
306    if ($self->{'OIDtype'} eq "auto") {
307    # hasn't been set in the plugin, use the processor values
308    $self->{'OIDtype'} = $processor->{'OIDtype'};
309    $self->{'OIDmetadata'} = $processor->{'OIDmetadata'};
310    }
311    if ($self->{'OIDtype'} eq "hash") {
312    # should we hash on the file or on the doc xml??
313    $self->{'OIDtype'} = $self->get_oid_hash_type();
314    if ($self->{'OIDtype'} !~ /^(hash_on_file|hash_on_ga_xml)$/) {
315        $self->{'OIDtype'} = "hash_on_file";
316    }
317    }
318}
319
320# This is called once if removeold is set with import.pl. Most plugins will do
321# nothing but if a plugin does any stuff outside of creating doc obj, then
322# it may need to clear something.
323sub remove_all {
324    my $self = shift (@_);
325    my ($pluginfo, $base_dir, $processor, $maxdocs) = @_;
326}
327
328# This is called per document for docs that have been deleted from the
329# collection. Most plugins will do nothing
330# but if a plugin does any stuff outside of creating doc obj, then it may need
331# to clear something.
332sub remove_one {
333    my $self = shift (@_);
334   
335    my ($file, $oids, $archivedir) = @_;
336    return 0 if $self->can_process_this_file($file);
337    return undef;
338}
339
340sub end {
341    # potentially called at the end of each plugin pass
342    # import.pl only has one plugin pass, but buildcol.pl has multiple ones
343
344    my ($self) = shift (@_);
345}
346
347sub deinit {
348    # called only once, after all plugin passes have been done
349
350    my ($self) = @_;
351}
352
353# default hashing type is to hash on the original file (or converted file)
354# override this to return hash_on_ga_xml for filetypes where hashing on the
355# file is no good eg video
356sub get_oid_hash_type {
357
358    my $self = shift (@_);
359
360    return "hash_on_file";
361}
362
363
364# this function should be overridden to return 1
365# in recursive plugins
366sub is_recursive {
367    my $self = shift (@_);
368
369    return 0;
370}
371
372sub get_default_block_exp {
373    my $self = shift (@_);
374
375    return "";
376}
377
378sub get_default_process_exp {
379    my $self = shift (@_);
380
381    return "";
382}
383
384# rename imported files and assoc files using URL encoding by default
385# as this will work for most plugins and give more legible filenames
386sub get_default_file_rename_method() {
387    my $self = shift (@_);
388    return "url";
389}
390
391# returns this plugin's active (possibly user-selected) file_rename_method
392sub get_file_rename_method() {
393    my $self = shift (@_);
394    my $rename_method = $self->{'file_rename_method'};
395    if($rename_method) {
396    return $rename_method;
397    } else {   
398    return $self->get_default_file_rename_method();
399    }
400}
401
402# default implementation is to do nothing
403sub store_block_files {
404   
405    my $self =shift (@_);
406    my ($filename_full_path, $block_hash) = @_;
407
408}
409
410# put files to block into hash
411sub use_block_expressions {
412
413    my $self =shift (@_);
414    my ($filename_full_path, $block_hash) = @_;
415
416    if ($self->{'block_exp'} ne "" && $filename_full_path =~ /$self->{'block_exp'}/) {
417    $block_hash->{'file_blocks'}->{$filename_full_path} = 1;
418    }
419
420}
421
422#default implementation is to block a file with same name as this, but extension jpg or JPG, if cover_images is on.
423sub block_cover_image
424{
425    my $self =shift;
426    my ($filename, $block_hash) = @_;
427
428    if ($self->{'cover_image'}) {
429    my $coverfile = $filename;
430    $coverfile =~ s/\.[^\\\/\.]+$/\.jpg/;
431    if (!-e $coverfile) {
432        $coverfile =~ s/jpg$/JPG/;
433    }   
434    if (-e $coverfile) {
435        $block_hash->{'file_blocks'}->{$coverfile} = 1;
436    }
437    }
438
439    return;
440}
441
442
443# discover all the files that should be blocked by this plugin
444# check the args ...
445sub file_block_read {
446
447    my $self = shift (@_); 
448    my ($pluginfo, $base_dir, $file, $block_hash, $metadata, $gli) = @_;
449    # Keep track of filenames with same root but different extensions
450    # Used to support -associate_ext and the more generalised
451    # -associate_tail_re
452    my ($filename_full_path, $filename_no_path) = &util::get_full_filenames($base_dir, $file);
453
454    if (!-d $filename_full_path) {
455    $block_hash->{'all_files'}->{$file} = 1;
456    }
457
458    my $associate_tail_re = $self->{'associate_tail_re'};
459    if ((defined $associate_tail_re) && ($associate_tail_re ne "")) {
460    my ($file_prefix,$file_ext)
461        = &util::get_prefix_and_tail_by_regex($filename_full_path,$associate_tail_re);
462    if ((defined $file_prefix) && (defined $file_ext)) {
463        my $shared_fileroot = $block_hash->{'shared_fileroot'};
464        if (!defined $shared_fileroot->{$file_prefix}) {
465        my $file_prefix_rec = { 'tie_to'  => undef,
466                        'exts'    => {} };
467        $shared_fileroot->{$file_prefix} = $file_prefix_rec;
468        }
469       
470        my $file_prefix_rec = $shared_fileroot->{$file_prefix};
471
472        if ($self->can_process_this_file($filename_full_path)) {
473        # This is the document the others should be tied to
474        $file_prefix_rec->{'tie_to'} = $file_ext;
475        }
476        else {
477        if ($file_ext =~ m/$associate_tail_re$/) {
478            # this file should be associated to the main one
479            $file_prefix_rec->{'exts'}->{$file_ext} = 1;
480        }
481        }
482
483    }
484    }
485
486    # check block expressions
487    $self->use_block_expressions($filename_full_path, $block_hash) unless $self->{'no_blocking'};
488
489    # now check whether we are actually processing this
490    if (!-f $filename_full_path || !$self->can_process_this_file($filename_full_path)) {
491    return undef; # can't recognise
492    }
493   
494    # if we have a block_exp, then this overrides the normal 'smart' blocking
495    $self->store_block_files($filename_full_path, $block_hash) unless ($self->{'no_blocking'} || $self->{'block_exp'} ne "");
496
497    # block the cover image if there is one
498    if ($self->{'cover_image'}) {
499    $self->block_cover_image($filename_full_path, $block_hash);
500    }
501       
502    return 1;
503}
504
505# plugins that rely on more than process_exp (eg XML plugins) can override this method
506sub can_process_this_file {
507    my $self = shift(@_);
508    my ($filename) = @_;
509
510    if (-d $filename && !$self->{'can_process_directories'}) {
511    return 0;
512    }
513    if ($self->{'process_exp'} ne "" && $filename =~ /$self->{'process_exp'}/) {
514    return 1;
515    }
516    return 0;
517   
518}
519
520# just converts path as is to utf8.
521sub filepath_to_utf8 {
522    my $self = shift (@_); 
523    my ($file, $file_encoding) = @_;
524    my $filemeta = $file;
525
526    my $filename_encoding = $self->{'filename_encoding'}; # filename encoding setting
527
528    # Whenever filename-encoding is set to any of the auto settings, we
529    # check if the filename is already in UTF8. If it is, then we're done.
530    if($filename_encoding =~ m/auto/) {
531    if(&unicode::check_is_utf8($filemeta))
532    {
533        $filename_encoding = "utf8";
534        return $filemeta;
535    }
536    }
537   
538    # Auto setting, but filename is not utf8
539    if ($filename_encoding eq "auto")
540    {
541    # try textcat
542    $filename_encoding = $self->textcat_encoding($filemeta);
543   
544    # check the locale next
545    $filename_encoding = $self->locale_encoding() if $filename_encoding eq "undefined";
546   
547
548    # now try the encoding of the document, if available
549    if ($filename_encoding eq "undefined" && defined $file_encoding) {
550        $filename_encoding = $file_encoding;
551    }
552
553    }
554
555    elsif ($filename_encoding eq "auto-language-analysis")
556    {   
557    $filename_encoding = $self->textcat_encoding($filemeta);
558
559    # now try the encoding of the document, if available
560    if ($filename_encoding eq "undefined" && defined $file_encoding) {
561        $filename_encoding = $file_encoding;
562    }
563    }
564
565    elsif ($filename_encoding eq "auto-filesystem-encoding")
566    {
567    # try locale
568    $filename_encoding = $self->locale_encoding();
569    }
570
571    elsif ($filename_encoding eq "auto-fl")
572    {
573    # filesystem-encoding (locale) then language-analysis (textcat)
574    $filename_encoding = $self->locale_encoding();
575   
576    # try textcat
577    $filename_encoding = $self->textcat_encoding($filemeta) if $filename_encoding eq "undefined";
578       
579    # else assume filename encoding is encoding of file content, if that's available
580    if ($filename_encoding eq "undefined" && defined $file_encoding) {
581        $filename_encoding = $file_encoding;
582    }
583    }
584   
585    elsif ($filename_encoding eq "auto-lf")
586    {
587    # language-analysis (textcat) then filesystem-encoding (locale)
588    $filename_encoding = $self->textcat_encoding($filemeta);
589   
590    # guess filename encoding from encoding of file content, if available
591    if ($filename_encoding eq "undefined" && defined $file_encoding) {
592        $filename_encoding = $file_encoding;
593    }
594
595    # try locale
596    $filename_encoding = $self->locale_encoding() if $filename_encoding eq "undefined";
597    }
598       
599    # if still undefined, use utf8 as fallback
600    if ($filename_encoding eq "undefined") {
601    $filename_encoding = "utf8";
602    }
603
604    #print STDERR "**** UTF8 encoding the filename $filemeta ";
605   
606    # if the filename encoding is set to utf8 but it isn't utf8 already--such as when
607    # 1. the utf8 fallback is used, or 2. if the system locale is used and happens to
608    # be always utf8 (in which case the filename's encoding is also set as utf8 even
609    # though the filename need not be if it originates from another system)--in such
610    # cases attempt to make the filename utf8 to match.
611    if($filename_encoding eq "utf8" && !&unicode::check_is_utf8($filemeta)) {
612    &unicode::ensure_utf8(\$filemeta);
613    }
614
615    # convert non-unicode encodings to utf8
616    if ($filename_encoding !~ m/(?:ascii|utf8|unicode)/) {
617    $filemeta = &unicode::unicode2utf8(
618      &unicode::convert2unicode($filename_encoding, \$filemeta)
619    );
620    }
621
622    #print STDERR " from encoding $filename_encoding -> $filemeta\n";
623    return $filemeta;
624}
625
626# gets the filename with no path, converts to utf8, and then dm safes it.
627# filename_encoding set by user
628sub filename_to_utf8_metadata
629{
630    my $self = shift (@_); 
631    my ($file, $file_encoding) = @_;
632
633    my $outhandle = $self->{'outhandle'};
634
635    my ($filemeta) = $file =~ /([^\\\/]+)$/; # getting the tail of the filepath (skips all string parts containing slashes upto the end)
636    $filemeta = $self->filepath_to_utf8($filemeta, $file_encoding);
637   
638    my $dmsafe_filemeta = &ghtml::dmsafe($filemeta);
639
640    return $dmsafe_filemeta;
641
642}
643
644sub locale_encoding {
645    my $self = shift(@_);
646   
647    if (!defined $self->{'filesystem_encoding'}) {
648    $self->{'filesystem_encoding'} = $self->get_filesystem_encoding();
649    $self->{'filesystem_encoding'} = "undefined" if !defined $self->{'filesystem_encoding'};
650    }
651
652    #print STDERR "*** filename encoding determined based on locale: " . $self->{'filesystem_encoding'} . "\n";
653    return $self->{'filesystem_encoding'}; # can be the string "undefined"
654}
655
656sub textcat_encoding {
657    my $self = shift(@_);
658    my ($filemeta) = @_;
659
660    # analyse filenames without extensions and digits (and trimmed of surrounding
661    # whitespace), so that irrelevant chars don't confuse textcat
662    my $strictfilemeta = $filemeta;
663    $strictfilemeta =~ s/\.[^\.]+$//g;
664    $strictfilemeta =~ s/\d//g;
665    $strictfilemeta =~ s/^\s*//g;
666    $strictfilemeta =~ s/\s*$//g;
667   
668    my $filename_encoding = $self->encoding_from_language_analysis($strictfilemeta);
669    if(!defined $filename_encoding) {
670    $filename_encoding = "undefined";
671    }
672
673    return $filename_encoding; # can be the string "undefined"
674}
675
676# performs textcat
677sub encoding_from_language_analysis {
678    my $self = shift(@_);
679    my ($text) = @_;
680
681    my $outhandle = $self->{'outhandle'};
682    my $best_encoding = undef;
683   
684    # get the language/encoding of the textstring using textcat
685    $self->{'textcat'} = new textcat() unless defined($self->{'textcat'});
686    my $results = $self->{'textcat'}->classify_cached_filename(\$text);
687
688
689    if (scalar @$results < 0) {
690    return undef;
691    }
692   
693    # We have some results, we choose the first
694    my ($language, $encoding) = $results->[0] =~ /^([^-]*)(?:-(.*))?$/;
695   
696    $best_encoding = $encoding;
697    if (!defined $best_encoding) {
698    return undef;
699    }
700       
701    if (defined $best_encoding && $best_encoding =~ m/^iso_8859/ && &unicode::check_is_utf8($text)) {
702    # the text is valid utf8, so assume that's the real encoding (since textcat is based on probabilities)
703    $best_encoding = 'utf8';
704    }
705   
706   
707    # check for equivalents where textcat doesn't have some encodings...
708    # eg MS versions of standard encodings
709    if (defined $best_encoding && $best_encoding =~ /^iso_8859_(\d+)/) {
710    my $iso = $1; # which variant of the iso standard?
711    # iso-8859 sets don't use chars 0x80-0x9f, windows codepages do
712    if ($text =~ /[\x80-\x9f]/) {
713        # Western Europe
714        if ($iso == 1 or $iso == 15) { $best_encoding = 'windows_1252' }
715        elsif ($iso == 2) {$best_encoding = 'windows_1250'} # Central Europe
716        elsif ($iso == 5) {$best_encoding = 'windows_1251'} # Cyrillic
717        elsif ($iso == 6) {$best_encoding = 'windows_1256'} # Arabic
718        elsif ($iso == 7) {$best_encoding = 'windows_1253'} # Greek
719        elsif ($iso == 8) {$best_encoding = 'windows_1255'} # Hebrew
720        elsif ($iso == 9) {$best_encoding = 'windows_1254'} # Turkish
721    }
722    }
723   
724    if (defined $best_encoding && $best_encoding !~ /^(ascii|utf8|unicode)$/ &&
725    !defined $encodings::encodings->{$best_encoding})
726    {
727    if ($self->{'verbosity'}) {
728        gsprintf($outhandle, "BasePlugin: {ReadTextFile.unsupported_encoding}\n", $text, $best_encoding, "undef");
729    }
730    $best_encoding = undef;
731    }
732   
733    return $best_encoding;
734}
735
736# uses locale
737sub get_filesystem_encoding {
738
739    my $self = shift(@_);
740
741    my $outhandle = $self->{'outhandle'};
742    my $filesystem_encoding = undef;
743
744    eval {
745    use POSIX qw(locale_h);
746   
747    # With only one parameter, setlocale retrieves the
748    # current value
749    my $current_locale = setlocale(LC_CTYPE);
750   
751    if ($current_locale =~ m/^.*\.(.*?)$/) {
752        my $char_encoding = lc($1);
753        if ($char_encoding =~ m/^(iso)(8859)(\d{1,2})$/) {
754        $char_encoding = "$1\_$2\_$3";
755        }
756
757        $char_encoding =~ s/-/_/g;
758        $char_encoding =~ s/^utf_8$/utf8/;
759       
760        if ($char_encoding =~ m/^\d+$/) {
761        if (defined $encodings::encodings->{"windows_$char_encoding"}) {
762            $char_encoding = "windows_$char_encoding";
763        }
764        elsif (defined $encodings::encodings->{"dos_$char_encoding"}) {
765            $char_encoding = "dos_$char_encoding";
766        }
767        }
768       
769        if (($char_encoding =~ m/(?:ascii|utf8|unicode)/)
770        || (defined $encodings::encodings->{$char_encoding})) {
771        $filesystem_encoding = $char_encoding;
772        }
773        else {
774        print $outhandle "Warning: Unsupported character encoding '$char_encoding' from locale '$current_locale'\n";
775        }
776    }
777   
778
779    };
780    if ($@) {
781    print $outhandle "$@\n";
782    print $outhandle "Warning: Unable to establish locale.  Will assume filesystem is UTF-8\n";
783   
784    }
785    return $filesystem_encoding;
786}
787
788# is there ever only one Source? Sometimes this will be called twice, for images etc that are converted.
789sub set_Source_metadata {
790    my $self = shift (@_); 
791    my ($doc_obj, $filename_no_path, $file_encoding) = @_;
792
793    my $top_section = $doc_obj->get_top_section();
794   
795    # UTF-8 version of filename
796    my $filemeta = $self->filename_to_utf8_metadata($filename_no_path, $file_encoding);
797   
798    # Source is the UTF8 display name - not necessarily the name of the file on the system
799    $doc_obj->set_utf8_metadata_element($top_section, "Source", $filemeta);
800
801    $filemeta = &util::rename_file($filemeta, $self->{'file_rename_method'});
802    # If using URL encoding, then SourceFile is the url-reference to url-encoded
803    # filemeta: it's a url that refers to the actual file on the system
804    $filemeta = &unicode::filename_to_url($filemeta);
805
806    $doc_obj->set_utf8_metadata_element($top_section, "SourceFile", $filemeta);
807}
808   
809# this should be called by all plugins to set the oid of the doc obj, rather
810# than calling doc_obj->set_OID directly
811sub add_OID {
812    my $self = shift (@_); 
813    my ($doc_obj) = @_;
814
815    $doc_obj->set_OIDtype($self->{'OIDtype'}, $self->{'OIDmetadata'});
816
817    # see if there is a plugin specific set_OID function
818    if (defined ($self->can('set_OID'))) {
819    $self->set_OID(@_); # pass through doc_obj and any extra arguments
820    }
821    else {
822    # use the default set_OID() in doc.pm
823    $doc_obj->set_OID();
824    }
825
826}
827 
828# The BasePlugin read_into_doc_obj() function. This function does all the
829# right things to make general options work for a given plugin.  It doesn't do anything with the file other than setting reads in
830# a file and sets up a slew of metadata all saved in doc_obj, which
831# it then returns as part of a tuple (process_status,doc_obj)
832#
833# Much of this functionality used to reside in read, but it was broken
834# down into a supporting routine to make the code more flexible. 
835#
836# recursive plugins (e.g. RecPlug) and specialized plugins like those
837# capable of processing many documents within a single file (e.g.
838# GMLPlug) will normally want to implement their own version of
839# read_into_doc_obj()
840#
841# Note that $base_dir might be "" and that $file might
842# include directories
843
844# currently blocking has been done before it gets here - does this affect secondary plugin stuff??
845sub read_into_doc_obj {
846    my $self = shift (@_); 
847    my ($pluginfo, $base_dir, $file, $block_hash, $metadata, $processor, $maxdocs, $total_count, $gli) = @_;
848
849    my $outhandle = $self->{'outhandle'};
850
851    # should we move this to read? What about secondary plugins?
852    print STDERR "<Processing n='$file' p='$self->{'plugin_type'}'>\n" if ($gli);
853    print $outhandle "$self->{'plugin_type'} processing $file\n"
854        if $self->{'verbosity'} > 1;
855
856    my ($filename_full_path, $filename_no_path) = &util::get_full_filenames($base_dir, $file);
857
858    # create a new document
859    my $doc_obj = new doc ($filename_full_path, "indexed_doc", $self->{'file_rename_method'});
860    my $top_section = $doc_obj->get_top_section();
861
862    $doc_obj->add_utf8_metadata($top_section, "Plugin", "$self->{'plugin_type'}");
863    $doc_obj->add_utf8_metadata($top_section, "FileSize", (-s $filename_full_path));
864 
865
866    # sets the UTF8 filename (Source) for display and sets the url ref to URL encoded version
867    # of the UTF8 filename (SourceFile) for generated files
868    $self->set_Source_metadata($doc_obj, $filename_no_path);
869
870
871    # plugin specific stuff - what args do we need here??
872    unless (defined ($self->process($pluginfo, $base_dir, $file, $metadata, $doc_obj, $gli))) {
873    print STDERR "<ProcessingError n='$file'>\n" if ($gli);
874    return -1;
875    }
876   
877    # include any metadata passed in from previous plugins
878    # note that this metadata is associated with the top level section
879    my $section = $doc_obj->get_top_section();
880    # can we merge these two methods??
881    $self->add_associated_files($doc_obj, $filename_full_path);
882    $self->extra_metadata ($doc_obj, $section, $metadata);
883    $self->auto_extract_metadata($doc_obj);
884
885    # if we haven't found any Title so far, assign one
886    # this was shifted to here from inside read()
887    $self->title_fallback($doc_obj,$section,$filename_no_path);
888   
889    $self->add_OID($doc_obj);
890   
891    $self->post_process_doc_obj($pluginfo, $base_dir, $file, $metadata, $doc_obj, $gli);
892    return (1,$doc_obj);
893}
894
895sub post_process_doc_obj {
896    my $self = shift (@_); 
897    my ($pluginfo, $base_dir, $file, $metadata, $doc_obj, $gli) = @_;
898
899    return 1;
900}
901
902sub add_dummy_text {
903    my $self = shift(@_);
904    my ($doc_obj, $section) = @_;
905
906    # add NoText metadata so we can hide this dummy text in format statements
907    $doc_obj->add_metadata($section, "NoText", "1");
908    $doc_obj->add_text($section, &gsprintf::lookup_string("{BasePlugin.dummy_text}",1));
909   
910}
911
912# does nothing. Can be overridden by subclass
913sub auto_extract_metadata {
914    my $self = shift(@_);
915    my ($doc_obj) = @_;
916}
917
918# adds cover image, associate_file options stuff. Should be called by sub class
919# read_into_doc_obj
920sub add_associated_files {
921    my $self = shift(@_);
922    # whatis filename??
923    my ($doc_obj, $filename) = @_;
924   
925    # add in the cover image
926    if ($self->{'cover_image'}) {
927    $self->associate_cover_image($doc_obj, $filename);
928    }
929    # store the original (used for eg TextPlugin to store the original for OAI)
930    if ($self->{'store_original_file'}) {
931    $self->associate_source_file($doc_obj, $filename);
932    }
933   
934
935}
936
937# implement this if you are extracting metadata for other documents
938sub metadata_read {
939    my $self = shift (@_);
940    my ($pluginfo, $base_dir, $file, $block_hash,
941    $extrametakeys, $extrametadata, $extrametafile,
942    $processor, $maxdocs, $gli) = @_;
943   
944    # can we process this file??
945    my ($filename_full_path, $filename_no_path) = &util::get_full_filenames($base_dir, $file);
946    return undef unless $self->can_process_this_file($filename_full_path);
947
948    return 1; # we recognise the file, but don't actually do anything with it
949}
950
951
952# The BasePlugin read() function. This function calls read_into_doc_obj()
953# to ensure all the right things to make general options work for a
954# given plugin are done. It then calls the process() function which
955# does all the work specific to a plugin (like the old read functions
956# used to do). Most plugins should define their own process() function
957# and let this read() function keep control. 
958#
959# recursive plugins (e.g. RecPlug) and specialized plugins like those
960# capable of processing many documents within a single file (e.g.
961# GMLPlug) might want to implement their own version of read(), but
962# more likely need to implement their own version of read_into_doc_obj()
963#
964# Return number of files processed, undef if can't recognise, -1 if can't
965# process
966
967sub read {
968    my $self = shift (@_); 
969    my ($pluginfo, $base_dir, $file, $block_hash, $metadata, $processor, $maxdocs, $total_count, $gli) = @_;
970
971    # can we process this file??
972    my ($filename_full_path, $filename_no_path) = &util::get_full_filenames($base_dir, $file);
973
974    return undef unless $self->can_process_this_file($filename_full_path);
975   
976    my ($process_status,$doc_obj) = $self->read_into_doc_obj(@_);
977   
978    if ((defined $process_status) && ($process_status == 1)) {
979   
980    # process the document
981    $processor->process($doc_obj);
982
983    $self->{'num_processed'} ++;
984    undef $doc_obj;
985    }
986    # delete any temp files that we may have created
987    $self->clean_up_after_doc_obj_processing();
988
989
990    # if process_status == 1, then the file has been processed.
991    return $process_status;
992
993}
994
995# returns undef if file is rejected by the plugin
996sub process {
997    my $self = shift (@_);
998    my ($textref, $pluginfo, $base_dir, $file, $metadata, $doc_obj, $gli) = @_;
999
1000    gsprintf(STDERR, "BasePlugin::process {common.must_be_implemented}\n") && die "\n";
1001
1002    return undef; # never gets here
1003}
1004
1005# overwrite this method to delete any temp files that we have created
1006sub clean_up_after_doc_obj_processing {
1007    my $self = shift(@_);
1008
1009}
1010
1011# write_file -- used by ConvertToPlug, for example in post processing
1012#
1013# where should this go, is here the best place??
1014sub utf8_write_file {
1015    my $self = shift (@_);
1016    my ($textref, $filename) = @_;
1017   
1018    if (!open (FILE, ">$filename")) {
1019    gsprintf(STDERR, "ConvertToPlug::write_file {ConvertToPlug.could_not_open_for_writing} ($!)\n", $filename);
1020     die "\n";
1021     }
1022    print FILE $$textref;
1023   
1024    close FILE;
1025}
1026
1027
1028sub filename_based_title
1029{
1030    my $self = shift (@_);
1031    my ($file) = @_;
1032
1033    my $file_derived_title = $file;
1034    $file_derived_title =~ s/_/ /g;
1035    $file_derived_title =~ s/\..*?$//;
1036
1037    return $file_derived_title;
1038}
1039
1040
1041sub title_fallback
1042{
1043    my $self = shift (@_);
1044    my ($doc_obj,$section,$file) = @_;
1045
1046    if (!defined $doc_obj->get_metadata_element ($section, "Title") or $doc_obj->get_metadata_element($section, "Title") eq "") {
1047
1048    my $file_derived_title = $self->filename_to_utf8_metadata($self->filename_based_title($file));
1049    if (!defined $doc_obj->get_metadata_element ($section, "Title")) {
1050        $doc_obj->add_utf8_metadata ($section, "Title", $file_derived_title);
1051    }
1052    else {
1053        $doc_obj->set_utf8_metadata_element ($section, "Title", $file_derived_title);
1054    }
1055    }
1056       
1057}
1058 
1059# add any extra metadata that's been passed around from one
1060# plugin to another.
1061# extra_metadata uses add_utf8_metadata so it expects metadata values
1062# to already be in utf8
1063sub extra_metadata {
1064    my $self = shift (@_);
1065    my ($doc_obj, $cursection, $metadata) = @_;
1066
1067    my $associate_tail_re = $self->{'associate_tail_re'};
1068
1069    foreach my $field (keys(%$metadata)) {
1070    # $metadata->{$field} may be an array reference
1071    if ($field eq "gsdlassocfile_tobe") {
1072        # 'gsdlassocfile_tobe' is artificially introduced metadata
1073        # that is used to signal that certain additional files should
1074        # be tied to this document.  Useful in situations where a
1075        # metadata pass in the plugin pipeline works out some files
1076        # need to be associated with a document, but the document hasn't
1077        # been formed yet.
1078        my $equiv_form = "";
1079        foreach my $gaf (@{$metadata->{$field}}) {
1080        my ($full_filename,$mimetype) = ($gaf =~ m/^(.*):(.*):$/);
1081        my ($tail_filename) = ($full_filename =~ /^.*[\/\\](.+?)$/);
1082       
1083        # we need to make sure the filename is valid utf-8 - we do
1084        # this by url or base64 encoding it
1085        # $tail_filename is the name that we store the file as
1086        $tail_filename = &util::rename_file($tail_filename, $self->{'file_rename_method'});
1087        $doc_obj->associate_file($full_filename,$tail_filename,$mimetype);
1088        $doc_obj->associate_source_file($full_filename);
1089        # If the filename is url_encoded, we need to encode the % signs
1090        # in the filename, so that it works in a url
1091        my $url_tail_filename = &unicode::filename_to_url($tail_filename);
1092        # work out extended tail extension (i.e. matching tail re)
1093
1094        my ($file_prefix,$file_extended_ext)
1095            = &util::get_prefix_and_tail_by_regex($tail_filename,$associate_tail_re);
1096        my ($pre_doc_ext) = ($file_extended_ext =~ m/^(.*)\..*$/);
1097        my ($doc_ext) = ($tail_filename =~ m/^.*\.(.*)$/);
1098        my $start_doclink = "<a href=\"_httpprefix_/collect/[collection]/index/assoc/{Or}{[parent(Top):assocfilepath],[assocfilepath]}/$url_tail_filename\">";
1099        my $srcicon = "_icon".$doc_ext."_";
1100        my $end_doclink = "</a>";
1101
1102        my $assoc_form = "$start_doclink\{If\}{$srcicon,$srcicon,$doc_ext\}$end_doclink";
1103
1104        if (defined $pre_doc_ext && $pre_doc_ext ne "") {
1105            # for metadata such as [mp3._edited] [mp3._full] ...
1106            $doc_obj->add_utf8_metadata ($cursection, "$doc_ext.$pre_doc_ext", $assoc_form);
1107        }
1108
1109        # for multiple metadata such as [mp3.assoclink]
1110        $doc_obj->add_utf8_metadata ($cursection, "$doc_ext.assoclink", $assoc_form);
1111       
1112        $equiv_form .= " $assoc_form"; 
1113        }
1114        $doc_obj->add_utf8_metadata ($cursection, "equivlink", $equiv_form);
1115    }
1116    elsif (ref ($metadata->{$field}) eq "ARRAY") {
1117        map {
1118        $doc_obj->add_utf8_metadata ($cursection, $field, $_);
1119        } @{$metadata->{$field}};
1120    } else {
1121        $doc_obj->add_utf8_metadata ($cursection, $field, $metadata->{$field});
1122    }
1123    }
1124}
1125
1126
1127sub compile_stats {
1128    my $self = shift(@_);
1129    my ($stats) = @_;
1130
1131    $stats->{'num_processed'} += $self->{'num_processed'};
1132    $stats->{'num_not_processed'} += $self->{'num_not_processed'};
1133    $stats->{'num_archives'} += $self->{'num_archives'};
1134
1135}
1136sub associate_source_file {
1137    my $self = shift(@_);
1138   
1139    my ($doc_obj, $filename) = @_;
1140    my $cursection = $doc_obj->get_top_section();
1141    my $assocfilename = $doc_obj->get_assocfile_from_sourcefile();
1142   
1143    $doc_obj->associate_file($filename, $assocfilename, undef, $cursection);
1144    $doc_obj->add_utf8_metadata ($cursection, "srclink_file", "[SourceFile]");
1145}
1146
1147sub associate_cover_image {
1148    my $self = shift(@_);
1149    my ($doc_obj, $filename) = @_;
1150
1151    $filename =~ s/\.[^\\\/\.]+$/\.jpg/;
1152    if (exists $self->{'covers_missing_cache'}->{$filename}) {
1153    # don't stat() for existence eg for multiple document input files
1154    # (eg SplitPlug)
1155    return;
1156    }
1157
1158    my $top_section=$doc_obj->get_top_section();
1159
1160    if (-e $filename) {
1161    $doc_obj->associate_source_file($filename);
1162        $doc_obj->associate_file($filename, "cover.jpg", "image/jpeg");
1163    $doc_obj->add_utf8_metadata($top_section, "hascover",  1);
1164    } else {
1165    my $upper_filename = $filename;
1166    $upper_filename =~ s/jpg$/JPG/;
1167    if (-e $upper_filename) {
1168        $doc_obj->associate_source_file($upper_filename);
1169        $doc_obj->associate_file($upper_filename, "cover.jpg",
1170                     "image/jpeg");
1171        $doc_obj->add_utf8_metadata($top_section, "hascover",  1);
1172    } else {
1173        # file doesn't exist, so record the fact that it's missing so
1174        # we don't stat() again (stat is slow)
1175        $self->{'covers_missing_cache'}->{$filename} = 1;
1176    }
1177    }
1178
1179}
1180
1181
1182# Overridden by exploding plugins (eg. ISISPlug)
1183sub clean_up_after_exploding
1184{
1185    my $self = shift(@_);
1186}
1187
1188
1189
11901;
Note: See TracBrowser for help on using the browser.