###############################################################################
#
# DBDrivers/TDB.pm -- utility functions for writing to tdb databases. Should be
#                     hauntingly similar to GDBM utility functions.
#
# A component of the Greenstone digital library software from the New Zealand
# Digital Library Project at the University of Waikato, New Zealand.
#
# Copyright (C) 2011-2015 New Zealand Digital Library Project
#
# This program is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free Software
# Foundation; either version 2 of the License, or (at your option) any later
# version.
#
# This program is distributed in the hope that it will be useful, but WITHOUT
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
# more details.
#
# You should have received a copy of the GNU General Public License along with
# this program; if not, write to the Free Software Foundation, Inc., 675 Mass
# Ave, Cambridge, MA 02139, USA.
#
###############################################################################

package DBDrivers::TDB;

# Pragma
use strict;

# Libraries
use Cwd;
use Devel::Peek;
use ghtml;
use Scalar::Util 'refaddr';
use util;
# - OO inheritence
use parent 'DBDrivers::GDBM';

sub BEGIN
{
    if (!defined $ENV{'GSDLHOME'} || !defined $ENV{'GSDLOS'}) {
        die("Error! Environment not prepared. Have you sourced setup.bash?\n");
    }
    if (!defined $ENV{'GEXTTDBEDIT_INSTALLED'}) {
        die("Error! Path to TDB binaries not found. Have you sourced setup.bash?\n");
    }
}

sub new
{
    my $class = shift(@_);

    my $self = DBDrivers::GDBM->new();

    # Default TDB file extension
    $self->{'default_file_extension'} = 'tdb';
    # Should the TDB used a specific affinity?
    $self->{'forced_affinity'} = -1; # zero upwards indicates the affinity
    # Keep track of all opened file handles
    $self->{'handle_pool'} = {};
    # Ask TDB executables to display debugging information?
    $self->{'tdb_debug'} = 0; # 1 to enable

    bless($self, $class);
    return $self;
}


## @function DESTROY
#
# Built-in destructor block that, unlike END, gets passed a reference to self.
# Responsible for properly closing any open database handles.
#
sub DESTROY
{
    my $self = shift(@_);
    # Close all remaining filehandles
    foreach my $infodb_file_path (keys(%{$self->{'handle_pool'}})) {
	my $infodb_handle = $self->{'handle_pool'}->{$infodb_file_path};
	# By passing the filepath as the second argument we instruct the driver
	# that we actually want to close the connection by passing a non-zero
	# value, but we sneakily optimize things a little as the close method
	# can now check to see if it's been provided a file_path rather than
	# having to search the handle pool for it. The file_path is needed to
	# remove the closed handle from the pool anyway.
	$self->close_infodb_write_handle($infodb_handle, $infodb_file_path);
    }
}
## DESTROY(void) => void ##


# -----------------------------------------------------------------------------
#   TDB IMPLEMENTATION
# -----------------------------------------------------------------------------


## @function _get_tdb_executable(string)
#
sub _get_tdb_executable
{
    my $self = shift(@_);
    my $program = shift(@_);
    if (!defined $ENV{GEXTTDBEDIT_INSTALLED} || !-d $ENV{GEXTTDBEDIT_INSTALLED})
    {
	die('Fatal Error! Path to TDB binaries not found. Have you sourced setup.bash?');
    }
    my $program_exe = &util::filename_cat($ENV{GEXTTDBEDIT_INSTALLED} . '/bin/' . $program . &util::get_os_exe());
    if (!-x $program_exe)
    {
	die('Fatal Error! File doesn\'t exist or isn\'t executable: ' . $program_exe);
    }
    return $program_exe;
}
## _get_tdb_executable(string) => string ##


# Handled by BaseDBDriver
# sub get_infodb_file_path(string, string)

# With infodb_handle already set up, these functions work the same as parent version
# sub delete_infodb_entry {}
# sub write_infodb_entry {}
# sub write_infodb_rawentry {}


## @function close_infodb_write_handle(filehandle)
#
#  Some slight-of-hand here due to the way Perl passes variables to methods.
#  Most of the time (i.e. under all the existing calls in the Greenstone code)
#  this does nothing, as TDB handles can be left open and reused by multiple
#  writers/readers (the exception being complete file reads, but they are
#  handled in their own function anyway).
#
#  However TDB's version of this function will look for an extra variable and,
#  if true (non-zero), will actually close the handle. Several methods below
#  call close but also pass the infodb_file_path as the second argument, which
#  is enough to have the connections properly closed.
#
#  Note that when this class passes from scope all open handles will be
#  properly closed by the DESTROY block.
#
sub close_infodb_write_handle {
    my $self = shift(@_);
    my $infodb_handle = shift(@_);
    my $actually_close = shift(@_); # Undefined most of the time
    if (defined($actually_close)) {
	$self->_debugPrint('(<infodb_handle>,"' . $actually_close . '")');
	# We'll need the file path so we can locate and remove the entry in the
	# handle pool
	my $infodb_file_path = undef;
	# Sometimes we can cheat, as the actually_close variable will have the
	# file_path in it thanks to the DESTROY block above. Doing a regex on
	# actually_close will treat it like a string no matter what it was, and
	# we can search for the appropriate file extension that should be there
	# for valid paths.
	my $pattern = '\.' . $self->{'default_file_extension'} . '$';
	if ($actually_close =~ /$pattern/) {
	    $infodb_file_path = $actually_close;
	}
	# If we can't cheat then we are stuck finding which connection in the
	# handle_pool we are about to close. Need to compare objects using
	# refaddr()
	else {
	    foreach my $possible_file_path (values(%{$self->{'handle_pool'}})) {
		my $possible_handle = $self->{'handle_pool'}->{$possible_file_path};
		if (ref($infodb_handle) && ref($possible_handle) && refaddr($infodb_handle) == refaddr($possible_handle)) {
		    $infodb_file_path = $possible_file_path;
		    last;
		}
	    }
	}
	if (defined($infodb_file_path)) {
	    delete($self->{'handle_pool'}->{$infodb_file_path});
	}
	else {
	    print STDERR "Warning! About to close TDB database handle, but couldn't locate in open handle pool.\n";
	}
	# Call GDBM's close to do the heavy-lifting
	$self->SUPER::close_infodb_write_handle($infodb_handle);
    }
}
## close_infodb_write_handle(filehandle) => void ##


## @function open_infodb_write_handle(string, string)
#
sub open_infodb_write_handle
{
    my $self = shift(@_);
    my $infodb_file_path = shift(@_);
    my $opt_append = shift(@_);

    my $txt2tdb_exe = $self->_get_tdb_executable('txt2tdb');

    my $cmd = '"' . $txt2tdb_exe . '"';
    if ((defined $opt_append) && ($opt_append eq "append")) {
        $cmd .= ' -append';
    }
    $cmd .= ' "' . $infodb_file_path . '"';
    # Optional flags
    if ($self->{'forced_affinity'} >= 0) {
        $cmd = 'taskset -c 5 ' . $cmd;
    }
    if ($self->{'debug'}) {
        $cmd .= ' -debug';
    }

    # we're going to pipe the key value pairs, in the appropriate format, from
    # within the buildproc, so we create a piped handle here
    my $infodb_file_handle = undef;
    # if the connection is already open, simply return it.
    if (defined $self->{'handle_pool'}->{$infodb_file_path}) {
	$infodb_file_handle = $self->{'handle_pool'}->{$infodb_file_path};
    }
    else {
	$self->_debugPrint('(' . $infodb_file_path . ')');
	if(!open($infodb_file_handle, "| $cmd")) {
	    print STDERR "Error: Failed to open pipe to $cmd\n";
	    print STDERR "       $!\n";
	    return undef;
	}
	binmode($infodb_file_handle,":utf8");
	# Remember to store the newly created connection in the pool so we can
	# re-use for subsequent calls.
	$self->{'handle_pool'}->{$infodb_file_path} = $infodb_file_handle;
    }
    return $infodb_file_handle;
}
## open_infodb_write_handle(string, string) => filehandle ##


## @function read_infodb_file
#
sub read_infodb_file
{
    my $self = shift(@_);
    my $infodb_file_path = shift(@_);
    my $infodb_map = shift(@_);

    $self->_debugPrint('(' . $infodb_file_path . ', <hashmap>)');

    my $tdb2txt_exe = $self->_get_tdb_executable('tdb2txt');

    if (!open (PIPEIN, '"' . $tdb2txt_exe . '" "' . $infodb_file_path . '" |')) {
        print STDERR 'Error: Failed to open pipe to ' . $tdb2txt_exe . "\n";
        print STDERR "       $!\n";
        return undef;
    }

    binmode(PIPEIN,":utf8");

    my $infodb_line = "";
    my $infodb_key = "";
    my $infodb_value = "";
    while (defined ($infodb_line = <PIPEIN>)) {
        if ($infodb_line =~ /^\[([^\]]+)\]$/) {
            $infodb_key = $1;
        }
        elsif ($infodb_line =~ /^-{70}$/) {
            $infodb_map->{$infodb_key} = $infodb_value;
            $infodb_key = "";
            $infodb_value = "";
        }
        else {
            $infodb_value .= $infodb_line;
        }
    }
    close (PIPEIN);
}
## read_infodb_file(string, hashmap) => void ##


## @function read_infodb_keys(string, hashmap)
#
sub read_infodb_keys
{
    my $self = shift(@_);
    my $infodb_file_path = shift(@_);
    my $infodb_map = shift(@_);

    $self->_debugPrint('(' . $infodb_file_path . ', <hashmap>)');

    my $tdbkeys_exe = $self->_get_tdb_executable('tdbkeys');

    if (!open (PIPEIN, '"' . $tdbkeys_exe . '" "' . $infodb_file_path . '" |')) {
        die("Error! Couldn't open pipe from read_infodb_keys: $infodb_file_path\n$!\n");
    }

    binmode(PIPEIN,":utf8");

    my $infodb_line = "";
    my $infodb_key = "";
    my $infodb_value = "";
    while (defined ($infodb_line = <PIPEIN>)) {
        # remove end of line
        chomp $infodb_line;
        $infodb_map->{$infodb_line} = 1;
    }

    close (PIPEIN);
}
## read_infodb_keys(string, hashmap) => void ##


## @function set_infodb_entry(string, string, hashmap)
#
sub set_infodb_entry
{
    my $self = shift(@_);
    my $infodb_file_path = shift(@_);
    my $infodb_key = shift(@_);
    my $infodb_map = shift(@_);

    $self->_debugPrint('(' . $infodb_file_path . ', ' . $infodb_key . ', <hashmap>)');

    # Protect metadata values that go inside quotes for tdbset
    foreach my $k (keys %$infodb_map) {
        my @escaped_v = ();
        foreach my $v (@{$infodb_map->{$k}}) {
            if ($k eq "contains") {
                # protect quotes in ".2;".3 etc
                $v =~ s/\"/\\\"/g;
                push(@escaped_v, $v);
            }
            else {
                my $ev = &ghtml::unescape_html($v);
                $ev =~ s/\"/\\\"/g;
                push(@escaped_v, $ev);
            }
        }
        $infodb_map->{$k} = \@escaped_v;
    }

    # Generate the record string
    my $serialized_infodb_map = $self->_convert_infodb_hash_to_string($infodb_map);

    # Store it into GDBM
    my $tdbset_exe = $self->_get_tdb_executable('tdbset');
    my $cmd = '"' . $tdbset_exe . '" "' . $infodb_file_path . '" "' . $infodb_key . '" "' . $serialized_infodb_map . '"';
    my $status = system($cmd);

    return $status;
}
## set_infodb_entry(string, string, hashmap) => integer ##

1;
