source: main/trunk/greenstone2/perllib/plugins/BasePlugin.pm@ 22632

Last change on this file since 22632 was 22632, checked in by mdewsnip, 14 years ago

Changed "use textcat" to a "require textcat", so it is only loaded if it is actually required.
  • Property svn:keywords set to Author Date Id Revision
File size: 37.1 KB
Line 
1###########################################################################
2#
3# BasePlugin.pm -- base class for all the import plugins
4# A component of the Greenstone digital library software
5# from the New Zealand Digital Library Project at the
6# University of Waikato, New Zealand.
7#
8# Copyright (C) 1999-2005 New Zealand Digital Library Project
9#
10# This program is free software; you can redistribute it and/or modify
11# it under the terms of the GNU General Public License as published by
12# the Free Software Foundation; either version 2 of the License, or
13# (at your option) any later version.
14#
15# This program is distributed in the hope that it will be useful,
16# but WITHOUT ANY WARRANTY; without even the implied warranty of
17# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18# GNU General Public License for more details.
19#
20# You should have received a copy of the GNU General Public License
21# along with this program; if not, write to the Free Software
22# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
23#
24###########################################################################
25
26package BasePlugin;
27
28use strict;
29no strict 'subs';
30no strict 'refs'; # allow filehandles to be variables and viceversa
31
32use File::Basename;
33
34use encodings;
35use unicode;
36use doc;
37use ghtml;
38use gsprintf 'gsprintf';
39
40use PrintInfo;
41
42BEGIN {
43 @BasePlugin::ISA = ( 'PrintInfo' );
44}
45
46# the different methods that can be applied when renaming
47# imported documents and their associated files
48our $file_rename_method_list =
49 [ { 'name' => "url",
50 'desc' => "{BasePlugin.rename_method.url}" },
51 { 'name' => "base64",
52 'desc' => "{BasePlugin.rename_method.base64}" },
53 { 'name' => "none",
54 'desc' => "{BasePlugin.rename_method.none}",
55 'hiddengli' => "yes" } ];
56
57our $encoding_list =
58 [ { 'name' => "ascii",
59 'desc' => "{BasePlugin.encoding.ascii}" },
60 { 'name' => "utf8",
61 'desc' => "{BasePlugin.encoding.utf8}" },
62 { 'name' => "unicode",
63 'desc' => "{BasePlugin.encoding.unicode}" } ];
64
65
66my $e = $encodings::encodings;
67foreach my $enc (sort {$e->{$a}->{'name'} cmp $e->{$b}->{'name'}} keys (%$e))
68{
69 my $hashEncode =
70 {'name' => $enc,
71 'desc' => $e->{$enc}->{'name'}};
72
73 push(@{$encoding_list},$hashEncode);
74}
75
76our $encoding_plus_auto_list =
77 [ { 'name' => "auto",
78 'desc' => "{BasePlugin.filename_encoding.auto}" },
79 { 'name' => "auto-language-analysis",
80 'desc' => "{BasePlugin.filename_encoding.auto_language_analysis}" }, # textcat
81 { 'name' => "auto-filesystem-encoding",
82 'desc' => "{BasePlugin.filename_encoding.auto_filesystem_encoding}" }, # locale
83 { 'name' => "auto-fl",
84 'desc' => "{BasePlugin.filename_encoding.auto_fl}" }, # locale followed by textcat
85 { 'name' => "auto-lf",
86 'desc' => "{BasePlugin.filename_encoding.auto_lf}" } ]; # texcat followed by locale
87
88push(@{$encoding_plus_auto_list},@{$encoding_list});
89
90our $oidtype_list =
91 [ { 'name' => "auto",
92 'desc' => "{BasePlugin.OIDtype.auto}" },
93 { 'name' => "hash",
94 'desc' => "{import.OIDtype.hash}" },
95 { 'name' => "assigned",
96 'desc' => "{import.OIDtype.assigned}" },
97 { 'name' => "incremental",
98 'desc' => "{import.OIDtype.incremental}" },
99 { 'name' => "dirname",
100 'desc' => "{import.OIDtype.dirname}" } ];
101
102my $arguments =
103 [ { 'name' => "process_exp",
104 'desc' => "{BasePlugin.process_exp}",
105 'type' => "regexp",
106 'deft' => "",
107 'reqd' => "no" },
108 { 'name' => "no_blocking",
109 'desc' => "{BasePlugin.no_blocking}",
110 'type' => "flag",
111 'reqd' => "no"},
112 { 'name' => "block_exp",
113 'desc' => "{BasePlugin.block_exp}",
114 'type' => "regexp",
115 'deft' => "",
116 'reqd' => "no" },
117 { 'name' => "store_original_file",
118 'desc' => "{BasePlugin.store_original_file}",
119 'type' => "flag",
120 'reqd' => "no" },
121 { 'name' => "associate_ext",
122 'desc' => "{BasePlugin.associate_ext}",
123 'type' => "string",
124 'reqd' => "no" },
125 { 'name' => "associate_tail_re",
126 'desc' => "{BasePlugin.associate_tail_re}",
127 'type' => "string",
128 'reqd' => "no" },
129 { 'name' => "OIDtype",
130 'desc' => "{import.OIDtype}",
131 'type' => "enum",
132 'list' => $oidtype_list,
133 # leave default empty so we can tell if its been set or not - if not set will use option from import.pl
134 'deft' => "auto",
135 'reqd' => "no" },
136 { 'name' => "OIDmetadata",
137 'desc' => "{import.OIDmetadata}",
138 'type' => "metadata",
139 'deft' => "dc.Identifier",
140 'reqd' => "no" },
141# { 'name' => "use_as_doc_identifier",
142# 'desc' => "{BasePlugin.use_as_doc_identifier}",
143# 'type' => "string",
144# 'reqd' => "no" ,
145# 'deft' => "" } ,
146 { 'name' => "no_cover_image",
147 'desc' => "{BasePlugin.no_cover_image}",
148 'type' => "flag",
149 'reqd' => "no" },
150 { 'name' => "filename_encoding",
151 'desc' => "{BasePlugin.filename_encoding}",
152 'type' => "enum",
153 'deft' => "auto",
154 'list' => $encoding_plus_auto_list,
155 'reqd' => "no" },
156 { 'name' => "smart_block",
157 'desc' => "{common.deprecated}. {BasePlugin.smart_block}",
158 'type' => "flag",
159 'reqd' => "no",
160 'hiddengli' => "yes" }, # deprecated, but leave in for old collections
161 { 'name' => "file_rename_method",
162 'desc' => "{BasePlugin.file_rename_method}",
163 'type' => "enum",
164 'deft' => &get_default_file_rename_method(), # by default rename imported files and assoc files using this encoding
165 'list' => $file_rename_method_list,
166 'reqd' => "no"
167 }
168
169 ];
170
171
172my $options = { 'name' => "BasePlugin",
173 'desc' => "{BasePlugin.desc}",
174 'abstract' => "yes",
175 'inherits' => "no",
176 'args' => $arguments };
177
178sub new {
179
180 my ($class) = shift (@_);
181 my ($pluginlist,$inputargs,$hashArgOptLists,$auxiliary) = @_;
182 push(@$pluginlist, $class);
183
184 push(@{$hashArgOptLists->{"ArgList"}},@{$arguments});
185 push(@{$hashArgOptLists->{"OptList"}},$options);
186
187 my $self = new PrintInfo($pluginlist, $inputargs, $hashArgOptLists,$auxiliary);
188
189 if ($self->{'info_only'}) {
190 # don't worry about any options etc
191 return bless $self, $class;
192 }
193
194 if ($self->{'smart_block'}) {
195 print STDERR "WARNING: -smart_block option has been deprecated and is no longer useful\n";
196 }
197 $self->{'smart_block'} = undef;
198
199 my $plugin_name = (defined $pluginlist->[0]) ? $pluginlist->[0] : $class;
200 $self->{'plugin_type'} = $plugin_name;
201
202 # remove ex. from OIDmetadata
203 $self->{'OIDmetadata'} =~ s/^ex\.// if defined $self->{'OIDmetadata'};
204 $self->{'num_processed'} = 0;
205 $self->{'num_not_processed'} = 0;
206 $self->{'num_blocked'} = 0;
207 $self->{'num_archives'} = 0;
208 $self->{'cover_image'} = 1; # cover image is on by default
209 $self->{'cover_image'} = 0 if ($self->{'no_cover_image'});
210 $self->{'can_process_directories'} = 0;
211 #$self->{'option_list'} = $hashArgOptLists->{"OptList"};
212
213 my $associate_ext = $self->{'associate_ext'};
214 if ((defined $associate_ext) && ($associate_ext ne "")) {
215
216 my $associate_tail_re = $self->{'associate_tail_re'};
217 if ((defined $associate_tail_re) && ($associate_tail_re ne "")) {
218 my $outhandle = $self->{'outhandle'};
219 print $outhandle "Warning: can only specify 'associate_ext' or 'associate_tail_re'\n";
220 print $outhandle " defaulting to 'associate_tail_re'\n";
221 }
222 else {
223 my @exts = split(/,/,$associate_ext);
224
225 my @exts_bracketed = map { $_ = "(?:\\.$_)" } @exts;
226 my $associate_tail_re = join("|",@exts_bracketed);
227 $self->{'associate_tail_re'} = $associate_tail_re;
228 }
229
230 delete $self->{'associate_ext'};
231 }
232
233 return bless $self, $class;
234
235}
236
237sub merge_inheritance
238{
239 my $self = {};
240 my @child_selfs = @_;
241
242 foreach my $child_self (@child_selfs) {
243 foreach my $key (keys %$child_self) {
244 if (defined $self->{$key}) {
245 if ($self->{$key} ne $child_self->{$key}) {
246# print STDERR "Warning: Conflicting value in multiple inheritance for '$key'\n";
247# print STDERR "Existing stored value = $self->{$key}\n";
248# print STDERR "New (child) value = $child_self->{$key}\n";
249# print STDERR "Keeping existing value\n";
250 # Existing value seems to be option specified in collect.cfg
251
252 ### $self->{$key} = $child_self->{$key};
253
254 }
255 else {
256## print STDERR "****Info: Value $self->{$key} for $key already defined through multiple inheritance as the same value\n";
257 }
258
259 }
260 else {
261 $self->{$key} = $child_self->{$key};
262 }
263 }
264 }
265
266 return $self;
267}
268
269# initialize BasePlugin options
270# if init() is overridden in a sub-class, remember to call BasePlugin::init()
271sub init {
272 my $self = shift (@_);
273 my ($verbosity, $outhandle, $failhandle) = @_;
274
275 # verbosity is passed through from the processor
276 $self->{'verbosity'} = $verbosity;
277
278 # as are the outhandle and failhandle
279 $self->{'outhandle'} = $outhandle if defined $outhandle;
280 $self->{'failhandle'} = $failhandle;
281# $self->SUPER::init(@_);
282
283 # set process_exp and block_exp to defaults unless they were
284 # explicitly set
285
286 if ((!$self->is_recursive()) and
287 (!defined $self->{'process_exp'}) || ($self->{'process_exp'} eq "")) {
288
289 $self->{'process_exp'} = $self->get_default_process_exp ();
290 if ($self->{'process_exp'} eq "") {
291 warn ref($self) . " Warning: Non-recursive plugin has no process_exp\n";
292 }
293 }
294
295 if ((!defined $self->{'block_exp'}) || ($self->{'block_exp'} eq "")) {
296 $self->{'block_exp'} = $self->get_default_block_exp ();
297 }
298
299}
300
301sub begin {
302 my $self = shift (@_);
303 my ($pluginfo, $base_dir, $processor, $maxdocs) = @_;
304
305 if ($self->{'OIDtype'} eq "auto") {
306 # hasn't been set in the plugin, use the processor values
307 $self->{'OIDtype'} = $processor->{'OIDtype'};
308 $self->{'OIDmetadata'} = $processor->{'OIDmetadata'};
309 }
310 if ($self->{'OIDtype'} eq "hash") {
311 # should we hash on the file or on the doc xml??
312 $self->{'OIDtype'} = $self->get_oid_hash_type();
313 if ($self->{'OIDtype'} !~ /^(hash_on_file|hash_on_ga_xml)$/) {
314 $self->{'OIDtype'} = "hash_on_file";
315 }
316 }
317}
318
319# This is called once if removeold is set with import.pl. Most plugins will do
320# nothing but if a plugin does any stuff outside of creating doc obj, then
321# it may need to clear something.
322sub remove_all {
323 my $self = shift (@_);
324 my ($pluginfo, $base_dir, $processor, $maxdocs) = @_;
325}
326
327# This is called per document for docs that have been deleted from the
328# collection. Most plugins will do nothing
329# but if a plugin does any stuff outside of creating doc obj, then it may need
330# to clear something.
331sub remove_one {
332 my $self = shift (@_);
333
334 my ($file, $oids, $archivedir) = @_;
335 return 0 if $self->can_process_this_file($file);
336 return undef;
337}
338
339sub end {
340 # potentially called at the end of each plugin pass
341 # import.pl only has one plugin pass, but buildcol.pl has multiple ones
342
343 my ($self) = shift (@_);
344}
345
346sub deinit {
347 # called only once, after all plugin passes have been done
348
349 my ($self) = @_;
350}
351
352# default hashing type is to hash on the original file (or converted file)
353# override this to return hash_on_ga_xml for filetypes where hashing on the
354# file is no good eg video
355sub get_oid_hash_type {
356
357 my $self = shift (@_);
358
359 return "hash_on_file";
360}
361
362
363# this function should be overridden to return 1
364# in recursive plugins
365sub is_recursive {
366 my $self = shift (@_);
367
368 return 0;
369}
370
371sub get_default_block_exp {
372 my $self = shift (@_);
373
374 return "";
375}
376
377sub get_default_process_exp {
378 my $self = shift (@_);
379
380 return "";
381}
382
383# rename imported files and assoc files using URL encoding by default
384# as this will work for most plugins and give more legible filenames
385sub get_default_file_rename_method() {
386 my $self = shift (@_);
387 return "url";
388}
389
390# returns this plugin's active (possibly user-selected) file_rename_method
391sub get_file_rename_method() {
392 my $self = shift (@_);
393 my $rename_method = $self->{'file_rename_method'};
394 if($rename_method) {
395 return $rename_method;
396 } else {
397 return $self->get_default_file_rename_method();
398 }
399}
400
401# default implementation is to do nothing
402sub store_block_files {
403
404 my $self =shift (@_);
405 my ($filename_full_path, $block_hash) = @_;
406
407}
408
409# put files to block into hash
410sub use_block_expressions {
411
412 my $self =shift (@_);
413 my ($filename_full_path, $block_hash) = @_;
414
415 if ($self->{'block_exp'} ne "" && $filename_full_path =~ /$self->{'block_exp'}/) {
416 $block_hash->{'file_blocks'}->{$filename_full_path} = 1;
417 }
418
419}
420
421#default implementation is to block a file with same name as this, but extension jpg or JPG, if cover_images is on.
422sub block_cover_image
423{
424 my $self =shift;
425 my ($filename, $block_hash) = @_;
426
427 if ($self->{'cover_image'}) {
428 my $coverfile = $filename;
429 $coverfile =~ s/\.[^\\\/\.]+$/\.jpg/;
430 if (!-e $coverfile) {
431 $coverfile =~ s/jpg$/JPG/;
432 }
433 if (-e $coverfile) {
434 $block_hash->{'file_blocks'}->{$coverfile} = 1;
435 }
436 }
437
438 return;
439}
440
441
442# discover all the files that should be blocked by this plugin
443# check the args ...
444sub file_block_read {
445
446 my $self = shift (@_);
447 my ($pluginfo, $base_dir, $file, $block_hash, $metadata, $gli) = @_;
448 # Keep track of filenames with same root but different extensions
449 # Used to support -associate_ext and the more generalised
450 # -associate_tail_re
451 my ($filename_full_path, $filename_no_path) = &util::get_full_filenames($base_dir, $file);
452
453 if (!-d $filename_full_path) {
454 $block_hash->{'all_files'}->{$file} = 1;
455 }
456
457 my $associate_tail_re = $self->{'associate_tail_re'};
458 if ((defined $associate_tail_re) && ($associate_tail_re ne "")) {
459 my ($file_prefix,$file_ext)
460 = &util::get_prefix_and_tail_by_regex($filename_full_path,$associate_tail_re);
461 if ((defined $file_prefix) && (defined $file_ext)) {
462 my $shared_fileroot = $block_hash->{'shared_fileroot'};
463 if (!defined $shared_fileroot->{$file_prefix}) {
464 my $file_prefix_rec = { 'tie_to' => undef,
465 'exts' => {} };
466 $shared_fileroot->{$file_prefix} = $file_prefix_rec;
467 }
468
469 my $file_prefix_rec = $shared_fileroot->{$file_prefix};
470
471 if ($self->can_process_this_file($filename_full_path)) {
472 # This is the document the others should be tied to
473 $file_prefix_rec->{'tie_to'} = $file_ext;
474 }
475 else {
476 if ($file_ext =~ m/$associate_tail_re$/) {
477 # this file should be associated to the main one
478 $file_prefix_rec->{'exts'}->{$file_ext} = 1;
479 }
480 }
481
482 }
483 }
484
485 # check block expressions
486 $self->use_block_expressions($filename_full_path, $block_hash) unless $self->{'no_blocking'};
487
488 # now check whether we are actually processing this
489 if (!-f $filename_full_path || !$self->can_process_this_file($filename_full_path)) {
490 return undef; # can't recognise
491 }
492
493 # if we have a block_exp, then this overrides the normal 'smart' blocking
494 $self->store_block_files($filename_full_path, $block_hash) unless ($self->{'no_blocking'} || $self->{'block_exp'} ne "");
495
496 # block the cover image if there is one
497 if ($self->{'cover_image'}) {
498 $self->block_cover_image($filename_full_path, $block_hash);
499 }
500
501 return 1;
502}
503
504# plugins that rely on more than process_exp (eg XML plugins) can override this method
505sub can_process_this_file {
506 my $self = shift(@_);
507 my ($filename) = @_;
508
509 if (-d $filename && !$self->{'can_process_directories'}) {
510 return 0;
511 }
512
513 if ($self->{'process_exp'} ne "" && $filename =~ /$self->{'process_exp'}/) {
514 return 1;
515 }
516 return 0;
517
518}
519
520# just converts path as is to utf8.
521sub filepath_to_utf8 {
522 my $self = shift (@_);
523 my ($file, $file_encoding) = @_;
524 my $filemeta = $file;
525
526 my $filename_encoding = $self->{'filename_encoding'}; # filename encoding setting
527
528 # Whenever filename-encoding is set to any of the auto settings, we
529 # check if the filename is already in UTF8. If it is, then we're done.
530 if($filename_encoding =~ m/auto/) {
531 if(&unicode::check_is_utf8($filemeta))
532 {
533 $filename_encoding = "utf8";
534 return $filemeta;
535 }
536 }
537
538 # Auto setting, but filename is not utf8
539 if ($filename_encoding eq "auto")
540 {
541 # try textcat
542 $filename_encoding = $self->textcat_encoding($filemeta);
543
544 # check the locale next
545 $filename_encoding = $self->locale_encoding() if $filename_encoding eq "undefined";
546
547
548 # now try the encoding of the document, if available
549 if ($filename_encoding eq "undefined" && defined $file_encoding) {
550 $filename_encoding = $file_encoding;
551 }
552
553 }
554
555 elsif ($filename_encoding eq "auto-language-analysis")
556 {
557 $filename_encoding = $self->textcat_encoding($filemeta);
558
559 # now try the encoding of the document, if available
560 if ($filename_encoding eq "undefined" && defined $file_encoding) {
561 $filename_encoding = $file_encoding;
562 }
563 }
564
565 elsif ($filename_encoding eq "auto-filesystem-encoding")
566 {
567 # try locale
568 $filename_encoding = $self->locale_encoding();
569 }
570
571 elsif ($filename_encoding eq "auto-fl")
572 {
573 # filesystem-encoding (locale) then language-analysis (textcat)
574 $filename_encoding = $self->locale_encoding();
575
576 # try textcat
577 $filename_encoding = $self->textcat_encoding($filemeta) if $filename_encoding eq "undefined";
578
579 # else assume filename encoding is encoding of file content, if that's available
580 if ($filename_encoding eq "undefined" && defined $file_encoding) {
581 $filename_encoding = $file_encoding;
582 }
583 }
584
585 elsif ($filename_encoding eq "auto-lf")
586 {
587 # language-analysis (textcat) then filesystem-encoding (locale)
588 $filename_encoding = $self->textcat_encoding($filemeta);
589
590 # guess filename encoding from encoding of file content, if available
591 if ($filename_encoding eq "undefined" && defined $file_encoding) {
592 $filename_encoding = $file_encoding;
593 }
594
595 # try locale
596 $filename_encoding = $self->locale_encoding() if $filename_encoding eq "undefined";
597 }
598
599 # if still undefined, use utf8 as fallback
600 if ($filename_encoding eq "undefined") {
601 $filename_encoding = "utf8";
602 }
603
604 #print STDERR "**** UTF8 encoding the filename $filemeta ";
605
606 # if the filename encoding is set to utf8 but it isn't utf8 already--such as when
607 # 1. the utf8 fallback is used, or 2. if the system locale is used and happens to
608 # be always utf8 (in which case the filename's encoding is also set as utf8 even
609 # though the filename need not be if it originates from another system)--in such
610 # cases attempt to make the filename utf8 to match.
611 if($filename_encoding eq "utf8" && !&unicode::check_is_utf8($filemeta)) {
612 &unicode::ensure_utf8(\$filemeta);
613 }
614
615 # convert non-unicode encodings to utf8
616 if ($filename_encoding !~ m/(?:ascii|utf8|unicode)/) {
617 $filemeta = &unicode::unicode2utf8(
618 &unicode::convert2unicode($filename_encoding, \$filemeta)
619 );
620 }
621
622 #print STDERR " from encoding $filename_encoding -> $filemeta\n";
623 return $filemeta;
624}
625
626# gets the filename with no path, converts to utf8, and then dm safes it.
627# filename_encoding set by user
628sub filename_to_utf8_metadata
629{
630 my $self = shift (@_);
631 my ($file, $file_encoding) = @_;
632
633 my $outhandle = $self->{'outhandle'};
634
635 my ($filemeta) = $file =~ /([^\\\/]+)$/; # getting the tail of the filepath (skips all string parts containing slashes upto the end)
636 $filemeta = $self->filepath_to_utf8($filemeta, $file_encoding);
637
638 my $dmsafe_filemeta = &ghtml::dmsafe($filemeta);
639
640 return $dmsafe_filemeta;
641
642}
643
644sub locale_encoding {
645 my $self = shift(@_);
646
647 if (!defined $self->{'filesystem_encoding'}) {
648 $self->{'filesystem_encoding'} = $self->get_filesystem_encoding();
649 $self->{'filesystem_encoding'} = "undefined" if !defined $self->{'filesystem_encoding'};
650 }
651
652 #print STDERR "*** filename encoding determined based on locale: " . $self->{'filesystem_encoding'} . "\n";
653 return $self->{'filesystem_encoding'}; # can be the string "undefined"
654}
655
656sub textcat_encoding {
657 my $self = shift(@_);
658 my ($filemeta) = @_;
659
660 # analyse filenames without extensions and digits (and trimmed of surrounding
661 # whitespace), so that irrelevant chars don't confuse textcat
662 my $strictfilemeta = $filemeta;
663 $strictfilemeta =~ s/\.[^\.]+$//g;
664 $strictfilemeta =~ s/\d//g;
665 $strictfilemeta =~ s/^\s*//g;
666 $strictfilemeta =~ s/\s*$//g;
667
668 my $filename_encoding = $self->encoding_from_language_analysis($strictfilemeta);
669 if(!defined $filename_encoding) {
670 $filename_encoding = "undefined";
671 }
672
673 return $filename_encoding; # can be the string "undefined"
674}
675
676# performs textcat
677sub encoding_from_language_analysis {
678 my $self = shift(@_);
679 my ($text) = @_;
680
681 my $outhandle = $self->{'outhandle'};
682 my $best_encoding = undef;
683
684 # get the language/encoding of the textstring using textcat
685 require textcat; # Only load the textcat module if it is required
686 $self->{'textcat'} = new textcat() unless defined($self->{'textcat'});
687 my $results = $self->{'textcat'}->classify_cached_filename(\$text);
688
689
690 if (scalar @$results < 0) {
691 return undef;
692 }
693
694 # We have some results, we choose the first
695 my ($language, $encoding) = $results->[0] =~ /^([^-]*)(?:-(.*))?$/;
696
697 $best_encoding = $encoding;
698 if (!defined $best_encoding) {
699 return undef;
700 }
701
702 if (defined $best_encoding && $best_encoding =~ m/^iso_8859/ && &unicode::check_is_utf8($text)) {
703 # the text is valid utf8, so assume that's the real encoding (since textcat is based on probabilities)
704 $best_encoding = 'utf8';
705 }
706
707
708 # check for equivalents where textcat doesn't have some encodings...
709 # eg MS versions of standard encodings
710 if (defined $best_encoding && $best_encoding =~ /^iso_8859_(\d+)/) {
711 my $iso = $1; # which variant of the iso standard?
712 # iso-8859 sets don't use chars 0x80-0x9f, windows codepages do
713 if ($text =~ /[\x80-\x9f]/) {
714 # Western Europe
715 if ($iso == 1 or $iso == 15) { $best_encoding = 'windows_1252' }
716 elsif ($iso == 2) {$best_encoding = 'windows_1250'} # Central Europe
717 elsif ($iso == 5) {$best_encoding = 'windows_1251'} # Cyrillic
718 elsif ($iso == 6) {$best_encoding = 'windows_1256'} # Arabic
719 elsif ($iso == 7) {$best_encoding = 'windows_1253'} # Greek
720 elsif ($iso == 8) {$best_encoding = 'windows_1255'} # Hebrew
721 elsif ($iso == 9) {$best_encoding = 'windows_1254'} # Turkish
722 }
723 }
724
725 if (defined $best_encoding && $best_encoding !~ /^(ascii|utf8|unicode)$/ &&
726 !defined $encodings::encodings->{$best_encoding})
727 {
728 if ($self->{'verbosity'}) {
729 gsprintf($outhandle, "BasePlugin: {ReadTextFile.unsupported_encoding}\n", $text, $best_encoding, "undef");
730 }
731 $best_encoding = undef;
732 }
733
734 return $best_encoding;
735}
736
737# uses locale
738sub get_filesystem_encoding {
739
740 my $self = shift(@_);
741
742 my $outhandle = $self->{'outhandle'};
743 my $filesystem_encoding = undef;
744
745 eval {
746 use POSIX qw(locale_h);
747
748 # With only one parameter, setlocale retrieves the
749 # current value
750 my $current_locale = setlocale(LC_CTYPE);
751
752 if ($current_locale =~ m/^.*\.(.*?)$/) {
753 my $char_encoding = lc($1);
754 if ($char_encoding =~ m/^(iso)(8859)(\d{1,2})$/) {
755 $char_encoding = "$1\_$2\_$3";
756 }
757
758 $char_encoding =~ s/-/_/g;
759 $char_encoding =~ s/^utf_8$/utf8/;
760
761 if ($char_encoding =~ m/^\d+$/) {
762 if (defined $encodings::encodings->{"windows_$char_encoding"}) {
763 $char_encoding = "windows_$char_encoding";
764 }
765 elsif (defined $encodings::encodings->{"dos_$char_encoding"}) {
766 $char_encoding = "dos_$char_encoding";
767 }
768 }
769
770 if (($char_encoding =~ m/(?:ascii|utf8|unicode)/)
771 || (defined $encodings::encodings->{$char_encoding})) {
772 $filesystem_encoding = $char_encoding;
773 }
774 else {
775 print $outhandle "Warning: Unsupported character encoding '$char_encoding' from locale '$current_locale'\n";
776 }
777 }
778
779
780 };
781 if ($@) {
782 print $outhandle "$@\n";
783 print $outhandle "Warning: Unable to establish locale. Will assume filesystem is UTF-8\n";
784
785 }
786 return $filesystem_encoding;
787}
788
789# is there ever only one Source? Sometimes this will be called twice, for images etc that are converted.
790sub set_Source_metadata {
791 my $self = shift (@_);
792 my ($doc_obj, $filename_no_path, $file_encoding) = @_;
793
794 my $top_section = $doc_obj->get_top_section();
795
796 # UTF-8 version of filename
797 my $filemeta = $self->filename_to_utf8_metadata($filename_no_path, $file_encoding);
798
799 # Source is the UTF8 display name - not necessarily the name of the file on the system
800 $doc_obj->set_utf8_metadata_element($top_section, "Source", $filemeta);
801
802 $filemeta = &util::rename_file($filemeta, $self->{'file_rename_method'});
803 # If using URL encoding, then SourceFile is the url-reference to url-encoded
804 # filemeta: it's a url that refers to the actual file on the system
805 $filemeta = &unicode::filename_to_url($filemeta);
806
807 $doc_obj->set_utf8_metadata_element($top_section, "SourceFile", $filemeta);
808}
809
810# this should be called by all plugins to set the oid of the doc obj, rather
811# than calling doc_obj->set_OID directly
812sub add_OID {
813 my $self = shift (@_);
814 my ($doc_obj) = @_;
815
816 $doc_obj->set_OIDtype($self->{'OIDtype'}, $self->{'OIDmetadata'});
817
818 # see if there is a plugin specific set_OID function
819 if (defined ($self->can('set_OID'))) {
820 $self->set_OID(@_); # pass through doc_obj and any extra arguments
821 }
822 else {
823 # use the default set_OID() in doc.pm
824 $doc_obj->set_OID();
825 }
826
827}
828
829# The BasePlugin read_into_doc_obj() function. This function does all the
830# right things to make general options work for a given plugin. It doesn't do anything with the file other than setting reads in
831# a file and sets up a slew of metadata all saved in doc_obj, which
832# it then returns as part of a tuple (process_status,doc_obj)
833#
834# Much of this functionality used to reside in read, but it was broken
835# down into a supporting routine to make the code more flexible.
836#
837# recursive plugins (e.g. RecPlug) and specialized plugins like those
838# capable of processing many documents within a single file (e.g.
839# GMLPlug) will normally want to implement their own version of
840# read_into_doc_obj()
841#
842# Note that $base_dir might be "" and that $file might
843# include directories
844
845# currently blocking has been done before it gets here - does this affect secondary plugin stuff??
846sub read_into_doc_obj {
847 my $self = shift (@_);
848 my ($pluginfo, $base_dir, $file, $block_hash, $metadata, $processor, $maxdocs, $total_count, $gli) = @_;
849
850 my $outhandle = $self->{'outhandle'};
851
852 # should we move this to read? What about secondary plugins?
853 print STDERR "<Processing n='$file' p='$self->{'plugin_type'}'>\n" if ($gli);
854 print $outhandle "$self->{'plugin_type'} processing $file\n"
855 if $self->{'verbosity'} > 1;
856
857 my ($filename_full_path, $filename_no_path) = &util::get_full_filenames($base_dir, $file);
858
859 # create a new document
860 my $doc_obj = new doc ($filename_full_path, "indexed_doc", $self->{'file_rename_method'});
861 my $top_section = $doc_obj->get_top_section();
862
863 $doc_obj->add_utf8_metadata($top_section, "Plugin", "$self->{'plugin_type'}");
864 $doc_obj->add_utf8_metadata($top_section, "FileSize", (-s $filename_full_path));
865
866
867 # sets the UTF8 filename (Source) for display and sets the url ref to URL encoded version
868 # of the UTF8 filename (SourceFile) for generated files
869 $self->set_Source_metadata($doc_obj, $filename_no_path);
870
871
872 # plugin specific stuff - what args do we need here??
873 unless (defined ($self->process($pluginfo, $base_dir, $file, $metadata, $doc_obj, $gli))) {
874 print STDERR "<ProcessingError n='$file'>\n" if ($gli);
875 return -1;
876 }
877
878 # include any metadata passed in from previous plugins
879 # note that this metadata is associated with the top level section
880 my $section = $doc_obj->get_top_section();
881 # can we merge these two methods??
882 $self->add_associated_files($doc_obj, $filename_full_path);
883 $self->extra_metadata ($doc_obj, $section, $metadata);
884 $self->auto_extract_metadata($doc_obj);
885
886 # if we haven't found any Title so far, assign one
887 # this was shifted to here from inside read()
888 $self->title_fallback($doc_obj,$section,$filename_no_path);
889
890 $self->add_OID($doc_obj);
891
892 $self->post_process_doc_obj($pluginfo, $base_dir, $file, $metadata, $doc_obj, $gli);
893 return (1,$doc_obj);
894}
895
896sub post_process_doc_obj {
897 my $self = shift (@_);
898 my ($pluginfo, $base_dir, $file, $metadata, $doc_obj, $gli) = @_;
899
900 return 1;
901}
902
903sub add_dummy_text {
904 my $self = shift(@_);
905 my ($doc_obj, $section) = @_;
906
907 # add NoText metadata so we can hide this dummy text in format statements
908 $doc_obj->add_metadata($section, "NoText", "1");
909 $doc_obj->add_text($section, &gsprintf::lookup_string("{BasePlugin.dummy_text}",1));
910
911}
912
913# does nothing. Can be overridden by subclass
914sub auto_extract_metadata {
915 my $self = shift(@_);
916 my ($doc_obj) = @_;
917}
918
919# adds cover image, associate_file options stuff. Should be called by sub class
920# read_into_doc_obj
921sub add_associated_files {
922 my $self = shift(@_);
923 # whatis filename??
924 my ($doc_obj, $filename) = @_;
925
926 # add in the cover image
927 if ($self->{'cover_image'}) {
928 $self->associate_cover_image($doc_obj, $filename);
929 }
930 # store the original (used for eg TextPlugin to store the original for OAI)
931 if ($self->{'store_original_file'}) {
932 $self->associate_source_file($doc_obj, $filename);
933 }
934
935
936}
937
938# implement this if you are extracting metadata for other documents
939sub metadata_read {
940 my $self = shift (@_);
941 my ($pluginfo, $base_dir, $file, $block_hash,
942 $extrametakeys, $extrametadata, $extrametafile,
943 $processor, $maxdocs, $gli) = @_;
944
945 # can we process this file??
946 my ($filename_full_path, $filename_no_path) = &util::get_full_filenames($base_dir, $file);
947 return undef unless $self->can_process_this_file($filename_full_path);
948
949 return 1; # we recognise the file, but don't actually do anything with it
950}
951
952
953# The BasePlugin read() function. This function calls read_into_doc_obj()
954# to ensure all the right things to make general options work for a
955# given plugin are done. It then calls the process() function which
956# does all the work specific to a plugin (like the old read functions
957# used to do). Most plugins should define their own process() function
958# and let this read() function keep control.
959#
960# recursive plugins (e.g. RecPlug) and specialized plugins like those
961# capable of processing many documents within a single file (e.g.
962# GMLPlug) might want to implement their own version of read(), but
963# more likely need to implement their own version of read_into_doc_obj()
964#
965# Return number of files processed, undef if can't recognise, -1 if can't
966# process
967
968sub read {
969 my $self = shift (@_);
970 my ($pluginfo, $base_dir, $file, $block_hash, $metadata, $processor, $maxdocs, $total_count, $gli) = @_;
971
972 # can we process this file??
973 my ($filename_full_path, $filename_no_path) = &util::get_full_filenames($base_dir, $file);
974
975 return undef unless $self->can_process_this_file($filename_full_path);
976
977 my ($process_status,$doc_obj) = $self->read_into_doc_obj(@_);
978
979 if ((defined $process_status) && ($process_status == 1)) {
980
981 # process the document
982 $processor->process($doc_obj);
983
984 $self->{'num_processed'} ++;
985 undef $doc_obj;
986 }
987 # delete any temp files that we may have created
988 $self->clean_up_after_doc_obj_processing();
989
990
991 # if process_status == 1, then the file has been processed.
992 return $process_status;
993
994}
995
996# returns undef if file is rejected by the plugin
997sub process {
998 my $self = shift (@_);
999 my ($textref, $pluginfo, $base_dir, $file, $metadata, $doc_obj, $gli) = @_;
1000
1001 gsprintf(STDERR, "BasePlugin::process {common.must_be_implemented}\n") && die "\n";
1002
1003 return undef; # never gets here
1004}
1005
1006# overwrite this method to delete any temp files that we have created
1007sub clean_up_after_doc_obj_processing {
1008 my $self = shift(@_);
1009
1010}
1011
1012# write_file -- used by ConvertToPlug, for example in post processing
1013#
1014# where should this go, is here the best place??
1015sub utf8_write_file {
1016 my $self = shift (@_);
1017 my ($textref, $filename) = @_;
1018
1019 if (!open (FILE, ">$filename")) {
1020 gsprintf(STDERR, "ConvertToPlug::write_file {ConvertToPlug.could_not_open_for_writing} ($!)\n", $filename);
1021 die "\n";
1022 }
1023 print FILE $$textref;
1024
1025 close FILE;
1026}
1027
1028
1029sub filename_based_title
1030{
1031 my $self = shift (@_);
1032 my ($file) = @_;
1033
1034 my $file_derived_title = $file;
1035 $file_derived_title =~ s/_/ /g;
1036 $file_derived_title =~ s/\..*?$//;
1037
1038 return $file_derived_title;
1039}
1040
1041
1042sub title_fallback
1043{
1044 my $self = shift (@_);
1045 my ($doc_obj,$section,$file) = @_;
1046
1047 if (!defined $doc_obj->get_metadata_element ($section, "Title") or $doc_obj->get_metadata_element($section, "Title") eq "") {
1048
1049 my $file_derived_title = $self->filename_to_utf8_metadata($self->filename_based_title($file));
1050 if (!defined $doc_obj->get_metadata_element ($section, "Title")) {
1051 $doc_obj->add_utf8_metadata ($section, "Title", $file_derived_title);
1052 }
1053 else {
1054 $doc_obj->set_utf8_metadata_element ($section, "Title", $file_derived_title);
1055 }
1056 }
1057
1058}
1059
1060# add any extra metadata that's been passed around from one
1061# plugin to another.
1062# extra_metadata uses add_utf8_metadata so it expects metadata values
1063# to already be in utf8
1064sub extra_metadata {
1065 my $self = shift (@_);
1066 my ($doc_obj, $cursection, $metadata) = @_;
1067
1068 my $associate_tail_re = $self->{'associate_tail_re'};
1069
1070 foreach my $field (keys(%$metadata)) {
1071 # $metadata->{$field} may be an array reference
1072 if ($field eq "gsdlassocfile_tobe") {
1073 # 'gsdlassocfile_tobe' is artificially introduced metadata
1074 # that is used to signal that certain additional files should
1075 # be tied to this document. Useful in situations where a
1076 # metadata pass in the plugin pipeline works out some files
1077 # need to be associated with a document, but the document hasn't
1078 # been formed yet.
1079 my $equiv_form = "";
1080 foreach my $gaf (@{$metadata->{$field}}) {
1081 my ($full_filename,$mimetype) = ($gaf =~ m/^(.*):(.*):$/);
1082 my ($tail_filename) = ($full_filename =~ /^.*[\/\\](.+?)$/);
1083
1084 # we need to make sure the filename is valid utf-8 - we do
1085 # this by url or base64 encoding it
1086 # $tail_filename is the name that we store the file as
1087 $tail_filename = &util::rename_file($tail_filename, $self->{'file_rename_method'});
1088 $doc_obj->associate_file($full_filename,$tail_filename,$mimetype);
1089 $doc_obj->associate_source_file($full_filename);
1090 # If the filename is url_encoded, we need to encode the % signs
1091 # in the filename, so that it works in a url
1092 my $url_tail_filename = &unicode::filename_to_url($tail_filename);
1093 # work out extended tail extension (i.e. matching tail re)
1094
1095 my ($file_prefix,$file_extended_ext)
1096 = &util::get_prefix_and_tail_by_regex($tail_filename,$associate_tail_re);
1097 my ($pre_doc_ext) = ($file_extended_ext =~ m/^(.*)\..*$/);
1098 my ($doc_ext) = ($tail_filename =~ m/^.*\.(.*)$/);
1099 my $start_doclink = "<a href=\"_httpprefix_/collect/[collection]/index/assoc/{Or}{[parent(Top):assocfilepath],[assocfilepath]}/$url_tail_filename\">";
1100 my $srcicon = "_icon".$doc_ext."_";
1101 my $end_doclink = "</a>";
1102
1103 my $assoc_form = "$start_doclink\{If\}{$srcicon,$srcicon,$doc_ext\}$end_doclink";
1104
1105 if (defined $pre_doc_ext && $pre_doc_ext ne "") {
1106 # for metadata such as [mp3._edited] [mp3._full] ...
1107 $doc_obj->add_utf8_metadata ($cursection, "$doc_ext.$pre_doc_ext", $assoc_form);
1108 }
1109
1110 # for multiple metadata such as [mp3.assoclink]
1111 $doc_obj->add_utf8_metadata ($cursection, "$doc_ext.assoclink", $assoc_form);
1112
1113 $equiv_form .= " $assoc_form";
1114 }
1115 $doc_obj->add_utf8_metadata ($cursection, "equivlink", $equiv_form);
1116 }
1117 elsif (ref ($metadata->{$field}) eq "ARRAY") {
1118 map {
1119 $doc_obj->add_utf8_metadata ($cursection, $field, $_);
1120 } @{$metadata->{$field}};
1121 } else {
1122 $doc_obj->add_utf8_metadata ($cursection, $field, $metadata->{$field});
1123 }
1124 }
1125}
1126
1127
1128sub compile_stats {
1129 my $self = shift(@_);
1130 my ($stats) = @_;
1131
1132 $stats->{'num_processed'} += $self->{'num_processed'};
1133 $stats->{'num_not_processed'} += $self->{'num_not_processed'};
1134 $stats->{'num_archives'} += $self->{'num_archives'};
1135
1136}
1137sub associate_source_file {
1138 my $self = shift(@_);
1139
1140 my ($doc_obj, $filename) = @_;
1141 my $cursection = $doc_obj->get_top_section();
1142 my $assocfilename = $doc_obj->get_assocfile_from_sourcefile();
1143
1144 $doc_obj->associate_file($filename, $assocfilename, undef, $cursection);
1145 $doc_obj->add_utf8_metadata ($cursection, "srclink_file", "[SourceFile]");
1146}
1147
1148sub associate_cover_image {
1149 my $self = shift(@_);
1150 my ($doc_obj, $filename) = @_;
1151
1152 $filename =~ s/\.[^\\\/\.]+$/\.jpg/;
1153 if (exists $self->{'covers_missing_cache'}->{$filename}) {
1154 # don't stat() for existence eg for multiple document input files
1155 # (eg SplitPlug)
1156 return;
1157 }
1158
1159 my $top_section=$doc_obj->get_top_section();
1160
1161 if (-e $filename) {
1162 $doc_obj->associate_source_file($filename);
1163 $doc_obj->associate_file($filename, "cover.jpg", "image/jpeg");
1164 $doc_obj->add_utf8_metadata($top_section, "hascover", 1);
1165 } else {
1166 my $upper_filename = $filename;
1167 $upper_filename =~ s/jpg$/JPG/;
1168 if (-e $upper_filename) {
1169 $doc_obj->associate_source_file($upper_filename);
1170 $doc_obj->associate_file($upper_filename, "cover.jpg",
1171 "image/jpeg");
1172 $doc_obj->add_utf8_metadata($top_section, "hascover", 1);
1173 } else {
1174 # file doesn't exist, so record the fact that it's missing so
1175 # we don't stat() again (stat is slow)
1176 $self->{'covers_missing_cache'}->{$filename} = 1;
1177 }
1178 }
1179
1180}
1181
1182
1183# Overridden by exploding plugins (eg. ISISPlug)
1184sub clean_up_after_exploding
1185{
1186 my $self = shift(@_);
1187}
1188
1189
1190
11911;
Note: See TracBrowser for help on using the repository browser.