source: gsdl/trunk/perllib/plugins/PagedImagePlugin.pm@ 19811

Last change on this file since 19811 was 19054, checked in by davidb, 15 years ago

MaxImageWidth and MaxImageHeight set as metadata
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 22.5 KB
Line 
1###########################################################################
2#
3# PagedImagePlugin.pm -- plugin for sets of images and OCR text that
4# make up a document
5# A component of the Greenstone digital library software
6# from the New Zealand Digital Library Project at the
7# University of Waikato, New Zealand.
8#
9# Copyright (C) 1999 New Zealand Digital Library Project
10#
11# This program is free software; you can redistribute it and/or modify
12# it under the terms of the GNU General Public License as published by
13# the Free Software Foundation; either version 2 of the License, or
14# (at your option) any later version.
15#
16# This program is distributed in the hope that it will be useful,
17# but WITHOUT ANY WARRANTY; without even the implied warranty of
18# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19# GNU General Public License for more details.
20#
21# You should have received a copy of the GNU General Public License
22# along with this program; if not, write to the Free Software
23# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
24#
25###########################################################################
26
27# PagedImagePlugin
28# processes sequences of images, with optional OCR text
29#
30# This plugin takes *.item files, which contain metadata and lists of image
31# files, and produces a document containing sections, one for each page.
32# The files should be named something.item, then you can have more than one
33# book in a directory. You will need to create these files, one for each
34# document/book.
35#
36#There are two formats for the item files: a plain text format, and an xml
37#format. You can use either format, and can have both formats in the same
38#collection if you like. If you use the plain format, you must not start the
39#file off with <PagedDocument>
40
41#### PLAIN FORMAT
42# The format of the xxx.item file is as follows:
43# The first lines contain any metadata for the whole document
44# <metadata-name>metadata-value
45# eg.
46# <Title>Snail farming
47# <Date>19230102
48# Then comes a list of pages, one page per line, each line has the format
49#
50# pagenum:imagefile:textfile:r
51#
52# page num and imagefile are required. pagenum is used for the Title
53# of the section, and in the display is shown as page <pagenum>.
54# imagefile is the image for the page. textfile is an optional text
55# file containing the OCR (or any) text for the page - this gets added
56# as the text for the section. r is optional, and signals that the image
57# should be rotated 180deg. Eg use this if the image has been made upside down.
58# So an example item file looks like:
59# <Title>Snail farming
60# <Date>19960403
61# 1:p1.gif:p1.txt:
62# 2:p2.gif::
63# 3:p3.gif:p3.txt:
64# 3b:p3b.gif:p3b.txt:r
65# The second page has no text, the fourth page is a back page, and
66# should be rotated.
67#
68
69#### XML FORMAT
70# The xml format looks like the following
71#<PagedDocument>
72#<Metadata name="Title">The Title of the entire document</Metadata>
73#<Page pagenum="1" imgfile="xxx.jpg" txtfile="yyy.txt">
74#<Metadata name="Title">The Title of this page</Metadata>
75#</Page>
76#... more pages
77#</PagedDocument>
78#PagedDocument contains a list of Pages, Metadata and PageGroups. Any metadata
79#that is not inside another tag will belong to the document.
80#Each Page has a pagenum (not used at the moment), an imgfile and/or a txtfile.
81#These are both optional - if neither is used, the section will have no content.
82#Pages can also have metadata associated with them.
83#PageGroups can be introduced at any point - they can contain Metadata and Pages and other PageGroups. They are used to introduce hierarchical structure into the document.
84#For example
85#<PagedDocument>
86#<PageGroup>
87#<Page>
88#<Page>
89#</PageGroup>
90#<Page>
91#</PagedDocument>
92#would generate a structure like
93#X
94#--X
95# --X
96# --X
97#--X
98#PageGroup tags can also have imgfile/textfile metadata if you like - this way they get some content themselves.
99
100#Currently the XML structure doesn't work very well with the paged document type, unless you use numerical Titles for each section.
101#There is still a bit of work to do on this format:
102#* enable other text file types, eg html, pdf etc
103#* make the document paging work properly
104#* add pagenum as Title unless a Title is present?
105
106# All the supplemetary image amd text files should be in the same folder as
107# the .item file.
108#
109# To display the images instead of the document text, you can use [srcicon]
110# in the DocumentText format statement.
111# For example,
112#
113# format DocumentText "<center><table width=_pagewidth_><tr><td>[srcicon]</td></tr></table></center>"
114#
115# To have it create thumbnail size images, use the '-create_thumbnail' option.
116# To have it create medium size images for display, use the '-create_screenview'
117# option. As usual, running
118# 'perl -S pluginfo.pl PagedImagePlugin' will list all the options.
119
120# If you want the resulting documents to be presented with a table of
121# contents, use '-documenttype hierarchy', otherwise they will have
122# next and previous arrows, and a goto page X box.
123
124# If you have used -create_screenview, you can also use [screenicon] in the format
125# statement to display the smaller image. Here is an example that switches
126# between the two:
127#
128# format DocumentText "<center><table width=_pagewidth_><tr><td>{If}{_cgiargp_ eq full,<a href='_httpdocument_&d=_cgiargd_&p=small'>Switch to small version.</a>,<a href='_httpdocument_&d=_cgiargd_&p=full'>Switch to fullsize version</a>}</td></tr><tr><td>{If}{_cgiargp_ eq full,<a href='_httpdocument_&d=_cgiargd_&p=small' title='Switch to small version'>[srcicon]</a>,<a href='_httpdocument_&d=_cgiargd_&p=full' title='Switch to fullsize version'>[screenicon]</a>}</td></tr></table></center>"
129#
130# Additional metadata can be added into the .item files, alternatively you can
131# use normal metadata.xml files, with the name of the xxx.item file as the
132# FileName (only for document level metadata).
133
134package PagedImagePlugin;
135
136use ReadXMLFile;
137use ReadTextFile;
138use ImageConverter;
139
140use strict;
141no strict 'refs'; # allow filehandles to be variables and viceversa
142
143sub BEGIN {
144 @PagedImagePlugin::ISA = ('ReadXMLFile', 'ReadTextFile', 'ImageConverter');
145}
146
147my $type_list =
148 [ { 'name' => "paged",
149 'desc' => "{PagedImagePlugin.documenttype.paged}" },
150 { 'name' => "hierarchy",
151 'desc' => "{PagedImagePlugin.documenttype.hierarchy}" } ];
152
153my $arguments =
154 [ { 'name' => "process_exp",
155 'desc' => "{BasePlugin.process_exp}",
156 'type' => "string",
157 'deft' => &get_default_process_exp(),
158 'reqd' => "no" },
159 { 'name' => "block_exp",
160 'desc' => "{BasePlugin.block_exp}",
161 'type' => "string",
162 'deft' => &get_default_block_exp(),
163 'reqd' => "no" },
164 { 'name' => "title_sub",
165 'desc' => "{HTMLPlugin.title_sub}",
166 'type' => "string",
167 'deft' => "" },
168 { 'name' => "headerpage",
169 'desc' => "{PagedImagePlugin.headerpage}",
170 'type' => "flag",
171 'reqd' => "no" },
172 { 'name' => "documenttype",
173 'desc' => "{PagedImagePlugin.documenttype}",
174 'type' => "enum",
175 'list' => $type_list,
176 'deft' => "paged",
177 'reqd' => "no" } ];
178
179
180my $options = { 'name' => "PagedImagePlugin",
181 'desc' => "{PagedImagePlugin.desc}",
182 'abstract' => "no",
183 'inherits' => "yes",
184 'args' => $arguments };
185
186sub new {
187 my ($class) = shift (@_);
188 my ($pluginlist,$inputargs,$hashArgOptLists) = @_;
189 push(@$pluginlist, $class);
190
191 push(@{$hashArgOptLists->{"ArgList"}},@{$arguments});
192 push(@{$hashArgOptLists->{"OptList"}},$options);
193
194 my $imc_self = new ImageConverter($pluginlist, $inputargs, $hashArgOptLists);
195 my $rtf_self = new ReadTextFile($pluginlist, $inputargs, $hashArgOptLists, 1);
196 my $rxf_self = new ReadXMLFile($pluginlist, $inputargs, $hashArgOptLists);
197
198 my $self = BasePlugin::merge_inheritance($imc_self,$rtf_self,$rxf_self);
199
200 # Update $self used by XML::Parser so it finds callback functions
201 # such as start_document here and not in ReadXMLFile (which is what
202 # $self was when new XML::Parser was done)
203 #
204 # If the $self returned by this constructor is the same as the one
205 # used in ReadXMLFile (e.g. in the GreenstoneXMLPlugin) then this step isn't necessary
206 #
207 # Consider embedding this type of assignment into merge_inheritance
208 # to help catch all cases?
209
210 $rxf_self->{'parser'}->{'PluginObj'} = $self;
211
212 return bless $self, $class;
213}
214
215
216sub init {
217 my $self = shift (@_);
218 my ($verbosity, $outhandle, $failhandle) = @_;
219
220 $self->SUPER::init(@_);
221 $self->ImageConverter::init();
222}
223
224sub begin {
225 my $self = shift (@_);
226 my ($pluginfo, $base_dir, $processor, $maxdocs) = @_;
227
228 $self->SUPER::begin(@_);
229 $self->ImageConverter::begin(@_);
230}
231
232sub get_default_process_exp {
233 my $self = shift (@_);
234
235 return q^\.item$^;
236}
237
238sub get_doctype {
239 my $self = shift(@_);
240
241 return "PagedDocument";
242}
243
244
245# want to block everything except the .item ones
246# but instead we will block images and txt files
247sub get_default_block_exp {
248 my $self = shift (@_);
249
250 return q^(?i)(\.jpe?g|\.gif|\.png|\.tif?f|\.te?xt|\.html?|~)$^
251### return q^(?i)(\.jpe?g|\.gif|\.png|\.tif?f|\.te?xt|\.html?|\.css|\.opd|\.pdf|~)$^
252}
253
254
255# want to use BasePlugin's version of this, not ReadXMLFile's
256sub can_process_this_file {
257 my $self = shift(@_);
258
259 return $self->BasePlugin::can_process_this_file(@_);
260}
261
262# we want to use BasePlugin's read, not ReadXMLFile's
263sub read
264{
265 my $self = shift (@_);
266
267 $self->BasePlugin::read(@_);
268}
269
270
271
272sub read_into_doc_obj {
273 my $self = shift (@_);
274 my ($pluginfo, $base_dir, $file, $block_hash, $metadata, $processor, $maxdocs, $total_count, $gli) = @_;
275 my $outhandle = $self->{'outhandle'};
276 my $verbosity = $self->{'verbosity'};
277
278 my ($filename_full_path, $filename_no_path) = &util::get_full_filenames($base_dir, $file);
279
280 print $outhandle "PagedImagePlugin processing \"$filename_full_path\"\n"
281 if $verbosity > 1;
282 print STDERR "<Processing n='$file' p='PagedImagePlugin'>\n" if ($gli);
283
284 $self->{'MaxImageWidth'} = 0;
285 $self->{'MaxImageHeight'} = 0;
286
287 # here we need to decide if we have an old text .item file, or a new xml
288 # .item file
289 my $xml_version = $self->is_xml_item_file($filename_full_path);
290
291 $self->tidy_item_file($filename_full_path);
292
293 my $doc_obj;
294 if ($xml_version) {
295 # careful checking needed here!! are we using local xml handlers or super ones
296 $self->ReadXMLFile::read($pluginfo, $base_dir, $file, $block_hash, $metadata, $processor, $maxdocs, $total_count, $gli);
297 $doc_obj = $self->{'doc_obj'};
298 } else {
299 my ($dir);
300 ($dir, $file) = $filename_full_path =~ /^(.*?)([^\/\\]*)$/;
301
302 #process the .item file
303 $doc_obj = $self->process_item($filename_full_path, $dir, $file, $processor);
304
305 }
306
307 my $section = $doc_obj->get_top_section();
308
309 $doc_obj->add_utf8_metadata($section, "Plugin", "$self->{'plugin_type'}");
310 $doc_obj->add_metadata($section, "FileFormat", "PagedImage");
311
312 # include any metadata passed in from previous plugins
313 # note that this metadata is associated with the top level section
314 $self->add_associated_files($doc_obj, $filename_full_path);
315 $self->extra_metadata ($doc_obj, $section, $metadata);
316 $self->auto_extract_metadata ($doc_obj);
317
318 # if we haven't found any Title so far, assign one
319 $self->title_fallback($doc_obj,$section,$filename_no_path);
320
321 $self->add_OID($doc_obj);
322 return (1,$doc_obj);
323}
324
325# for now, the test is if the first non-empty line is <PagedDocument>, then its xml
326sub is_xml_item_file {
327 my $self = shift(@_);
328 my ($filename) = @_;
329
330 my $xml_version = 0;
331 open (ITEMFILE, $filename) || die "couldn't open $filename\n";
332
333 my $line = "";
334 my $num = 0;
335 $line = <ITEMFILE>;
336 while ($line !~ /\w/) {
337 $line = <ITEMFILE>;
338 }
339 chomp $line;
340 if ($line =~ /<PagedDocument/) {
341 $xml_version = 1;
342 }
343 close ITEMFILE;
344 return $xml_version;
345}
346
347sub tidy_item_file {
348 my $self = shift(@_);
349 my ($filename) = @_;
350
351 open (ITEMFILE, $filename) || die "couldn't open $filename\n";
352 my $backup_filename = "backup.item";
353 open (BACKUP,">$backup_filename")|| die "couldn't write to $backup_filename\n";
354 my $line = "";
355 $line = <ITEMFILE>;
356 $line =~ s/^\xEF\xBB\xBF//; # strip BOM
357 $line =~ s/\x0B+//ig;
358 $line =~ s/&/&amp;/g;
359 print BACKUP ($line);
360 #Tidy up the item file some metadata title contains \vt-vertical tab
361 while ($line = <ITEMFILE>) {
362 $line =~ s/\x0B+//ig;
363 $line =~ s/&/&amp;/g;
364 print BACKUP ($line);
365 }
366 close ITEMFILE;
367 close BACKUP;
368 &File::Copy::copy ($backup_filename, $filename);
369 &util::rm($backup_filename);
370
371}
372
373sub rotate_image {
374 my $self = shift (@_);
375 my ($filename_full_path) = @_;
376
377 my ($this_filetype) = $filename_full_path =~ /\.([^\.]*)$/;
378 my $result = $self->convert($filename_full_path, $this_filetype, "-rotate 180", "ROTATE");
379 my ($new_filename) = ($result =~ /=>(.*\.$this_filetype)/);
380 if (-e "$new_filename") {
381 return $new_filename;
382 }
383 # somethings gone wrong
384 return $filename_full_path;
385
386}
387
388sub process_image {
389 my $self = shift(@_);
390 my ($filename_full_path, $filename_no_path, $doc_obj, $section, $rotate) = @_;
391 # do rotation
392 if ((defined $rotate) && ($rotate eq "r")) {
393 # check the filenames
394 return 0 if ($filename_no_path eq "" || !-f $filename_full_path);
395
396 # we get a new temporary file which is rotated
397 $filename_full_path = $self->rotate_image($filename_full_path);
398 }
399
400 # do generate images
401 my $result = 0;
402 if ($self->{'image_conversion_available'} == 1) {
403 # do we need to convert $filename_no_path to utf8? We are already reading in from a file, what encoding is it in???
404 $result = $self->generate_images($filename_full_path, $filename_no_path, $doc_obj, $section);
405 }
406 #overwrite one set in ImageConverter
407 $doc_obj->set_metadata_element ($section, "FileFormat", "PagedImage");
408 return $result;
409}
410
411
412sub xml_start_tag {
413 my $self = shift(@_);
414 my ($expat, $element) = @_;
415 $self->{'element'} = $element;
416
417 my $doc_obj = $self->{'doc_obj'};
418 if ($element eq "PagedDocument") {
419 $self->{'current_section'} = $doc_obj->get_top_section();
420 } elsif ($element eq "PageGroup" || $element eq "Page") {
421 # create a new section as a child
422 $self->{'current_section'} = $doc_obj->insert_section($doc_obj->get_end_child($self->{'current_section'}));
423 $self->{'num_pages'}++;
424 # assign pagenum as what??
425 my $pagenum = $_{'pagenum'}; #TODO!!
426 if (defined $pagenum) {
427 $doc_obj->set_utf8_metadata_element($self->{'current_section'}, 'PageNum', $pagenum);
428 }
429 my ($imgfile) = $_{'imgfile'};
430 if (defined $imgfile) {
431 # *****
432 # What about support for rotate image (e.g. old ':r' notation)?
433 $self->process_image($self->{'xml_file_dir'}.$imgfile, $imgfile, $doc_obj, $self->{'current_section'});
434 }
435 my ($txtfile) = $_{'txtfile'};
436 if (defined($txtfile)&& $txtfile ne "") {
437 $self->process_text ($self->{'xml_file_dir'}.$txtfile, $txtfile, $doc_obj, $self->{'current_section'});
438 } else {
439 $self->add_dummy_text($doc_obj, $self->{'current_section'});
440 }
441 } elsif ($element eq "Metadata") {
442 $self->{'metadata_name'} = $_{'name'};
443 }
444}
445
446sub xml_end_tag {
447 my $self = shift(@_);
448 my ($expat, $element) = @_;
449
450 my $doc_obj = $self->{'doc_obj'};
451 if ($element eq "Page" || $element eq "PageGroup") {
452 # if Title hasn't been assigned, set PageNum as Title
453 if (!defined $doc_obj->get_metadata_element ($self->{'current_section'}, "Title") && defined $doc_obj->get_metadata_element ($self->{'current_section'}, "PageNum" )) {
454 $doc_obj->add_utf8_metadata ($self->{'current_section'}, "Title", $doc_obj->get_metadata_element ($self->{'current_section'}, "PageNum" ));
455 }
456 # move the current section back to the parent
457 $self->{'current_section'} = $doc_obj->get_parent_section($self->{'current_section'});
458 } elsif ($element eq "Metadata") {
459
460 $doc_obj->add_utf8_metadata ($self->{'current_section'}, $self->{'metadata_name'}, $self->{'metadata_value'});
461 $self->{'metadata_name'} = "";
462 $self->{'metadata_value'} = "";
463
464 }
465 # otherwise we ignore the end tag
466}
467
468
469sub xml_text {
470 my $self = shift(@_);
471 my ($expat) = @_;
472
473 if ($self->{'element'} eq "Metadata" && $self->{'metadata_name'}) {
474 $self->{'metadata_value'} .= $_;
475 }
476}
477
478sub xml_doctype {
479}
480
481sub open_document {
482 my $self = shift(@_);
483
484 # create a new document
485 $self->{'doc_obj'} = new doc ($self->{'filename'}, "indexed_doc", $self->{'file_rename_method'});
486 # TODO is file filenmae_no_path??
487 $self->set_initial_doc_fields($self->{'doc_obj'}, $self->{'file'}, $self->{'processor'});
488
489 my ($dir, $file) = $self->{'filename'} =~ /^(.*?)([^\/\\]*)$/;
490 $self->{'xml_file_dir'} = $dir;
491 $self->{'num_pages'} = 0;
492
493}
494
495sub close_document {
496 my $self = shift(@_);
497 my $doc_obj = $self->{'doc_obj'};
498
499 # add numpages metadata
500 my $topsection = $doc_obj->get_top_section();
501
502 $doc_obj->set_utf8_metadata_element ($topsection, 'NumPages', $self->{'num_pages'});
503
504 $doc_obj->set_utf8_metadata_element($topsection,"MaxImageWidth",$self->{'MaxImageWidth'});
505 $doc_obj->set_utf8_metadata_element($topsection,"MaxImageHeight",$self->{'MaxImageHeight'});
506 $self->{'MaxImageWidth'} = undef;
507 $self->{'MaxImageHeight'} = undef;
508
509}
510
511
512sub set_initial_doc_fields {
513 my $self = shift(@_);
514 my ($doc_obj, $filename_no_path, $processor) = @_;
515
516 my $topsection = $doc_obj->get_top_section();
517
518 if ($self->{'documenttype'} eq 'paged') {
519 # set the gsdlthistype metadata to Paged - this ensures this document will
520 # be treated as a Paged doc, even if Titles are not numeric
521 $doc_obj->set_utf8_metadata_element ($topsection, "gsdlthistype", "Paged");
522 } else {
523 $doc_obj->set_utf8_metadata_element ($topsection, "gsdlthistype", "Hierarchy");
524 }
525
526 $self->set_Source_metadata($doc_obj, $filename_no_path);
527
528 # if we want a header page, we need to add some text into the top section, otherwise this section will become invisible
529 if ($self->{'headerpage'}) {
530 $self->add_dummy_text($doc_obj, $topsection);
531 }
532
533
534}
535
536
537sub process_item {
538 my $self = shift (@_);
539 my ($filename_full_path, $dir, $filename_no_path, $processor) = @_;
540
541 my $doc_obj = new doc ($filename_full_path, "indexed_doc", $self->{'file_rename_method'});
542 $self->set_initial_doc_fields($doc_obj, $filename_no_path, $processor);
543 my $topsection = $doc_obj->get_top_section();
544 open (ITEMFILE, $filename_full_path) || die "couldn't open $filename_full_path\n";
545 my $line = "";
546 my $num = 0;
547 while (defined ($line = <ITEMFILE>)) {
548 next unless $line =~ /\w/;
549 chomp $line;
550 next if $line =~ /^#/; # ignore comment lines
551 if ($line =~ /^<([^>]*)>\s*(.*?)\s*$/) {
552 $doc_obj->set_utf8_metadata_element ($topsection, $1, $2);
553 #$meta->{$1} = $2;
554 } else {
555 $num++;
556 # line should be like page:imagefilename:textfilename:r - the r is optional -> means rotate the image 180 deg
557 $line =~ s/^\s+//; #remove space at the front
558 $line =~ s/\s+$//; #remove space at the end
559 my ($pagenum, $imgname, $txtname, $rotate) = split /:/, $line;
560
561 # create a new section for each image file
562 my $cursection = $doc_obj->insert_section($doc_obj->get_end_child($topsection));
563 # the page number becomes the Title
564 $doc_obj->set_utf8_metadata_element($cursection, 'Title', $pagenum);
565
566 # process the image for this page if there is one
567 if (defined $imgname && $imgname ne "") {
568 my $result1 = $self->process_image($dir.$imgname, $imgname, $doc_obj, $cursection, $rotate);
569
570 if (!defined $result1)
571 {
572 print "PagedImagePlugin: couldn't process image \"$dir.$imgname\" for item \"$filename_full_path\"\n";
573 }
574 }
575 # process the text file if one is there
576 if (defined $txtname && $txtname ne "") {
577 my $result2 = $self->process_text ($dir.$txtname, $txtname, $doc_obj, $cursection);
578
579 if (!defined $result2) {
580 print "PagedImagePlugin: couldn't process text file \"$dir.$txtname\" for item \"$filename_full_path\"\n";
581 $self->add_dummy_text($doc_obj, $cursection);
582 }
583 } else {
584 # otherwise add in some dummy text
585 $self->add_dummy_text($doc_obj, $cursection);
586 }
587 }
588 }
589
590 close ITEMFILE;
591
592 # add numpages metadata
593 $doc_obj->set_utf8_metadata_element ($topsection, 'NumPages', "$num");
594
595 $doc_obj->set_utf8_metadata_element($topsection,"MaxImageWidth",$self->{'MaxImageWidth'});
596 $doc_obj->set_utf8_metadata_element($topsection,"MaxImageHeight",$self->{'MaxImageHeight'});
597 $self->{'MaxImageWidth'} = undef;
598 $self->{'MaxImageHeight'} = undef;
599
600
601 return $doc_obj;
602}
603
604sub process_text {
605 my $self = shift (@_);
606 my ($filename_full_path, $file, $doc_obj, $cursection) = @_;
607
608 # check that the text file exists!!
609 if (!-f $filename_full_path) {
610 print "PagedImagePlugin: ERROR: File $filename_full_path does not exist, skipping\n";
611 return 0;
612 }
613
614 # Do encoding stuff
615 my ($language, $encoding) = $self->textcat_get_language_encoding ($filename_full_path);
616
617 my $text="";
618 &ReadTextFile::read_file($self, $filename_full_path, $encoding, $language, \$text);
619 if (!length ($text)) {
620 # It's a bit unusual but not out of the question to have no text, so just give a warning
621 print "PagedImagePlugin: WARNING: $filename_full_path contains no text\n";
622 }
623
624 # we need to escape the escape character, or else mg will convert into
625 # eg literal newlines, instead of leaving the text as '\n'
626 $text =~ s/\\/\\\\/g; # macro language
627 $text =~ s/_/\\_/g; # macro language
628
629
630 if ($text =~ m/<html.*?>\s*<head.*?>.*<\/head>\s*<body.*?>(.*)<\/body>\s*<\/html>\s*$/is) {
631 # looks like HTML input
632 # no need to escape < and > or put in <pre> tags
633
634 $text = $1;
635
636 # insert preformat tags and add text to document object
637 $doc_obj->add_utf8_text($cursection, "$text");
638 }
639 else {
640 $text =~ s/</&lt;/g;
641 $text =~ s/>/&gt;/g;
642
643 # insert preformat tags and add text to document object
644 $doc_obj->add_utf8_text($cursection, "<pre>\n$text\n</pre>");
645 }
646
647
648 return 1;
649}
650
651
652sub clean_up_after_doc_obj_processing {
653 my $self = shift(@_);
654
655 $self->ImageConverter::clean_up_temporary_files();
656}
657
6581;
Note: See TracBrowser for help on using the repository browser.