source: trunk/gsdl/perllib/classify/AZClassify.pm@ 244

# classifier plugin for sorting alphabetically

package AZClassify;

sub new {
    my ($class, @options) = @_;

    if (!defined @options || !scalar @options) {
    die "AZClassify used with no metadata name to classify by\n";
    }

    return bless {
    'OID'=>"NULL",
    'list'=>{},
    'metaname' => $options[0]
    }, $class;
}

sub init {
    my $self = shift (@_);

    $self->{'list'} = {};
}

sub set_OID {
    my $self = shift (@_);
    my ($OID) = @_;

    $self->{'OID'} = $OID;
}

sub get_OID {
    my $self = shift (@_);
    return $self->{'OID'};
}

sub classify {
    my $self = shift (@_);
    my ($doc_obj) = @_;

    my $doc_OID = $doc_obj->get_OID();
    my $metavalue = $doc_obj->get_metadata_element ($doc_obj->get_top_section(),
                            $self->{'metaname'});

    # if this document doesn't contain the metadata element we're
    # sorting by we won't include it in this classification
    if (defined $metavalue) {
    if ($self->{'metaname'} eq 'Creator') {
        $self->format_string_name_english (\$metavalue);
    } else {
        $self->format_string_english (\$metavalue);
    }
    if (defined $self->{'list'}->{$doc_OID}) {
        print STDERR "WARNING: AZClassify::classify called multiple times for $doc_OID\n";
    } 
    $self->{'list'}->{$doc_OID} = $metavalue;
    }
}

sub output_classify_info {
    my $self = shift (@_);
    my ($handle) = @_;

    my @classlist = sort {$self->{'list'}->{$a} cmp $self->{'list'}->{$b};} keys %{$self->{'list'}};
    my $subclasses = $self->splitlist (\@classlist);

    if (scalar @$subclasses) {
    
    my @contents = ();
    map { push (@contents, "\".$_->[1]"); } @$subclasses;
    # write out top level entry
    $self->output_entry ($handle, $self->{'OID'}, $self->{'metaname'}, \@contents, "List");

    # write out the entries for each sub-classification
    map {$self->output_entry ($handle, "$self->{'OID'}.$_->[1]", $_->[0], $_->[2]);} @$subclasses;
 
    } else {

    # write out top level entry
    $self->output_entry ($handle, $self->{'OID'}, $self->{'metaname'}, \@classlist, "List");
    }
}

# splitlist takes an ordered list of classifications (@$classlistref) and splits it
# up into alphabetical sub-sections. returns a list reference each entry of which is 
# in the form ["sub-section title", "sub-section number", [contents list]]
# note that the title of each classification in @$classlistref is obtained from
# $self->{'list'}->{$classlistref->[n]}
sub splitlist {
    my $self = shift (@_);
    my ($classlistref) = @_;
    my $classhash = {};
    my $rarr = [];

    # don't need to do any splitting if there are less than 20 classifications
    return [] if ((scalar @$classlistref) <= 20);

    # first split up the list into separate A-Z and 0-9 classifications
    foreach $classification (@$classlistref) {
    my $title = $self->{'list'}->{$classification};
    $title =~ s/^(.).*$/$1/;
    $title =~ tr/[a-z]/[A-Z]/;
    if ($title =~ /^[0-9]$/) {$title = '0-9';}
    elsif ($title !~ /^[A-Z]$/) {
        print STDERR "AZClassify: WARNING $classification has badly formatted title ($title)\n";
    }
    $classhash->{$title} = [] unless defined $classhash->{$title};
    push (@{$classhash->{$title}}, $classification);
    }

    $classhash = $self->compactlist ($classhash);

    my $count = 1;
    foreach $subsection (sort keys (%$classhash)) {
    push (@$rarr, [$subsection, $count, $classhash->{$subsection}]);
    $count ++;
    }
    return $rarr;
}

sub compactlist {
    my $self = shift (@_);
    my ($classhashref) = @_;
    my $compactedhash = {};
    my @currentOIDs = ();
    my $currentfirstletter = "";
    my $currentlastletter = "";
    my $lastkey = "";

    # minimum and maximum documents to be displayed per page.
    # the actual maximum will be max + (min-1).
    # the smallest sub-section is a single letter at present
    # so in this case there may be many times max documents
    # displayed on a page.
    my $min = 10; 
    my $max = 30;

    foreach $subsection (sort keys %$classhashref) {
    if ($subsection eq '0-9') {
        @{$compactedhash->{$subsection}} = @{$classhashref->{$subsection}};
        next;
    }
    $currentfirstletter = $subsection if $currentfirstletter eq "";
    if ((scalar (@currentOIDs) < $min) ||
        ((scalar (@currentOIDs) + scalar (@{$classhashref->{$subsection}})) <= $max)) {
        push (@currentOIDs, @{$classhashref->{$subsection}});
        $currentlastletter = $subsection;
    } else {

        if ($currentfirstletter eq $currentlastletter) {
        @{$compactedhash->{$currentfirstletter}} = @currentOIDs;
        $lastkey = $currentfirstletter;
        } else {
        @{$compactedhash->{"$currentfirstletter-$currentlastletter"}} = @currentOIDs;
        $lastkey = "$currentfirstletter-$currentlastletter";
        } 
        if (scalar (@{$classhashref->{$subsection}}) >= $max) {
        $compactedhash->{$subsection} = $classhashref->{$subsection};
        @currentOIDs = ();
        $currentfirstletter = "";
        } else {
        @currentOIDs = @{$classhashref->{$subsection}};
        $currentfirstletter = $subsection;
        $currentlastletter = $subsection;
        }
    }
    }

    # add final OIDs to last sub-classification if there aren't many otherwise
    # add final sub-classification
    if (scalar (@currentOIDs) < $min) {
    my ($newkey) = $lastkey =~ /^(.)/;
    @currentOIDs = (@{$compactedhash->{$lastkey}}, @currentOIDs);
    delete $compactedhash->{$lastkey};
    @{$compactedhash->{"$newkey-$currentlastletter"}} = @currentOIDs;   
    } else {
    if ($currentfirstletter eq $currentlastletter) {
        @{$compactedhash->{$currentfirstletter}} = @currentOIDs;
    } else {
        @{$compactedhash->{"$currentfirstletter-$currentlastletter"}} = @currentOIDs;
    } 
    }

    return $compactedhash;
}

sub output_entry {
    my $self = shift (@_);
    my ($handle, $OID, $title, $contentsref, $classifytype) = @_;
    
    print $handle "[$OID]\n";
    print $handle "<doctype>classify\n";
    print $handle "<hastxt>0\n";
    print $handle "<Title>$title\n";
    print $handle "<classifytype>$classifytype\n" if defined $classifytype;
    if (scalar @$contentsref) {
    print $handle "<contains>", join (";", @$contentsref), "\n";
    }
    print $handle '-' x 70, "\n";
}

# format an english name for sorting
# i.e. convert to lowercase, put surname before
# first names etc.    
sub format_string_name_english {
    my $self = shift (@_);
    my ($stringref) = @_;

    $$stringref =~ tr/A-Z/a-z/;
    $$stringref =~ s/[^a-z0-9 ]//g;
    $$stringref =~ s/\s+/ /g;
    $$stringref =~ s/^\s+//;
    my @names = split / /, $$stringref;
    my $surname = pop @names;
    while (scalar @names && $surname =~ /^(jnr|snr)$/i) {
    $surname = pop @names;
    }
    $$stringref = $surname . " " . $$stringref;
}

# format an english string for sorting
# i.e. convert to lowercase, remove the, a or an
# from beginning of string etc.
sub format_string_english {
    my $self = shift (@_);
    my ($stringref) = @_;

    $$stringref =~ tr/A-Z/a-z/;
    $$stringref =~ s/[^a-z0-9 ]//g;
    $$stringref =~ s/^\s*(the|a|an)\b//;
    $$stringref =~ s/^\s+//;
}

1;