source: main/trunk/package-kits/linux/generate@ 29481

#!/usr/bin/env perl

# Generates Makefiles for different systems and packages
# Uses a hashmap to do config variables  (see readvar for how variables are
#  read in and an example of how they are resolved / used)

use strict;
use warnings;
use utf8;
use File::Basename;
use File::Path 'make_path';
use File::Copy;
use Storable 'dclone';

my $USAGE = "Usage: " . basename($0) . " <platforms> <packages>
    platforms: A comma separated list of the platforms defined in pkg.in/platforms
               Or 'all' (for all platforms)
    packages:  A comma separated list of the packages defined in pkg.in/packages
               Or 'all' (for all platforms)
";

$#ARGV == 1 or die $USAGE;

sub globbify {
    my ($dir, $files) = @_;
    $files =~ /^all$/i and return glob "$dir/*";
    my @list = glob "$dir/{$files}";
    for (@list) {
        -f or die "Could not find '", $_, "'";
    }
    return @list;
}

sub readvar {
    my ($vars, $line) = @_;
    my ($var, $val) = split "=", $line;
    defined $var and defined $val or die "Invalid variable assignment: '$line'";
    $val =~ s/%([\w]+)%/$vars->{$1}/g;
    $vars->{$var} = $val;
}

my @platforms = globbify "pkg.in/platforms", shift;
my @packages  = globbify "pkg.in/packages",  shift;

for (@platforms) {
    my ($platform) = /^pkg\.in\/platforms\/(.*)$/;
    my %platform_vars = ();
    open FH, '<', $_ or die "Failed to open '$_' for reading: $!";
    # read platform variable definitons
    while (<FH>) {
        chomp;
        readvar \%platform_vars, $_;
    }
    close FH;

    for (@packages) {
        my ($package) = /^pkg\.in\/packages\/(.*)$/;
        my $package_path = "build/$platform/$package";
        make_path $package_path;

        open FH, '<', $_ or die "Failed to open '$_' for reading: $!";

        # read package file dependencies
        while (<FH>) {
            chomp;
            /^[\s]*$/ and last;
            -e "pkg.in/files/$_" or die "Could not find '", $_, "'";
            copy "pkg.in/files/$_", "$package_path/$_" or die "Failed to copy '$_': $!";
        }

        my %package_vars = %{dclone \%platform_vars};
        # read package variable definitions
        while (<FH>) {
            chomp;
            /^[\s]*$/ and last;
            readvar \%package_vars, $_;
        }
        
        my $outfile = "$package_path/Makefile";
        open OUT, '>', $outfile or die "Failed to open '$outfile' for writing: $!";
        # read package makefile segments
        while (<FH>) {
            chomp;
            open SEG, '<', "pkg.in/segments/$_" or die "Failed to open '$_' for reading: $!";
            # write the makefile
            while (<SEG>) {
                s/%([\w]+)%/$package_vars{$1}/g;
                print OUT;
            }
            close SEG;
        }
        close FH;
        close OUT;
    }
    print "Generated $platform build scripts in build/$platform/\n";
}