root/main/trunk/greenstone2/perllib/plugins/GreenstoneSQLPlugin.pm @ 32586

Revision 32586, 22.1 KB (checked in by ak19, 5 weeks ago)

Renaming 'site_name' parameter used by GS SQL Plugout and Plugin to 'site' for consistency with existing uses of site.

Line 
1###########################################################################
2#
3# GreenstoneSQLPlugin.pm -- reads into doc_obj from SQL db and docsql.xml
4# Metadata and/or fulltext are stored in SQL db, the rest may be stored in
5# the docsql .xml files.
6# A component of the Greenstone digital library software
7# from the New Zealand Digital Library Project at the
8# University of Waikato, New Zealand.
9#
10# Copyright (C) 2001 New Zealand Digital Library Project
11#
12# This program is free software; you can redistribute it and/or modify
13# it under the terms of the GNU General Public License as published by
14# the Free Software Foundation; either version 2 of the License, or
15# (at your option) any later version.
16#
17# This program is distributed in the hope that it will be useful,
18# but WITHOUT ANY WARRANTY; without even the implied warranty of
19# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
20# GNU General Public License for more details.
21#
22# You should have received a copy of the GNU General Public License
23# along with this program; if not, write to the Free Software
24# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
25#
26###########################################################################
27
28package GreenstoneSQLPlugin;
29
30
31use strict;
32no strict 'refs'; # allow filehandles to be variables and viceversa
33
34use DBI;
35use docprint; # for new unescape_text() subroutine
36use GreenstoneXMLPlugin;
37use gssql;
38
39
40# TODO:
41# - Run TODOs here, in Plugout and in gssql.pm by Dr Bainbridge.
42# - Have not yet tested writing out just meta or just fulltxt to sql db and reading just that
43# back in from the sql db while the remainder is to be read back in from the docsql .xml files.
44
45# TODO: Add public instructions on using this plugin and its plugout: start with installing mysql binary, changing pwd, running the server (and the client against it for checking: basic cmds like create and drop). Then discuss db name, table names (per coll), db cols and col types, and how the plugout and plugin work.
46# Discuss the plugin/plugout parameters.
47
48# TODO, test on windows and mac.
49# Note: if parsing fails (e.g. using wrong plugout like GS XML plugout, which chokes on args intended for SQL plugout) then SQL plugin init would have already been called and done connection, but disconnect would not have been done because SQL plugin disconnect would not have been called upon parse failure.
50
51# DONE:
52# + TODO: For on cancel, add a SIGTERM handler or so to call end()
53# or to explicitly call gs_sql->close_connection if $gs_sql def
54#
55# + TODO: Incremental delete can't work until GSSQLPlugout has implemented build_mode = incremental
56# (instead of tossing away db on every build)
57# + Ask about docsql naming convention adopted to identify OID. Better way?
58# collection names -> table names: it seems hyphens not allowed. Changed to underscores.
59# + Startup parameters (except removeold/build_mode)
60# + how do we detect we're to do removeold during plugout in import.pl phase
61# + incremental building: where do we need to add code to delete rows from our sql table after
62# incrementally importing a coll with fewer docs (for instance)? What about deleted/modified meta?
63# + Ask if I can assume that all SQL dbs (not just MySQL) will preserve the order of inserted nodes
64# (sections) which in this case had made it easy to reconstruct the doc_obj in memory in the correct order.
65# YES: Otherwise for later db types (drivers), can set order by primary key column and then order by did column
66# + NOTTODO: when db is not running GLI is paralyzed -> can we set timeout on DBI connection attempt?
67#   NOT A PROBLEM: Tested to find DBI connection attempt fails immediately when MySQL server not
68# running. The GLI "paralyzing" incident last time was not because of the gs sql connection code,
69# but because my computer was freezing on-and-off.
70# + "Courier" demo documents in lucene-sql collection: character (degree symbol) not preserved in title. Is this because we encode in utf8 when putting into db and reading back in?
71# Test doc with meta and text like macron in Maori text.
72# + TODO Q: During import, the GS SQL Plugin is called before the GS SQL Plugout with undesirable side
73# effect that if the db doesn't exist, gssql::use_db() fails, as it won't create db.
74#   This got fixed when GSSQLPlugin stopped connecting on init().
75#
76#
77#+ TODO: deal with incremental vs removeold. If docs removed from import folder, then import step
78# won't delete it from archives but buildcol step will. Need to implement this with this database plugin or wherever the actual flow is.
79#
80# + TODO Q: is "reindex" = del from db + add to db?
81# - is this okay for reindexing, or will it need to modify existing values (update table)
82# - if it's okay, what does reindex need to accomplish (and how) if the OID changes because hash id produced is different?
83# - delete is accomplished in GS SQL Plugin, during buildcol.pl. When should reindexing take place?
84# during SQL plugout/import.pl or during plugin? If adding is done by GSSQLPlugout, does it need to
85# be reimplemented in GSSQLPlugin to support the adding portion of reindexing.
86#
87# INCREMENTAL REBUILDING IMPLEMENTED CORRECTLY AND WORKS:
88# Overriding plugins' remove_all() method covered removeold.
89# Overriding plugins' remove_one() method is all I needed to do for reindex and deletion
90# (incremental and non-incremental) to work.
91# but doing all this needed an overhaul of gssql.pm and its use by the GS SQL plugin and plugout.
92# - needed to correct plugin.pm::remove_some() to process all files
93# - and needed to correct GreenstoneSQLPlugin::close_document() to setOID() after all
94# All incremental import and buildcol worked after that:
95# - deleting files and running incr-import and incr-buildcol (= "incr delete"),
96# - deleting files and running incr-import and buildcol (="non-incr delete")
97# - modifying meta and doing an incr rebuild
98# - modifying fulltext and doing an incr rebuild
99# - renaming a file forces a reindex: doc is removed from db and added back in, due to remove_one()
100# - tested CSV file: adding some records, changing some records
101#    + CSVPlugin test (collection csvsql)
102#    + MetadataCSVPlugin test (modified collection sqltest to have metadata.csv refer to the
103#      filenames of sqltest's documents)
104#    + shared image test (collection shareimg): if 2 html files reference the same image, the docs
105#      are indeed both reindexed if the image is modified (e.g. I replaced the image with another
106#      of the same name) which in the GS SQL plugin/plugout case is that the 2 docs are deleted
107#      and added in again.
108
109########################################################################################
110
111# GreenstoneSQLPlugin inherits from GreenstoneXMLPlugin so that it if meta or fulltext
112# is still written out to doc.xml (docsql .xml), that will be processed as usual,
113# whereas GreenstoneSQLPlugin will process all the rest (full text and/or meta, whichever
114# is written out by GreenstoneSQLPlugout into the SQL db).
115
116
117sub BEGIN {
118    @GreenstoneSQLPlugin::ISA = ('GreenstoneXMLPlugin');
119}
120
121# This plugin must be in the document plugins pipeline IN PLACE OF GreenstoneXMLPlugin
122# So we won't have a process exp conflict here.
123# The structure of docsql.xml files is identical to doc.xml and the contents are similar except:
124#   - since metadata and/or fulltxt are stored in mysql db instead, just XML comments indicating
125#   this are left inside docsql.xml within the <Description> (for meta) and/or <Content> (for txt)
126#   - the root element Archive now has a docoid attribute: <Archive docoid="OID">
127sub get_default_process_exp {
128    my $self = shift (@_);
129
130    return q^(?i)docsql(-\d+)?\.xml$^; # regex based on this method in GreenstoneXMLPlugin
131}
132
133my $process_mode_list =
134    [ { 'name' => "meta_only",
135        'desc' => "{GreenstoneSQLPlug.process_mode.meta_only}" },     
136      { 'name' => "text_only",
137        'desc' => "{GreenstoneSQLPlug.process_mode.text_only}" },
138      { 'name' => "all",
139        'desc' => "{GreenstoneSQLPlug.process_mode.all}" } ];
140
141my $rollback_on_cancel_list =
142    [ { 'name' => "true",
143        'desc' => "{GreenstoneSQLPlug.rollback_on_cancel}" },     
144      { 'name' => "false",
145        'desc' => "{GreenstoneSQLPlug.rollbacl_on_cancel}" } ];
146
147my $arguments =
148    [ { 'name' => "process_exp",
149    'desc' => "{BaseImporter.process_exp}",
150    'type' => "regexp",
151    'deft' => &get_default_process_exp(),
152    'reqd' => "no" },
153      { 'name' => "process_mode",
154    'desc' => "{GreenstoneSQLPlug.process_mode}",
155    'type' => "enum",
156    'list' => $process_mode_list,
157    'deft' => "all",
158    'reqd' => "no"},
159      { 'name' => "rollback_on_cancel",
160    'desc' => "{GreenstoneSQLPlug.rollback_on_cancel}",
161    'type' => "enum",
162    'list' => $rollback_on_cancel_list,
163    'deft' => "false", # TODO Q: what's the better default? If "true", any memory concerns?
164    'reqd' => "no",
165    'hiddengli' => "no"},
166      { 'name' => "db_driver",
167    'desc' => "{GreenstoneSQLPlug.db_driver}",
168    'type' => "string",
169    'deft' => "mysql",
170    'reqd' => "yes"},
171      { 'name' => "db_client_user",
172    'desc' => "{GreenstoneSQLPlug.db_client_user}",
173    'type' => "string",
174    'deft' => "root",
175    'reqd' => "yes"},
176      { 'name' => "db_client_pwd",
177    'desc' => "{GreenstoneSQLPlug.db_client_pwd}",
178    'type' => "string",
179    'deft' => "",
180    'reqd' => "yes"}, # pwd required?
181      { 'name' => "db_host",
182    'desc' => "{GreenstoneSQLPlug.db_host}",
183    'type' => "string",
184    'deft' => "127.0.0.1",
185    'reqd' => "yes"},
186    ];
187
188my $options = { 'name'     => "GreenstoneSQLPlugin",
189        'desc'     => "{GreenstoneSQLPlugin.desc}",
190        'abstract' => "no",
191        'inherits' => "yes",
192            'args'     => $arguments };
193
194
195###### Methods called during buildcol and import #######
196
197sub new {
198    my ($class) = shift (@_);
199    my ($pluginlist,$inputargs,$hashArgOptLists) = @_;
200    push(@$pluginlist, $class);
201
202    push(@{$hashArgOptLists->{"ArgList"}},@{$arguments});
203    push(@{$hashArgOptLists->{"OptList"}},$options);
204
205    my $self = new GreenstoneXMLPlugin($pluginlist, $inputargs, $hashArgOptLists);
206
207   
208    #return bless $self, $class;
209    $self = bless $self, $class;
210    if ($self->{'info_only'}) {
211    # If running pluginfo, we don't need to go further.
212    return $self;
213    }
214
215    # do anything else that needs to be done here when not pluginfo
216   
217    return $self;
218}
219
220# GS SQL Plugin::init() (and deinit()) is called by import.pl and also by buildcol.pl
221# This means it connects and deconnects during import.pl as well. This is okay
222# as removeold, which should drop the collection tables, happens during the import phase,
223# calling GreenstoneSQLPlugin::and therefore also requires a db connection.
224# TODO: Eventually can try moving get_gssql_instance into gssql.pm? That way both GS SQL Plugin
225# and Plugout would be using one connection during import.pl phase when both plugs exist.
226
227# Call init() not begin() because there can be multiple plugin passes and begin() called for
228# each pass (one for doc level and another for section level indexing), whereas init() should
229# be called before any and all passes.
230# This way, we can connect to the SQL database once per buildcol run.
231sub init {
232    my ($self) = shift (@_);
233    ##print STDERR "@@@@@@@@@@ INIT CALLED\n";
234   
235    $self->SUPER::init(@_); # super (GreenstoneXMLPlugin) will not yet be trying to read from doc.xml (docsql .xml) files in init().
236
237    ####################
238#    print "@@@ SITE NAME: ". $self->{'site'} . "\n" if defined $self->{'site'};
239#    print "@@@ COLL NAME: ". $ENV{'GSDLCOLLECTION'} . "\n";
240
241#    print STDERR "@@@@ db_pwd: " . $self->{'db_client_pwd'} . "\n";
242#    print STDERR "@@@@ user: " . $self->{'db_client_user'} . "\n";
243#    print STDERR "@@@@ db_host: " . $self->{'db_host'} . "\n";
244#    print STDERR "@@@@ db_driver: " . $self->{'db_driver'} . "\n";
245    ####################
246
247    # create gssql object.
248    # collection name will be used for naming tables (site name will be used for naming database)
249    my $gs_sql = new gssql({
250    'collection_name' => $ENV{'GSDLCOLLECTION'},
251    'verbosity' => $self->{'verbosity'} || 0
252               });
253   
254    # if autocommit is set, there's no rollback support
255    my $autocommit = ($self->{'rollback_on_cancel'} eq "false") ? 1 : 0;
256
257    # try connecting to the mysql db, die if that fails
258    if(!$gs_sql->connect_to_db({
259    'db_driver' => $self->{'db_driver'},
260    'db_client_user' => $self->{'db_client_user'},
261    'db_client_pwd' => $self->{'db_client_pwd'},
262    'db_host' => $self->{'db_host'},
263    'autocommit' => $autocommit
264                   })
265    )
266    {
267    # This is fatal for the plugout, let's terminate here
268    # PrintError would already have displayed the warning message on connection fail   
269    die("Could not connect to db. Can't proceed.\n");
270    }
271   
272    my $db_name = $self->{'site'} || "greenstone2"; # one database per GS3 site, for GS2 the db is called greenstone2
273
274    # Attempt to use the db, create it if it doesn't exist (but don't create the tables yet)
275    # Bail if we can't use the database
276    if(!$gs_sql->use_db($db_name)) {
277   
278    # This is fatal for the plugout, let's terminate here after disconnecting again
279    # PrintError would already have displayed the warning message on load fail
280    # And on die() perl will call gssql destroy which will ensure a disconnect() from db
281    #$gs_sql->force_disconnect_from_db();
282    die("Could not use db $db_name. Can't proceed.\n");
283    }
284   
285   
286    # store db handle now that we're connected
287    $self->{'gs_sql'} = $gs_sql;   
288}
289
290
291# This method also runs on import.pl if gs_sql has a value. But we just want to run it on buildcol
292# Call deinit() not end() because there can be multiple plugin passes:
293# one for doc level and another for section level indexing
294# and deinit() should be called before all passes
295# This way, we can close the SQL database once per buildcol run.
296sub deinit {
297    my ($self) = shift (@_);
298   
299    ##print STDERR "@@@@@@@@@@ GreenstoneSQLPlugin::DEINIT CALLED\n";
300   
301    if($self->{'gs_sql'}) {
302
303    # Important to call finished():
304    # it will disconnect from db if this is the last gssql instance,
305    # and it will commit to db before disconnecting if rollbback_on_cancel turned on
306    $self->{'gs_sql'}->finished();
307
308    # Clear gs_sql (setting key to undef has a different meaning from deleting:
309    # undef makes key still exist but its value is unded whereas delete deletes the key)
310    # So all future use has to make the connection again
311    delete $self->{'gs_sql'};
312    }
313
314    $self->SUPER::deinit(@_);
315}
316
317
318
319###### Methods only called during import.pl #####
320
321# This is called once if removeold is set with import.pl. Most plugins will do
322# nothing but if a plugin does any stuff outside of creating doc obj, then
323# it may need to clear something.
324# In the case of GreenstoneSQL plugs: this is the first time we have a chance
325# to purge the tables of the current collection from the current site's database
326sub remove_all {
327    my $self = shift (@_);
328    my ($pluginfo, $base_dir, $processor, $maxdocs) = @_;
329
330    $self->SUPER::remove_all(@_);
331   
332    print STDERR "   Building with removeold option set, so deleting current collection's tables if they exist\n" if($self->{'verbosity'});
333   
334    # if we're in here, we'd already have run 'use database <site>;' during sub init()
335    # so we can go ahead and delete the collection's tables
336    my $gs_sql = $self->{'gs_sql'};
337    $gs_sql->delete_collection_tables(); # will delete them if they exist
338
339    # and recreate tables? No. Tables' existence is ensured in GreenstoneSQLPlugout::begin()
340    my $proc_mode = $self->{'process_mode'};
341    if($proc_mode ne "text_only") {
342    $gs_sql->ensure_meta_table_exists();
343    }
344    if($proc_mode ne "meta_only") {
345    $gs_sql->ensure_fulltxt_table_exists();
346    }
347
348}
349
350# This is called during import.pl per document for docs that have been deleted from the
351# collection. Most plugins will do nothing
352# but if a plugin does any stuff outside of creating doc obj, then it may need
353# to clear something.
354# remove the doc(s) denoted by oids from GS SQL db
355# This takes care of incremental deletes (docs marked D by ArchivesInfPlugin when building
356# incrementally) as well as cases of "Non-icremental Delete", see ArchivesInfPlugin.pm
357sub remove_one {
358    my $self = shift (@_);
359   
360    my ($file, $oids, $archivedir) = @_;
361
362    my $rv = $self->SUPER::remove_one(@_);
363   
364    print STDERR "@@@ IN SQLPLUG::REMOVE_ONE: $file\n";
365   
366    #return undef unless $self->can_process_this_file($file); # NO, DON'T DO THIS (inherited remove_one behaviour) HERE:
367           # WE DON'T CARE IF IT'S AN IMAGE FILE THAT WAS DELETED.
368           # WE CARE ABOUT REMOVING THE DOC_OID OF THAT IMAGE FILE FROM THE SQL DB
369           # SO DON'T RETURN IF CAN'T_PROCESS_THIS_FILE
370   
371   
372    my $gs_sql = $self->{'gs_sql'} || return 0; # couldn't make the connection or no db etc
373
374    print STDERR "*****************************\nAsked to remove_one oid\n***********************\n";
375    print STDERR "Num oids: " . scalar (@$oids) . "\n";
376   
377    my $proc_mode = $self->{'process_mode'};
378    foreach my $oid (@$oids) { 
379    if($proc_mode eq "all" || $proc_mode eq "meta_only") {
380        print STDERR "@@@@@@@@ Deleting $oid from meta table\n" if $self->{'verbosity'} > 2;
381        $gs_sql->delete_recs_from_metatable_with_docid($oid);
382    }
383    if($proc_mode eq "all" || $proc_mode eq "text_only") {
384        print STDERR "@@@@@@@@ Deleting $oid from fulltxt table\n" if $self->{'verbosity'} > 2;
385        $gs_sql->delete_recs_from_texttable_with_docid($oid);
386    }
387    }
388    return $rv;
389}
390
391##### Methods called only during buildcol #####
392
393sub xml_start_tag {
394    my $self = shift(@_);
395    my ($expat, $element) = @_;
396
397    my $outhandle = $self->{'outhandle'};
398   
399    $self->{'element'} = $element;
400    if ($element eq "Archive") { # docsql.xml files contain a OID attribute on Archive element
401    # the element's attributes are in %_ as per ReadXMLFile::xml_start_tag() (while $_
402    # contains the tag)
403
404    # Don't access %_{'docoid'} directly: keep getting a warning message to
405    # use $_{'docoid'} for scalar contexts, but %_ is the element's attr hashmap
406    # whereas $_ has the tag info. So we don't want to do $_{'docoid'}.
407    my %attr_hash = %_; # right way, see OAIPlugin.pm
408    $self->{'doc_oid'} = $attr_hash{'docoid'};
409    print $outhandle "Extracted OID from docsql.xml: ".$self->{'doc_oid'}."\n"
410        if $self->{'verbosity'} > 2;
411
412    }
413    else { # let superclass GreenstoneXMLPlugin continue to process <Section> and <Metadata> elements
414    $self->SUPER::xml_start_tag(@_);
415    }
416}
417
418# TODO Q: Why are there 4 passes when we're only indexing at doc and section level (2 passes)? What's the dummy pass, why is there a pass for infodb?
419
420# We should only ever get here during the buildcol.pl phase
421# At the end of superclass GreenstoneXMLPlugin.pm's close_document() method,
422# the doc_obj in memory is processed (indexed) and then made undef.
423# So we have to work with doc_obj before superclass close_document() is finished.
424sub close_document {
425    my $self = shift(@_);
426
427    ##print STDERR "XXXXXXXXX in SQLPlugin::close_doc()\n";
428   
429    my $gs_sql = $self->{'gs_sql'};
430   
431    my $outhandle = $self->{'outhandle'};
432    my $doc_obj = $self->{'doc_obj'};
433
434    my $oid = $self->{'doc_oid'}; # we stored current doc's OID during sub xml_start_tag()
435    my $proc_mode = $self->{'process_mode'};
436   
437    # For now, we have access to doc_obj (until just before super::close_document() terminates)
438
439    # OID parsed of docsql.xml file does need to be set on $doc_obj, as noticed in this case:
440    # when a doc in import is renamed, and you do incremental import, it is marked for reindexing
441    # (reindexing is implemented by this plugin as a delete followed by add into the sql db).
442    # In that case, UNLESS you set the OID at this stage, the old deleted doc id (for the old doc
443    # name) continues to exist in the index at the end of incremental rebuilding if you were to
444    # browse the rebuilt collection by files/titles. So unless you set the OID here, the deleted
445    # doc oids will still be listed in the index.
446    $self->{'doc_obj'}->set_OID($oid);
447   
448    print STDERR "   GreenstoneSQLPlugin processing doc $oid (reading into docobj from SQL db)\n"
449    if $self->{'verbosity'};
450   
451    if($proc_mode eq "all" || $proc_mode eq "meta_only") {
452    # read in meta for the collection (i.e. select * from <col>_metadata table
453   
454    my $records = $gs_sql->select_from_metatable_matching_docid($oid, $outhandle);
455   
456    print $outhandle "----------SQL DB contains meta-----------\n" if $self->{'verbosity'} > 2;
457    # https://www.effectiveperlprogramming.com/2010/07/set-custom-dbi-error-handlers/
458
459    foreach my $row (@$records) {
460        #print $outhandle "row: @$row\n";
461        my ($primary_key, $did, $sid, $metaname, $metaval) = @$row;
462       
463        # get rid of the artificial "root" introduced in section id when saving to sql db
464        $sid =~ s@^root@@;
465        $sid = $doc_obj->get_top_section() unless $sid;
466        print $outhandle "### did: $did, sid: |$sid|, meta: $metaname, val: $metaval\n"
467        if $self->{'verbosity'} > 2;
468       
469        # TODO:  we accessed the db in utf8 mode, so, we can call doc_obj->add_utf8_meta directly:
470        $doc_obj->add_utf8_metadata($sid, $metaname, &docprint::unescape_text($metaval));
471    }
472    print $outhandle "----------FIN READING DOC's META FROM SQL DB------------\n"
473        if $self->{'verbosity'} > 2;
474    }
475   
476    if($proc_mode eq "all" || $proc_mode eq "text_only") {
477    # read in fulltxt for the collection (i.e. select * from <col>_fulltxt table
478   
479    my $fulltxt_table = $gs_sql->get_fulltext_table_name();
480   
481   
482    my $records = $gs_sql->select_from_texttable_matching_docid($oid, $outhandle);
483   
484   
485    print $outhandle "----------\nSQL DB contains txt entries for-----------\n"
486        if $self->{'verbosity'} > 2;
487
488    foreach my $row (@$records) {
489        my ($primary_key, $did, $sid, $text) = @$row;
490       
491        # get rid of the artificial "root" introduced in section id when saving to sql db
492        #$sid =~ s@^root@@;
493        $sid = $doc_obj->get_top_section() if ($sid eq "root");
494        print $outhandle "### did: $did, sid: |$sid|, fulltext: <TXT>\n"
495        if $self->{'verbosity'} > 2;
496       
497        # TODO - pass by ref?
498        # TODO: we accessed the db in utf8 mode, so, we can call doc_obj->add_utf8_text directly:
499        my $textref = &docprint::unescape_textref(\$text);
500        $doc_obj->add_utf8_text($sid, $$textref);
501    }   
502    print $outhandle "----------FIN READING DOC's TXT FROM SQL DB------------\n"
503        if $self->{'verbosity'} > 2;
504    }
505   
506    # done reading into docobj from SQL db
507   
508    # don't forget to clean up on close() in superclass
509    # It will get the doc_obj indexed then make it undef
510    $self->SUPER::close_document(@_);
511}
512
513
5141;
Note: See TracBrowser for help on using the browser.