source: main/trunk/greenstone2/common-src/indexers/lucene-gs/winMake-lucene-version-33.bat@ 24718

@echo off

set LUCENEHOME=.

rem ---- Where to put class files ----
set JAVACLASSDIR=classes

rem ---- Name and location of java programs ----
set JAVAC="%JAVA_HOME%\bin\javac"
set JAVAH="%JAVA_HOME%\bin\javah"
set JAVA="%JAVA_HOME%\bin\java"
set JAVADOC="%JAVA_HOME%\bin\javadoc"
set JAR="%JAVA_HOME%\bin\jar"

set JAVACOPTIONS=-deprecation -g -O

rem set LUCENE_JAR=.\lib\lucene-core-2.3.2.jar
set LUCENE_JAR=.\lib\lucene-core-3.3.0.jar
set MYCLASSPATH=%LUCENE_JAR%;%JAVACLASSDIR%

if "%DEBUG%" == "" (
  set MAKE_VARS=DEBUG=0
) else (
  set MAKE_VARS=DEBUG=%DEBUG%
)

if ""%1"" == """" goto all
if ""%1"" == ""all"" goto all
if ""%1"" == ""install"" goto install
if ""%1"" == ""clean"" goto clean

:unknown
    echo Error: Unrecognized argument %1.
    goto done

:all
    if not exist %JAVACLASSDIR% mkdir %JAVACLASSDIR%
    echo Compiling Greenstone Lucene Java classes ...
    %JAVAC% -d %JAVACLASSDIR% -classpath %MYCLASSPATH% %JAVACOPTIONS% -sourcepath src src\org\greenstone\LuceneWrapper\*.java
    cd %JAVACLASSDIR%
    %JAR% xf ..\%LUCENE_JAR%
    cd ..
    %JAR% cf LuceneWrapper.jar -C %JAVACLASSDIR% .
    goto done

:install
    goto done

:clean
    echo Cleaning up Greenstone Lucene ...
    if exist %JAVACLASSDIR% rmdir /S /Q %JAVACLASSDIR%
        if exist LuceneWrapper.jar del LuceneWrapper.jar
    goto done 

:done