@echo off


::  -------- Generate documentation for the Greenstone Librarian Interface --------

:: This script must be run from within the directory in which it lives
if exist document.bat goto findJavadoc
    echo This script must be run from the directory in which it resides.
    goto exit


:findJavadoc
:: ---- Check Javadoc exists ----
set JAVADOCPATH=

:: Some users may set the above line manually
if not "%JAVADOCPATH%" == "" goto testJavadoc

    :: If it is set, use the JAVAHOME environment variable
    if not "%JAVAHOME%" == "" goto javahome

    :: Check if Javadoc is on the search path
    echo %PATH%| winutil\which javadoc.exe | winutil\setvar JAVADOCPATH > setjavadoc.bat
    call setjavadoc.bat
    del setjavadoc.bat
    if not "%JAVADOCPATH%" == "" goto testJavadoc

    :: Still haven't found anything, so try looking in the registry (gulp!)
    type nul > jdk.reg
    regedit /E jdk.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit"
    type jdk.reg > jdk.txt
    del jdk.reg

    winutil\findjava jdk.txt | winutil\setvar JAVADOCPATH > setjavadoc.bat
    del jdk.txt
    call setjavadoc.bat
    del setjavadoc.bat

    :: If nothing was found in the registry, we're stuck
    if "%JAVADOCPATH%" == "" goto noJavadoc

    set JAVADOCPATH=%JAVADOCPATH%\bin
    goto testJavadoc

:javahome
    set JAVADOCPATH=%JAVAHOME%\bin

:testJavadoc
:: Check that a Javadoc executable has been found
echo Checking Javadoc: %JAVADOCPATH%
if exist "%JAVADOCPATH%\javadoc.exe" goto docGLI

:noJavadoc
    echo.
    echo Failed to locate an appropriate version of Javadoc. You must install a
    echo Java Development Kit (version 1.4 or greater) before generating the
    echo documentation for the Greenstone Librarian Interface.
    goto exit


:docGLI
:: ---- Document the GLI ----
echo.
echo Generating documentation for the Greenstone Librarian Interface...

"%JAVADOCPATH%\javadoc.exe" -classpath classes/ -sourcepath src/ -source 1.4 -author -breakiterator -d docs/ -group "Gatherer v2.3" org.greenstone.gatherer:org.greenstone.gatherer.checklist:org.greenstone.gatherer.collection:org.greenstone.gatherer.file:org.greenstone.gatherer.gui:org.greenstone.gatherer.gui.browser:org.greenstone.gatherer.gui.combobox:org.greenstone.gatherer.gui.messages:org.greenstone.gatherer.gui.metaaudit:org.greenstone.gatherer.gui.table:org.greenstone.gatherer.gui.tree:org.greenstone.gatherer.help:org.greenstone.gatherer.sarm:org.greenstone.gatherer.shell:org.greenstone.gatherer.util -group "Collection Design Module" org.greenstone.gatherer.cdm:org.greenstone.gatherer.cdm.custom -group "Metadata Set Manager" org.greenstone.gatherer.msm:org.greenstone.gatherer.msm.parsers -group "Value Tree Controls" org.greenstone.gatherer.valuetree -private -splitindex -version   org.greenstone.gatherer org.greenstone.gatherer.checklist org.greenstone.gatherer.collection org.greenstone.gatherer.file org.greenstone.gatherer.gui org.greenstone.gatherer.gui.browser org.greenstone.gatherer.gui.combobox org.greenstone.gatherer.gui.messages org.greenstone.gatherer.gui.metaaudit org.greenstone.gatherer.gui.table org.greenstone.gatherer.gui.tree org.greenstone.gatherer.help org.greenstone.gatherer.sarm org.greenstone.gatherer.shell org.greenstone.gatherer.util org.greenstone.gatherer.cdm org.greenstone.gatherer.cdm.custom org.greenstone.gatherer.msm org.greenstone.gatherer.msm.parsers org.greenstone.gatherer.valuetree 

echo Done!

:exit
echo.
pause

:: ---- Clean up ----
set JAVADOCPATH=