source: greenstone3/trunk/gs3-setup.bat@ 15355

@echo off

set java_min_version=1.4.0_00

if exist gs3-setup.bat goto start
  echo This script must be run from within the Greenstone 3 home directory
  goto exit

:start
:: ---- Set the GSDL3HOME variable to the current directory ----
cd | winutil\setvar.exe GSDL3SRCHOME > %TMP%\setgsdl3.bat
call %TMP%\setgsdl3.bat
del %TMP%\setgsdl3.bat
set GSDL3HOME=%GSDL3SRCHOME%\web

:: change if using external tomcat
set TOMCAT_HOME=%GSDL3SRCHOME%\packages\tomcat

:: ---- Set other important environment variables ----
set GSDLOS=windows
set ANT_HOME=%GSDL3SRCHOME%\packages\ant
set PATH=%PATH%;%GSDL3SRCHOME%\bin;%GSDL3SRCHOME%\bin\script;%GSDL3SRCHOME%\lib\jni;%ANT_HOME%\bin

:: ---- Set the CLASSPATH environment variable ----
if "%GS_CP_SET%" == "yes" goto skipSetCp
set CLASSPATH=.;%GSDL3HOME%\WEB-INF\classes;%GSDL3SRCHOME%\resources\java;%CLASSPATH%
if exist %TMP%\setcp.bat del %TMP%\setcp.bat
for %%j in ("%GSDL3SRCHOME%"\*.jar) do echo set CLASSPATH=%%CLASSPATH%%;%%j>> %TMP%\setcp.bat
for %%j in ("%GSDL3HOME%"\WEB-INF\lib\*.jar) do echo set CLASSPATH=%%CLASSPATH%%;%%j>> %TMP%\setcp.bat
for %%j in ("%GSDL3SRCHOME%"\lib\jni\*.jar) do echo set CLASSPATH=%%CLASSPATH%%;%%j>> %TMP%\setcp.bat
for %%j in ("%TOMCAT_HOME%"\common\endorsed\*.jar) do echo set CLASSPATH=%%CLASSPATH%%;%%j>> %TMP%\setcp.bat
for %%j in ("%GSDL3SRCHOME%"\build\*.jar) do echo set CLASSPATH=%%CLASSPATH%%;%%j>> %TMP%\setcp.bat
echo set GS_CP_SET=yes >> %TMP%\setcp.bat
call %TMP%\setcp.bat
del %TMP%\setcp.bat
:skipSetCp

winutil\search4j.exe -m %java_min_version% | winutil\setvar.exe _JRE_HOME > %TMP%\set_jre_home.bat
call %TMP%\set_jre_home.bat
del %TMP%\set_jre_home.bat

echo %_JRE_HOME%\bin\java.exe | winutil\setvar.exe RUNJAVA > %TMP%\setrunjava.bat
call %TMP%\setrunjava.bat
del %TMP%\setrunjava.bat

if "%JRE_HOME%" == "" set JRE_HOME=%_JRE_HOME%

echo GSDL3SRCHOME : %GSDL3SRCHOME%
echo GSDL3HOME    : %GSDL3HOME%
echo JAVA         : %RUNJAVA%