source: indexers/trunk/mgpp/java/org/greenstone/mgpp/winMake.bat@ 19524

@echo off

set MGPPHOME=..\..\..\..

rem ---- Where to put class files ----
set JAVACLASSDIR=classes

rem ---- Name and location of java programs ----
set JAVAC="%JAVA_HOME%\bin\javac"
set JAVAH="%JAVA_HOME%\bin\javah"
set JAVA="%JAVA_HOME%\bin\java"
set JAVADOC="%JAVA_HOME%\bin\javadoc"
set JAR="%JAVA_HOME%\bin\jar"

set JAVACOPTIONS= -deprecation -g -O

if "%DEBUG%" == "" (
  set MAKE_VARS=DEBUG=0
) else (
  set MAKE_VARS=DEBUG=%DEBUG%
)


if ""%1"" == """" goto all
if ""%1"" == ""all"" goto all
if ""%1"" == ""install"" goto install
if ""%1"" == ""clean"" goto clean

:unknown
    echo Error: Unrecognized argument %1.
    goto done

:all
    if not exist %JAVACLASSDIR% mkdir %JAVACLASSDIR%
    echo Compiling MGPP Java classes ...
        %JAVAC% -d %JAVACLASSDIR% %JAVACOPTIONS% *.java
        %JAVAH% -classpath %JAVACLASSDIR% -d %MGPPHOME%\jni org.greenstone.mgpp.MGPPWrapper
        %JAR% cf %MGPPHOME%\mgpp.jar -C %JAVACLASSDIR% org
    goto done

:install
    goto done

:clean
    echo Cleaning up...
    if exist %JAVACLASSDIR% rmdir /S /Q %JAVACLASSDIR%
        if exist %MGPPHOME%\mgpp.jar del %MGPPHOME%\mgpp.jar
        if exist %MGPPHOME%\jni\org_greenstone_mgpp_MGPPWrapper.h del %MGPPHOME%\jni\org_greenstone_mgpp_MGPPWrapper.h
    goto done

:done