source: main/trunk/greenstone2/perllib/plugins/ImageConverter.pm@ 21722

Last change on this file since 21722 was 21722, checked in by kjdon, 12 years ago

now return 1 from generate_images - PagedImagePlugin is expecting soemthing to be returned

  • Property svn:executable set to *
File size: 17.6 KB
Line 
1###########################################################################
2#
3# ImageConverter - helper plugin that does image conversion using ImageMagick
4#
5# A component of the Greenstone digital library software
6# from the New Zealand Digital Library Project at the
7# University of Waikato, New Zealand.
8#
9# Copyright (C) 2008 New Zealand Digital Library Project
10#
11# This program is free software; you can redistribute it and/or modify
12# it under the terms of the GNU General Public License as published by
13# the Free Software Foundation; either version 2 of the License, or
14# (at your option) any later version.
15#
16# This program is distributed in the hope that it will be useful,
17# but WITHOUT ANY WARRANTY; without even the implied warranty of
18# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19# GNU General Public License for more details.
20#
21# You should have received a copy of the GNU General Public License
22# along with this program; if not, write to the Free Software
23# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
24#
25###########################################################################
26package ImageConverter;
27
28use BaseMediaConverter;
29
30
31use strict;
32no strict 'refs'; # allow filehandles to be variables and viceversa
33
34use gsprintf 'gsprintf';
35
36BEGIN {
37 @ImageConverter::ISA = ('BaseMediaConverter');
38}
39
40my $arguments = [
41 { 'name' => "create_thumbnail",
42 'desc' => "{ImageConverter.create_thumbnail}",
43 'type' => "enum",
44 'list' => [{'name' => "true", 'desc' => "{common.true}"},
45 {'name' => "false", 'desc' => "{common.false}"}],
46 'deft' => "true",
47 'reqd' => "no" },
48 { 'name' => "thumbnailsize",
49 'desc' => "{ImageConverter.thumbnailsize}",
50 'type' => "int",
51 'deft' => "100",
52 'range' => "1,",
53 'reqd' => "no" },
54 { 'name' => "thumbnailtype",
55 'desc' => "{ImageConverter.thumbnailtype}",
56 'type' => "string",
57 'deft' => "gif",
58 'reqd' => "no" },
59 { 'name' => "noscaleup",
60 'desc' => "{ImageConverter.noscaleup}",
61 'type' => "flag",
62 'reqd' => "no" },
63 { 'name' => "create_screenview",
64 'desc' => "{ImageConverter.create_screenview}",
65 'type' => "enum",
66 'list' => [{'name' => "true", 'desc' => "{common.true}"},
67 {'name' => "false", 'desc' => "{common.false}"}],
68 'deft' => "true",
69 'reqd' => "no" },
70 { 'name' => "screenviewsize",
71 'desc' => "{ImageConverter.screenviewsize}",
72 'type' => "int",
73 'deft' => "500",
74 'range' => "1,",
75 'reqd' => "no" },
76 { 'name' => "screenviewtype",
77 'desc' => "{ImageConverter.screenviewtype}",
78 'type' => "string",
79 'deft' => "jpg",
80 'reqd' => "no" },
81 { 'name' => "converttotype",
82 'desc' => "{ImageConverter.converttotype}",
83 'type' => "string",
84 'deft' => "",
85 'reqd' => "no" },
86 { 'name' => "minimumsize",
87 'desc' => "{ImageConverter.minimumsize}",
88 'type' => "int",
89 'deft' => "100",
90 'range' => "1,",
91 'reqd' => "no" }
92 ];
93
94my $options = { 'name' => "ImageConverter",
95 'desc' => "{ImageConverter.desc}",
96 'abstract' => "yes",
97 'inherits' => "yes",
98 'args' => $arguments };
99
100sub new {
101 my ($class) = shift (@_);
102 my ($pluginlist,$inputargs,$hashArgOptLists) = @_;
103 push(@$pluginlist, $class);
104
105 push(@{$hashArgOptLists->{"ArgList"}},@{$arguments});
106 push(@{$hashArgOptLists->{"OptList"}},$options);
107
108 my $self = new BaseMediaConverter($pluginlist, $inputargs, $hashArgOptLists, 1);
109
110
111 return bless $self, $class;
112
113}
114
115# needs to be called after BasePlugin init, so that outhandle is set up.
116sub init {
117 my $self = shift(@_);
118
119 $self->{'tmp_file_paths'} = ();
120
121 # Check that ImageMagick is installed and available on the path
122 my $image_conversion_available = 1;
123 my $no_image_conversion_reason = "";
124 # None of this works very well on Windows 95/98...
125 if ($ENV{'GSDLOS'} eq "windows" && !Win32::IsWinNT()) {
126 $image_conversion_available = 0;
127 $no_image_conversion_reason = "win95notsupported";
128 } else {
129 my $result = `identify -help 2>&1`;
130 my $return_value = $?;
131 if ( ($ENV{'GSDLOS'} eq "windows" && $return_value == 256) || $return_value == -1) { # Linux and Windows return different values for "program not found"
132 $image_conversion_available = 0;
133 $no_image_conversion_reason = "imagemagicknotinstalled";
134 }
135 }
136 $self->{'image_conversion_available'} = $image_conversion_available;
137 $self->{'no_image_conversion_reason'} = $no_image_conversion_reason;
138
139 if ($self->{'image_conversion_available'} == 0) {
140 my $outhandle = $self->{'outhandle'};
141 &gsprintf($outhandle, "ImageConverter: {ImageConverter.noconversionavailable} ({ImageConverter.".$self->{'no_image_conversion_reason'}."})\n");
142 }
143
144}
145
146
147# convert image to new type if converttotype is set
148# generate thumbnails if required
149# generate screenview if required
150# discover image metadata
151# filename_no_path must be in utf8 and url-encoded
152sub generate_images {
153 my $self = shift(@_);
154 my ($filename_full_path, $filename_no_path, $doc_obj, $section) = @_;
155
156 # check image magick status
157 return 0 if $self->{'image_conversion_available'} == 0;
158
159 # check the filenames
160 return 0 if ($filename_no_path eq "" || !-f $filename_full_path);
161
162 if ($self->{'enable_cache'}) {
163 $self->init_cache_for_file($filename_full_path);
164 }
165 if ($self->{'store_file_paths'}) {
166 $self->{'orig_file'} = "";
167 $self->{'thumb_file'} = "";
168 $self->{'screen_file'} = "";
169 }
170 my $verbosity = $self->{'verbosity'};
171 my $outhandle = $self->{'outhandle'};
172
173 # check the size of the image against minimum size if specified
174 my $minimumsize = $self->{'minimumsize'};
175 if (defined $minimumsize && (-s $filename_full_path < $minimumsize)) {
176 print $outhandle "ImageConverter: \"$filename_full_path\" too small, skipping\n"
177 if ($verbosity > 1);
178 return 0; # or is there a better return value??
179 }
180
181 my $filehead = $filename_no_path;
182 $filehead =~ s/\.([^\.]*)$//; # filename with no extension
183 my $assocfilemeta = "[assocfilepath]";
184 if ($section ne $doc_obj->get_top_section()) {
185 $assocfilemeta = "[parent(Top):assocfilepath]";
186 }
187
188 # The images that will get generated may contain percent signs in their src filenames
189 # Encode those percent signs themselves so that urls to the imgs refer to them correctly
190 my $url_to_filehead = &unicode::filename_to_url($filehead);
191 my $url_to_filename_no_path = &unicode::filename_to_url($filename_no_path);
192
193 # Convert the image to a new type (if required).
194 my $converttotype = $self->{'converttotype'};
195 my $type = "unknown";
196
197 if ($converttotype ne "" && $filename_full_path !~ m/$converttotype$/) {
198 # $doc_obj->add_utf8_metadata($section, "Image", $utf8_filename_meta);
199
200 my ($result, $converted_filename_full_path)
201 = $self->convert($filename_full_path, $converttotype, "", "CONVERTTYPE");
202
203 $type = $converttotype;
204 $filename_full_path = $converted_filename_full_path;
205 $filename_no_path = "$filehead.$type";
206 $url_to_filename_no_path = "$url_to_filehead.$type";
207 if ($self->{'store_file_paths'}) {
208 $self->{'orig_file'} = $converted_filename_full_path;
209 }
210 }
211
212 # add Image metadata
213 $doc_obj->add_utf8_metadata($section, "Image", $url_to_filename_no_path); # url to generated image
214
215 # here we overwrite the original with the potentially converted one
216 $doc_obj->set_utf8_metadata_element($section, "Source", &unicode::url_decode($filename_no_path)); # displayname of generated image
217 $doc_obj->set_utf8_metadata_element($section, "SourceFile", $url_to_filename_no_path); # displayname of generated image
218
219 # use identify to get info about the (possibly converted) image
220 my ($image_type, $image_width, $image_height, $image_size)
221 = &identify($filename_full_path, $outhandle, $verbosity);
222
223 if ($image_type ne " ") {
224 $type = $self->correct_mime_type($image_type);
225 }
226
227 #overwrite the ones added in BasePlugin
228 $doc_obj->set_metadata_element ($section, "FileFormat", $type);
229 $doc_obj->set_metadata_element ($section, "FileSize", $image_size);
230
231 $doc_obj->add_metadata ($section, "ImageType", $image_type);
232 $doc_obj->add_metadata ($section, "ImageWidth", $image_width);
233 $doc_obj->add_metadata ($section, "ImageHeight", $image_height);
234 $doc_obj->add_metadata ($section, "ImageSize", $image_size);
235
236 if ((defined $self->{'MaxImageWidth'})
237 && ($image_width > $self->{'MaxImageWidth'})) {
238 $self->{'MaxImageWidth'} = $image_width;
239 }
240 if ((defined $self->{'MaxImageHeight'})
241 && ($image_height > $self->{'MaxImageHeight'})) {
242 $self->{'MaxImageHeight'} = $image_height;
243 }
244
245
246 $doc_obj->add_metadata ($section, "srclink", "<a href=\"_httpprefix_/collect/[collection]/index/assoc/$assocfilemeta/[Image]\">");
247 $doc_obj->add_metadata ($section, "/srclink", "</a>");
248 $doc_obj->add_metadata ($section, "srcicon", "<img src=\"_httpprefix_/collect/[collection]/index/assoc/$assocfilemeta/[Image]\" width=\"[ImageWidth]\" height=\"[ImageHeight]\">");
249
250 # Add the image as an associated file
251 $doc_obj->associate_file($filename_full_path, $filename_no_path, "image/$type", $section);
252
253 if ($self->{'create_thumbnail'} eq "true") {
254 $self->create_thumbnail($filename_full_path, $filehead, $doc_obj, $section, $assocfilemeta, $url_to_filehead);
255 }
256 if ($self->{'create_screenview'} eq "true") {
257 $self->create_screenview($filename_full_path, $filehead, $doc_obj, $section, $assocfilemeta, $url_to_filehead, $image_width, $image_height);
258 }
259
260 return 1;
261}
262
263sub create_thumbnail {
264 my $self = shift(@_);
265 my ($original_file, $filehead, $doc_obj, $section, $assocfilemeta, $url_to_filehead) = @_;
266 $url_to_filehead = $filehead unless defined $url_to_filehead;
267
268 my $thumbnailsize = $self->{'thumbnailsize'};
269 my $thumbnailtype = $self->correct_mime_type($self->{'thumbnailtype'});
270
271 # Generate the thumbnail with convert
272 my ($result,$thumbnailfile)
273 = $self->convert($original_file, $thumbnailtype, "-geometry $thumbnailsize" . "x$thumbnailsize", "THUMB");
274
275 # Add the thumbnail as an associated file ...
276 if (-e "$thumbnailfile") {
277 $doc_obj->associate_file("$thumbnailfile", $filehead."_thumb.$thumbnailtype",
278 "image/$thumbnailtype",$section); # name of generated image
279 $doc_obj->add_metadata ($section, "ThumbType", $thumbnailtype);
280 $doc_obj->add_utf8_metadata ($section, "Thumb", $url_to_filehead."_thumb.$thumbnailtype"); # url to generated image
281
282 $doc_obj->add_metadata ($section, "thumbicon", "<img src=\"_httpprefix_/collect/[collection]/index/assoc/$assocfilemeta/[Thumb]\" width=[ThumbWidth] height=[ThumbHeight]>");
283
284
285 # Extract Thumbnail metadata from convert output
286 if ($result =~ m/[0-9]+x[0-9]+=>([0-9]+)x([0-9]+)/) {
287 $doc_obj->add_metadata ($section, "ThumbWidth", $1);
288 $doc_obj->add_metadata ($section, "ThumbHeight", $2);
289 }
290 if ($self->{'store_file_paths'}) {
291 $self->{'thumb_file'} = $thumbnailfile;
292 }
293
294 } else {
295 my $outhandle = $self->{'outhandle'};
296 print $outhandle "Couldn't find thumbnail $thumbnailfile\n";
297
298 }
299}
300
301sub create_screenview {
302
303 my $self = shift(@_);
304 my ($original_file, $filehead, $doc_obj, $section, $assocfilemeta, $url_to_filehead, $image_width, $image_height) = @_;
305 $url_to_filehead = $filehead unless defined $url_to_filehead;
306
307 my $screenviewsize = $self->{'screenviewsize'};
308 my $screenviewtype = $self->correct_mime_type($self->{'screenviewtype'});
309
310 # Scale the image, unless the original image is smaller than the screenview size and -noscaleup is set
311 my $scale_option = "-geometry $screenviewsize" . "x$screenviewsize";
312 if ($self->{'noscaleup'} && $image_width < $screenviewsize && $image_height < $screenviewsize)
313 {
314 $scale_option = "";
315 }
316
317 # make the screenview image
318 my ($result,$screenviewfilename)
319 = $self->convert($original_file, $screenviewtype, $scale_option, "SCREEN");
320
321 #add the screenview as an associated file ...
322 if (-e "$screenviewfilename") {
323 $doc_obj->associate_file("$screenviewfilename", $filehead."_screen.$screenviewtype", "image/$screenviewtype",$section); # name of generated image
324 $doc_obj->add_metadata ($section, "ScreenType", $screenviewtype);
325 $doc_obj->add_utf8_metadata ($section, "Screen", $url_to_filehead."_screen.$screenviewtype"); # url to generated image
326
327 $doc_obj->add_metadata ($section, "screenicon", "<img src=\"_httpprefix_/collect/[collection]/index/assoc/$assocfilemeta/[Screen]\" width=[ScreenWidth] height=[ScreenHeight]>");
328
329 # get screenview dimensions, size and type
330 if ($result =~ m/[0-9]+x[0-9]+=>([0-9]+)x([0-9]+)/) {
331 $doc_obj->add_metadata ($section, "ScreenWidth", $1);
332 $doc_obj->add_metadata ($section, "ScreenHeight", $2);
333 } elsif ($result =~ m/([0-9]+)x([0-9]+)/) {
334 #if the image hasn't changed size, the previous regex doesn't match
335 $doc_obj->add_metadata ($section, "ScreenWidth", $1);
336 $doc_obj->add_metadata ($section, "ScreenHeight", $2);
337 }
338
339 if ($self->{'store_file_paths'}) {
340 $self->{'screen_file'} = $screenviewfilename;
341 }
342
343 } else {
344 my $outhandle = $self->{'outhandle'};
345 print $outhandle "Couldn't find screenview file $screenviewfilename\n";
346
347 }
348
349}
350
351
352
353sub convert {
354 my $self = shift(@_);
355 my $source_file_path = shift(@_);
356 my $target_file_type = shift(@_);
357 my $convert_options = shift(@_) || "";
358 my $convert_id = shift(@_) || "";
359 my $cache_mode = shift(@_) || "";
360
361 my $outhandle = $self->{'outhandle'};
362 my $verbosity = $self->{'verbosity'};
363
364 my $source_file_no_path = &File::Basename::basename($source_file_path);
365
366 # Determine the full name and path of the output file
367 my $target_file_path;
368 if ($self->{'enable_cache'}) {
369 my $cached_image_dir = $self->{'cached_dir'};
370 my $image_root = $self->{'cached_file_root'};
371 $image_root .= "_$convert_id" if ($convert_id ne "");
372 my $image_file = "$image_root.$target_file_type";
373 $target_file_path = &util::filename_cat($cached_image_dir,$image_file);
374 }
375 else {
376 $target_file_path = &util::get_tmp_filename($target_file_type);
377 push(@{$self->{'tmp_file_paths'}}, $target_file_path);
378
379 # Output filename used to be parsed from result line:
380 # my ($ofilename) = ($result =~ m/=>(.*\.$target_file_type)/);
381 # by the function that called 'convert'
382 # but this is no longer needed, as output filename is now
383 # explicitly passed back
384 }
385
386 # Generate and run the convert command
387 my $convert_command = "convert -interlace plane -verbose $convert_options \"$source_file_path\" \"$target_file_path\"";
388
389 my $print_info = { 'message_prefix' => $convert_id,
390 'message' => "Converting image $source_file_no_path to: $convert_id $target_file_type" };
391 $print_info->{'cache_mode'} = $cache_mode if ($cache_mode ne "");
392
393 my ($regenerated,$result,$had_error)
394 = $self->autorun_general_cmd($convert_command,$target_file_path,$print_info);
395
396 return ($result,$target_file_path);
397}
398
399sub convert_without_result {
400 my $self = shift(@_);
401
402 my $source_file_path = shift(@_);
403 my $target_file_type = shift(@_);
404 my $convert_options = shift(@_) || "";
405 my $convert_id = shift(@_) || "";
406
407 return $self->convert($source_file_path,$target_file_type,
408 $convert_options,$convert_id,"without_result");
409}
410
411
412# Discover the characteristics of an image file with the ImageMagick
413# "identify" command.
414
415sub identify {
416 my ($image, $outhandle, $verbosity) = @_;
417
418 # Use the ImageMagick "identify" command to get the file specs
419 my $command = "identify \"$image\" 2>&1";
420 print $outhandle "$command\n" if ($verbosity > 2);
421 my $result = '';
422 $result = `$command`;
423 print $outhandle "$result\n" if ($verbosity > 3);
424
425 # Read the type, width, and height
426 my $type = 'unknown';
427 my $width = 'unknown';
428 my $height = 'unknown';
429
430 my $image_safe = quotemeta $image;
431 if ($result =~ /^$image_safe (\w+) (\d+)x(\d+)/) {
432 $type = $1;
433 $width = $2;
434 $height = $3;
435 }
436
437 # Read the size
438 my $size = "unknown";
439 if ($result =~ m/^.* ([0-9]+)b/) {
440 $size = $1;
441 }
442 elsif ($result =~ m/^.* ([0-9]+)(\.([0-9]+))?kb?/) {
443 $size = 1024 * $1;
444 if (defined($2)) {
445 $size = $size + (1024 * $2);
446 # Truncate size (it isn't going to be very accurate anyway)
447 $size = int($size);
448 }
449 }
450 elsif ($result =~ m/^.* (([0-9]+)(\.([0-9]+))?e\+([0-9]+))(kb|b)?/) {
451 # Deals with file sizes on Linux of type "3.4e+02kb" where e+02 is 1*10^2.
452 # 3.4e+02 therefore evaluates to 3.4 x 1 x 10^2 = 340kb.
453 # Programming languages including Perl know how that 3.4e+02 is a number,
454 # so we don't need to do any calculations.
455 $size = $1*1; # turn the string into a number by multiplying it by 1
456 #if we did $size = $1; $size would be merely the string "3.4e+02"
457 $size = int($size); # truncate size
458 }
459 print $outhandle "file: $image:\t $type, $width, $height, $size\n"
460 if ($verbosity > 2);
461
462 # Return the specs
463 return ($type, $width, $height, $size);
464}
465
466sub clean_up_temporary_files {
467 my $self = shift(@_);
468
469 foreach my $tmp_file_path (@{$self->{'tmp_file_paths'}}) {
470 if (-e $tmp_file_path) {
471 &util::rm($tmp_file_path);
472 }
473 }
474
475}
476
477# image/jpg is not a valid mime-type, it ought to be image/jpeg.
478# Sometimes JPEG is passed in also, want to keep things lowercase just in case.
479sub correct_mime_type {
480 my $self = shift(@_);
481 my ($file_extension) = @_;
482
483 $file_extension = lc($file_extension);
484 $file_extension =~ s/jpg/jpeg/s;
485
486 return $file_extension;
487}
488
4891;
Note: See TracBrowser for help on using the repository browser.