source: main/tags/3.04/gsdl/makegs2.bat@ 21181

@echo off
pushd "%CD%"
CD /D "%~dp0"


:: Path to VCVARS32.bat -- You can set this variable manually if needed
:: e.g. set VCVARS="C:\Program Files\Microsoft Visual Studio\VC98\Bin\VCVARS32.BAT"
set VCVARS=""

:: Path to Microsoft Platform SDK's SetEnv.cmd -- You can set this variable manually if needed
set SDK_ENV=""


rem Checking for Winbin and Unzip utility
IF NOT EXIST .\bin\windows\*.* GOTO ENDNOWINBIN
IF NOT EXIST .\bin\windows\choice.exe GOTO ENDNOWINBIN


echo.
echo.
echo  ####                        #                  ###  
echo ##                           #                     # 
echo #     ###  ##   ##  ### ### ###  ##  ###  ##       # 
echo #   # #   #### #### # # ##   #  #  # # # ####    ##  
echo ##  # #   #    #    # #   #  #  #  # # # #      ##   
echo  #### #    ###  ### # # ###  ##  ##  # #  ###   #### 
echo   (C) 2008, New Zealand Digital Library Project
echo.
echo.
echo.


rem Checking for existance of the packages extracted / zipped
IF NOT EXIST .\common-src\packages\windows\crypt\crypt\nul IF NOT EXIST .\common-src\packages\windows\crypt\crypt.zip GOTO ENDNOWINPACK

IF NOT EXIST .\common-src\packages\windows\expat\expat\nul IF NOT EXIST .\common-src\packages\windows\expat\expat.zip GOTO ENDNOWINPACK

:: IF NOT EXIST .\common-src\packages\windows\gdbm\gdbm\nul IF NOT EXIST .\common-src\packages\windows\gdbm\gdbm.zip GOTO ENDNOWINPACK

IF NOT EXIST .\common-src\packages\windows\stlport\stlport\nul IF NOT EXIST .\common-src\packages\windows\stlport\stlport.zip GOTO ENDNOWINPACK

IF NOT EXIST .\common-src\indexers\packages\windows\iconv\iconv\nul IF NOT EXIST .\common-src\indexers\packages\windows\iconv\iconv.zip GOTO ENDNOICONV

IF NOT EXIST .\common-src\packages\sqlite\sqlite* IF NOT EXIST .\common-src\packages\sqlite\sqlite*.tar.gz GOTO ENDNOSQLITE

rem Ask the user to extract now or to directly compile
echo Do you want to extract the required packages (Recommended)? This will be the default action in 10 seconds.
.\bin\windows\choice.exe /T:Y,10 /C:YN
    IF errorlevel 2 GOTO COMPILE
    IF errorlevel 1 GOTO UNZIP
    IF errorlevel 0 GOTO END
    

:UNZIP
IF NOT EXIST .\bin\windows\unzip.exe GOTO ENDNOUNZIP
IF NOT EXIST .\bin\windows\gunzip.exe GOTO ENDNOUNZIP
IF NOT EXIST .\bin\windows\tar.exe GOTO ENDNOUNZIP

rem Extracting the packages
IF EXIST .\common-src\packages\windows\crypt\crypt.zip .\bin\windows\unzip.exe -o .\common-src\packages\windows\crypt\crypt.zip -d .\common-src\packages\windows\crypt\

IF EXIST .\common-src\packages\windows\expat\expat.zip .\bin\windows\unzip.exe -o .\common-src\packages\windows\expat\expat.zip -d .\common-src\packages\windows\expat\

IF EXIST .\common-src\packages\windows\gdbm\gdbm.zip .\bin\windows\unzip.exe -o .\common-src\packages\windows\gdbm\gdbm.zip -d .\common-src\packages\windows\gdbm\

IF EXIST .\common-src\packages\windows\stlport\stlport.zip .\bin\windows\unzip.exe -o .\common-src\packages\windows\stlport\stlport.zip -d .\common-src\packages\windows\stlport\

IF EXIST .\common-src\indexers\packages\windows\iconv\iconv.zip .\bin\windows\unzip.exe -o .\common-src\indexers\packages\windows\iconv\iconv.zip -d .\common-src\indexers\packages\windows\iconv\

IF EXIST .\common-src\packages\sqlite\sqlite*.tar.gz .\bin\windows\gunzip.exe -cd .\common-src\packages\sqlite\sqlite*.tar.gz | .\bin\windows\tar.exe xv --directory=./common-src/packages/sqlite


echo.
echo.
:COMPILE

rem Last check if all the packages have been extracted prior compilation
IF NOT EXIST .\common-src\packages\windows\crypt\crypt\*.* GOTO NEEDUNZIP
IF NOT EXIST .\common-src\packages\windows\expat\expat\*.* GOTO NEEDUNZIP
:: IF NOT EXIST .\common-src\packages\windows\gdbm\gdbm\*.* GOTO NEEDUNZIP
IF NOT EXIST .\common-src\packages\windows\stlport\stlport\*.* GOTO NEEDUNZIP
IF NOT EXIST .\common-src\indexers\packages\windows\iconv\iconv\*.* GOTO NEEDUNZIP
IF NOT EXIST .\common-src\packages\sqlite\sqlite* GOTO NEEDUNZIP

rem Check some known paths to VCVARS32.BAT
:: if the user has set VCVARS32 don't look in the default places at all
IF NOT %VCVARS%=="" GOTO PROMPT

:: Visual Studio 2005 Pro --- NOT READY YET
IF EXIST "%programfiles%\Microsoft Visual Studio 8\VC\bin\vcvars32.bat" set VCVARS="%programfiles%\Microsoft Visual Studio 8\VC\bin\vcvars32.bat"

:: Visual Studio 2003 \ VS7
IF %VCVARS%=="" IF EXIST "%programfiles%\Microsoft Visual Studio .NET 2003\Vc7\bin\vcvars32.bat" set VCVARS="%programfiles%\Microsoft Visual Studio .NET 2003\Vc7\bin\vcvars32.bat"

:: Visual Studio 6 \ VS6
IF %VCVARS%=="" IF EXIST "%programfiles%\Microsoft Visual Studio\VC98\Bin\VCVARS32.BAT" set VCVARS="%programfiles%\Microsoft Visual Studio\VC98\Bin\VCVARS32.BAT"

IF %VCVARS%=="" GOTO ENDNOVCVARS32
:: Now VCVARS has been set so it can be used when we need it


:PROMPT
echo.
rem Ask the user what to compile
echo What do you want to compile?
echo.
echo 1. Local library only
echo 2. Web library only
echo 3. Both
echo 4. Apache local library (needs Microsoft Platform SDK)
echo 5. Quit
echo.
echo Please choose a number from the menu. Otherwise both libraries will be compiled in 15 seconds.
.\bin\windows\choice.exe /N /T:3,15 /C:12345
    IF errorlevel 5 GOTO END
    IF errorlevel 4 GOTO WITHAPACHE
    IF errorlevel 3 GOTO WITHBOTH
    IF errorlevel 2 GOTO WITHOUTLOCALLIB
    IF errorlevel 1 GOTO WITHLOCALLIB
    IF errorlevel 0 GOTO END


:WITHAPACHE
:: Only compile up the Apache web server if we're asked to

rem Check known path(s) to SetEnv.cmd
:: if the user has set SDK_ENV don't look in the default places at all
IF NOT %SDK_ENV%=="" GOTO CALL_SDK

IF EXIST "%programfiles%\Microsoft Platform SDK\SetEnv.cmd" set SDK_ENV="%programfiles%\Microsoft Platform SDK\SetEnv.cmd"

IF %SDK_ENV%=="" GOTO ENDNOSDKENV

:CALL_SDK
call %SDK_ENV%
echo.
echo.

call %VCVARS%
echo.
echo.

:: Now unpack the custom GS2 apache web server tar.gz file
IF NOT EXIST .\runtime-src\packages\apache-httpd\httpd-2.2.11\nul .\bin\windows\gunzip.exe -cd .\runtime-src\packages\apache-httpd\httpd-*.tar.gz | .\bin\windows\tar.exe xv --directory=./runtime-src/packages/apache-httpd

nmake /f win32.mak APACHE_HTTPD=1
GOTO ENDOK


:WITHOUTLOCALLIB
call %VCVARS%
echo.
echo.
nmake /f win32.mak
GOTO ENDOK

:WITHLOCALLIB
call %VCVARS%
echo.
echo.
nmake /f win32.mak LOCAL_LIBRARY=1
GOTO ENDOK

:WITHBOTH
call %VCVARS%
echo.
echo.
nmake /f win32.mak
nmake /f win32.mak LOCAL_LIBRARY=1
GOTO ENDOK

:NEEDUNZIP
echo.
echo /!\ Error /!\ - Some or all the packages are not properly extracted.
echo.
echo If you wish to compile Greenstone 2 you need to unzip the required packages now.
echo.
rem Ask to Unzip the packages now otherwise quit
echo Do you want to unzip these required packages now? This will be the default action in 10 seconds.
.\bin\windows\choice.exe /T:Y,10 /c:YN
    IF errorlevel 2 GOTO END
    IF errorlevel 1 GOTO UNZIP
    IF errorlevel 0 GOTO END

:ENDNOWINBIN
echo.
echo /!\ Error /!\ - Winbin has not been found.
echo This is required to get the conversion tools used for importing different types of files.
echo For more info please visit this page
echo http://wiki.greenstone.org/wiki/index.php/Installing_Greenstone_2_from_SVN_source_on_Windows#Getting_winbin
GOTO END

:ENDNOUNZIP
echo.
echo /!\ Error /!\ - Extacting tools are missing.
echo They are required to extract all packages needed for compilation.
echo These tools are contained in the Winbin folder, more info on this web page:
echo http://wiki.greenstone.org/wiki/index.php/Installing_Greenstone_2_from_SVN_source_on_Windows#Getting_winbin
GOTO END

:ENDNOWINPACK
echo.
echo /!\ Error /!\ - Windows packages are missing.
echo Some required packages are missing in .\common-src\packages\windows\
echo Please go to this page for more information on how to get everything:
echo http://wiki.greenstone.org/wiki/index.php/Installing_Greenstone_2_from_SVN_source_on_Windows
GOTO END

:ENDNOSQLITE
echo.
echo /!\ Error /!\ - SQLite is missing.
echo Some required packages are missing in .\common-src\packages\sqlite\
echo Please go to this page for more information on how to get everything:
echo http://wiki.greenstone.org/wiki/index.php/Installing_Greenstone_2_from_SVN_source_on_Windows
GOTO END

:ENDNOICONV
echo.
echo /!\ Error /!\ - Indexers are missing.
echo Some required packages are missing in .\common-src\indexers\packages\windows\
echo Please go to this page for more information on how to get everything:
echo http://wiki.greenstone.org/wiki/index.php/Installing_Greenstone_2_from_SVN_source_on_Windows
GOTO END

:ENDNOVCVARS32
echo.
echo /!\ Error /!\ - Not able to find 'vcvars32.bat'.
echo You need Visual Studio to compile the source code but we were
echo unable to find the file vcvars32.bat in your system.
echo.
echo Please edit this bat file and manually set the full path to 
echo vcvars32.bat then run this script again.
GOTO END

:ENDNOSDKENV
echo.
echo /!\ Error /!\ - Not able to find 'SetEnv.cmd'.
echo You need Microsoft Platform SDK to compile up the Apache web server
echo but we were unable to find the SDK file SetEnv.cmd on your system.
echo.
echo Please edit the makegs2.bat file and manually set the full path to 
echo SetEnv.cmd then run this script again.
GOTO END

:ENDOK
echo.
echo Done!
echo.
echo This program is free software; you can redistribute it and/or
echo modify it under the terms of the GNU General Public License
echo as published by the Free Software Foundation; either version 2
echo of the License, or (at your option) any later version.
echo.
echo This program is distributed in the hope that it will be useful,
echo but WITHOUT ANY WARRANTY; without even the implied warranty of
echo MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
echo GNU General Public License for more details.
echo.
GOTO END

:END
popd