@echo off

pushd "%CD%"
CD /D "%~dp0"

call cascade-make/lib/cascade-lib.bat

:: Guaranteed that GSDLOS has now been set


:: Make sure can find javac

:: Remove any quotes from around JAVA_HOME
if defined JAVA_HOME set JAVA_HOME=%JAVA_HOME:"=%


if "%JAVA_HOME%" == "" (
  echo Testing for Java compiler ...

  javac -version 2>nul
  if ERRORLEVEL 1 (
    echo ... failed to find 'javac'
    cmd /c exit -4
    goto:EOF
  ) else (
    echo ... found it
  )
) else (

  :: Good chance it's in the path already => don't want to see any output
  javac -version 2>nul
  if ERRORLEVEL 1 (
    echo Setting path to include "%JAVA_HOME%\bin"
    set "PATH=%JAVA_HOME%\bin;%PATH%"
  )
)


for /D %%d IN ("%GSDLOS%" "lib\java") do (
  if not exist "%GEXT_MUSICIR_INSTALLED%\%%d" (
    echo Creating %GEXT_MUSICIR_INSTALLED%\%%d
    mkdir "%GEXT_MUSICIR_INSTALLED%\%%d"
  )
)

set dirlist=build-srcpack

for /D %%d IN (%dirlist%) do (
  echo Running %%d\CASCADE-MAKE.bat %*

  (cd %%d && call CASCADE-MAKE.bat %* && cd ..)
  
  if ERRORLEVEL 1 (
    echo Error encountered running %%d\CASCADE-MAKE.bat
    cmd /c exit 1
    goto:EOF
  )
)


if  %install% == 1 (
  type README.txt
)