source: other-projects/trunk/gs2build-extra/configure.in@ 16299

dnl Process this file with autoconf to produce a configure script.
dnl Use autoconf-2.59 or later... it might not work anymore with
dnl the older 2.1x versions - jrm21 12/2004
AC_INIT
AC_CONFIG_SRCDIR([src/lib/text_t.h])
AC_CONFIG_HEADER(config.h)

PACKAGE=gsdl
VERSION=2.1
AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
AC_SUBST(PACKAGE)
AC_SUBST(VERSION)

dnl
dnl look for libgdbm if not in standard location
dnl
AC_ARG_WITH(gdbm, [  --with-gdbm=dir         Use local gdbm library and headers], gdbmdir=$withval)


dnl 
dnl disable compilation of accent folding stuff for mgpp (and one day mg)
dnl
AC_ARG_ENABLE(accentfold, [  --disable-accentfold          Disable Accent Folding for MGPP], ENABLE_ACCENTFOLD=0, ENABLE_ACCENTFOLD=1)
AC_DEFINE(ENABLE_ACCENTFOLD, $ENABLE_ACCENTFOLD)
AC_SUBST(ENABLE_ACCENTFOLD)


dnl Checks for programs.
LDFLAGS=
dnl only set CFLAGS if not already set in environment
if test -z "$CFLAGS"; then
CFLAGS=-O2
fi
AC_SUBST(CFLAGS)

AC_PROG_CC
AC_PROG_CXX
AC_PROG_AWK
AC_PROG_YACC
dnl get $target_cpu, $target_vendor, and $target_os
dnl (as well as host_*)
AC_CANONICAL_TARGET([])
dnl do we actually want this? It adds a prefix based on host, system etc
dnl AC_ARG_PROGRAM
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_RANLIB


AC_MSG_CHECKING(to see if architecture is 64-bit)
arch_64bit=no
case "$host_cpu" in
x86_64) arch_64bit=yes ;;
esac

if test "$arch_64bit" = yes; then
  AC_MSG_RESULT(yes)
  if test -z "$COMPAT32BITFLAGS" ; then
    COMPAT32BITFLAGS="-m32"
  fi
else
  AC_MSG_RESULT(no)
  if test -z "$COMPAT32BITFLAGS" ; then
    COMPAT32BITFLAGS=
  fi
fi
export COMPAT32BITFLAGS
AC_SUBST(COMPAT32BITFLAGS)


dnl Checks for typedefs, structures, and compiler characteristics.
AC_AIX
AC_ISC_POSIX
AC_MINIX
fp_C_PROTOTYPES
AC_C_CONST
AC_TYPE_OFF_T
AC_TYPE_SIZE_T
AC_HEADER_TIME
AC_STRUCT_TM

dnl --- This should be in the stdc checking -----------------
if test "$ac_cv_prog_cc_stdc" = '-Xc'; then
dnl The Pyramids running SMP_DC.OSx on MIPS r3000 chips with
dnl /usr/opt/cc3.11/bin/cc treat -Xc as full ANSI mode - no POSIX or
dnl XOPEN extensions (like popen).
dnl Unfortunately -D_{XOPEN,POSIX}_SOURCE can't provide all that mg
dnl needs. So drop back to -Xa
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
]], [[ FILE *rubbish = popen("yes", "r"); ]])],[],[CC="`echo $CC | sed 's/-Xc/-Xa/'`"    ac_cv_prog_cc_stdc='-Xa'])
fi
dnl ----------------------


dnl Checks for libraries.
dnl check for -lg:
AC_CHECK_LIB([g],[main],[],[],[])ac_cv_lib_g=ac_cv_lib_g_main

dnl check for -lm:
AC_CHECK_LIB([m],[main],[],[],[])ac_cv_lib_m=ac_cv_lib_m_main

dnl check for -lcrypt:
AC_CHECK_LIB([crypt],[main],[],[],[])ac_cv_lib_crypt=ac_cv_lib_crypt_main

if test $ENABLE_ACCENTFOLD = 1; then
AC_CHECK_LIB([ICONV],[main],[],[],[])ac_cv_lib_ICONV=ac_cv_lib_ICONV_main

fi


dnl Checks for header files.
AC_HEADER_DIRENT
AC_HEADER_STDC
AC_CHECK_HEADERS(fcntl.h limits.h sys/time.h unistd.h crypt.h string.h memory.h sys/procfs.h)
AC_EGREP_HEADER(fread, stdio.h, AC_DEFINE(HAVE_FREAD_DECL))
AC_EGREP_HEADER(fgetc, stdio.h, AC_DEFINE(HAVE_FGETC_DECL))
AC_EGREP_HEADER(pr_brksize, sys/procfs.h, AC_DEFINE(HAVE_PR_BRKSIZE))

dnl Checks for library functions.
AC_FUNC_ALLOCA
AC_PROG_GCC_TRADITIONAL
AC_TYPE_SIGNAL
AC_FUNC_VPRINTF
AC_CHECK_FUNCS(ftime select strftime strtol getrusage times mallinfo setbuffer getpagesize strerror)
AC_REPLACE_FUNCS(ftruncate strstr strcasecmp)

dnl see if gettext is in libc. (try the textdomain() function).
AC_CHECK_FUNC(textdomain, AC_DEFINE(ENABLE_NLS ,1) )

# *** Custom checking (based on GNU tar configure.in) ***
# ---------------------------------------------------------------------------
AC_MSG_CHECKING(for HP-UX needing gmalloc)
if test "`(uname -s) 2> /dev/null`" = 'HP-UX'; then
  AC_MSG_RESULT(yes)
  AC_LIBOBJ([gmalloc])
  AC_DEFINE(HAVE_VALLOC)
else
  AC_MSG_RESULT(no)
  AC_CHECK_FUNCS(valloc)
fi

# we cannot generate static libraries under Darwin
AC_MSG_CHECKING(for Apple MacOS X/Darwin)
if test "`(uname -s) 2> /dev/null`" = 'Darwin'; then
  AC_MSG_RESULT(yes)
  STATIC=""
else
  AC_MSG_RESULT(no)
  STATIC="-static "
fi
AC_SUBST(STATIC)

fp_WITH_DMALLOC
fp_WITH_REGEX

# ---------------------------------------------------------------------------
if test "$ac_cv_func_alloca" = 'no'; then
dnl    support functions for alloca.c
  AC_LIBOBJ([xmalloc])
  AC_LIBOBJ([error])
fi


# ---------------------------------------------------------------------------

dnl
dnl Switch into C++
dnl
AC_LANG([C++])

dnl
dnl Check that the GDBM library is available
dnl
dnl check libgdbm manually, in case it's not in the standard location.

AC_MSG_CHECKING(that the GDBM library is available)
if test ! -z "$gdbmdir" ; then
  # look in given directory for header file
  if test -r $gdbmdir/include/gdbm.h ; then
    GDBM_INCLUDE="-I$gdbmdir/include" ;
  elif test -r $gdbmdir/gdbm.h ; then
    GDBM_INCLUDE="-I$gdbmdir" ;
  fi

  # look in given directory for library
  if test -r $gdbmdir/libgdbm.a ; then
    GDBM_LIBPATH="-L$gdbmdir" ;
  elif test -r $gdbmdir/lib/libgdbm.a ; then
    GDBM_LIBPATH="-L$gdbmdir/lib" ;
  elif test -r $gdbmdir/.libs/libgdbm.a ; then
    GDBM_LIBPATH="-L$gdbmdir/.libs" ;
  fi

  if test ! -z "$GDBM_LIBPATH" -a ! -z "$GDBM_INCLUDE" ; then
    AC_MSG_RESULT($gdbmdir) ;
  else
    AC_MSG_RESULT(can't find gdbm.h and libgdbm.a in $gdbmdir);
    AC_MSG_CHECKING(   looking for GDBM library in default locations)
  fi
fi

# look in default path and in /usr/local
if test -z "$GDBM_INCLUDE" ; then
  # try in system directory 
  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gdbm.h>
]], [[]])],[success=yes],[success=no
  ])

  if test $success = "no"; then
# last chance - look in /usr/local (eg FreeBSD)
    GDBM_LIBPATH=-L/usr/local/lib
    GDBM_INCLUDE=-I/usr/local/include
    ac_save_CXXFLAGS="$CXXFLAGS"
    ac_save_LIBS="$LIBS"
      CXXFLAGS="$CXXFLAGS -I/usr/local/include"
      LIBS="$LIBS -L/usr/local/lib -lgdbm"
      AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gdbm.h>
#include <stdio.h>
    ]], [[printf("%s",gdbm_version);]])],[success=/usr/local],[success=no
      ])
      CXXFLAGS=$ac_save_CXXFLAGS
      LIBS=$ac_save_LIBS
  fi

  AC_MSG_RESULT($success)
  if test $success = "no"; then
  AC_MSG_ERROR(GDBM Library not available - cannot install)
  fi
fi
dnl I don't think anything actually checks this define, but...
AC_DEFINE(HAVE_LIBGDBM , 1)

AC_SUBST(GDBM_LIBPATH)
AC_SUBST(GDBM_INCLUDE)

dnl
dnl Now check that Perl is actually around, and can be found
dnl
AC_MSG_CHECKING(that Perl 5 is available)
success="no"
pl_path="$PATH"
IFS="${IFS=   }"; pl_save_ifs="$IFS"; IFS=":"
for pl_dir in $pl_path; do
  test -z "$pl_dir" && pl_dir=.
  if test -x $pl_dir/perl; then
    success="yes"
    break
  fi
done
IFS="$pl_save_ifs"

dnl
dnl Perl actually can be run; now we see if it is version 5 by
dnl running a sample script (which returns a "clean" version number
dnl and then tests the result using expr.  If perl errors in some
dnl way (eg. broken Perl executable, missing script), we set a failure
dnl value ("0") and then proceed as best we can
dnl
if test $success = "yes"; then
try=`perl configtest.pl` || try="0"
try=`expr $try \> 5.000`
if test $try = "1"; then
AC_MSG_RESULT("yes")
else
success="no"
fi
fi

if test $success = "no"; then
AC_MSG_RESULT("no")
AC_MSG_ERROR("Perl 5 not available - cannot install")
fi

dnl
dnl Check if the STL library has any known faults;
dnl In GCC 2.7.2.x series, some STL library headers are missing
dnl a file called "new" which is referred to by other headers
dnl (eg. vector/vector.h); if this applies, then all use of the
dnl STL will cause a compile fail, so we'd better let the user
dnl know now, before things really go wrong!
dnl
success=no
AC_MSG_CHECKING("whether STL library has known faults")

dnl - first shot, try simple good old vector on its own
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <vector>
]], [[]])],[success=yes],[])

dnl - try using the .h equivalent
if test $success = "no"; then
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <vector.h>
]], [[]])],[success="yes"],[])
fi

dnl - now try for the objectspace headers
if test $success = "no"; then
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <ospace\\std\\vector>
]], [[]])],[success="yes"],[])
fi

if test $success = yes; then
AC_MSG_RESULT("no")
else
AC_MSG_RESULT("yes")
AC_MSG_ERROR("STL Broken - Obtain newer version of GNU C Compiler")
fi

gsdlos=`uname | tr ABCDEFGHIJKLMNOPQRSTUVWXYZ abcdefghijklmnopqrstuvwxyz`
# check for running bash under cygwin
 if test "`echo $gsdlos | sed 's/cygwin//'`" != "$gsdlos" ;
 then
  gsdlos=windows
 fi
AC_SUBST(gsdlos)

# check for endianness
AC_C_BIGENDIAN
# ---------------------------------------------------------------------------
if test "$ac_cv_func_alloca" = 'no'; then
dnl    support functions for alloca.c
  AC_LIBOBJ([xmalloc.o])
  AC_LIBOBJ([error])
fi

# ---------------------------------------------------------------------------

dnl
dnl Locate all children of the modules folder
dnl
moduleDirs=""
MODULEDIRS=""
for x in `find modules -mindepth 1 -maxdepth 2`; do
  if test -d "$x"; then
    d="$x/Makefile.in"
    if test -e "$d"; then
dnl      echo $d
      moduleDirs="$moduleDirs $x/Makefile"
      MODULEDIRS="$MODULEDIRS $x"
    fi
  fi
done
echo "Making$moduleDirs in modules directory"
AC_SUBST(MODULEDIRS)

# ---------------------------------------------------------------------------
dnl for Darwin, as our packages don't (yet) correctly guess our system type.
dnl not needed any more?
dnl ac_configure_args="$ac_configure_args --build=$build --target=$target"

# indexers needs bindir option to get the binaries into the 
# right place
gsdlprefix=`pwd`
ac_configure_args="$ac_configure_args --bindir=$gsdlprefix/bin/$gsdlos "

AC_CONFIG_SUBDIRS(packages indexers)

# the list of folders in the src folder
srclist="src/hashfile/Makefile src/gdbmedit/txt2db/Makefile src/gdbmedit/db2txt/Makefile src/phind/generate/Makefile "

AC_CONFIG_FILES([packages/Makefile src/lib/Makefile Makefile $srclist $moduleDirs])
AC_OUTPUT