source: main/trunk/greenstone2/perllib/inexport.pm@ 25957

Last change on this file since 25957 was 25957, checked in by kjdon, 12 years ago

adding in support for plugins knowing what version of greenstone (2/3) they are running in. gs_version now passed in when loading plugins, and '-gs_version 2/3' will be added to input args. base plugin class PrintInfo defines the gs_version arg
  • Property svn:executable set to *
File size: 38.5 KB
Line 
1###########################################################################
2#
3# inexport.pm -- useful class to support import.pl and export.pl
4# A component of the Greenstone digital library software
5# from the New Zealand Digital Library Project at the
6# University of Waikato, New Zealand.
7#
8# Copyright (C) 1999 New Zealand Digital Library Project
9#
10# This program is free software; you can redistribute it and/or modify
11# it under the terms of the GNU General Public License as published by
12# the Free Software Foundation; either version 2 of the License, or
13# (at your option) any later version.
14#
15# This program is distributed in the hope that it will be useful,
16# but WITHOUT ANY WARRANTY; without even the implied warranty of
17# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18# GNU General Public License for more details.
19#
20# You should have received a copy of the GNU General Public License
21# along with this program; if not, write to the Free Software
22# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
23#
24###########################################################################
25
26package inexport;
27
28use strict;
29
30no strict 'refs'; # allow filehandles to be variables and vice versa
31no strict 'subs'; # allow barewords (eg STDERR) as function arguments
32
33use arcinfo;
34use colcfg;
35use dbutil;
36use doc;
37use plugin;
38use plugout;
39use manifest;
40use inexport;
41use util;
42use scriptutil;
43use FileHandle;
44use gsprintf 'gsprintf';
45use printusage;
46use parse2;
47
48use File::Basename;
49
50sub new
51{
52 my $class = shift (@_);
53 my ($mode,$argv,$options,$opt_listall_options) = @_;
54
55 my $self = { 'xml' => 0, 'mode' => $mode };
56
57 # general options available to all plugins
58 my $arguments = $options->{'args'};
59 my $intArgLeftinAfterParsing = parse2::parse($argv,$arguments,$self,"allow_extra_options");
60 # Parse returns -1 if something has gone wrong
61 if ($intArgLeftinAfterParsing == -1)
62 {
63 &PrintUsage::print_txt_usage($options, "{import.params}");
64 die "\n";
65 }
66
67 my $language = $self->{'language'};
68 # If $language has been specified, load the appropriate resource bundle
69 # (Otherwise, the default resource bundle will be loaded automatically)
70 if ($language && $language =~ /\S/) {
71 &gsprintf::load_language_specific_resource_bundle($language);
72 }
73
74 if ($self->{'listall'}) {
75 if ($self->{'xml'}) {
76 &PrintUsage::print_xml_usage($opt_listall_options);
77 }
78 else
79 {
80 &PrintUsage::print_txt_usage($opt_listall_options,"{export.params}");
81 }
82 die "\n";
83 }
84
85
86 if ($self->{'xml'}) {
87 &PrintUsage::print_xml_usage($options);
88 print "\n";
89 return bless $self, $class;
90 }
91
92 if ($self->{'gli'}) { # the gli wants strings to be in UTF-8
93 &gsprintf::output_strings_in_UTF8;
94 }
95
96 # now check that we had exactly one leftover arg, which should be
97 # the collection name. We don't want to do this earlier, cos
98 # -xml arg doesn't need a collection name
99 # Or if the user specified -h, then we output the usage also
100
101 if ($intArgLeftinAfterParsing != 1 || (@$argv && $argv->[0] =~ /^\-+h/))
102 {
103 &PrintUsage::print_txt_usage($options, "{import.params}");
104 die "\n";
105 }
106
107 $self->{'close_out'} = 0;
108 my $out = $self->{'out'};
109 if ($out !~ /^(STDERR|STDOUT)$/i) {
110 open (OUT, ">$out") ||
111 (&gsprintf(STDERR, "{common.cannot_open_output_file}: $!\n", $out) && die);
112 $out = 'inexport::OUT';
113 $self->{'close_out'} = 1;
114 }
115 $out->autoflush(1);
116 $self->{'out'} = $out;
117
118 # @ARGV should be only one item, the name of the collection
119 $self->{'collection'} = shift @$argv;
120
121 if ((defined $self->{'jobs'}) && ($self->{'jobs'}>1)) {
122 require ParallelInexport;
123 }
124
125 return bless $self, $class;
126}
127
128# Simplified version of the contstructor for use with CGI scripts
129sub newCGI
130{
131 my $class = shift (@_);
132 my ($mode,$collect,$gsdl_cgi,$opt_site) = @_;
133
134 my $self = { 'xml' => 0, 'mode' => $mode };
135
136 $self->{'out'} = STDERR;
137
138 if (defined $gsdl_cgi) {
139 $self->{'site'} = $opt_site;
140 my $collect_dir = $gsdl_cgi->get_collection_dir($opt_site);
141 $self->{'collectdir'} = $collect_dir;
142 }
143 else {
144 $self->{'site'} = "";
145 $self->{'collectdir'} = &util::filename_cat($ENV{'GSDLHOME'},"collect");
146 }
147 $self->{'faillog'} = "";
148
149 $self->{'collection'} = $collect;
150
151 return bless $self, $class;
152}
153sub get_collection
154{
155 my $self = shift @_;
156
157 return $self->{'collection'};
158}
159
160
161sub read_collection_cfg
162{
163 my $self = shift @_;
164 my ($collection,$options) = @_;
165
166 my $collectdir = $self->{'collectdir'};
167 my $site = $self->{'site'};
168 my $out = $self->{'out'};
169
170 if (($collection = &colcfg::use_collection($site, $collection, $collectdir)) eq "") {
171 &PrintUsage::print_txt_usage($options, "{import.params}");
172 die "\n";
173 }
174
175 # set gs_verison 2/3
176 $self->{'gs_version'} = "2";
177 if ((defined $site) && ($site ne "")) {
178 # gs3
179 $self->{'gs_version'} = "3";
180 }
181 # add collection's perllib dir into include path in
182 # case we have collection specific modules
183 unshift (@INC, "$ENV{'GSDLCOLLECTDIR'}/perllib");
184
185 # check that we can open the faillog
186 my $faillog = $self->{'faillog'};
187 if ($faillog eq "") {
188 $faillog = &util::filename_cat($ENV{'GSDLCOLLECTDIR'}, "etc", "fail.log");
189 }
190 open (FAILLOG, ">$faillog") ||
191 (&gsprintf(STDERR, "{import.cannot_open_fail_log}\n", $faillog) && die);
192
193
194 my $faillogname = $faillog;
195 $faillog = 'inexport::FAILLOG';
196 $faillog->autoflush(1);
197 $self->{'faillog'} = $faillog;
198 $self->{'faillogname'} = $faillogname;
199
200 # Read in the collection configuration file.
201 my ($config_filename, $gs_mode) = &colcfg::get_collect_cfg_name($out);
202 my $collectcfg = &colcfg::read_collection_cfg ($config_filename, $gs_mode);
203
204 return ($config_filename,$collectcfg);
205}
206
207sub set_collection_options
208{
209 my $self = shift @_;
210 my ($collectcfg) = @_;
211
212 my $inexport_mode = $self->{'mode'};
213
214 my $verbosity = $self->{'verbosity'};
215 my $debug = $self->{'debug'};
216 my $importdir = $self->{'importdir'};
217 my $archivedir = $self->{'archivedir'} || $self->{'exportdir'} || "";
218 my $out = $self->{'out'};
219
220 # If the infodbtype value wasn't defined in the collect.cfg file, use the default
221 if (!defined($collectcfg->{'infodbtype'}))
222 {
223 $collectcfg->{'infodbtype'} = &dbutil::get_default_infodb_type();
224 }
225 if ($collectcfg->{'infodbtype'} eq "gdbm-txtgz") {
226 # we can't use the text version for archives dbs.
227 $collectcfg->{'infodbtype'} = "gdbm";
228 }
229 if (defined $collectcfg->{'importdir'} && $importdir eq "") {
230 $importdir = $collectcfg->{'importdir'};
231 }
232 if (defined $collectcfg->{'archivedir'} && $archivedir eq "") {
233 $archivedir = $collectcfg->{'archivedir'};
234 }
235 # fill in the default import and archives directories if none
236 # were supplied, turn all \ into / and remove trailing /
237 $importdir = &util::filename_cat ($ENV{'GSDLCOLLECTDIR'}, "import") if $importdir eq "";
238 $importdir =~ s/[\\\/]+/\//g;
239 $importdir =~ s/\/$//;
240 if (!-e $importdir) {
241 &gsprintf($out, "{import.no_import_dir}\n\n", $importdir);
242 die "\n";
243 }
244 $self->{'importdir'} = $importdir;
245
246 if ($archivedir eq "") {
247 if ($inexport_mode eq "import") {
248 $archivedir = &util::filename_cat ($ENV{'GSDLCOLLECTDIR'}, "archives");
249 }
250 elsif ($inexport_mode eq "export") {
251 $archivedir = &util::filename_cat ($ENV{'GSDLCOLLECTDIR'}, "export");
252 }
253 else {
254 print STDERR "Warning: Unrecognized import/export mode '$inexport_mode'\n";
255 print STDERR " Defaulting to 'archives' for file output\n";
256 $archivedir = &util::filename_cat ($ENV{'GSDLCOLLECTDIR'}, "archives");
257 }
258 }
259
260 $archivedir =~ s/[\\\/]+/\//g;
261 $archivedir =~ s/\/$//;
262 $self->{'archivedir'} = $archivedir;
263
264 if ($verbosity !~ /\d+/) {
265 if (defined $collectcfg->{'verbosity'} && $collectcfg->{'verbosity'} =~ /\d+/) {
266 $verbosity = $collectcfg->{'verbosity'};
267 } else {
268 $verbosity = 2; # the default
269 }
270 }
271 $self->{'verbosity'} = $verbosity;
272
273 if (defined $collectcfg->{'manifest'} && $self->{'manifest'} eq "") {
274 $self->{'manifest'} = $collectcfg->{'manifest'};
275 }
276
277 if (defined $collectcfg->{'gzip'} && !$self->{'gzip'}) {
278 if ($collectcfg->{'gzip'} =~ /^true$/i) {
279 $self->{'gzip'} = 1;
280 }
281 }
282
283 if ($self->{'maxdocs'} !~ /\-?\d+/) {
284 if (defined $collectcfg->{'maxdocs'} && $collectcfg->{'maxdocs'} =~ /\-?\d+/) {
285 $self->{'maxdocs'} = $collectcfg->{'maxdocs'};
286 } else {
287 $self->{'maxdocs'} = -1; # the default
288 }
289 }
290
291 if ((defined $self->{'groupsize'}) && ($self->{'groupsize'} == 1)) {
292 if (defined $collectcfg->{'groupsize'} && $collectcfg->{'groupsize'} =~ /\d+/) {
293 $self->{'groupsize'} = $collectcfg->{'groupsize'};
294 }
295 }
296
297 if (!defined $self->{'OIDtype'}
298 || ($self->{'OIDtype'} !~ /^(hash|incremental|assigned|dirname)$/ )) {
299 if (defined $collectcfg->{'OIDtype'}
300 && $collectcfg->{'OIDtype'} =~ /^(hash|incremental|assigned|dirname)$/) {
301 $self->{'OIDtype'} = $collectcfg->{'OIDtype'};
302 } else {
303 $self->{'OIDtype'} = "hash"; # the default
304 }
305 }
306
307 if ((!defined $self->{'OIDmetadata'}) || ($self->{'OIDmetadata'} eq "")) {
308 if (defined $collectcfg->{'OIDmetadata'}) {
309 $self->{'OIDmetadata'} = $collectcfg->{'OIDmetadata'};
310 } else {
311 $self->{'OIDmetadata'} = "dc.Identifier"; # the default
312 }
313 }
314
315 my $sortmeta = $self->{'sortmeta'};
316 if (defined $collectcfg->{'sortmeta'} && (!defined $sortmeta || $sortmeta eq "")) {
317 $sortmeta = $collectcfg->{'sortmeta'};
318 }
319 # sortmeta cannot be used with group size
320 $sortmeta = undef unless defined $sortmeta && $sortmeta =~ /\S/;
321 if (defined $sortmeta && $self->{'groupsize'} > 1) {
322 &gsprintf($out, "{import.cannot_sort}\n\n");
323 $sortmeta = undef;
324 }
325 $self->{'sortmeta'} = $sortmeta;
326
327 if (defined $collectcfg->{'removeprefix'} && $self->{'removeprefix'} eq "") {
328 $self->{'removeprefix'} = $collectcfg->{'removeprefix'};
329 }
330
331 if (defined $collectcfg->{'removesuffix'} && $self->{'removesuffix'} eq "") {
332 $self->{'removesuffix'} = $collectcfg->{'removesuffix'};
333 }
334 if (defined $collectcfg->{'debug'} && $collectcfg->{'debug'} =~ /^true$/i) {
335 $self->{'debug'} = 1;
336 }
337 if (defined $collectcfg->{'gli'} && $collectcfg->{'gli'} =~ /^true$/i) {
338 $self->{'gli'} = 1;
339 }
340 $self->{'gli'} = 0 unless defined $self->{'gli'};
341
342 # check keepold and removeold
343 my $checkdir = ($inexport_mode eq "import") ? "archives" : "export";
344
345 my ($removeold, $keepold, $incremental, $incremental_mode)
346 = &scriptutil::check_removeold_and_keepold($self->{'removeold'}, $self->{'keepold'},
347 $self->{'incremental'}, $checkdir,
348 $collectcfg);
349
350 $self->{'removeold'} = $removeold;
351 $self->{'keepold'} = $keepold;
352 $self->{'incremental'} = $incremental;
353 $self->{'incremental_mode'} = $incremental_mode;
354}
355
356sub process_files
357{
358 my $self = shift @_;
359 my ($config_filename,$collectcfg) = @_;
360
361 my $inexport_mode = $self->{'mode'};
362
363 my $verbosity = $self->{'verbosity'};
364 my $debug = $self->{'debug'};
365
366 my $importdir = $self->{'importdir'};
367 my $archivedir = $self->{'archivedir'} || $self->{'exportdir'};
368
369 my $incremental = $self->{'incremental'};
370 my $incremental_mode = $self->{'incremental_mode'};
371
372 my $gs_version = $self->{'gs_version'};
373
374 my $removeold = $self->{'removeold'};
375 my $keepold = $self->{'keepold'};
376
377 my $saveas = $self->{'saveas'};
378 my $OIDtype = $self->{'OIDtype'};
379 my $OIDmetadata = $self->{'OIDmetadata'};
380
381 my $out = $self->{'out'};
382 my $faillog = $self->{'faillog'};
383
384 my $maxdocs = $self->{'maxdocs'};
385 my $gzip = $self->{'gzip'};
386 my $groupsize = $self->{'groupsize'};
387 my $sortmeta = $self->{'sortmeta'};
388
389 my $removeprefix = $self->{'removeprefix'};
390 my $removesuffix = $self->{'removesuffix'};
391
392 my $gli = $self->{'gli'};
393
394 my $jobs = $self->{'jobs'};
395 my $epoch = $self->{'epoch'};
396
397 # related to export
398 my $xsltfile = $self->{'xsltfile'};
399 my $group_marc = $self->{'group_marc'};
400 my $mapping_file = $self->{'mapping_file'};
401 my $xslt_mets = $self->{'xslt_mets'};
402 my $xslt_txt = $self->{'xslt_txt'};
403 my $fedora_namespace = $self->{'fedora_namespace'};
404 my $metadata_prefix = $self->{'metadata_prefix'};
405
406 if ($inexport_mode eq "import") {
407 print STDERR "<Import>\n" if $gli;
408 }
409 else {
410 print STDERR "<export>\n" if $gli;
411 }
412
413 my $manifest_lookup = new manifest($collectcfg->{'infodbtype'},$archivedir);
414 if ($self->{'manifest'} ne "") {
415 my $manifest_filename = $self->{'manifest'};
416
417 if (!&util::filename_is_absolute($manifest_filename)) {
418 $manifest_filename = &util::filename_cat ($ENV{'GSDLCOLLECTDIR'}, $manifest_filename);
419 }
420
421 $self->{'manifest'} =~ s/[\\\/]+/\//g;
422 $self->{'manifest'} =~ s/\/$//;
423
424 $manifest_lookup->parse($manifest_filename);
425 }
426
427 my $manifest = $self->{'manifest'};
428
429 # load all the plugins
430 my $plugins = [];
431 if (defined $collectcfg->{'plugin'}) {
432 $plugins = $collectcfg->{'plugin'};
433 }
434
435 my $plugin_incr_mode = $incremental_mode;
436 if ($manifest ne "") {
437 # if we have a manifest file, then we pretend we are fully incremental for plugins
438 $plugin_incr_mode = "all";
439 }
440 #some global options for the plugins
441 my @global_opts = ();
442
443 my $pluginfo = &plugin::load_plugins ($plugins, $verbosity, $out, $faillog, \@global_opts, $plugin_incr_mode, $gs_version);
444 if (scalar(@$pluginfo) == 0) {
445 &gsprintf($out, "{import.no_plugins_loaded}\n");
446 die "\n";
447 }
448
449 # remove the old contents of the archives directory (and tmp
450 # directory) if needed
451
452 if ($removeold) {
453 if (-e $archivedir) {
454 &gsprintf($out, "{import.removing_archives}\n");
455 &util::rm_r ($archivedir);
456 }
457 my $tmpdir = &util::filename_cat ($ENV{'GSDLCOLLECTDIR'}, "tmp");
458 $tmpdir =~ s/[\\\/]+/\//g;
459 $tmpdir =~ s/\/$//;
460 if (-e $tmpdir) {
461 &gsprintf($out, "{import.removing_tmpdir}\n");
462 &util::rm_r ($tmpdir);
463 }
464 }
465
466 # create the archives dir if needed
467 &util::mk_all_dir($archivedir);
468
469 # read the archive information file
470
471 # BACKWARDS COMPATIBILITY: Just in case there are old .ldb/.bdb files (won't do anything for other infodbtypes)
472 &util::rename_ldb_or_bdb_file(&util::filename_cat($archivedir, "archiveinf-doc"));
473 &util::rename_ldb_or_bdb_file(&util::filename_cat($archivedir, "archiveinf-src"));
474
475 my $arcinfo_doc_filename = &dbutil::get_infodb_file_path($collectcfg->{'infodbtype'}, "archiveinf-doc", $archivedir);
476 my $arcinfo_src_filename = &dbutil::get_infodb_file_path($collectcfg->{'infodbtype'}, "archiveinf-src", $archivedir);
477
478 my $archive_info = new arcinfo ($collectcfg->{'infodbtype'});
479 $archive_info->load_info ($arcinfo_doc_filename);
480
481 if ($manifest eq "") {
482 # Load in list of files in import folder from last import (if present)
483 $archive_info->load_prev_import_filelist ($arcinfo_src_filename);
484 }
485
486 ####Use Plugout####
487 my $plugout;
488
489 if ($inexport_mode eq "import") {
490 if (defined $collectcfg->{'plugout'}) {
491 # If a plugout was specified in the collect.cfg file, assume it is sensible
492 # We can't check the name because it could be anything, if it is a custom plugout
493 $plugout = $collectcfg->{'plugout'};
494 }
495 else{
496 if ($saveas !~ /^(GreenstoneXML|GreenstoneMETS)$/) {
497 push @$plugout,"GreenstoneXMLPlugout";
498 }
499 else{
500 push @$plugout,$saveas."Plugout";
501 }
502 }
503 }
504 else {
505 if (defined $collectcfg->{'plugout'} && $collectcfg->{'plugout'} =~ /^(.*METS|DSpace|MARCXML)Plugout/) {
506 $plugout = $collectcfg->{'plugout'};
507 }
508 else{
509 if ($saveas !~ /^(GreenstoneMETS|FedoraMETS|DSpace|MARCXML)$/) {
510 push @$plugout,"GreenstoneMETSPlugout";
511 }
512 else{
513 push @$plugout,$saveas."Plugout";
514 }
515 }
516 }
517
518 my $plugout_name = $plugout->[0];
519
520 push @$plugout,("-output_info",$archive_info) if (defined $archive_info);
521 push @$plugout,("-verbosity",$verbosity) if (defined $verbosity);
522 push @$plugout,("-debug") if ($debug);
523 push @$plugout,("-group_size",$groupsize) if (defined $groupsize);
524 push @$plugout,("-gzip_output") if ($gzip);
525 push @$plugout,("-output_handle",$out) if (defined $out);
526
527 push @$plugout,("-xslt_file",$xsltfile) if (defined $xsltfile && $xsltfile ne "");
528
529 if ($plugout_name =~ m/^MARCXMLPlugout$/) {
530 push @$plugout,("-group") if ($group_marc);
531 push @$plugout,("-mapping_file",$mapping_file) if (defined $mapping_file && $mapping_file ne "");
532 }
533 if ($plugout_name =~ m/^.*METSPlugout$/) {
534 push @$plugout,("-xslt_mets",$xslt_mets) if (defined $xslt_mets && $xslt_mets ne "");
535 push @$plugout,("-xslt_txt",$xslt_txt) if (defined $xslt_txt && $xslt_txt ne "");
536 }
537
538 if ($plugout_name eq "FedoraMETSPlugout") {
539 push @$plugout,("-fedora_namespace",$fedora_namespace) if (defined $fedora_namespace && $fedora_namespace ne "");
540 }
541
542 if ($plugout_name eq "DSpacePlugout") {
543 push @$plugout,("-metadata_prefix",$metadata_prefix) if (defined $metadata_prefix && $metadata_prefix ne "");
544 }
545
546 my $processor = &plugout::load_plugout($plugout);
547 $processor->setoutputdir ($archivedir);
548 $processor->set_sortmeta ($sortmeta, $removeprefix, $removesuffix) if defined $sortmeta;
549 $processor->set_OIDtype ($OIDtype, $OIDmetadata);
550
551 &plugin::begin($pluginfo, $importdir, $processor, $maxdocs, $gli);
552
553 if ($removeold) {
554 # occasionally, plugins may want to do something on remove
555 # old, eg pharos image indexing
556 &plugin::remove_all($pluginfo, $importdir, $processor, $maxdocs, $gli);
557 }
558
559 # process the import directory
560 my $block_hash = {};
561 $block_hash->{'new_files'} = {};
562 $block_hash->{'reindex_files'} = {};
563 my $metadata = {};
564
565 # global blocking pass may set up some metadata
566 &plugin::file_block_read($pluginfo, $importdir, "", $block_hash, $metadata, $gli);
567
568 if ($manifest ne "") {
569 #
570 # 1. Process delete files first
571 #
572 my @deleted_files = keys %{$manifest_lookup->{'delete'}};
573 my @full_deleted_files = ();
574
575 # ensure all filenames are absolute
576 foreach my $df (@deleted_files) {
577 my $full_df =
578 (&util::filename_is_absolute($df))
579 ? $df
580 : &util::filename_cat($importdir,$df);
581
582 if (-d $full_df) {
583 &add_dir_contents_to_list($full_df, \@full_deleted_files);
584 } else {
585 push(@full_deleted_files,$full_df);
586 }
587 }
588
589 &plugin::remove_some($pluginfo, $collectcfg->{'infodbtype'}, $archivedir, \@full_deleted_files);
590 mark_docs_for_deletion($archive_info,{},
591 \@full_deleted_files,
592 $archivedir, $verbosity, "delete");
593
594
595 #
596 # 2. Now files for reindexing
597 #
598
599 my @reindex_files = keys %{$manifest_lookup->{'reindex'}};
600 my @full_reindex_files = ();
601 # ensure all filenames are absolute
602 foreach my $rf (@reindex_files) {
603 my $full_rf =
604 (&util::filename_is_absolute($rf))
605 ? $rf
606 : &util::filename_cat($importdir,$rf);
607
608 if (-d $full_rf) {
609 &add_dir_contents_to_list($full_rf, \@full_reindex_files);
610 } else {
611 push(@full_reindex_files,$full_rf);
612 }
613 }
614
615 &plugin::remove_some($pluginfo, $collectcfg->{'infodbtype'}, $archivedir, \@full_reindex_files);
616 mark_docs_for_deletion($archive_info,{},\@full_reindex_files, $archivedir,$verbosity, "reindex");
617
618 # And now to ensure the new version of the file processed by
619 # appropriate plugin, we need to add it to block_hash reindex list
620 foreach my $full_rf (@full_reindex_files) {
621 $block_hash->{'reindex_files'}->{$full_rf} = 1;
622 }
623
624
625 #
626 # 3. Now finally any new files - add to block_hash new_files list
627 #
628
629 my @new_files = keys %{$manifest_lookup->{'index'}};
630 my @full_new_files = ();
631
632 foreach my $nf (@new_files) {
633 # ensure filename is absolute
634 my $full_nf =
635 (&util::filename_is_absolute($nf))
636 ? $nf
637 : &util::filename_cat($importdir,$nf);
638
639 if (-d $full_nf) {
640 &add_dir_contents_to_list($full_nf, \@full_new_files);
641 } else {
642 push(@full_new_files,$full_nf);
643 }
644 }
645
646 my $arcinfo_src_filename = &dbutil::get_infodb_file_path($collectcfg->{'infodbtype'}, "archiveinf-src", $archivedir);
647 my $arcinfodb_map = {};
648 &dbutil::read_infodb_file($collectcfg->{'infodbtype'}, $arcinfo_src_filename, $arcinfodb_map);
649 foreach my $f (@full_new_files) {
650 # check that we haven't seen it already
651 if (defined $arcinfodb_map->{$f}) {
652 # TODO make better warning
653 print STDERR "Warning: $f already in src archive, \n";
654 } else {
655 $block_hash->{'new_files'}->{$f} = 1;
656 }
657 }
658
659 undef $arcinfodb_map;
660 }
661 else {
662 # if incremental, we read through the import folder to see whats changed.
663
664 if ($incremental || $incremental_mode eq "onlyadd") {
665 prime_doc_oid_count($archivedir);
666
667 # Can now work out which files were new, already existed, and have
668 # been deleted
669
670 new_vs_old_import_diff($archive_info,$block_hash,$importdir,
671 $archivedir,$verbosity,$incremental_mode);
672
673 my @new_files = sort keys %{$block_hash->{'new_files'}};
674 if (scalar(@new_files>0)) {
675 print STDERR "New files and modified metadata files since last import:\n ";
676 print STDERR join("\n ",@new_files), "\n";
677 }
678
679 if ($incremental) {
680 # only look for deletions if we are truely incremental
681 my @deleted_files = sort keys %{$block_hash->{'deleted_files'}};
682 # Filter out any in gsdl/tmp area
683 my @filtered_deleted_files = ();
684 my $gsdl_tmp_area = &util::filename_cat($ENV{'GSDLHOME'}, "tmp");
685 my $collect_tmp_area = &util::filename_cat($ENV{'GSDLCOLLECTDIR'}, "tmp");
686 $gsdl_tmp_area = &util::filename_to_regex($gsdl_tmp_area);
687 $collect_tmp_area = &util::filename_to_regex($collect_tmp_area);
688
689 foreach my $df (@deleted_files) {
690 next if ($df =~ m/^$gsdl_tmp_area/);
691 next if ($df =~ m/^$collect_tmp_area/);
692
693 push(@filtered_deleted_files,$df);
694 }
695
696
697 @deleted_files = @filtered_deleted_files;
698
699 if (scalar(@deleted_files)>0) {
700 print STDERR "Files deleted since last import:\n ";
701 print STDERR join("\n ",@deleted_files), "\n";
702
703
704 &plugin::remove_some($pluginfo, $collectcfg->{'infodbtype'}, $archivedir, \@deleted_files);
705
706 mark_docs_for_deletion($archive_info,$block_hash,\@deleted_files, $archivedir,$verbosity, "delete");
707 }
708
709 my @reindex_files = sort keys %{$block_hash->{'reindex_files'}};
710
711 if (scalar(@reindex_files)>0) {
712 print STDERR "Files to reindex since last import:\n ";
713 print STDERR join("\n ",@reindex_files), "\n";
714 &plugin::remove_some($pluginfo, $collectcfg->{'infodbtype'}, $archivedir, \@reindex_files);
715 mark_docs_for_deletion($archive_info,$block_hash,\@reindex_files, $archivedir,$verbosity, "reindex");
716 }
717
718 }
719 }
720 }
721
722 # Check for existence of the file that's to contain earliestDateStamp in archivesdir
723 # Do nothing if the file already exists (file exists on incremental build).
724 # If the file doesn't exist, as happens on full build, create it and write out the current datestamp into it
725 # In buildcol, read the file's contents and set the earliestdateStamp in GS2's build.cfg / GS3's buildconfig.xml
726 # In doc.pm have set_oaiLastModified similar to set_lastmodified, and create the doc fields
727 # oailastmodified and oailastmodifieddate
728 my $earliestDatestampFile = &util::filename_cat($archivedir, "earliestDatestamp");
729 if (!-f $earliestDatestampFile && -d $archivedir) {
730 my $current_time_in_seconds = time; # in seconds
731
732 if(open(FOUT, ">$earliestDatestampFile")) {
733 # || (&gsprintf(STDERR, "{common.cannot_open}: $!\n", $earliestDatestampFile) && die);
734 print FOUT $current_time_in_seconds;
735 close(FOUT);
736 }
737 else {
738 &gsprintf(STDERR, "{import.cannot_write_earliestdatestamp}\n", $earliestDatestampFile);
739 }
740
741 }
742
743 # now, whichever mode we are in, we can process the entire import folder
744 if ((defined $jobs) && ($jobs > 1))
745 {
746 # if jobs are set to >1, run in parallel using MPI helper
747 # [hs, 1 july 2010]
748 &ParallelInexport::farm_out_processes($jobs, $epoch, $importdir, $block_hash,
749 $self->{'collection'}, $self->{'site'});
750 }
751 else
752 {
753 &plugin::read ($pluginfo, $importdir, "", $block_hash, $metadata, $processor, $maxdocs, 0, $gli);
754 }
755
756
757 if ($saveas eq "FedoraMETS") {
758 # create collection "doc obj" for Fedora that contains
759 # collection-level metadata
760
761 my $doc_obj = new doc($config_filename,"nonindexed_doc","none");
762 $doc_obj->set_OID("collection");
763
764 my $col_name = undef;
765 my $col_meta = $collectcfg->{'collectionmeta'};
766
767 if (defined $col_meta) {
768 store_collectionmeta($col_meta,"collectionname",$doc_obj); # in GS3 this is a collection's name
769 store_collectionmeta($col_meta,"collectionextra",$doc_obj); # in GS3 this is a collection's description
770 }
771 $processor->process($doc_obj);
772 }
773
774 &plugin::end($pluginfo, $processor);
775
776 &plugin::deinit($pluginfo, $processor);
777
778 # Store the value of OIDCount (used in doc.pm) so it can be
779 # restored correctly to this value on an incremental build
780 store_doc_oid_count($archivedir);
781
782 # write out the archive information file
783 $processor->close_file_output() if (defined $groupsize) && ($groupsize > 1);
784 $processor->close_group_output() if $processor->is_group();
785
786 # for backwards compatability with archvies.inf file
787 if ($arcinfo_doc_filename =~ m/(contents)|(\.inf)$/) {
788 $archive_info->save_info($arcinfo_doc_filename);
789 }
790 else {
791 $archive_info->save_revinfo_db($arcinfo_src_filename);
792 }
793
794 return $pluginfo;
795}
796
797
798sub generate_statistics
799{
800 my $self = shift @_;
801 my ($pluginfo) = @_;
802
803 my $inexport_mode = $self->{'mode'};
804
805 my $statsfile = $self->{'statsfile'};
806 my $out = $self->{'out'};
807 my $faillogname = $self->{'faillogname'};
808 my $gli = $self->{'gli'};
809 my $jobs = $self->{'jobs'};
810
811 # write out import stats
812
813 if ((!defined $jobs) || ($jobs == 1))
814 {
815 # only output statistics if there are multiple jobs
816 # [hs, 1 july 2010]
817
818 my $close_stats = 0;
819 if ($statsfile !~ /^(STDERR|STDOUT)$/i) {
820 if (open (STATS, ">$statsfile")) {
821 $statsfile = 'inexport::STATS';
822 $close_stats = 1;
823 } else {
824 &gsprintf($out, "{import.cannot_open_stats_file}", $statsfile);
825 &gsprintf($out, "{import.stats_backup}\n");
826 $statsfile = 'STDERR';
827 }
828 }
829
830 &gsprintf($out, "\n");
831 &gsprintf($out, "*********************************************\n");
832 &gsprintf($out, "{$inexport_mode.complete}\n");
833 &gsprintf($out, "*********************************************\n");
834
835 &plugin::write_stats($pluginfo, $statsfile, $faillogname, $gli);
836 if ($close_stats) {
837 close STATS;
838 }
839 }
840
841 close OUT if $self->{'close_out'};
842 close FAILLOG;
843}
844
845
846sub store_collectionmeta
847{
848 my ($collectionmeta,$field,$doc_obj) = @_;
849
850 my $section = $doc_obj->get_top_section();
851
852 my $field_hash = $collectionmeta->{$field};
853
854 foreach my $k (keys %$field_hash)
855 {
856 my $val = $field_hash->{$k};
857
858 ### print STDERR "*** $k = $field_hash->{$k}\n";
859
860 my $md_label = "ex.$field";
861
862
863 if ($k =~ m/^\[l=(.*?)\]$/)
864 {
865
866 my $md_suffix = $1;
867 $md_label .= "^$md_suffix";
868 }
869
870
871 $doc_obj->add_utf8_metadata($section,$md_label, $val);
872
873 # see collConfigxml.pm: GS2's "collectionextra" is called "description" in GS3,
874 # while "collectionname" in GS2 is called "name" in GS3.
875 # Variable $nameMap variable in collConfigxml.pm maps between GS2 and GS3
876 if (($md_label eq "ex.collectionname^en") || ($md_label eq "ex.collectionname"))
877 {
878 $doc_obj->add_utf8_metadata($section,"dc.Title", $val);
879 }
880
881 }
882}
883
884
885sub oid_count_file {
886 my ($archivedir) = @_;
887 return &util::filename_cat ($archivedir, "OIDcount");
888}
889
890
891sub prime_doc_oid_count
892{
893 my ($archivedir) = @_;
894 my $oid_count_filename = &oid_count_file($archivedir);
895
896 if (-e $oid_count_filename) {
897 if (open(OIDIN,"<$oid_count_filename")) {
898 my $OIDcount = <OIDIN>;
899 chomp $OIDcount;
900 close(OIDIN);
901
902 $doc::OIDcount = $OIDcount;
903 }
904 else {
905 &gsprintf(STDERR, "{import.cannot_read_OIDcount}\n", $oid_count_filename);
906 }
907 }
908
909}
910
911sub store_doc_oid_count
912{
913 # Use the file "OIDcount" in the archives directory to record
914 # what value doc.pm got up to
915
916 my ($archivedir) = @_;
917 my $oid_count_filename = &oid_count_file($archivedir);
918
919
920 if (open(OIDOUT,">$oid_count_filename")) {
921 print OIDOUT $doc::OIDcount, "\n";
922
923 close(OIDOUT);
924 }
925 else {
926 &gsprintf(STDERR, "{import.cannot_write_OIDcount}\n", $oid_count_filename);
927 }
928}
929
930
931
932sub new_vs_old_import_diff
933{
934 my ($archive_info,$block_hash,$importdir,$archivedir,$verbosity,$incremental_mode) = @_;
935
936 # Get the infodbtype value for this collection from the arcinfo object
937 my $infodbtype = $archive_info->{'infodbtype'};
938
939 # in this method, we want to know if metadata files are modified or not.
940 my $arcinfo_doc_filename = &dbutil::get_infodb_file_path($infodbtype, "archiveinf-doc", $archivedir);
941
942 my $archiveinf_timestamp = -M $arcinfo_doc_filename;
943
944 # First convert all files to absolute form
945 # This is to support the situation where the import folder is not
946 # the default
947
948 my $prev_all_files = $archive_info->{'prev_import_filelist'};
949 my $full_prev_all_files = {};
950
951 foreach my $prev_file (keys %$prev_all_files) {
952
953 if (!&util::filename_is_absolute($prev_file)) {
954 my $full_prev_file = &util::filename_cat($ENV{'GSDLCOLLECTDIR'},$prev_file);
955 $full_prev_all_files->{$full_prev_file} = $prev_file;
956 }
957 else {
958 $full_prev_all_files->{$prev_file} = $prev_file;
959 }
960 }
961
962
963 # Figure out which are the new files, existing files and so
964 # by implication the files from the previous import that are not
965 # there any more => mark them for deletion
966 foreach my $curr_file (keys %{$block_hash->{'all_files'}}) {
967
968 my $full_curr_file = $curr_file;
969
970 # entry in 'all_files' is moved to either 'existing_files',
971 # 'deleted_files', 'new_files', or 'new_or_modified_metadata_files'
972
973 if (!&util::filename_is_absolute($curr_file)) {
974 # add in import dir to make absolute
975 $full_curr_file = &util::filename_cat($importdir,$curr_file);
976 }
977
978 # figure out if new file or not
979 if (defined $full_prev_all_files->{$full_curr_file}) {
980 # delete it so that only files that need deleting are left
981 delete $full_prev_all_files->{$full_curr_file};
982
983 # had it before. is it a metadata file?
984 if ($block_hash->{'metadata_files'}->{$full_curr_file}) {
985
986 # is it modified??
987 if (-M $full_curr_file < $archiveinf_timestamp) {
988 print STDERR "*** Detected a *modified metadata* file: $full_curr_file\n" if $verbosity >= 2;
989 # its newer than last build
990 $block_hash->{'new_or_modified_metadata_files'}->{$full_curr_file} = 1;
991 }
992 }
993 else {
994 if ($incremental_mode eq "all") {
995
996 # had it before
997 $block_hash->{'existing_files'}->{$full_curr_file} = 1;
998
999 }
1000 else {
1001 # Warning in "onlyadd" mode, but had it before!
1002 print STDERR "Warning: File $full_curr_file previously imported.\n";
1003 print STDERR " Treating as new file\n";
1004
1005 $block_hash->{'new_files'}->{$full_curr_file} = 1;
1006
1007 }
1008 }
1009 }
1010 else {
1011 if ($block_hash->{'metadata_files'}->{$full_curr_file}) {
1012 # the new file is the special sort of file greenstone uses
1013 # to attach metadata to src documents
1014 # i.e metadata.xml
1015 # (but note, the filename used is not constrained in
1016 # Greenstone to always be this)
1017
1018 print STDERR "*** Detected *new* metadata file: $full_curr_file\n" if $verbosity >= 2;
1019 $block_hash->{'new_or_modified_metadata_files'}->{$full_curr_file} = 1;
1020 }
1021 else {
1022 $block_hash->{'new_files'}->{$full_curr_file} = 1;
1023 }
1024 }
1025
1026
1027 delete $block_hash->{'all_files'}->{$curr_file};
1028 }
1029
1030
1031
1032
1033 # Deal with complication of new or modified metadata files by forcing
1034 # everything from this point down in the file hierarchy to
1035 # be freshly imported.
1036 #
1037 # This may mean files that have not changed are reindexed, but does
1038 # guarantee by the end of processing all new metadata is correctly
1039 # associated with the relevant document(s).
1040
1041 foreach my $new_mdf (keys %{$block_hash->{'new_or_modified_metadata_files'}}) {
1042 my ($fileroot,$situated_dir,$ext) = fileparse($new_mdf, "\\.[^\\.]+\$");
1043
1044 $situated_dir =~ s/[\\\/]+$//; # remove tailing slashes
1045 $situated_dir = &util::filename_to_regex($situated_dir); # need to escape windows slash \ and brackets in regular expression
1046
1047 # Go through existing_files, and mark anything that is contained
1048 # within 'situated_dir' to be reindexed (in case some of the metadata
1049 # attaches to one of these files)
1050
1051 my $reindex_files = [];
1052
1053 foreach my $existing_f (keys %{$block_hash->{'existing_files'}}) {
1054
1055 if ($existing_f =~ m/^$situated_dir/) {
1056
1057 print STDERR "**** Existing file $existing_f\nis located within\n$situated_dir\n";
1058
1059 push(@$reindex_files,$existing_f);
1060 $block_hash->{'reindex_files'}->{$existing_f} = 1;
1061 delete $block_hash->{'existing_files'}->{$existing_f};
1062
1063 }
1064 }
1065
1066 # metadata file needs to be in new_files list so parsed by MetadataXMLPlug
1067 # (or equivalent)
1068 $block_hash->{'new_files'}->{$new_mdf} = 1;
1069
1070 }
1071
1072 # go through remaining existing files and work out what has changed and needs to be reindexed.
1073 my @existing_files = sort keys %{$block_hash->{'existing_files'}};
1074
1075 my $reindex_files = [];
1076
1077 foreach my $existing_filename (@existing_files) {
1078 if (-M $existing_filename < $archiveinf_timestamp) {
1079 # file is newer than last build
1080
1081 my $existing_file = $existing_filename;
1082 #my $collectdir = &util::filename_cat($ENV{'GSDLCOLLECTDIR'});
1083
1084 #my $collectdir_resafe = &util::filename_to_regex($collectdir);
1085 #$existing_file =~ s/^$collectdir_resafe(\\|\/)?//;
1086
1087 print STDERR "**** Reindexing existing file: $existing_file\n";
1088
1089 push(@$reindex_files,$existing_file);
1090 $block_hash->{'reindex_files'}->{$existing_filename} = 1;
1091 }
1092
1093 }
1094
1095
1096 # By this point full_prev_all_files contains the files
1097 # mentioned in archiveinf-src.db but are not in the 'import'
1098 # folder (or whatever was specified through -importdir ...)
1099
1100 # This list can contain files that were created in the 'tmp' or
1101 # 'cache' areas (such as screen-size and thumbnail images).
1102 #
1103 # In building the final list of files to delete, we test to see if
1104 # it exists on the filesystem and if it does (unusual for a "normal"
1105 # file in import, but possible in the case of 'tmp' files),
1106 # supress it from going into the final list
1107
1108 my $collectdir = $ENV{'GSDLCOLLECTDIR'};
1109
1110 my @deleted_files = values %$full_prev_all_files;
1111 map { my $curr_file = $_;
1112 my $full_curr_file = $curr_file;
1113
1114 if (!&util::filename_is_absolute($curr_file)) {
1115 # add in import dir to make absolute
1116
1117 $full_curr_file = &util::filename_cat($collectdir,$curr_file);
1118 }
1119
1120
1121 if (!-e $full_curr_file) {
1122 $block_hash->{'deleted_files'}->{$curr_file} = 1;
1123 }
1124 } @deleted_files;
1125
1126
1127
1128}
1129
1130
1131# this is used to delete "deleted" docs, and to remove old versions of "changed" docs
1132# $mode is 'delete' or 'reindex'
1133sub mark_docs_for_deletion
1134{
1135 my ($archive_info,$block_hash,$deleted_files,$archivedir,$verbosity,$mode) = @_;
1136
1137 my $mode_text = "deleted from index";
1138 if ($mode eq "reindex") {
1139 $mode_text = "reindexed";
1140 }
1141
1142 # Get the infodbtype value for this collection from the arcinfo object
1143 my $infodbtype = $archive_info->{'infodbtype'};
1144
1145 my $arcinfo_doc_filename = &dbutil::get_infodb_file_path($infodbtype, "archiveinf-doc", $archivedir);
1146 my $arcinfo_src_filename = &dbutil::get_infodb_file_path($infodbtype, "archiveinf-src", $archivedir);
1147
1148
1149 # record files marked for deletion in arcinfo
1150 foreach my $file (@$deleted_files) {
1151 # use 'archiveinf-src' info database file to look up all the OIDs
1152 # that this file is used in (note in most cases, it's just one OID)
1153
1154 my $src_rec = &dbutil::read_infodb_entry($infodbtype, $arcinfo_src_filename, $file);
1155 my $oids = $src_rec->{'oid'};
1156 my $file_record_deleted = 0;
1157
1158 # delete the src record
1159 my $src_infodb_file_handle = &dbutil::open_infodb_write_handle($infodbtype, $arcinfo_src_filename, "append");
1160 &dbutil::delete_infodb_entry($infodbtype, $src_infodb_file_handle, $file);
1161 &dbutil::close_infodb_write_handle($infodbtype, $src_infodb_file_handle);
1162
1163
1164 foreach my $oid (@$oids) {
1165
1166 # find the source doc (the primary file that becomes this oid)
1167 my $doc_rec = &dbutil::read_infodb_entry($infodbtype, $arcinfo_doc_filename, $oid);
1168 my $doc_source_file = $doc_rec->{'src-file'}->[0];
1169 if (!&util::filename_is_absolute($doc_source_file)) {
1170 $doc_source_file = &util::filename_cat($ENV{'GSDLCOLLECTDIR'},$doc_source_file);
1171 }
1172
1173 if ($doc_source_file ne $file) {
1174 # its an associated or metadata file
1175
1176 # mark source doc for reimport as one of its assoc files has changed or deleted
1177 $block_hash->{'reindex_files'}->{$doc_source_file} = 1;
1178
1179 }
1180 my $curr_status = $archive_info->get_status_info($oid);
1181 if (defined($curr_status) && (($curr_status ne "D"))) {
1182 if ($verbosity>1) {
1183 print STDERR "$oid ($doc_source_file) marked to be $mode_text on next buildcol.pl\n";
1184 }
1185 # mark oid for deletion (it will be deleted or reimported)
1186 $archive_info->set_status_info($oid,"D");
1187 my $val = &dbutil::read_infodb_rawentry($infodbtype, $arcinfo_doc_filename, $oid);
1188 $val =~ s/^<index-status>(.*)$/<index-status>D/m;
1189
1190 my $val_rec = &dbutil::convert_infodb_string_to_hash($val);
1191 my $doc_infodb_file_handle = &dbutil::open_infodb_write_handle($infodbtype, $arcinfo_doc_filename, "append");
1192
1193 &dbutil::write_infodb_entry($infodbtype, $doc_infodb_file_handle, $oid, $val_rec);
1194 &dbutil::close_infodb_write_handle($infodbtype, $doc_infodb_file_handle);
1195 }
1196 }
1197
1198 }
1199
1200 # now go through and check that we haven't marked any primary
1201 # files for reindex (because their associated files have
1202 # changed/deleted) when they have been deleted themselves. only in
1203 # delete mode.
1204
1205 if ($mode eq "delete") {
1206 foreach my $file (@$deleted_files) {
1207 if (defined $block_hash->{'reindex_files'}->{$file}) {
1208 delete $block_hash->{'reindex_files'}->{$file};
1209 }
1210 }
1211 }
1212
1213
1214}
1215
1216sub add_dir_contents_to_list {
1217
1218 my ($dirname, $list) = @_;
1219
1220 # Recur over directory contents.
1221 my (@dir, $subfile);
1222
1223 # find all the files in the directory
1224 if (!opendir (DIR, $dirname)) {
1225 print STDERR "inexport: WARNING - couldn't read directory $dirname\n";
1226 return -1; # error in processing
1227 }
1228 @dir = readdir (DIR);
1229 closedir (DIR);
1230
1231 for (my $i = 0; $i < scalar(@dir); $i++) {
1232 my $subfile = $dir[$i];
1233 next if ($subfile =~ m/^\.\.?$/);
1234 next if ($subfile =~ /^\.svn$/);
1235 my $full_file = &util::filename_cat($dirname, $subfile);
1236 if (-d $full_file) {
1237 &add_dir_contents_to_list($full_file, $list);
1238 } else {
1239 push (@$list, $full_file);
1240 }
1241 }
1242
1243}
1244
1245
12461;
Note: See TracBrowser for help on using the repository browser.