source: trunk/gsdl/perllib/plugins/ConvertToPlug.pm@ 1435

###########################################################################
#
# ConvertToPlug.pm -- plugin that inherits from HTML or TEXT Plug, depending
#                     on plugin argument convert_to
#
# A component of the Greenstone digital library software
# from the New Zealand Digital Library Project at the 
# University of Waikato, New Zealand.
#
# Copyright (C) 1999 New Zealand Digital Library Project
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
###########################################################################

# The plugin is inherited by such plugins as WordPlug and PDFPlug.
# It facilitates the conversion of these document types to either HTML
# or TEXT by setting up variable that instruct ConvertToBasPlug
# how to work.

# It works by dynamically inheriting HTMLPlug or TEXTPlug based on
# the plugin argument 'convert_to'.  If the argument is not present,
# the default is to inherit HTMLPlug.


package ConvertToPlug;

use HTMLPlug;
use TEXTPlug;

sub BEGIN {
    @ISA = ('HTMLPlug', 'TEXTPlug');
}

use strict;

sub print_usage {
    my ($plugin_name) = @_;

    print STDERR "\n  usage: plugin $plugin_name [options]\n\n";
    print STDERR "  options:\n";
    print STDERR "   -convert_to (html|text) plugin converts to TEXT or HTML\n";
    print STDERR "                           (default html)\n";
}

sub parse_args
{
    my $class = shift (@_);
    my ($args) = @_;

    my $plugin_name = $class;
    $plugin_name =~ s/\.pm$//;

    my $generate_format;
    if (!parsargv::parse($args, 
             q^convert_to/(html|text)/html^, \$generate_format,
             "allow_extra_options")) {

    print STDERR "\nIncorrect options passed to $plugin_name, ";
    print STDERR "check your collect.cfg configuration file\n";
    &print_usage($plugin_name);
    die "\n";
    }

    return ($plugin_name,$generate_format);
}

sub new {
    my $class = shift (@_);
    
    my ($plugin_name,$generate_format) = $class->parse_args(\@_);

    my $self;

    if ($generate_format eq "text")
    {
    $self = new TEXTPlug ($class, @_);
    $self->{'convert_to'} = "TEXT";
    $self->{'convert_to_ext'} = "txt";
    }
    else
    {
    $self = new HTMLPlug ($class, @_);
    $self->{'convert_to'} = "HTML";
    $self->{'convert_to_ext'} = "html";
    }

    return bless $self, $class;
}



# Run conversion utility on the input file.  Output files generated in
# collection specific 'tmp' directory.  
# The collection tmp area is used to convert Word, PDF etc documents into 
# another format (such as text or HTML) suitable for reading and indexing

sub tmp_area_convert_file {
    my $self = shift (@_);
    my ($output_ext,$input_filename, $textref) = @_;

    # softlink to collection tmp dir
    my $colname = &util::use_collection();
    my $tmp_dirname 
    = &util::filename_cat($ENV{'GSDLHOME'},"collect",$colname,"tmp");
    &util::mk_dir($tmp_dirname) if (!-e $tmp_dirname);

    # derive tmp filename from input filename
    my ($tailname,$dirname,$suffix)
    = File::Basename::fileparse($input_filename,'\..+');
    my $tmp_filename = &util::filename_cat($tmp_dirname,"$tailname$suffix");

    # Remove any white space from filename -- no risk of name collision, and
    # makes latter conversion by utils simpler
    $tmp_filename =~ s/\s+//g; 

    &util::soft_link($input_filename,$tmp_filename);

    my $output_filename 
    = &util::filename_cat($tmp_dirname,"$tailname.$output_ext");
    $output_filename =~ s/\s+//g; 

    my $verbosity = $self->{'verbosity'};
    if ($verbosity>0)
    {
    print STDERR "Converting $tailname$suffix to $self->{'convert_to'}\n";
    }
    
    # run either gs2txt.pl or gs2html.pl to peform the requested conversion
    if (system("gs2$output_ext.pl -verbose $verbosity \"$tmp_filename\"")>0)
    {
    print STDERR "Warning: unable to convert to $output_ext format\n";
    }

    # remove symbolic link to original file
    &util::rm($tmp_filename);

    return $output_filename;
}


# Remove collection specific tmp directory and all its contents.

sub cleanup_tmp_area {
    my $self = shift (@_);

    my $colname = &util::use_collection();
    my $tmp_dirname 
    = &util::filename_cat($ENV{'GSDLHOME'},"collect",$colname,"tmp");
    &util::rm_r($tmp_dirname);
    &util::mk_dir($tmp_dirname);
}



# Override BasPlug read_file

sub read_file {
    my $self = shift (@_);
    my ($src_filename, $textref) = @_;

    my $output_ext = $self->{'convert_to_ext'};
    my $conv_filename = $self->tmp_area_convert_file($output_ext,$src_filename);
    $self->{'conv_filename'} = $conv_filename;

    BasPlug::read_file($self,$conv_filename,$textref);
}


# Override BasPlug read

sub read {
    my $self = shift (@_);
    
    my $ret_val = BasPlug::read($self,@_);

    $self->cleanup_tmp_area();
    
    return $ret_val;
}


# do plugin specific processing of doc_obj for HTML type
sub process_type {
    my $self = shift (@_);
    my ($doc_ext, $textref, $pluginfo, $base_dir, $file, $metadata, $doc_obj) = @_;
    
    my $conv_filename = $self->{'conv_filename'};
    my $tmp_dirname = File::Basename::dirname($conv_filename);
    my $tmp_tailname = File::Basename::basename($conv_filename);

    my $convert_to = $self->{'convert_to'};
    my $ret_val;    

    if ($convert_to eq "TEXT")
    {
    $ret_val = TEXTPlug::process($self,$textref,$pluginfo,
                     $tmp_dirname,$tmp_tailname,
                     $metadata,$doc_obj);
    }
    else
    {
    $ret_val = HTMLPlug::process($self,$textref,$pluginfo,
                     $tmp_dirname,$tmp_tailname,
                     $metadata,$doc_obj);
    }

    # associate original file with doc object
    my $cursection = $doc_obj->get_top_section();
    my $filename = &util::filename_cat($base_dir,$file);
    $doc_obj->associate_file($filename, "doc.$doc_ext", undef, $cursection);

    my $doclink = "<a href=_httpcollection_/index/assoc/[archivedir]/doc.$doc_ext>";
    $doc_obj->add_utf8_metadata ($cursection, "srclink",  $doclink); 
    $doc_obj->add_utf8_metadata ($cursection, "srcicon",  "_icon".$doc_ext."_"); 
    $doc_obj->add_utf8_metadata ($cursection, "/srclink", "</a>"); 

    return $ret_val;
}

1;