source: main/trunk/package-kits/linux/pacman/demo/PKGBUILD@ 29460

# Maintainer: Jeremy Symon <[email protected]>
pkgname=greenstone-demo-svn
pkgver=r29457  
pkgrel=1
pkgdesc="Demo Greenstone Digital Library Collections"
url="http://greenstone.org"
arch=('any')
license=('GPLv2')
depends=('greenstone')
optdepends=()
makedepends=(
  'greenstone-tools'
  'svn'
)
# conflicts=()
# replaces=()
# backup=()
# install=''
source=("svn+http://svn.greenstone.org/main/trunk/greenstone3/web/sites/localsite/collect")
md5sums=('SKIP')

pkgver() {
  cd "collect"
  local ver="$(svnversion)"
  printf "r%s" "${ver//[[:alpha:]]}"
}

build() {
  cd "${srcdir}/collect"
  find . -type d -name ".svn" -exec rm -rf {} \; || :
  rm -f */index.zip
  cd "${srcdir}"
  rm -rf sites/
  mkdir -p sites/localsite
  mv collect sites/localsite/
  export GSDL3HOME=$(pwd)
  . greenstone --no-interactive
  find sites/localsite/collect/ -mindepth 1 -maxdepth 1 -not -name ".*" -execdir bash -c 'col="$(basename $1)"; import.pl -removeold -site localsite "$col"; buildcol.pl -removeold -site localsite "$col"; mv "${col}/building" "${col}/index"' -- {} \;
  mv sites/localsite/collect .
}

package() {
  install -d ${pkgdir}/srv/gsdl/sites/localsite
  cp -r ${srcdir}/collect ${pkgdir}/srv/gsdl/sites/localsite/
}

# vim:expandtab:ts=2:sw=2: