source: trunk/gsdl/perllib/arcinfo.pm@ 14

# This module stores information about the archives. At the moment
# this information just consists of the file name (relative to the
# directory the archives information file is in) and its OID.

# This module assumes there is a one to one correspondance between
# a file in the archives directory and an OID.


package arcinfo;

sub new {
    my ($class) = @_;
    my $self = {'info'=>{},
        'order'=>[]};

    return bless $self, $class;
}

sub load_info {
    my $self = shift (@_);
    my ($filename) = @_;

    $self->{'info'} = {};

    if (-e $filename) {
    open (INFILE, $filename) || 
        die "arcinfo::load_info couldn't read $filename\n";

    my ($line, @line);
    while (defined ($line = <INFILE>)) {
        $line =~ s/\cM|\cJ//g; # remove end-of-line characters
        @line = split ("\t", $line); # filename, 
        if (scalar(@line) >= 2) {
        $self->add_info (@line);
        }
    }

    close (INFILE);
    }
}

sub save_info {
    my $self = shift (@_);
    my ($filename) = @_;

    my ($OID, $info);

    open (OUTFILE, ">$filename") || 
    die "arcinfo::save_info couldn't write $filename\n";

    foreach $info (@{$self->get_OID_list()}) {
    if (defined $info) {
        print OUTFILE join("\t", @$info), "\n";
    }
    }
    
    close (OUTFILE);
}

sub delete_info {
    my $self = shift (@_);
    my ($OID) = @_;

    if (defined $self->{'info'}->{$OID}) {
    delete $self->{'info'}->{$OID};
    
    my $i = 0;
    while ($i < scalar (@{$self->{'order'}})) {
        if ($self->{'order'}->[$i] eq $OID) {
        splice (@{$self->{'order'}}, $i, 1);
        last;
        }
        
        $i ++;
    }
    }
}

sub add_info {
    my $self = shift (@_);
    my ($OID, $doc_file) = @_;

    $self->delete_info ($OID);
    $self->{'info'}->{$OID} = [$doc_file];
    push (@{$self->{'order'}}, $OID);
}

# returns a list of the form [[OID, doc_file], ...]
sub get_OID_list {
    my $self = shift (@_);

    my ($OID);
    my @list = ();

    foreach $OID (@{$self->{'order'}}) {
    push (@list, [$OID, $self->{'info'}->{$OID}->[0]]);
    }

    return \@list;
}

# returns a list of the form [[doc_file, OID], ...]
sub get_file_list {
    my $self = shift (@_);

    my ($OID);
    my @list = ();

    foreach $OID (@{$self->{'order'}}) {
    push (@list, [$self->{'info'}->{$OID}->[0], $OID]);
    }

    return \@list;
}


# returns a list of the form [doc_file]
sub get_info {
    my $self = shift (@_);
    my ($OID) = @_;

    if (defined $self->{'info'}->{$OID}) {
    return $self->{'info'}->{$OID};
    }

    return undef;
}


1;