@echo off
set GLILANG=en


::  -------- Run the Greenstone Librarian Interface --------

:: This script must be run from within the directory in which it lives
if exist gli4gs3.bat goto start
    if "%GLILANG%" == "en" echo This script must be run from the directory in which it resides.
    if "%GLILANG%" == "es" echo Este gui¢n deber  ejecutarse desde el directorio en el que reside.
    if "%GLILANG%" == "fr" echo Ce script doit ˆtre ex‚cut‚ … partir du r‚pertoire dans lequel il se trouve.
    if "%GLILANG%" == "ru" echo �â®â áªà¨¯â ¤®«¦¥­ ¡ëâì ¢§ïâ ¨§ ¤¨à¥ªâ®à¨¨, ¢ ª®â®à®© ®­ à á¯®«®¦¥­
    goto exit

:start
if "%OS%" == "Windows_NT" goto findGSDL3
    :: Invoke a new command processor to ensure there's enough environment space
    if "%1" == "Second" goto findGSDL3
        command /E:2048 /C %0 Second %1 %2 %3 %4 %5 %6 %7 %8 %9
        goto done

:findGSDL3
echo.
if "%GLILANG%" == "en" echo Greenstone Librarian Interface (GLI)
if "%GLILANG%" == "en" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%GLILANG%" == "en" echo GLI comes with ABSOLUTELY NO WARRANTY; for details see LICENSE.txt
if "%GLILANG%" == "en" echo This is free software, and you are welcome to redistribute it

if "%GLILANG%" == "es" echo Interfaz de la Biblioteca Digital Greenstone (Greenstone Librarian Interface - GLI)
if "%GLILANG%" == "es" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%GLILANG%" == "es" echo La Interfaz de la Biblioteca Digital Greenstone NO INCLUYE ABSOLUTAMENTE NINGUNA GARANTÖA.
if "%GLILANG%" == "es" echo Para mayor informaci¢n vea los t‚rminos de la licencia en LICENSE.txt
if "%GLILANG%" == "es" echo Este es un software abierto, por lo que lo invitamos a que lo distribuya de forma gratuita

if "%GLILANG%" == "fr" echo Interface du Biblioth‚caire Greenstone (Greenstone Librarian Interface - GLI)
if "%GLILANG%" == "fr" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%GLILANG%" == "fr" echo GLI est fourni sans AUCUNE GARANTIE; pour des d‚tails, voir LICENSE.txt
if "%GLILANG%" == "fr" echo Ceci est un logiciel libre, et vous ˆtes invit‚ … le redistribuer

if "%GLILANG%" == "ru" echo �¨¡«¨®â¥ç­ë© ¨­â¥à䥩á Greenstone (Greenstone Librarian Interface - GLI)
if "%GLILANG%" == "ru" echo Copyright (C) 2006, New Zealand Digital Library Project, University Of Waikato
if "%GLILANG%" == "ru" echo �ˆƒ ­¥ ¤ ¥â €�‘Ž‹ž’�Ž �ˆŠ€Šˆ• ƒ€�€�’ˆ‰; ¤¥â «¨ á¬. ¢ ⥪á⥠LICENSE.TXT
if "%GLILANG%" == "ru" echo �â® - ᢮¡®¤­® à á¯à®áâ࠭塞®¥ ¯à®£à ¬¬­®¥ ®¡¥á¯¥ç¥­¨¥ ¨ ‚ë ¬®¦¥â¥ à á¯à®áâà ­ïâì ¥£®

echo.
::  ---- Determine GSDL3HOME ----
set GSDL3PATH=%GSDL3PATH%

:: Some users may set the above line manually, or it may be set as an argument
if not "%GSDL3PATH%" == "" goto testGSDL3

    :: The default location for the GLI is a subdirectory of Greenstone 3
    set GSDL3PATH=..

    :: If it is set, use the GSDL3HOME environment variable
    if "%GSDL3SRCHOME%" == "" goto testGSDL3
	set GSDL3PATH=%GSDL3SRCHOME%

:testGSDL3
:: Check that the Greenstone 3 installation looks OK
if "%GLILANG%" == "en" echo Checking GSDL3: %GSDL3PATH%
if "%GLILANG%" == "es" echo Revisando GSDL3: %GSDL3PATH%
if "%GLILANG%" == "fr" echo V‚rification de GSDL3: %GSDL3PATH%
if "%GLILANG%" == "ru" echo �஢¥àª  GSDL3: %GSDL3PATH%
if exist "%GSDL3PATH%\gs3-setup.bat" goto prepGSDL3
    echo.
    if "%GLILANG%" == "en" echo The Greenstone 3 installation could not be found, or is incomplete.
    if "%GLILANG%" == "en" echo Try reinstalling Greenstone 3 then running this script again.

    if "%GLILANG%" == "es" echo No se pudo encontrar la instalaci¢n de Greenstone 3 o est  incompleta.
    if "%GLILANG%" == "es" echo Trate de reinstalar Greenstone 3 y a continuaci¢n ejecute nuevamente este gui¢n.

    if "%GLILANG%" == "fr" echo L'installation de Greenstone 3 est introuvable ou incomplŠte. Essayez
    if "%GLILANG%" == "fr" echo de r‚installer Greenstone 3 et ex‚cutez ce script … nouveau.

    if "%GLILANG%" == "ru" echo ˆ­áâ ««ïæ¨ï Greenstone 3 ­¥ ¡ë«  ­ ©¤¥­  ¨«¨ ®­  ­¥¯®«­ . �®¯à®¡ã©â¥ ¯®¢â®à­®
    if "%GLILANG%" == "ru" echo ãáâ ­®¢¨âì Greenstone, 3   § â¥¬ ¢¢¥á⨠íâ®â áªà¨¯â á­®¢ .
    goto exit

:prepGSDL3
:: Setup Greenstone 3, unless it has already been done
if not "%GSDL3SRCHOME%" == "" goto doneGSDL3
    cd | winutil\setvar.exe GLIDIR > setgli.bat
    call setgli.bat
    del setgli.bat
    cd "%GSDL3PATH%"
    call gs3-setup.bat SetEnv > nul
    cd %GLIDIR%

:doneGSDL3
:: GSDL3PATH is no longer needed, since GSDL3HOME should now be set
set GSDL3PATH=


::  ---- Determine GSDLHOME ----
set GSDLPATH=%GSDLPATH%

:: Some users may set the above line manually, or it may be set in the environment
if not "%GSDLPATH%" == "" goto testGSDL

    :: The default location for Greenstone is a gs2build subdirectory of Greenstone 3
    set GSDLPATH=%GSDL3SRCHOME%\gs2build

    :: If it is set, use the GSDLHOME environment variable
    if "%GSDLHOME%" == "" goto testGSDL
	set GSDLPATH=%GSDLHOME%

:testGSDL
:: Check that the Greenstone installation looks OK
if "%GLILANG%" == "en" echo Checking GSDL: %GSDLPATH%
if "%GLILANG%" == "es" echo Revisando GSDL: %GSDLPATH%
if "%GLILANG%" == "fr" echo V‚rification de GSDL: %GSDLPATH%
if "%GLILANG%" == "ru" echo �஢¥àª  GSDL: %GSDLPATH%
if exist "%GSDLPATH%\setup.bat" goto prepGSDL
    echo.
    if "%GLILANG%" == "en" echo The Greenstone installation could not be found, or is incomplete.
    if "%GLILANG%" == "en" echo Try reinstalling Greenstone then running this script again.

    if "%GLILANG%" == "es" echo No se pudo encontrar la instalaci¢n de Greenstone o est  incompleta.
    if "%GLILANG%" == "es" echo Trate de reinstalar Greenstone y a continuaci¢n ejecute nuevamente este gui¢n.

    if "%GLILANG%" == "fr" echo L'installation de Greenstone est introuvable ou incomplŠte. Essayez
    if "%GLILANG%" == "fr" echo de r‚installer Greenstone et ex‚cutez ce script … nouveau.

    if "%GLILANG%" == "ru" echo ˆ­áâ ««ïæ¨ï Greenstone ­¥ ¡ë«  ­ ©¤¥­  ¨«¨ ®­  ­¥¯®«­ . �®¯à®¡ã©â¥ ¯®¢â®à­®
    if "%GLILANG%" == "ru" echo ãáâ ­®¢¨âì Greenstone,   § â¥¬ ¢¢¥á⨠íâ®â áªà¨¯â á­®¢ .
    goto exit

:prepGSDL
:: Setup Greenstone, unless it has already been done
if not "%GSDLHOME%" == "" goto doneGSDL
    call "%GSDLPATH%\setup.bat" SetEnv > nul

:doneGSDL
:: GSDLPATH is no longer needed, since GSDLHOME should now be set
set GSDLPATH=


:findPerl
::  ---- Check Perl exists ----
set PERLPATH=

:: Some users may set the above line manually
if not "%PERLPATH%" == "" goto testPerl

    :: Check if Perl is on the search path
    echo %PATH%| winutil\which.exe perl.exe | winutil\setvar.exe PERLPATH > setperl.bat
    call setperl.bat
    del setperl.bat
    if not "%PERLPATH%" == "" goto testPerl

    :: If not, try GSDLHOME\bin\windows\perl\bin
    if exist "%GSDLHOME%\bin\windows\perl\bin\perl.exe" goto gsdlPerl

    :: Still haven't found anything, so try looking in the registry (gulp!)
    type nul > perl.reg
    regedit /E perl.reg "HKEY_LOCAL_MACHINE\SOFTWARE\Perl"
    type perl.reg > perl.txt
    del perl.reg

    winutil\findperl.exe perl.txt | winutil\setvar.exe PERLPATH > setperl.bat
    del perl.txt
    call setperl.bat
    del setperl.bat

    :: If nothing was found in the registry, we're stuck
    if "%PERLPATH%" == "" goto noPerl

    goto testPerl

:gsdlPerl
    set PERLPATH=%GSDLHOME%\bin\windows\perl\bin

:testPerl
:: Check that a Perl executable has been found
if "%GLILANG%" == "en" echo Checking Perl: %PERLPATH%
if "%GLILANG%" == "es" echo Revisando Perl: %PERLPATH%
if "%GLILANG%" == "fr" echo V‚rification de Perl: %PERLPATH%
if "%GLILANG%" == "ru" echo �஢¥àª  Perl: %PERLPATH%
if exist "%PERLPATH%\perl.exe" goto findJava

:noPerl
    echo.
    if "%GLILANG%" == "en" echo The Greenstone Librarian Interface requires perl in order to operate,
    if "%GLILANG%" == "en" echo but perl could not be detected on your system. Please ensure that perl
    if "%GLILANG%" == "en" echo is installed and is on your search path, then rerun this script.

    if "%GLILANG%" == "es" echo La Interfaz de la Biblioteca Digital Greenstone requiere Perl para poder
    if "%GLILANG%" == "es" echo operar, pero ‚ste no aparece en su sistema. Por favor aseg£rese de
    if "%GLILANG%" == "es" echo que Perl est  instalado y se encuentra en su ruta de b£squeda.
    if "%GLILANG%" == "es" echo A continuaci¢n ejecute nuevamente este gui¢n.

    if "%GLILANG%" == "fr" echo Greenstone Librarian Interface n‚cessite perl pour son fonctionnement,
    if "%GLILANG%" == "fr" echo mais perl n'a pas pu ˆtre d‚tect‚ dans votre systŠme. Veuillez vous 
    if "%GLILANG%" == "fr" echo assurer que perl est install‚ et est sp‚cifi‚ dans votre chemin de 
    if "%GLILANG%" == "fr" echo recherche, puis red‚marrez ce script.

    if "%GLILANG%" == "ru" echo �¨¡«¨®â¥ç­ë© ¨­â¥à䥩á Greenstone âॡã¥â Perl, çâ®¡ë ¨¬¥âì ¢®§¬®¦­®áâì
    if "%GLILANG%" == "ru" echo à ¡®â âì, ­® Perl ­¥ ¡ë« ¢ ¢ è¥© á¨á⥬¥. �®¦ «ã©áâ , ¯®¤â¢¥à¤¨â¥,
    if "%GLILANG%" == "ru" echo çâ® Perl ãáâ ­®¢«¥­ ¨ ­ å®¤¨âáï ­  ¢ è¥¬ ¯ã⨠¯®¨áª , § â¥¬
    if "%GLILANG%" == "ru" echo ¯®¢â®à­®¢¢¥¤¨â¥ íâ®â áªà¨¯â.
    goto exit


:findJava
:: ---- Check Java exists ----
set JAVAPATH=

:: Some users may set the above line manually
if not "%JAVAPATH%" == "" goto testJava

    :: If it is set, use the JAVA_HOME environment variable
    if not "%JAVA_HOME%" == "" goto javahome

    :: Check if Java is on the search path
    echo %PATH%| winutil\which.exe java.exe | winutil\setvar.exe JAVAPATH > setjava.bat
    call setjava.bat
    del setjava.bat
    if not "%JAVAPATH%" == "" goto testJava

    :: Still haven't found anything, so try looking in the registry (gulp!)
    type nul > jdk.reg
    regedit /E jdk.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit"
    type jdk.reg > jdk.txt
    del jdk.reg
    type nul > jre.reg
    regedit /E jre.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Runtime Environment"
    type jre.reg > jre.txt
    del jre.reg

    winutil\findjava.exe jdk.txt jre.txt | winutil\setvar.exe JAVAPATH > setjava.bat
    del jdk.txt
    del jre.txt
    call setjava.bat
    del setjava.bat

    :: If nothing was found in the registry, we're stuck
    if "%JAVAPATH%" == "" goto noJava

    set JAVAPATH=%JAVAPATH%\bin
    goto testJava

:javahome
    set JAVAPATH=%JAVA_HOME%\bin

:testJava
:: Check that a Java executable has been found
if "%GLILANG%" == "en" echo Checking Java: %JAVAPATH%
if "%GLILANG%" == "es" echo Revisando Java: %JAVAPATH%
if "%GLILANG%" == "fr" echo V‚rification de Java: %JAVAPATH%
if "%GLILANG%" == "ru" echo �஢¥àª  Java: %JAVAPATH%
if exist "%JAVAPATH%\java.exe" goto checkGLI

:noJava
    echo.
    if "%GLILANG%" == "en" echo Failed to locate an appropriate version of Java. You must install a
    if "%GLILANG%" == "en" echo Java Runtime Environment (version 1.4 or greater) before running the
    if "%GLILANG%" == "en" echo Greenstone Librarian Interface.

    if "%GLILANG%" == "es" echo No se pudo localizar una versi¢n apropiada de Java. Usted deber 
    if "%GLILANG%" == "es" echo instalar un Ambiente de Ejecuci¢n Java (versi¢n 1.4 o superior)
    if "%GLILANG%" == "es" echo antes de correr la Interfaz de la Biblioteca Digital Greenstone.

    if "%GLILANG%" == "fr" echo Une version ad‚quate de Java n'a pas pu ˆtre localis‚e. Vous devez
    if "%GLILANG%" == "fr" echo installer un Java Runtime Environment (version 1.4 ou sup‚rieur)
    if "%GLILANG%" == "fr" echo avant de d‚marrer Greenstone Librarian Interface.

    if "%GLILANG%" == "ru" echo �¥ 㤠«®áì ®¯à¥¤¥«¨âì ¬¥áâ®­ å®¦¤¥­¨¥ ᮮ⢥âáâ¢ãî饩 ¢¥àᨨ Java.
    if "%GLILANG%" == "ru" echo ‚ë ¤®«¦­ë ãáâ ­®¢¨âì Java Runtime Environment (¢¥àá¨î 1.4 ¨«¨ ¢ëè¥) ¯¥à¥¤ ¢¢®¤®¬
    if "%GLILANG%" == "ru" echo ¡¨¡«¨®â¥ç­®£® ¨­â¥àä¥©á  Greenstone.
    goto exit


:checkGLI
:: ---- Check that the GLI has been compiled ----
if exist "classes/org/greenstone/gatherer/GathererProg.class" goto runGLI
if exist "GLI.jar" goto runGLI
    echo.
    if "%GLILANG%" == "en" echo You need to compile the Greenstone Librarian Interface (using makegli.bat)
    if "%GLILANG%" == "en" echo before running this script.

    if "%GLILANG%" == "es" echo Usted necesita compilar la Interfaz de la Biblioteca Digital Greenstone
    if "%GLILANG%" == "es" echo (por medio de makegli.bat) antes de ejecutar este gui¢n.

    if "%GLILANG%" == "fr" echo Vous devez compiler le Greenstone Interface (en utilisant makegil.bat)
    if "%GLILANG%" == "fr" echo avant d'ex‚cuter ce script.

    if "%GLILANG%" == "ru" echo ‚ë ¤®«¦­ë ª®¬¯¨«¨à®¢ âì ¡¨¡«¨®â¥ç­ë© ¨­â¥à䥩á Greenstone (¨á¯®«ì§ãï makegli.bat)
    if "%GLILANG%" == "ru" echo ¯¥à¥¤ ¢¢®¤®¬ í⮣® áªà¨¯â 
    goto exit


:runGLI
:: ---- Finally, run the GLI ----
echo.

if "%GLILANG%" == "en" echo Running the Greenstone Librarian Interface...
if "%GLILANG%" == "es" echo Ejecutando la Interfaz de la Biblioteca Digital Greenstone...
if "%GLILANG%" == "fr" echo Ex‚cution de Greenstone Librarian Interface
if "%GLILANG%" == "ru" echo ’¥ªã騩 ¡¨¡«¨®â¥ç­ë© ¨­â¥à䥩á Greenstone...

:: -Xms32M          To set minimum memory
:: -Xmx32M          To set maximum memory
:: -verbose:gc      To set garbage collection messages
:: -Xincgc          For incremental garbage collection
:: -Xprof           Function call profiling
:: -Xloggc:<file>   Write garbage collection log

"%JAVAPATH%\java" -cp classes/;GLI.jar;lib/apache.jar;lib/qfslib.jar org.greenstone.gatherer.GathererProg -gsdl %GSDLHOME% -gsdlos %GSDLOS% -gsdl3 %GSDL3HOME% -gsdl3src %GSDL3SRCHOME% -perl %PERLPATH% %1 %2 %3 %4 %5 %6 %7 %8 %9

if "%GLILANG%" == "en" echo Done!
if "%GLILANG%" == "es" echo ­Hecho!
if "%GLILANG%" == "fr" echo Termin‚!
if "%GLILANG%" == "ru" echo ‚믮«­¥­®!
goto done

:exit
echo.
pause

:done
:: ---- Clean up ----
set PERLPATH=
set JAVAPATH=