#!/usr/bin/perl -w

###########################################################################
#
# import.pl --
# A component of the Greenstone digital library software
# from the New Zealand Digital Library Project at the 
# University of Waikato, New Zealand.
#
# Copyright (C) 1999 New Zealand Digital Library Project
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
###########################################################################


# This program will import a number of files into a particular collection

package import;

BEGIN {
    die "GSDLHOME not set\n" unless defined $ENV{'GSDLHOME'};
    die "GSDLOS not set\n" unless defined $ENV{'GSDLOS'};
    unshift (@INC, "$ENV{'GSDLHOME'}/perllib");
    unshift (@INC, "$ENV{'GSDLHOME'}/perllib/cpan");
    unshift (@INC, "$ENV{'GSDLHOME'}/perllib/plugins");
    unshift (@INC, "$ENV{'GSDLHOME'}/perllib/plugouts");
    unshift (@INC, "$ENV{'GSDLHOME'}/perllib/classify");

    if (defined $ENV{'GSDLEXTS'}) {
	my @extensions = split(/:/,$ENV{'GSDLEXTS'});
	foreach my $e (@extensions) {
	    my $ext_prefix = "$ENV{'GSDLHOME'}/ext/$e";

	    unshift (@INC, "$ext_prefix/perllib");
	    unshift (@INC, "$ext_prefix/perllib/cpan");
	}
    }
}

use strict;
no strict 'refs'; # allow filehandles to be variables and vice versa
no strict 'subs'; # allow barewords (eg STDERR) as function arguments

use arcinfo;
use colcfg;
use plugin;
use plugout;
use manifest;
use util;
use scriptutil;
use FileHandle;
use gsprintf 'gsprintf';
use printusage;
use parse2;



my $oidtype_list = 
    [ { 'name' => "hash",
        'desc' => "{import.OIDtype.hash}" },
      { 'name' => "assigned",
        'desc' => "{import.OIDtype.assigned}" },
      { 'name' => "incremental",
        'desc' => "{import.OIDtype.incremental}" },
      { 'name' => "dirname",
        'desc' => "{import.OIDtype.dirname}" } ];


# used to control output file format
my $saveas_list = 
    [ { 'name' => "DSpace",
        'desc' => "{export.saveas.DSpace}" },
      { 'name' => "GreenstoneMETS",
        'desc' => "{export.saveas.GreenstoneMETS}"},
      { 'name' => "FedoraMETS",
        'desc' => "{export.saveas.FedoraMETS}"},
      { 'name' => "GA",
        'desc' => "{export.saveas.GA}"},
      { 'name' => "MARCXML",
        'desc' => "{export.saveas.MARCXML}"}
     ];


# Possible attributes for each argument
# name: The name of the argument
# desc: A description (or more likely a reference to a description) for this argument
# type: The type of control used to represent the argument. Options include: string, int, flag, regexp, metadata, language, enum etc
# reqd: Is this argument required?
# hiddengli: Is this argument hidden in GLI?
# modegli: The lowest detail mode this argument is visible at in GLI

my $saveas_argument
    = { 'name' => "saveas",
	'desc' => "{import.saveas}",
	'type' => "enum",
	'list' => $saveas_list,
	'deft' => "GA",
	'reqd' => "no",
	'modegli' => "3" };


my $arguments = 
    [ 
      $saveas_argument,
      { 'name' => "archivedir",
	'desc' => "{import.archivedir}",
	'type' => "string",
	'reqd' => "no",
        'hiddengli' => "yes" },
      { 'name' => "importdir",
	'desc' => "{import.importdir}",
	'type' => "string",
	'reqd' => "no",
        'hiddengli' => "yes" },
      { 'name' => "collectdir",
	'desc' => "{import.collectdir}",
	'type' => "string",
	# parsearg left "" as default
	#'deft' => &util::filename_cat ($ENV{'GSDLHOME'}, "collect"),
	'deft' => "",
	'reqd' => "no",
        'hiddengli' => "yes" },
      { 'name' => "site",
	'desc' => "{import.site}",
	'type' => "string",
	'deft' => "",
	'reqd' => "no",
        'hiddengli' => "yes" },
      { 'name' => "manifest",
	'desc' => "{import.manifest}",
	'type' => "string",
	'deft' => "",
	'reqd' => "no",
        'hiddengli' => "yes" },
      { 'name' => "debug",
	'desc' => "{import.debug}",
	'type' => "flag",
	'reqd' => "no",
        'hiddengli' => "yes" },
      { 'name' => "faillog",
	'desc' => "{import.faillog}",
	'type' => "string",
	# parsearg left "" as default
	#'deft' => &util::filename_cat("&lt;collectdir&gt;", "colname", "etc", "fail.log"),
	'deft' => "",
	'reqd' => "no",
        'modegli' => "4" },
      { 'name' => "incremental",
	'desc' => "{import.incremental}",
	'type' => "flag",
	'hiddengli' => "yes" },
      { 'name' => "keepold",
	'desc' => "{import.keepold}",
	'type' => "flag",
	'reqd' => "no",
	'hiddengli' => "yes" },
      { 'name' => "removeold",
	'desc' => "{import.removeold}",
	'type' => "flag",
	'reqd' => "no",
	'hiddengli' => "yes" },
      { 'name' => "language",
	'desc' => "{scripts.language}",
	'type' => "string",
	'reqd' => "no",
	'hiddengli' => "yes" },
      { 'name' => "maxdocs",
	'desc' => "{import.maxdocs}",
	'type' => "int",
	'reqd' => "no",
	# parsearg left "" as default
	#'deft' => "-1",
	'range' => "1,",
	'modegli' => "1" },
      { 'name' => "OIDtype",
	'desc' => "{import.OIDtype}",
	'type' => "enum",
	'list' => $oidtype_list,
	# parsearg left "" as default
	#'deft' => "hash",
	'reqd' => "no",
	'modegli' => "2" },
      { 'name' => "OIDmetadata",
	'desc' => "{import.OIDmetadata}",
	'type' => "metadata",
	'deft' => "dc.Identifier",
	'reqd' => "no",
	'modegli' => "2" },
      { 'name' => "out",
	'desc' => "{import.out}",
	'type' => "string",
	'deft' => "STDERR",
	'reqd' => "no",
        'hiddengli' => "yes" },
      { 'name' => "sortmeta",
	'desc' => "{import.sortmeta}",
	'type' => "metadata",
#	'type' => "string",
	'reqd' => "no",
	'modegli' => "3" },
      { 'name' => "removeprefix",
	'desc' => "{BasClas.removeprefix}",
	'type' => "regexp",
	'deft' => "",
	'reqd' => "no", 
	'modegli' => "3" },
      { 'name' => "removesuffix",
	'desc' => "{BasClas.removesuffix}",
	'type' => "regexp",
	'deft' => "",
	'reqd' => "no",
	'modegli' => "3" }, 
      { 'name' => "groupsize",
	'desc' => "{import.groupsize}",
	'type' => "int",
	'deft' => "1",
	'reqd' => "no",
	'modegli' => "3" },
      { 'name' => "gzip",
	'desc' => "{import.gzip}",
	'type' => "flag",
	'reqd' => "no",
	'modegli' => "4" },
      { 'name' => "statsfile",
	'desc' => "{import.statsfile}",
	'type' => "string",
	'deft' => "STDERR",
	'reqd' => "no",
        'hiddengli' => "yes" },
      { 'name' => "verbosity",
	'desc' => "{import.verbosity}",
	'type' => "int",
	'range' => "0,",
	# parsearg left "" as default
	#'deft' => "2",
	'reqd' => "no",
	'modegli' => "4" },
      { 'name' => "gli",
	'desc' => "",
	'type' => "flag",
	'reqd' => "no",
	'hiddengli' => "yes" },
      { 'name' => "xml",
	'desc' => "{scripts.xml}",
	'type' => "flag",
	'reqd' => "no",
	'hiddengli' => "yes" }];

my $options = { 'name' => "import.pl",
		'desc' => "{import.desc}",
		'args' => $arguments };


&main();

sub main {
    # params
    my ($language, $verbosity, $debug,
	$importdir, $site, $manifest, $incremental, $keepold, 
	$removeold, $saveas,
	$OIDtype, $OIDmetadata, 
	$maxdocs, $statsfile,
	$out, $faillog, $collectdir, $gli,

	$archivedir, 
	$gzip, $groupsize, 
	$sortmeta, $removeprefix, $removesuffix, 
	);

    my $xml = 0;

    # other vars
    my ($configfilename, $collectcfg, $collection, 
	$archive_info_filename, $archive_info, 
	$gs_mode,
	$processor, $pluginfo);

    my $service = "import";

    my $hashParsingResult = {};
    # general options available to all plugins
    my $intArgLeftinAfterParsing = parse2::parse(\@ARGV,$arguments,$hashParsingResult,"allow_extra_options");
    # Parse returns -1 if something has gone wrong
    if ($intArgLeftinAfterParsing == -1)
    {
	&PrintUsage::print_txt_usage($options, "{import.params}");
	die "\n";
    }
    
    foreach my $strVariable (keys %$hashParsingResult)
    {
	eval "\$$strVariable = \$hashParsingResult->{\"\$strVariable\"}";
    }

    # If $language has been specified, load the appropriate resource bundle
    # (Otherwise, the default resource bundle will be loaded automatically)
    if ($language && $language =~ /\S/) {
	&gsprintf::load_language_specific_resource_bundle($language);
    }

    if ($xml) {
        &PrintUsage::print_xml_usage($options);
	print "\n";
	return;
    }

    if ($gli) { # the gli wants strings to be in UTF-8
	&gsprintf::output_strings_in_UTF8; 
    }
    
    # now check that we had exactly one leftover arg, which should be 
    # the collection name. We don't want to do this earlier, cos 
    # -xml arg doesn't need a collection name
    # Or if the user specified -h, then we output the usage also
    if ($intArgLeftinAfterParsing != 1 || (@ARGV && $ARGV[0] =~ /^\-+h/))
    {
	&PrintUsage::print_txt_usage($options, "{buildcol.params}");
	die "\n";
    }

    my $close_out = 0;
    if ($out !~ /^(STDERR|STDOUT)$/i) {
	open (OUT, ">$out") ||
	    (&gsprintf(STDERR, "{common.cannot_open_output_file}: $!\n", $out) && die);
	$out = 'import::OUT';
	$close_out = 1;
    }
    $out->autoflush(1);

    # get and check the collection name
    if (($collection = &colcfg::use_collection($site, @ARGV, $collectdir)) eq "") {
	&PrintUsage::print_txt_usage($options, "{import.params}");
	die "\n";
    }

    # add collection's perllib dir  into include path in 
    # case we have collection specific modules
    unshift (@INC, "$ENV{'GSDLCOLLECTDIR'}/perllib");

    # check that we can open the faillog
    if ($faillog eq "") {
	$faillog = &util::filename_cat($ENV{'GSDLCOLLECTDIR'}, "etc", "fail.log");
    }
    open (FAILLOG, ">$faillog") ||
	(&gsprintf(STDERR, "{import.cannot_open_fail_log}\n", $faillog) && die);

    
    my $faillogname = $faillog;
    $faillog = 'import::FAILLOG';
    $faillog->autoflush(1);
    
    # Read in the collection configuration file.
    ($configfilename, $gs_mode) = &colcfg::get_collect_cfg_name($out);

    if ($gs_mode eq "gs2") {
        $collectcfg = &colcfg::read_collect_cfg ($configfilename);
    } elsif ($gs_mode eq "gs3") {
	$collectcfg = &colcfg::read_collection_cfg_xml ($configfilename);
    }

    if (defined $collectcfg->{'importdir'} && $importdir eq "") {
	$importdir = $collectcfg->{'importdir'};
    }
    if (defined $collectcfg->{'archivedir'} && $archivedir eq "") {
	$archivedir = $collectcfg->{'archivedir'};
    }
    # fill in the default import and archives directories if none
    # were supplied, turn all \ into / and remove trailing /
    $importdir = &util::filename_cat ($ENV{'GSDLCOLLECTDIR'}, "import") if $importdir eq "";
    $importdir =~ s/[\\\/]+/\//g;
    $importdir =~ s/\/$//;
    if (!-e $importdir) {
	&gsprintf($out, "{import.no_import_dir}\n\n", $importdir);
	die "\n";
    }

    $archivedir = &util::filename_cat ($ENV{'GSDLCOLLECTDIR'}, "archives") if $archivedir eq "";
    $archivedir =~ s/[\\\/]+/\//g;
    $archivedir =~ s/\/$//;

    my $plugins = [];
    if (defined $collectcfg->{'plugin'}) {
	$plugins = $collectcfg->{'plugin'};
    }
    #some global options for the plugins
    my @global_opts = ();

    if ($verbosity !~ /\d+/) {
	if (defined $collectcfg->{'verbosity'} && $collectcfg->{'verbosity'} =~ /\d+/) {
	    $verbosity = $collectcfg->{'verbosity'};
	} else {
	    $verbosity = 2; # the default
	}
    }
    if (defined $collectcfg->{'manifest'} && $manifest eq "") {
	$manifest = $collectcfg->{'manifest'};
    }

    if (defined $collectcfg->{'gzip'} && !$gzip) {
	if ($collectcfg->{'gzip'} =~ /^true$/i) {
	    $gzip = 1;
	}
    }

    if ($maxdocs !~ /\-?\d+/) {
	if (defined $collectcfg->{'maxdocs'} && $collectcfg->{'maxdocs'} =~ /\-?\d+/) {
	    $maxdocs = $collectcfg->{'maxdocs'};
	} else {
	    $maxdocs = -1; # the default
	}
    }
    if ($groupsize == 1) {
	if (defined $collectcfg->{'groupsize'} && $collectcfg->{'groupsize'} =~ /\d+/) {
	    $groupsize = $collectcfg->{'groupsize'};
	}
    }

    if ($OIDtype !~ /^(hash|incremental|assigned|dirname)$/) {
	if (defined $collectcfg->{'OIDtype'} && $collectcfg->{'OIDtype'} =~ /^(hash|incremental|assigned|dirname)$/) {
	    $OIDtype = $collectcfg->{'OIDtype'};
	} else {
	    $OIDtype = "hash"; # the default
	}
    }

    my ($plugout); 
    if (defined $collectcfg->{'plugout'}) {
	$plugout = $collectcfg->{'plugout'};
    }
    else{
	if ($saveas !~ /^(GA|.*METS|DSpace|MARCXML)$/) {
	    push @$plugout,"GAPlugout";
	}
	else{
	    push @$plugout,$saveas."Plugout";
	}
    }

    if (defined $collectcfg->{'sortmeta'} && (!defined $sortmeta || $sortmeta eq "")) {
	$sortmeta = $collectcfg->{'sortmeta'};
    }
    # sortmeta cannot be used with group size
    $sortmeta = undef unless defined $sortmeta && $sortmeta =~ /\S/;
    if (defined $sortmeta && $groupsize > 1) {
	&gsprintf($out, "{import.cannot_sort}\n\n");
	$sortmeta = undef;
    }

    if (defined $collectcfg->{'removeprefix'} && $removeprefix eq "") {
	$removeprefix = $collectcfg->{'removeprefix'};
    }
    
    if (defined $collectcfg->{'removesuffix'} && $removesuffix eq "") {
	$removesuffix = $collectcfg->{'removesuffix'};
    }
    if (defined $collectcfg->{'debug'} && $collectcfg->{'debug'} =~ /^true$/i) {
	$debug = 1;
    }
    if (defined $collectcfg->{'gli'} && $collectcfg->{'gli'} =~ /^true$/i) {
	$gli = 1;
    }
    
    
    # global plugin stuff
    if (defined $collectcfg->{'separate_cjk'} && $collectcfg->{'separate_cjk'} =~ /^true$/i) {
	push @global_opts, "-separate_cjk";
    }
    
    # check keepold and removeold
    ($removeold, $keepold, $incremental) = &scriptutil::check_removeold_and_keepold($removeold, $keepold, $incremental, "archives", $collectcfg);
 
    $gli = 0 unless defined $gli;

    print STDERR "<Import>\n" if $gli;
    
    my $manifest_lookup = new manifest();
    if ($manifest ne "") {	
	my $manifest_filename = $manifest;

	if ($manifest_filename !~ m/^[\\\/]/) {
	    $manifest_filename = &util::filename_cat ($ENV{'GSDLCOLLECTDIR'}, $manifest_filename);
	}

	$manifest =~ s/[\\\/]+/\//g;
	$manifest =~ s/\/$//;

	$manifest_lookup->parse($manifest_filename);
    }


    # load all the plugins
    $pluginfo = &plugin::load_plugins ($plugins, $verbosity, $out, $faillog, \@global_opts, $incremental);
    if (scalar(@$pluginfo) == 0) {
	&gsprintf($out, "{import.no_plugins_loaded}\n");
	die "\n";
    }

    # remove the old contents of the archives directory (and tmp directory) if needed
    if ($removeold) {
	if (-e $archivedir) {
	    &gsprintf($out, "{import.removing_archives}\n");
	    &util::rm_r ($archivedir);
	}
	my $tmpdir = &util::filename_cat ($ENV{'GSDLCOLLECTDIR'}, "tmp");
	$tmpdir =~ s/[\\\/]+/\//g;
	$tmpdir =~ s/\/$//;
	if (-e $tmpdir) {
	    &gsprintf($out, "{import.removing_tmpdir}\n");
	    &util::rm_r ($tmpdir);
	}
    }
    # create the archives dir if needed
    &util::mk_all_dir($archivedir);

    # read the archive information file

    # If saveas=DSpace, a "contents" file will be created, otherwise "archives.inf"
    
    # the plugouts should be doing this!!
    if ($saveas eq "DSpace"){
	$archive_info_filename = &util::filename_cat ($archivedir, "contents");
    } elsif ($saveas =~ m/^.*METS$/ || $saveas eq "GA" || $saveas eq "MARC" ) {
	$archive_info_filename = &util::filename_cat ($archivedir, "archives.inf");
    }

    $archive_info = new arcinfo ();
    $archive_info->load_info ($archive_info_filename);
    

    ####Use Plugout####
    push @$plugout,("-output_info",$archive_info) if (defined $archive_info); 
    push @$plugout,("-verbosity",$verbosity) if (defined $verbosity);
    push @$plugout,("-gzip_output") if ($gzip);
    push @$plugout,("-group_size",$groupsize) if (defined $groupsize);
    push @$plugout,("-output_handle",$out) if (defined $out);
    push @$plugout,("-debug") if ($debug);
    
    $processor = &plugout::load_plugout($plugout);                        
    $processor->setoutputdir ($archivedir);
    $processor->set_sortmeta ($sortmeta, $removeprefix, $removesuffix) if defined $sortmeta;
    $processor->set_OIDtype ($OIDtype, $OIDmetadata);
    
    &plugin::begin($pluginfo, $importdir, $processor, $maxdocs, $gli);

    if ($manifest eq "") {
	# process the import directory
	&plugin::read ($pluginfo, $importdir, "", {}, $processor, $maxdocs, 0, $gli);
    }
    else {

	# process any new files
	foreach my $file (keys %{$manifest_lookup->{'index'}}) {
	    &plugin::read ($pluginfo, $importdir, $file, {}, $processor, $maxdocs, 0, $gli);
	}

	# record files marked for deletion in arcinfo
	foreach my $file (keys %{$manifest_lookup->{'delete'}}) {
	    # consider finding it?
	    # $archive_info->add_info($OID,$doc_xml_file,"D");
	}
    }

    if ($saveas eq "FedoraMETS")
    {
	# This would be better (should?!) be done in Plugout!!

	# create collection "doc obj" for Fedora that contains
	# collection-level metadata
	
	my $doc_obj = new doc($configfilename,"nonindexed_doc");
	$doc_obj->set_OID("collection");
	
	my $col_name = undef;
	my $col_meta = $collectcfg->{'collectionmeta'};
	if (defined $col_meta)
	{
	    store_collectionmeta($col_meta,"collectionname",$doc_obj);
	    store_collectionmeta($col_meta,"collectioextra",$doc_obj);
	    
	}
	
	$processor->process($doc_obj);
    }


    &plugin::end($pluginfo, $processor);

    &plugin::deinit($pluginfo, $processor);

    # write out the archive information file
    $processor->close_file_output() if $groupsize > 1;
    $processor->close_group_output() if $processor->is_group();

# The following 'if' statement is in the export.pl version of the script,
# but not (so far) the import.pl version.  Why is this?
##    if ($saveas =~ m/^.*METS$/) {
	# should we still do this in debug mode??

	$archive_info->save_info($archive_info_filename);
##    }
    
    # write out import stats
    my $close_stats = 0;
    if ($statsfile !~ /^(STDERR|STDOUT)$/i) {
	if (open (STATS, ">$statsfile")) {
	    $statsfile = 'import::STATS';
	    $close_stats = 1;
	} else {
	    &gsprintf($out, "{import.cannot_open_stats_file}", $statsfile);
	    &gsprintf($out, "{import.stats_backup}\n");
	    $statsfile = 'STDERR';
	}
    }

    &gsprintf($out, "\n");
    &gsprintf($out, "*********************************************\n");
    &gsprintf($out, "{import.complete}\n");
    &gsprintf($out, "*********************************************\n");

    &plugin::write_stats($pluginfo, $statsfile, $faillogname, $gli);
    if ($close_stats) {
	close STATS;
    }

    close OUT if $close_out;
    close FAILLOG;
}
