source: gsdl/trunk/perllib/plugins/PagedImagePlugin.pm@ 16384

Last change on this file since 16384 was 16384, checked in by kjdon, 13 years ago

global block pass: new block_hash arg to read and metadata_read. Also added a comment about whether we need to convert the filename to utf8 before calling generate_images (I am not sure)

  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 20.6 KB
Line 
1###########################################################################
2#
3# PagedImagePlugin.pm -- plugin for sets of images and OCR text that
4# make up a document
5# A component of the Greenstone digital library software
6# from the New Zealand Digital Library Project at the
7# University of Waikato, New Zealand.
8#
9# Copyright (C) 1999 New Zealand Digital Library Project
10#
11# This program is free software; you can redistribute it and/or modify
12# it under the terms of the GNU General Public License as published by
13# the Free Software Foundation; either version 2 of the License, or
14# (at your option) any later version.
15#
16# This program is distributed in the hope that it will be useful,
17# but WITHOUT ANY WARRANTY; without even the implied warranty of
18# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19# GNU General Public License for more details.
20#
21# You should have received a copy of the GNU General Public License
22# along with this program; if not, write to the Free Software
23# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
24#
25###########################################################################
26
27# PagedImagePlugin
28# processes sequences of images, with optional OCR text
29#
30# This plugin takes *.item files, which contain metadata and lists of image
31# files, and produces a document containing sections, one for each page.
32# The files should be named something.item, then you can have more than one
33# book in a directory. You will need to create these files, one for each
34# document/book.
35#
36#There are two formats for the item files: a plain text format, and an xml
37#format. You can use either format, and can have both formats in the same
38#collection if you like. If you use the plain format, you must not start the
39#file off with <PagedDocument>
40
41#### PLAIN FORMAT
42# The format of the xxx.item file is as follows:
43# The first lines contain any metadata for the whole document
44# <metadata-name>metadata-value
45# eg.
46# <Title>Snail farming
47# <Date>19230102
48# Then comes a list of pages, one page per line, each line has the format
49#
50# pagenum:imagefile:textfile:r
51#
52# page num and imagefile are required. pagenum is used for the Title
53# of the section, and in the display is shown as page <pagenum>.
54# imagefile is the image for the page. textfile is an optional text
55# file containing the OCR (or any) text for the page - this gets added
56# as the text for the section. r is optional, and signals that the image
57# should be rotated 180deg. Eg use this if the image has been made upside down.
58# So an example item file looks like:
59# <Title>Snail farming
60# <Date>19960403
61# 1:p1.gif:p1.txt:
62# 2:p2.gif::
63# 3:p3.gif:p3.txt:
64# 3b:p3b.gif:p3b.txt:r
65# The second page has no text, the fourth page is a back page, and
66# should be rotated.
67#
68
69#### XML FORMAT
70# The xml format looks like the following
71#<PagedDocument>
72#<Metadata name="Title">The Title of the entire document</Metadata>
73#<Page pagenum="1" imgfile="xxx.jpg" txtfile="yyy.txt">
74#<Metadata name="Title">The Title of this page</Metadata>
75#</Page>
76#... more pages
77#</PagedDocument>
78#PagedDocument contains a list of Pages, Metadata and PageGroups. Any metadata
79#that is not inside another tag will belong to the document.
80#Each Page has a pagenum (not used at the moment), an imgfile and/or a txtfile.
81#These are both optional - if neither is used, the section will have no content.
82#Pages can also have metadata associated with them.
83#PageGroups can be introduced at any point - they can contain Metadata and Pages and other PageGroups. They are used to introduce hierarchical structure into the document.
84#For example
85#<PagedDocument>
86#<PageGroup>
87#<Page>
88#<Page>
89#</PageGroup>
90#<Page>
91#</PagedDocument>
92#would generate a structure like
93#X
94#--X
95# --X
96# --X
97#--X
98#PageGroup tags can also have imgfile/textfile metadata if you like - this way they get some content themselves.
99
100#Currently the XML structure doesn't work very well with the paged document type, unless you use numerical Titles for each section.
101#There is still a bit of work to do on this format:
102#* enable other text file types, eg html, pdf etc
103#* make the document paging work properly
104#* add pagenum as Title unless a Title is present?
105
106# All the supplemetary image amd text files should be in the same folder as
107# the .item file.
108#
109# To display the images instead of the document text, you can use [srcicon]
110# in the DocumentText format statement.
111# For example,
112#
113# format DocumentText "<center><table width=_pagewidth_><tr><td>[srcicon]</td></tr></table></center>"
114#
115# To have it create thumbnail size images, use the '-create_thumbnail' option.
116# To have it create medium size images for display, use the '-create_screenview'
117# option. As usual, running
118# 'perl -S pluginfo.pl PagedImagePlugin' will list all the options.
119
120# If you want the resulting documents to be presented with a table of
121# contents, use '-documenttype hierarchy', otherwise they will have
122# next and previous arrows, and a goto page X box.
123
124# If you have used -create_screenview, you can also use [screenicon] in the format
125# statement to display the smaller image. Here is an example that switches
126# between the two:
127#
128# format DocumentText "<center><table width=_pagewidth_><tr><td>{If}{_cgiargp_ eq full,<a href='_httpdocument_&d=_cgiargd_&p=small'>Switch to small version.</a>,<a href='_httpdocument_&d=_cgiargd_&p=full'>Switch to fullsize version</a>}</td></tr><tr><td>{If}{_cgiargp_ eq full,<a href='_httpdocument_&d=_cgiargd_&p=small' title='Switch to small version'>[srcicon]</a>,<a href='_httpdocument_&d=_cgiargd_&p=full' title='Switch to fullsize version'>[screenicon]</a>}</td></tr></table></center>"
129#
130# Additional metadata can be added into the .item files, alternatively you can
131# use normal metadata.xml files, with the name of the xxx.item file as the
132# FileName (only for document level metadata).
133
134package PagedImagePlugin;
135
136use ReadXMLFile;
137use ReadTextFile;
138use ImageConverter;
139
140use strict;
141no strict 'refs'; # allow filehandles to be variables and viceversa
142
143sub BEGIN {
144 @PagedImagePlugin::ISA = ('ReadXMLFile', 'ReadTextFile', 'ImageConverter');
145}
146
147my $type_list =
148 [ { 'name' => "paged",
149 'desc' => "{PagedImagePlugin.documenttype.paged}" },
150 { 'name' => "hierarchy",
151 'desc' => "{PagedImagePlugin.documenttype.hierarchy}" } ];
152
153my $arguments =
154 [ { 'name' => "process_exp",
155 'desc' => "{BasePlugin.process_exp}",
156 'type' => "string",
157 'deft' => &get_default_process_exp(),
158 'reqd' => "no" },
159 { 'name' => "block_exp",
160 'desc' => "{BasePlugin.block_exp}",
161 'type' => "string",
162 'deft' => &get_default_block_exp(),
163 'reqd' => "no" },
164 { 'name' => "title_sub",
165 'desc' => "{HTMLPlugin.title_sub}",
166 'type' => "string",
167 'deft' => "" },
168 { 'name' => "headerpage",
169 'desc' => "{PagedImagePlugin.headerpage}",
170 'type' => "flag",
171 'reqd' => "no" },
172 { 'name' => "documenttype",
173 'desc' => "{PagedImagePlugin.documenttype}",
174 'type' => "enum",
175 'list' => $type_list,
176 'deft' => "paged",
177 'reqd' => "no" } ];
178
179
180my $options = { 'name' => "PagedImagePlugin",
181 'desc' => "{PagedImagePlugin.desc}",
182 'abstract' => "no",
183 'inherits' => "yes",
184 'args' => $arguments };
185
186sub new {
187 my ($class) = shift (@_);
188 my ($pluginlist,$inputargs,$hashArgOptLists) = @_;
189 push(@$pluginlist, $class);
190
191 push(@{$hashArgOptLists->{"ArgList"}},@{$arguments});
192 push(@{$hashArgOptLists->{"OptList"}},$options);
193
194 new ImageConverter($pluginlist, $inputargs, $hashArgOptLists);
195 new ReadTextFile($pluginlist, $inputargs, $hashArgOptLists, 1);
196 my $self = new ReadXMLFile($pluginlist, $inputargs, $hashArgOptLists);
197
198 return bless $self, $class;
199}
200
201
202sub init {
203 my $self = shift (@_);
204 my ($verbosity, $outhandle, $failhandle) = @_;
205
206 $self->SUPER::init(@_);
207 $self->ImageConverter::init();
208}
209
210sub get_default_process_exp {
211 my $self = shift (@_);
212
213 return q^\.item$^;
214}
215
216sub get_doctype {
217 my $self = shift(@_);
218
219 return "PagedDocument";
220}
221
222
223# want to block everything except the .item ones
224# but instead we will block images and txt files
225sub get_default_block_exp {
226 my $self = shift (@_);
227
228 return q^(?i)(\.jpe?g|\.gif|\.png|\.tif?f|\.te?xt|\.html?|~)$^
229}
230
231# we want to use BasePlugin's read, not ReadXMLFile's
232sub read
233{
234 my $self = shift (@_);
235 $self->BasePlugin::read(@_);
236}
237
238
239sub read_into_doc_obj {
240 my $self = shift (@_);
241 my ($pluginfo, $base_dir, $file, $block_hash, $metadata, $processor, $maxdocs, $total_count, $gli) = @_;
242 my $outhandle = $self->{'outhandle'};
243
244 my ($filename_full_path, $filename_no_path) = &util::get_full_filenames($base_dir, $file);
245
246 print $outhandle "PagedImagePlugin processing \"$filename_full_path\"\n"
247 if $self->{'verbosity'} > 1;
248 print STDERR "<Processing n='$file' p='PagedImagePlugin'>\n" if ($gli);
249
250
251 # here we need to decide if we have an old text .item file, or a new xml
252 # .item file
253 my $xml_version = $self->is_xml_item_file($filename_full_path);
254
255 $self->tidy_item_file($filename_full_path);
256
257 my $doc_obj;
258 if ($xml_version) {
259 # careful checking needed here!! are we using local xml handlers or super ones
260 $self->ReadXMLFile::read($pluginfo, $base_dir, $file, $block_hash, $metadata, $processor, $maxdocs, $total_count, $gli);
261 $doc_obj = $self->{'doc_obj'};
262 } else {
263 my ($dir);
264 ($dir, $file) = $filename_full_path =~ /^(.*?)([^\/\\]*)$/;
265
266 #process the .item file
267 $doc_obj = $self->process_item($filename_full_path, $dir, $file, $processor);
268
269 }
270
271 my $section = $doc_obj->get_top_section();
272
273 $doc_obj->add_utf8_metadata($section, "Plugin", "$self->{'plugin_type'}");
274 $doc_obj->add_metadata($section, "FileFormat", "PagedImage");
275
276 # include any metadata passed in from previous plugins
277 # note that this metadata is associated with the top level section
278 $self->add_associated_files($doc_obj, $filename_full_path);
279 $self->extra_metadata ($doc_obj, $section, $metadata);
280 $self->auto_extract_metadata ($doc_obj);
281
282 # if we haven't found any Title so far, assign one
283 $self->title_fallback($doc_obj,$section,$filename_no_path);
284
285 $self->add_OID($doc_obj);
286 return (1,$doc_obj);
287}
288
289# for now, the test is if the first non-empty line is <PagedDocument>, then its xml
290sub is_xml_item_file {
291 my $self = shift(@_);
292 my ($filename) = @_;
293
294 my $xml_version = 0;
295 open (ITEMFILE, $filename) || die "couldn't open $filename\n";
296
297 my $line = "";
298 my $num = 0;
299 $line = <ITEMFILE>;
300 while ($line !~ /\w/) {
301 $line = <ITEMFILE>;
302 }
303 chomp $line;
304 if ($line =~ /<PagedDocument/) {
305 $xml_version = 1;
306 }
307 close ITEMFILE;
308 return $xml_version;
309}
310
311sub tidy_item_file {
312 my $self = shift(@_);
313 my ($filename) = @_;
314
315 open (ITEMFILE, $filename) || die "couldn't open $filename\n";
316 my $backup_filename = "backup.item";
317 open (BACKUP,">$backup_filename")|| die "couldn't write to $backup_filename\n";
318 my $line = "";
319 $line = <ITEMFILE>;
320 $line =~ s/^\xEF\xBB\xBF//; # strip BOM
321 $line =~ s/\x0B+//ig;
322 $line =~ s/&/&amp;/g;
323 print BACKUP ($line);
324 #Tidy up the item file some metadata title contains \vt-vertical tab
325 while ($line = <ITEMFILE>) {
326 $line =~ s/\x0B+//ig;
327 $line =~ s/&/&amp;/g;
328 print BACKUP ($line);
329 }
330 close ITEMFILE;
331 close BACKUP;
332 &File::Copy::copy ($backup_filename, $filename);
333 &util::rm($backup_filename);
334
335}
336
337sub rotate_image {
338 my $self = shift (@_);
339 my ($filename_full_path) = @_;
340
341 my ($this_filetype) = $filename_full_path =~ /\.([^\.]*)$/;
342 my $result = $self->convert($filename_full_path, $this_filetype, "-rotate 180", "ROTATE");
343 my ($new_filename) = ($result =~ /=>(.*\.$this_filetype)/);
344 if (-e "$new_filename") {
345 return $new_filename;
346 }
347 # somethings gone wrong
348 return $filename_full_path;
349
350}
351
352sub process_image {
353 my $self = shift(@_);
354 my ($filename_full_path, $filename_no_path, $doc_obj, $section, $rotate) = @_;
355 # do rotation
356 if ($rotate eq "r") {
357 # check the filenames
358 return 0 if ($filename_no_path eq "" || !-f $filename_full_path);
359
360 # we get a new temporary file which is rotated
361 $filename_full_path = $self->rotate_image($filename_full_path);
362 }
363
364 # do generate images
365 my $result = 0;
366 if ($self->{'image_conversion_available'} == 1) {
367 # do we need to convert $filename_no_path to utf8? We are already reading in from a file, what encoding is it in???
368 $result = $self->generate_images($filename_full_path, $filename_no_path, $doc_obj, $section);
369 }
370 #overwrite one set in ImageConverter
371 $doc_obj->set_metadata_element ($section, "FileFormat", "PagedImage");
372 return $result;
373}
374
375
376sub xml_start_tag {
377 my $self = shift(@_);
378 my ($expat, $element) = @_;
379 $self->{'element'} = $element;
380
381 my $doc_obj = $self->{'doc_obj'};
382 if ($element eq "PagedDocument") {
383 $self->{'current_section'} = $doc_obj->get_top_section();
384 } elsif ($element eq "PageGroup" || $element eq "Page") {
385 # create a new section as a child
386 $self->{'current_section'} = $doc_obj->insert_section($doc_obj->get_end_child($self->{'current_section'}));
387 $self->{'num_pages'}++;
388 # assign pagenum as what??
389 my $pagenum = $_{'pagenum'}; #TODO!!
390 if (defined $pagenum) {
391 $doc_obj->set_utf8_metadata_element($self->{'current_section'}, 'PageNum', $pagenum);
392 }
393 my ($imgfile) = $_{'imgfile'};
394 if (defined $imgfile) {
395 $self->process_image($self->{'base_dir'}.$imgfile, $imgfile, $doc_obj, $self->{'current_section'});
396 }
397 my ($txtfile) = $_{'txtfile'};
398 if (defined($txtfile)&& $txtfile ne "") {
399 $self->process_text ($self->{'base_dir'}.$txtfile, $txtfile, $doc_obj, $self->{'current_section'});
400 } else {
401 $self->add_dummy_text($doc_obj, $self->{'current_section'});
402 }
403 } elsif ($element eq "Metadata") {
404 $self->{'metadata_name'} = $_{'name'};
405 }
406}
407
408sub xml_end_tag {
409 my $self = shift(@_);
410 my ($expat, $element) = @_;
411
412 my $doc_obj = $self->{'doc_obj'};
413 if ($element eq "Page" || $element eq "PageGroup") {
414 # if Title hasn't been assigned, set PageNum as Title
415 if (!defined $doc_obj->get_metadata_element ($self->{'current_section'}, "Title") && defined $doc_obj->get_metadata_element ($self->{'current_section'}, "PageNum" )) {
416 $doc_obj->add_utf8_metadata ($self->{'current_section'}, "Title", $doc_obj->get_metadata_element ($self->{'current_section'}, "PageNum" ));
417 }
418 # move the current section back to the parent
419 $self->{'current_section'} = $doc_obj->get_parent_section($self->{'current_section'});
420 } elsif ($element eq "Metadata") {
421
422 $doc_obj->add_utf8_metadata ($self->{'current_section'}, $self->{'metadata_name'}, $self->{'metadata_value'});
423 $self->{'metadata_name'} = "";
424 $self->{'metadata_value'} = "";
425
426 }
427 # otherwise we ignore the end tag
428}
429
430
431sub xml_text {
432 my $self = shift(@_);
433 my ($expat) = @_;
434
435 if ($self->{'element'} eq "Metadata" && $self->{'metadata_name'}) {
436 $self->{'metadata_value'} .= $_;
437 }
438}
439
440sub xml_doctype {
441}
442
443sub open_document {
444 my $self = shift(@_);
445
446 # create a new document
447 $self->{'doc_obj'} = new doc ($self->{'filename'}, "indexed_doc");
448 # TODO is file filenmae_no_path??
449 $self->set_initial_doc_fields($self->{'doc_obj'}, $self->{'file'}, $self->{'processor'});
450
451 my ($dir, $file) = $self->{'filename'} =~ /^(.*?)([^\/\\]*)$/;
452 $self->{'base_dir'} = $dir;
453 $self->{'num_pages'} = 0;
454
455}
456
457sub close_document {
458 my $self = shift(@_);
459 my $doc_obj = $self->{'doc_obj'};
460
461 # add numpages metadata
462 $doc_obj->set_utf8_metadata_element ($doc_obj->get_top_section(), 'NumPages', $self->{'num_pages'});
463
464
465}
466
467
468sub set_initial_doc_fields {
469 my $self = shift(@_);
470 my ($doc_obj, $filename_no_path, $processor) = @_;
471
472 $doc_obj->set_OIDtype ($processor->{'OIDtype'}, $processor->{'OIDmetadata'});
473 my $topsection = $doc_obj->get_top_section();
474
475 if ($self->{'documenttype'} eq 'paged') {
476 # set the gsdlthistype metadata to Paged - this ensures this document will
477 # be treated as a Paged doc, even if Titles are not numeric
478 $doc_obj->set_utf8_metadata_element ($topsection, "gsdlthistype", "Paged");
479 } else {
480 $doc_obj->set_utf8_metadata_element ($topsection, "gsdlthistype", "Hierarchy");
481 }
482
483 $self->set_Source_metadata($doc_obj, $filename_no_path);
484
485 # if we want a header page, we need to add some text into the top section, otherwise this section will become invisible
486 if ($self->{'headerpage'}) {
487 $self->add_dummy_text($doc_obj, $topsection);
488 }
489
490
491}
492
493
494sub process_item {
495 my $self = shift (@_);
496 my ($filename_full_path, $dir, $filename_no_path, $processor) = @_;
497
498 my $doc_obj = new doc ($filename_full_path, "indexed_doc");
499 $self->set_initial_doc_fields($doc_obj, $filename_no_path, $processor);
500 my $topsection = $doc_obj->get_top_section();
501 open (ITEMFILE, $filename_full_path) || die "couldn't open $filename_full_path\n";
502 my $line = "";
503 my $num = 0;
504 while (defined ($line = <ITEMFILE>)) {
505 next unless $line =~ /\w/;
506 chomp $line;
507 next if $line =~ /^#/; # ignore comment lines
508 if ($line =~ /^<([^>]*)>\s*(.*?)\s*$/) {
509 $doc_obj->set_utf8_metadata_element ($topsection, $1, $2);
510 #$meta->{$1} = $2;
511 } else {
512 $num++;
513 # line should be like page:imagefilename:textfilename:r - the r is optional -> means rotate the image 180 deg
514 $line =~ s/^\s+//; #remove space at the front
515 $line =~ s/\s+$//; #remove space at the end
516 my ($pagenum, $imgname, $txtname, $rotate) = split /:/, $line;
517
518 # create a new section for each image file
519 my $cursection = $doc_obj->insert_section($doc_obj->get_end_child($topsection));
520 # the page number becomes the Title
521 $doc_obj->set_utf8_metadata_element($cursection, 'Title', $pagenum);
522
523 # process the image for this page if there is one
524 if (defined $imgname && $imgname ne "") {
525 my $result1 = $self->process_image($dir.$imgname, $imgname, $doc_obj, $cursection, $rotate);
526
527 if (!defined $result1)
528 {
529 print "PagedImagePlugin: couldn't process image \"$dir.$imgname\" for item \"$filename_full_path\"\n";
530 }
531 }
532 # process the text file if one is there
533 if (defined $txtname && $txtname ne "") {
534 my $result2 = $self->process_text ($dir.$txtname, $txtname, $doc_obj, $cursection);
535
536 if (!defined $result2) {
537 print "PagedImagePlugin: couldn't process text file \"$dir.$txtname\" for item \"$filename_full_path\"\n";
538 $self->add_dummy_text($doc_obj, $cursection);
539 }
540 } else {
541 # otherwise add in some dummy text
542 $self->add_dummy_text($doc_obj, $cursection);
543 }
544 }
545 }
546
547 close ITEMFILE;
548
549 # add numpages metadata
550 $doc_obj->set_utf8_metadata_element ($topsection, 'NumPages', "$num");
551 return $doc_obj;
552}
553
554sub process_text {
555 my $self = shift (@_);
556 my ($filename_full_path, $file, $doc_obj, $cursection) = @_;
557
558 # check that the text file exists!!
559 if (!-f $filename_full_path) {
560 print "PagedImagePlugin: ERROR: File $filename_full_path does not exist, skipping\n";
561 return 0;
562 }
563
564 # Do encoding stuff
565 my ($language, $encoding) = $self->textcat_get_language_encoding ($filename_full_path);
566
567 my $text="";
568 &ReadTextFile::read_file($self, $filename_full_path, $encoding, $language, \$text);
569 if (!length ($text)) {
570 # It's a bit unusual but not out of the question to have no text, so just give a warning
571 print "PagedImagePlugin: WARNING: $filename_full_path contains no text\n";
572 }
573
574 # we need to escape the escape character, or else mg will convert into
575 # eg literal newlines, instead of leaving the text as '\n'
576 $text =~ s/\\/\\\\/g; # macro language
577 $text =~ s/_/\\_/g; # macro language
578
579
580 if ($text =~ m/<html.*?>\s*<head.*?>.*<\/head>\s*<body.*?>(.*)<\/body>\s*<\/html>\s*$/s) {
581 # looks like HTML input
582 # no need to escape < and > or put in <pre> tags
583
584 $text = $1;
585
586 # insert preformat tags and add text to document object
587 $doc_obj->add_utf8_text($cursection, "$text");
588 }
589 else {
590 $text =~ s/</&lt;/g;
591 $text =~ s/>/&gt;/g;
592
593 # insert preformat tags and add text to document object
594 $doc_obj->add_utf8_text($cursection, "<pre>\n$text\n</pre>");
595 }
596
597
598 return 1;
599}
600
601
602sub clean_up_after_doc_obj_processing {
603 my $self = shift(@_);
604
605 $self->ImageConverter::clean_up_temporary_files();
606}
607
6081;
Note: See TracBrowser for help on using the repository browser.