source: main/trunk/greenstone2/perllib/plugins/MetadataXMLPlugin.pm@ 21905

Last change on this file since 21905 was 21905, checked in by mdewsnip, 11 years ago

Changes made by Jeffrey Ke at DL Consulting Ltd to remove the global $self variable, so more than one variant of MetadataXMLPlugin (e.g. if you subclass MetadataXMLPlugin.pm) can be included in a collection without everything going pear-shaped.

  • Property svn:keywords set to Author Date Id Revision
File size: 10.2 KB
Line 
1###########################################################################
2#
3# MetadataXMLPlugin.pm --
4# A component of the Greenstone digital library software
5# from the New Zealand Digital Library Project at the
6# University of Waikato, New Zealand.
7#
8# Copyright (C) 2006 New Zealand Digital Library Project
9#
10# This program is free software; you can redistribute it and/or modify
11# it under the terms of the GNU General Public License as published by
12# the Free Software Foundation; either version 2 of the License, or
13# (at your option) any later version.
14#
15# This program is distributed in the hope that it will be useful,
16# but WITHOUT ANY WARRANTY; without even the implied warranty of
17# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18# GNU General Public License for more details.
19#
20# You should have received a copy of the GNU General Public License
21# along with this program; if not, write to the Free Software
22# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
23#
24###########################################################################
25
26# MetadataXMLPlugin process metadata.xml files in a collection
27
28# Here's an example of a metadata file that uses three FileSet structures
29# (ignore the # characters):
30
31#<?xml version="1.0" encoding="UTF-8" standalone="no"?>
32#<!DOCTYPE DirectoryMetadata SYSTEM "http://greenstone.org/dtd/DirectoryMetadata/1.0/DirectoryMetadata.dtd">
33#<DirectoryMetadata>
34# <FileSet>
35# <FileName>nugget.*</FileName>
36# <Description>
37# <Metadata name="Title">Nugget Point, The Catlins</Metadata>
38# <Metadata name="Place" mode="accumulate">Nugget Point</Metadata>
39# </Description>
40# </FileSet>
41# <FileSet>
42# <FileName>nugget-point-1.jpg</FileName>
43# <Description>
44# <Metadata name="Title">Nugget Point Lighthouse, The Catlins</Metadata>
45# <Metadata name="Subject">Lighthouse</Metadata>
46# </Description>
47# </FileSet>
48# <FileSet>
49# <FileName>kaka-point-dir</FileName>
50# <Description>
51# <Metadata name="Title">Kaka Point, The Catlins</Metadata>
52# </Description>
53# </FileSet>
54#</DirectoryMetadata>
55
56# Metadata elements are read and applied to files in the order they appear
57# in the file.
58#
59# The FileName element describes the subfiles in the directory that the
60# metadata applies to as a perl regular expression (a FileSet group may
61# contain multiple FileName elements). So, <FileName>nugget.*</FileName>
62# indicates that the metadata records in the following Description block
63# apply to every subfile that starts with "nugget". For these files, a
64# Title metadata element is set, overriding any old value that the Title
65# might have had.
66#
67# Occasionally, we want to have multiple metadata values applied to a
68# document; in this case we use the "mode=accumulate" attribute of the
69# particular Metadata element. In the second metadata element of the first
70# FileSet above, the "Place" metadata is accumulating, and may therefore be
71# given several values. If we wanted to override these values and use a
72# single metadata element again, we could set the mode attribute to
73# "override" instead. Remember: every element is assumed to be in override
74# mode unless you specify otherwise, so if you want to accumulate metadata
75# for some field, every occurance must have "mode=accumulate" specified.
76#
77# The second FileSet element above applies to a specific file, called
78# nugget-point-1.jpg. This element overrides the Title metadata set in the
79# first FileSet, and adds a "Subject" metadata field.
80#
81# The third and final FileSet sets metadata for a subdirectory rather than
82# a file. The metadata specified (a Title) will be passed into the
83# subdirectory and applied to every file that occurs in the subdirectory
84# (and to every subsubdirectory and its contents, and so on) unless the
85# metadata is explictly overridden later in the import.
86
87package MetadataXMLPlugin;
88
89use strict;
90no strict 'refs';
91use BasePlugin;
92use util;
93use metadatautil;
94
95sub BEGIN {
96 @MetadataXMLPlugin::ISA = ('BasePlugin');
97 unshift (@INC, "$ENV{'GSDLHOME'}/perllib/cpan");
98}
99
100use XMLParser;
101
102my $arguments = [
103 { 'name' => "process_exp",
104 'desc' => "{BasePlugin.process_exp}",
105 'type' => "regexp",
106 'reqd' => "no",
107 'deft' => &get_default_process_exp() }
108
109];
110
111my $options = { 'name' => "MetadataXMLPlugin",
112 'desc' => "{MetadataXMLPlugin.desc}",
113 'abstract' => "no",
114 'inherits' => "yes",
115 'args' => $arguments };
116
117sub new {
118 my ($class) = shift (@_);
119 my ($pluginlist,$inputargs,$hashArgOptLists) = @_;
120 push(@$pluginlist, $class);
121
122 push(@{$hashArgOptLists->{"ArgList"}},@{$arguments});
123 push(@{$hashArgOptLists->{"OptList"}},$options);
124
125 my $self = new BasePlugin($pluginlist, $inputargs, $hashArgOptLists);
126
127 if ($self->{'info_only'}) {
128 # don't worry about any options or initialisations etc
129 return bless $self, $class;
130 }
131
132 # create XML::Parser object for parsing metadata.xml files
133 my $parser;
134 if ($]<5.008) {
135 # Perl 5.6
136 $parser = new XML::Parser('Style' => 'Stream',
137 'PluginObj' => $self,
138 'Handlers' => {'Char' => \&Char,
139 'Doctype' => \&Doctype
140 });
141 }
142 else {
143 # Perl 5.8
144 $parser = new XML::Parser('Style' => 'Stream',
145 'PluginObj' => $self,
146 'ProtocolEncoding' => 'ISO-8859-1',
147 'Handlers' => {'Char' => \&Char,
148 'Doctype' => \&Doctype
149 });
150 }
151
152 $self->{'parser'} = $parser;
153 $self->{'in_filename'} = 0;
154
155
156 return bless $self, $class;
157}
158
159
160sub get_default_process_exp
161{
162 return q^metadata\.xml$^;
163}
164
165
166sub file_block_read {
167 my $self = shift (@_);
168 my ($pluginfo, $base_dir, $file, $block_hash, $metadata, $gli) = @_;
169
170 my $filename = &util::filename_cat($base_dir, $file);
171 if ($filename !~ /metadata\.xml$/ || !-f $filename) {
172 return undef;
173 }
174
175 $block_hash->{'metadata_files'}->{$filename} = 1;
176
177 return 1;
178}
179
180sub metadata_read
181{
182 my $self = shift (@_);
183 my ($pluginfo, $base_dir, $file, $block_hash,
184 $extrametakeys, $extrametadata,$extrametafile,
185 $processor, $maxdocs, $gli) = @_;
186
187 my $filename = &util::filename_cat($base_dir, $file);
188 if ($filename !~ /metadata\.xml$/ || !-f $filename) {
189 return undef;
190 }
191
192 $self->{'metadata-file'} = $file;
193 $self->{'metadata-filename'} = $filename;
194
195
196 my $outhandle = $self->{'outhandle'};
197
198 print STDERR "\n<Processing n='$file' p='MetadataXMLPlugin'>\n" if ($gli);
199 print $outhandle "MetadataXMLPlugin: processing $file\n" if ($self->{'verbosity'})> 1;
200 # add the file to the block list so that it won't be processed in read, as we will do all we can with it here
201 $block_hash->{'file_blocks'}->{$filename} = 1;
202
203 $self->{'metadataref'} = $extrametadata;
204 $self->{'metafileref'} = $extrametafile;
205 $self->{'metakeysref'} = $extrametakeys;
206
207 eval {
208 $self->{'parser'}->parsefile($filename);
209 };
210
211 if ($@) {
212 my $plugin_name = ref ($self);
213 print $outhandle "$plugin_name failed to process $file ($@)\n";
214
215 return -1; #error
216 }
217
218 return 1;
219
220}
221
222
223# Updated by Jeffrey 2010/04/16 @ DL Consulting Ltd.
224# Get rid off the global $self as it cause problems when there are 2+ MetadataXMLPlugin in your collect.cfg...
225# For example when you have an OAIMetadataXMLPlugin that is a child of MetadataXMLPlugin
226sub Doctype {$_[0]->{'PluginObj'}->xml_doctype(@_);}
227sub StartTag {$_[0]->{'PluginObj'}->xml_start_tag(@_);}
228sub EndTag {$_[0]->{'PluginObj'}->xml_end_tag(@_);}
229sub Text {$_[0]->{'PluginObj'}->xml_text(@_);}
230
231
232sub xml_doctype {
233 my $self = shift(@_);
234 my ($expat, $name, $sysid, $pubid, $internal) = @_;
235
236 # allow the short-lived and badly named "GreenstoneDirectoryMetadata" files
237 # to be processed as well as the "DirectoryMetadata" files which should now
238 # be created by import.pl
239 die if ($name !~ /^(Greenstone)?DirectoryMetadata$/);
240}
241
242sub xml_start_tag {
243 my $self = shift(@_);
244 my ($expat, $element) = @_;
245
246 if ($element eq "FileSet") {
247 $self->{'saved_targets'} = [];
248 $self->{'saved_metadata'} = {};
249 }
250 elsif ($element eq "FileName") {
251 $self->{'in_filename'} = 1;
252 }
253 elsif ($element eq "Metadata") {
254 $self->{'metadata_name'} = $_{'name'};
255 $self->{'metadata_value'} = "";
256 if ((defined $_{'mode'}) && ($_{'mode'} eq "accumulate")) {
257 $self->{'metadata_accumulate'} = 1;
258 } else {
259 $self->{'metadata_accumulate'} = 0;
260 }
261 }
262}
263
264sub xml_end_tag {
265 my $self = shift(@_);
266 my ($expat, $element) = @_;
267
268 if ($element eq "FileSet") {
269 foreach my $target (@{$self->{'saved_targets'}}) {
270 my $file_metadata = $self->{'metadataref'}->{$target};
271 my $saved_metadata = $self->{'saved_metadata'};
272
273 if (!defined $file_metadata) {
274 $self->{'metadataref'}->{$target} = $saved_metadata;
275
276 # not had target before
277 push (@{$self->{'metakeysref'}}, $target);
278 }
279 else {
280 &metadatautil::combine_metadata_structures($file_metadata,$saved_metadata);
281 }
282
283
284 # now record which metadata.xml file it came from
285
286 my $file = $self->{'metadata-file'};
287 my $filename = $self->{'metadata-filename'};
288
289 if (!defined $self->{'metafileref'}->{$target}) {
290 $self->{'metafileref'}->{$target} = {};
291 }
292
293 $self->{'metafileref'}->{$target}->{$file} = $filename
294 }
295 }
296 elsif ($element eq "FileName") {
297 $self->{'in_filename'} = 0;
298 }
299 elsif ($element eq "Metadata") {
300 &metadatautil::store_saved_metadata($self,$self->{'metadata_name'}, $self->{'metadata_value'}, $self->{'metadata_accumulate'});
301 $self->{'metadata_name'} = "";
302 }
303
304}
305
306sub xml_text {
307 my $self = shift(@_);
308
309 if ($self->{'in_filename'}) {
310 # $_ == FileName content
311 push (@{$self->{'saved_targets'}}, $_);
312 }
313 elsif (defined ($self->{'metadata_name'}) && $self->{'metadata_name'} ne "") {
314 # $_ == Metadata content
315 $self->{'metadata_value'} = $_;
316 }
317}
318
319# This Char function overrides the one in XML::Parser::Stream to overcome a
320# problem where $expat->{Text} is treated as the return value, slowing
321# things down significantly in some cases.
322sub Char {
323 if ($]<5.008) {
324 use bytes; # Necessary to prevent encoding issues with XML::Parser 2.31+ and Perl 5.6
325 }
326 $_[0]->{'Text'} .= $_[1];
327 return undef;
328}
329
330#sub combine_metadata_structures
331#{
332# my $self = shift(@_);
333#
334# my ($mdref1, $mdref2) = @_;
335# &metadatautil::combine_metadata_structures($mdref1, $mdref2);
336#}
337
338
3391;
Note: See TracBrowser for help on using the repository browser.