source: main/trunk/greenstone2/perllib/plugins/MetadataXMLPlugin.pm@ 30600

Last change on this file since 30600 was 30600, checked in by ak19, 7 years ago

An empty metadata.xml was unrecognised by MetadataXMLPlugin because the self-closing root tag in the XML file was not matched in the regex.

  • Property svn:keywords set to Author Date Id Revision
File size: 12.9 KB
Line 
1###########################################################################
2#
3# MetadataXMLPlugin.pm --
4# A component of the Greenstone digital library software
5# from the New Zealand Digital Library Project at the
6# University of Waikato, New Zealand.
7#
8# Copyright (C) 2006 New Zealand Digital Library Project
9#
10# This program is free software; you can redistribute it and/or modify
11# it under the terms of the GNU General Public License as published by
12# the Free Software Foundation; either version 2 of the License, or
13# (at your option) any later version.
14#
15# This program is distributed in the hope that it will be useful,
16# but WITHOUT ANY WARRANTY; without even the implied warranty of
17# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18# GNU General Public License for more details.
19#
20# You should have received a copy of the GNU General Public License
21# along with this program; if not, write to the Free Software
22# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
23#
24###########################################################################
25
26# MetadataXMLPlugin process metadata.xml files in a collection
27
28# Here's an example of a metadata file that uses three FileSet structures
29# (ignore the # characters):
30
31#<?xml version="1.0" encoding="UTF-8" standalone="no"?>
32#<!DOCTYPE DirectoryMetadata SYSTEM "http://greenstone.org/dtd/DirectoryMetadata/1.0/DirectoryMetadata.dtd">
33#<DirectoryMetadata>
34# <FileSet>
35# <FileName>nugget.*</FileName>
36# <Description>
37# <Metadata name="Title">Nugget Point, The Catlins</Metadata>
38# <Metadata name="Place" mode="accumulate">Nugget Point</Metadata>
39# </Description>
40# </FileSet>
41# <FileSet>
42# <FileName>nugget-point-1.jpg</FileName>
43# <Description>
44# <Metadata name="Title">Nugget Point Lighthouse, The Catlins</Metadata>
45# <Metadata name="Subject">Lighthouse</Metadata>
46# </Description>
47# </FileSet>
48# <FileSet>
49# <FileName>kaka-point-dir</FileName>
50# <Description>
51# <Metadata name="Title">Kaka Point, The Catlins</Metadata>
52# </Description>
53# </FileSet>
54#</DirectoryMetadata>
55
56# Metadata elements are read and applied to files in the order they appear
57# in the file.
58#
59# The FileName element describes the subfiles in the directory that the
60# metadata applies to as a perl regular expression (a FileSet group may
61# contain multiple FileName elements). So, <FileName>nugget.*</FileName>
62# indicates that the metadata records in the following Description block
63# apply to every subfile that starts with "nugget". For these files, a
64# Title metadata element is set, overriding any old value that the Title
65# might have had.
66#
67# Occasionally, we want to have multiple metadata values applied to a
68# document; in this case we use the "mode=accumulate" attribute of the
69# particular Metadata element. In the second metadata element of the first
70# FileSet above, the "Place" metadata is accumulating, and may therefore be
71# given several values. If we wanted to override these values and use a
72# single metadata element again, we could set the mode attribute to
73# "override" instead. Remember: every element is assumed to be in override
74# mode unless you specify otherwise, so if you want to accumulate metadata
75# for some field, every occurance must have "mode=accumulate" specified.
76#
77# The second FileSet element above applies to a specific file, called
78# nugget-point-1.jpg. This element overrides the Title metadata set in the
79# first FileSet, and adds a "Subject" metadata field.
80#
81# The third and final FileSet sets metadata for a subdirectory rather than
82# a file. The metadata specified (a Title) will be passed into the
83# subdirectory and applied to every file that occurs in the subdirectory
84# (and to every subsubdirectory and its contents, and so on) unless the
85# metadata is explictly overridden later in the import.
86
87package MetadataXMLPlugin;
88
89use strict;
90no strict 'refs';
91
92use Encode;
93
94use BasePlugin;
95use extrametautil;
96use util;
97use FileUtils;
98use metadatautil;
99
100sub BEGIN {
101 @MetadataXMLPlugin::ISA = ('BasePlugin');
102 unshift (@INC, "$ENV{'GSDLHOME'}/perllib/cpan");
103}
104
105use XMLParser;
106
107my $arguments = [
108 { 'name' => "process_exp",
109 'desc' => "{BasePlugin.process_exp}",
110 'type' => "regexp",
111 'reqd' => "no",
112 'deft' => &get_default_process_exp() }
113
114];
115
116my $options = { 'name' => "MetadataXMLPlugin",
117 'desc' => "{MetadataXMLPlugin.desc}",
118 'abstract' => "no",
119 'inherits' => "yes",
120 'args' => $arguments };
121
122sub new {
123 my ($class) = shift (@_);
124 my ($pluginlist,$inputargs,$hashArgOptLists) = @_;
125 push(@$pluginlist, $class);
126
127 push(@{$hashArgOptLists->{"ArgList"}},@{$arguments});
128 push(@{$hashArgOptLists->{"OptList"}},$options);
129
130 my $self = new BasePlugin($pluginlist, $inputargs, $hashArgOptLists);
131
132 if ($self->{'info_only'}) {
133 # don't worry about any options or initialisations etc
134 return bless $self, $class;
135 }
136
137 # The following used to be passed in as a parameter to XML::Parser,
138 # if the version of perl was greater than or equal to 5.8.
139 # The svn commit comment explaining the reason for adding this was
140 # not very clear and also said that it was quick fix and hadn't
141 # been tested under windows.
142 # More recent work has been to make strings in Perl "Unicode-aware"
143 # and so this line might actually be potentially harmful, however
144 # it is not the case that we encountered an actual error leading to
145 # its removal, rather it has been eliminated in an attempt to tighten
146 # up the code. For example, this protocol encoding is not used in
147 # ReadXMLFile.
148 # 'ProtocolEncoding' => 'ISO-8859-1',
149
150 # create XML::Parser object for parsing metadata.xml files
151 my $parser = new XML::Parser('Style' => 'Stream',
152 'Pkg' => 'MetadataXMLPlugin',
153 'PluginObj' => $self,
154 'Handlers' => {'Char' => \&Char,
155 'Doctype' => \&Doctype
156 });
157
158 $self->{'parser'} = $parser;
159 $self->{'in_filename'} = 0;
160
161 return bless $self, $class;
162}
163
164
165sub get_default_process_exp
166{
167 return q^metadata\.xml$^;
168}
169
170sub get_doctype {
171 my $self = shift(@_);
172
173 return "(Greenstone)?DirectoryMetadata"
174}
175
176sub can_process_this_file {
177 my $self = shift(@_);
178 my ($filename) = @_;
179
180 if (-f $filename && $self->SUPER::can_process_this_file($filename) && $self->check_doctype($filename)) {
181 return 1; # its a file for us
182 }
183
184 return 0;
185}
186
187sub check_doctype {
188 my $self = shift (@_);
189
190 my ($filename) = @_;
191
192 if (open(XMLIN,"<$filename")) {
193 my $doctype = $self->get_doctype();
194 ## check whether the doctype has the same name as the root element tag
195 while (defined (my $line = <XMLIN>)) {
196 ## find the root element
197 if ($line =~ /<([\w\d:]+)[\s\/>]/){
198 my $root = $1;
199 if ($root !~ $doctype){
200 close(XMLIN);
201 return 0;
202 }
203 else {
204 close(XMLIN);
205 return 1;
206 }
207 }
208 }
209 close(XMLIN);
210 }
211
212 return undef; # haven't found a valid line
213
214}
215
216sub file_block_read {
217 my $self = shift (@_);
218 my ($pluginfo, $base_dir, $file, $block_hash, $metadata, $gli) = @_;
219
220 my $filename_full_path = &FileUtils::filenameConcatenate($base_dir, $file);
221 return undef unless $self->can_process_this_file($filename_full_path);
222
223 if (($ENV{'GSDLOS'} =~ m/^windows$/) && ($^O ne "cygwin")) {
224
225 my $lower_drive = $filename_full_path;
226 $lower_drive =~ s/^([A-Z]):/\l$1:/i;
227
228 my $upper_drive = $filename_full_path;
229 $upper_drive =~ s/^([A-Z]):/\u$1:/i;
230
231 $block_hash->{'metadata_files'}->{$lower_drive} = 1;
232 $block_hash->{'metadata_files'}->{$upper_drive} = 1;
233 }
234 else {
235 $block_hash->{'metadata_files'}->{$filename_full_path} = 1;
236 }
237
238 return 1;
239}
240
241sub metadata_read
242{
243 my $self = shift (@_);
244 my ($pluginfo, $base_dir, $file, $block_hash,
245 $extrametakeys, $extrametadata,$extrametafile,
246 $processor, $gli, $aux) = @_;
247
248 my $filename = &FileUtils::filenameConcatenate($base_dir, $file);
249 return undef unless $self->can_process_this_file($filename);
250
251 $self->{'metadata-file'} = $file;
252 $self->{'metadata-filename'} = $filename;
253
254 my $outhandle = $self->{'outhandle'};
255
256 print STDERR "\n<Processing n='$file' p='MetadataXMLPlugin'>\n" if ($gli);
257 print $outhandle "MetadataXMLPlugin: processing $file\n" if ($self->{'verbosity'})> 1;
258 # add the file to the block list so that it won't be processed in read, as we will do all we can with it here
259 &util::block_filename($block_hash,$filename);
260
261 $self->{'metadataref'} = $extrametadata;
262 $self->{'metafileref'} = $extrametafile;
263 $self->{'metakeysref'} = $extrametakeys;
264
265 eval {
266 $self->{'parser'}->parsefile($filename);
267 };
268
269 if ($@) {
270 print STDERR "**** Error is: $@\n";
271 my $plugin_name = ref ($self);
272 my $failhandle = $self->{'failhandle'};
273 print $outhandle "$plugin_name failed to process $file ($@)\n";
274 print $failhandle "$plugin_name failed to process $file ($@)\n";
275 print STDERR "<ProcessingError n='$file'>\n" if ($gli);
276 return -1; #error
277 }
278
279 return 1;
280
281}
282
283
284# Updated by Jeffrey 2010/04/16 @ DL Consulting Ltd.
285# Get rid off the global $self as it cause problems when there are 2+ MetadataXMLPlugin in your collect.cfg...
286# For example when you have an OAIMetadataXMLPlugin that is a child of MetadataXMLPlugin
287sub Doctype {$_[0]->{'PluginObj'}->xml_doctype(@_);}
288sub StartTag {$_[0]->{'PluginObj'}->xml_start_tag(@_);}
289sub EndTag {$_[0]->{'PluginObj'}->xml_end_tag(@_);}
290sub Text {$_[0]->{'PluginObj'}->xml_text(@_);}
291
292
293sub xml_doctype {
294 my $self = shift(@_);
295 my ($expat, $name, $sysid, $pubid, $internal) = @_;
296
297 # allow the short-lived and badly named "GreenstoneDirectoryMetadata" files
298 # to be processed as well as the "DirectoryMetadata" files which should now
299 # be created by import.pl
300 die if ($name !~ /^(Greenstone)?DirectoryMetadata$/);
301}
302
303sub xml_start_tag {
304 my $self = shift(@_);
305 my ($expat, $element) = @_;
306
307 if ($element eq "FileSet") {
308 $self->{'saved_targets'} = [];
309 $self->{'saved_metadata'} = {};
310 }
311 elsif ($element eq "FileName") {
312 $self->{'in_filename'} = 1;
313 }
314 elsif ($element eq "Metadata") {
315 $self->{'metadata_name'} = $_{'name'};
316 $self->{'metadata_value'} = "";
317 if ((defined $_{'mode'}) && ($_{'mode'} eq "accumulate")) {
318 $self->{'metadata_accumulate'} = 1;
319 } else {
320 $self->{'metadata_accumulate'} = 0;
321 }
322 }
323}
324
325sub xml_end_tag {
326 my $self = shift(@_);
327 my ($expat, $element) = @_;
328
329 if ($element eq "FileSet") {
330 foreach my $target (@{$self->{'saved_targets'}}) {
331
332 # FileNames must be regex, but we allow \\ for path separator on windows. convert to /
333 $target = &util::filepath_regex_to_url_format($target);
334
335 # we want proper unicode for the regex, so convert url-encoded chars
336 if (&unicode::is_url_encoded($target)) {
337 $target = &unicode::url_decode($target);
338 }
339
340 my $file_metadata = &extrametautil::getmetadata($self->{'metadataref'}, $target);
341 my $saved_metadata = $self->{'saved_metadata'};
342
343 if (!defined $file_metadata) {
344 &extrametautil::setmetadata($self->{'metadataref'}, $target, $saved_metadata);
345
346 # not had target before
347 &extrametautil::addmetakey($self->{'metakeysref'}, $target);
348 }
349 else {
350 &metadatautil::combine_metadata_structures($file_metadata,$saved_metadata);
351 }
352
353
354 # now record which metadata.xml file it came from
355
356 my $file = $self->{'metadata-file'};
357 my $filename = $self->{'metadata-filename'};
358
359 if (!defined &extrametautil::getmetafile($self->{'metafileref'}, $target)) {
360 &extrametautil::setmetafile($self->{'metafileref'}, $target, {});
361 }
362
363 &extrametautil::setmetafile_for_named_file($self->{'metafileref'}, $target, $file, $filename);
364 }
365 }
366 elsif ($element eq "FileName") {
367 $self->{'in_filename'} = 0;
368 }
369 elsif ($element eq "Metadata") {
370 # text read in by XML::Parser is in Perl's binary byte value
371 # form ... need to explicitly make it UTF-8
372
373 my $metadata_name = $self->{'metadata_name'};
374 my $metadata_value = $self->{'metadata_value'};
375 #my $metadata_name = decode("utf-8",$self->{'metadata_name'});
376 #my $metadata_value = decode("utf-8",$self->{'metadata_value'});
377
378 &metadatautil::store_saved_metadata($self,
379 $metadata_name, $metadata_value,
380 $self->{'metadata_accumulate'});
381 $self->{'metadata_name'} = "";
382 }
383
384}
385
386sub xml_text {
387 my $self = shift(@_);
388
389 if ($self->{'in_filename'}) {
390 # $_ == FileName content
391 push (@{$self->{'saved_targets'}}, $_);
392 }
393 elsif (defined ($self->{'metadata_name'}) && $self->{'metadata_name'} ne "") {
394 # $_ == Metadata content
395 $self->{'metadata_value'} = $_;
396 }
397}
398
399# This Char function overrides the one in XML::Parser::Stream to overcome a
400# problem where $expat->{Text} is treated as the return value, slowing
401# things down significantly in some cases.
402sub Char {
403# use bytes; # Necessary to prevent encoding issues with XML::Parser 2.31+
404
405# if ($]<5.008) {
406# use bytes; # Necessary to prevent encoding issues with XML::Parser 2.31+ and Perl 5.6
407# }
408 $_[0]->{'Text'} .= $_[1];
409 return undef;
410}
411
412
413
4141;
Note: See TracBrowser for help on using the repository browser.