source: trunk/gli/gems4gs3.bat@ 13676

@echo off
set GLILANG=en

::  -------- Run the Greenstone Editor for Metadata Sets --------

:: This script must be run from within the directory in which it lives
if exist gems.bat goto start
    if "%GLILANG%" == "en" echo This script must be run from the directory in which it resides.
    if "%GLILANG%" == "es" echo Este gui¢n deber  ejecutarse desde el directorio en el que reside.
    if "%GLILANG%" == "fr" echo Ce script doit ˆtre ex‚cut‚ …
 partir du r‚pertoire dans lequel il se trouve.
    if "%GLILANG%" == "ru" echo â®â áªàš¯â €®«Š¥­ ¡ëâì ¢§ïâ š§ €šà¥ªâ®àšš, ¢ ª®â®à®© ®­ à ᯮ«®Š¥­
    goto exit

:start
if "%OS%" == "Windows_NT" goto findGSDL3
    :: Invoke a new command processor to ensure there's enough environment space
    if "%1" == "Second" goto findGSDL3
        command /E:2048 /C %0 Second %1 %2 %3 %4 %5 %6 %7 %8 %9
        goto done

:findGSDL3
echo.
if "%GLILANG%" == "en" echo Greenstone Editor for Metadata Sets (GEMS)
if "%GLILANG%" == "en" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%GLILANG%" == "en" echo GEMS comes with ABSOLUTELY NO WARRANTY; for details see LICENSE.txt
if "%GLILANG%" == "en" echo This is free software, and you are welcome to redistribute it

if "%GLILANG%" == "es" echo Editar conjuntos de metadatos (Greenstone Editor for Metadata Sets - GEMS)
if "%GLILANG%" == "es" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%GLILANG%" == "es" echo GEMS NO INCLUYE ABSOLUTAMENTE NINGUNA GARANTÖA.
if "%GLILANG%" == "es" echo Para mayor informaci¢n vea los t‚rminos de la licencia en LICENSE.txt
if "%GLILANG%" == "es" echo Este es un software abierto, por lo que lo invitamos a que lo distribuya de forma gratuita

if "%GLILANG%" == "fr" echo Editer les jeux de méta-données (Greenstone Editor for Metadata Sets - GEMS)
if "%GLILANG%" == "fr" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%GLILANG%" == "fr" echo GEMS est fourni sans AUCUNE GARANTIE; pour des d‚tails, voir LICENSE.txt
if "%GLILANG%" == "fr" echo Ceci est un logiciel libre, et vous ˆtes invit‚ …
 le redistribuer

if "%GLILANG%" == "ru" echo Ðåäàêòèðîâàòü íàáîðû ìåòàäàííûõ (Greenstone Editor for Metadata Sets - GEMS)
if "%GLILANG%" == "ru" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%GLILANG%" == "ru" echo ˆƒ ­¥ € ¥â €‘Ž‹ž’Ž ˆŠ€Šˆ• ƒ€€’ˆ‰; €¥â «š á¬. ¢ ⥪á⥠LICENSE.TXT
if "%GLILANG%" == "ru" echo â® - ᢮¡®€­® à á¯à®áâà ­ï¥¬®¥ ¯à®£à ¬¬­®¥ ®¡¥á¯¥ç¥­š¥ š ‚ë ¬®Š¥â¥ à á¯à®áâà ­ïâì ¥£®

echo.
::  ---- Determine GSDL3HOME ----
set GSDL3SRCPATH=

:: Some users may set the above line manually
if not "%GSDL3SRCPATH%" == "" goto testGSDL3
    :: The default location for the GLI (and thus GEMS) is a subdirectory of Greenston
    set GSDL3SRCPATH=..
    :: If it is set, use the GSDLSRCHOME environment variable 
    if "%GSDL3SRCHOME%" == "" goto testGSDL3
    set GSDL3SRCPATH=%GSDL3SRCHOME%


:testGSDL3
:: Check that the Greenstone installation looks OK
if "%GLILANG%" == "en" echo Checking GSDL3: %GSDL3SRCPATH%
if "%GLILANG%" == "es" echo Revisando GSDL3: %GSDL3SRCPATH%
if "%GLILANG%" == "fr" echo V‚rification de GSDL3: %GSDLSRCPATH%
if "%GLILANG%" == "ru" echo à®¢¥àª  GSDL3: %GSDLSRCPATH%
:: Some users may set the above line manually
if exist "%GSDL3SRCPATH%\gs3-setup.bat" goto prepGSDL3
    echo.
    if "%GLILANG%" == "en" echo The Greenstone installation could not be found, or is incomplete.
    if "%GLILANG%" == "en" echo Try reinstalling Greenstone then running this script again.

    if "%GLILANG%" == "es" echo No se pudo encontrar la instalaci¢n de Greenstone o est  incompleta.
    if "%GLILANG%" == "es" echo Trate de reinstalar Greenstone y a continuaci¢n ejecute nuevamente este gui¢n.

    if "%GLILANG%" == "fr" echo L'installation de Greenstone est introuvable ou incomplŠte. Essayez
    if "%GLILANG%" == "fr" echo de r‚installer Greenstone et ex‚cutez ce script …
 nouveau.

    if "%GLILANG%" == "ru" echo ˆ­áâ ««ïæšï Greenstone ­¥ ¡ë«  ­ ©€¥­  š«š ®­  ­¥¯®«­ . ®¯à®¡ã©â¥ ¯®¢â®à­®
    if "%GLILANG%" == "ru" echo ãáâ ­®¢šâì Greenstone,   § ⥬ ¢¢¥áâš íâ®â áªàš¯â á­®¢ .
    goto exit

:prepGSDL3
:: Setup Greenstone, unless it has already been done
if not "%GSDL3SRCHOME%" == "" goto doneGSDL3
    call "%GSDL3SRCPATH%\gs3-setup.bat" SetEnv > nul


:doneGSDL3
:: GSDL3SRCPATH is no longer needed, since GSDL3HOME should now be set
set GSDL3SRCPATH=

:findJava
:: ---- Check Java exists ----
set JAVAPATH=

:: Some users may set the above line manually
if not "%JAVAPATH%" == "" goto testJava

    :: If it is set, use the JAVA_HOME environment variable
    if not "%JAVA_HOME%" == "" goto javahome

    :: Check if Java is on the search path
    echo %PATH%| winutil\which.exe java.exe | winutil\setvar.exe JAVAPATH > setjava.bat
    call setjava.bat
    del setjava.bat
    if not "%JAVAPATH%" == "" goto testJava

    :: Still haven't found anything, so try looking in the registry (gulp!)
    type nul > jdk.reg
    regedit /E jdk.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit"
    type jdk.reg > jdk.txt
    del jdk.reg
    type nul > jre.reg
    regedit /E jre.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Runtime Environment"
    type jre.reg > jre.txt
    del jre.reg

    winutil\findjava.exe jdk.txt jre.txt | winutil\setvar.exe JAVAPATH > setjava.bat
    del jdk.txt
    del jre.txt
    call setjava.bat
    del setjava.bat

    :: If nothing was found in the registry, we're stuck
    if "%JAVAPATH%" == "" goto noJava

    set JAVAPATH=%JAVAPATH%\bin
    goto testJava

:javahome
    set JAVAPATH=%JAVA_HOME%\bin

:testJava
:: Check that a Java executable has been found
if "%GLILANG%" == "en" echo Checking Java: %JAVAPATH%
if "%GLILANG%" == "es" echo Revisando Java: %JAVAPATH%
if "%GLILANG%" == "fr" echo V‚rification de Java: %JAVAPATH%
if "%GLILANG%" == "ru" echo à®¢¥àª  Java: %JAVAPATH%
if exist "%JAVAPATH%\java.exe" goto checkGEMS

:noJava
    echo.
    if "%GLILANG%" == "en" echo Failed to locate an appropriate version of Java. You must install a
    if "%GLILANG%" == "en" echo Java Runtime Environment (version 1.4 or greater) before running the
    if "%GLILANG%" == "en" echo Greenstone Editor for Metadata Sets.

    if "%GLILANG%" == "es" echo No se pudo localizar una versi¢n apropiada de Java. Usted deber 
    if "%GLILANG%" == "es" echo instalar un Ambiente de Ejecuci¢n Java (versi¢n 1.4 o superior)
    if "%GLILANG%" == "es" echo antes de correr la Editar conjuntos de metadatos.

    if "%GLILANG%" == "fr" echo Une version ad‚quate de Java n'a pas pu ˆtre localis‚e. Vous devez
    if "%GLILANG%" == "fr" echo installer un Java Runtime Environment (version 1.4 ou sup‚rieur)
    if "%GLILANG%" == "fr" echo avant de d‚marrer Editer les jeux de méta-données.

    if "%GLILANG%" == "ru" echo ¥ 〠«®áì ®¯à¥€¥«šâì ¬¥áâ®­ 宊€¥­š¥ ᮮ⢥âáâ¢ãî饩 ¢¥àášš Java.
    if "%GLILANG%" == "ru" echo ‚ë €®«Š­ë ãáâ ­®¢šâì Java Runtime Environment (¢¥àášî 1.4 š«š ¢ëè¥) ¯¥à¥€ ¢¢®€®¬
    if "%GLILANG%" == "ru" echo Ðåäàêòèðîâàòü íàáîðû ìåòàäàííûõ.
    goto exit


:checkGEMS
:: ---- Check that the GEMS has been compiled ----
if exist "classes/org/greenstone/gatherer/gems/GEMS.class" goto runGEMS
if exist "GLI.jar" goto runGEMS
    echo.
    if "%GLILANG%" == "en" echo You need to compile the Greenstone Editor for Metadata Sets (using makegli.bat)
    if "%GLILANG%" == "en" echo before running this script.

    if "%GLILANG%" == "es" echo Usted necesita compilar la Editar conjuntos de metadatos
    if "%GLILANG%" == "es" echo (por medio de makegli.bat) antes de ejecutar este gui¢n.

    if "%GLILANG%" == "fr" echo Vous devez compiler le Editer les jeux de méta-données (en utilisant
    if "%GLILANG%" == "fr" echo makegli.bat) avant d'ex‚cuter ce script.

    if "%GLILANG%" == "ru" echo ‚ë €®«Š­ë ª®¬¯š«šà®¢ âì Ðåäàêòèðîâàòü íàáîðû ìåòàäàííûõ (šá¯®«ì§ãï makegli.bat)
    if "%GLILANG%" == "ru" echo ¯¥à¥€ ¢¢®€®¬ í⮣® áªàš¯â 
    goto exit


:runGEMS
:: ---- Finally, run the GEMS ----
echo.

if "%GLILANG%" == "en" echo Running the Greenstone Editor for Metadata Sets...
if "%GLILANG%" == "es" echo Ejecutando la Editar conjuntos de metadatos...
if "%GLILANG%" == "fr" echo Ex‚cution de Editer les jeux de méta-données
if "%GLILANG%" == "ru" echo ’¥ªãéš© Ðåäàêòèðîâàòü íàáîðû ìåòàäàííûõ...

:: -Xms32M          To set minimum memory
:: -Xmx32M          To set maximum memory
:: -verbose:gc      To set garbage collection messages
:: -Xincgc          For incremental garbage collection
:: -Xprof           Function call profiling
:: -Xloggc:<file>   Write garbage collection log

"%JAVAPATH%\java" -cp classes/;GLI.jar;lib/apache.jar org.greenstone.gatherer.gems.GEMS -gsdl3 %GSDL3HOME% %1 %2 %3 %4 %5 %6 %7 %8 %9

if "%GLILANG%" == "en" echo Done!
if "%GLILANG%" == "es" echo ­Hecho!
if "%GLILANG%" == "fr" echo Termin‚!
if "%GLILANG%" == "ru" echo ‚믮«­¥­®!
goto done

:exit
echo.
pause

:done
:: ---- Clean up ----
set JAVAPATH=