source: trunk/gsdl/perllib/classify/Hierarchy.pm@ 384

# classifier plugin for generating hierarchical classifications

# options for this classifier are:
# file.txt - classification file
# Metaname - metadata field to test against file.txt
# sort=Meta - this option is optional (genious;-). by default this 
#             classifier will sort documents within each section 
#             alphabetically by Title. sort=nosort prevents sorting 
#             (i.e. documents will end up in build order), sort=Meta 
#             will sort each field alphabetically by Meta (Meta may 
#             also be 'Filename' to sort by the original filename).


package Hierarchy;

use util;
use cfgread;
use sorttools;

sub new {
    my ($class, @options) = @_;

    if (!defined @options || (scalar @options < 2)) {
    die "Error in options passed to Hierarchy classification\n" .
        "Usage: Hierarchy subjectfile metadata\n";
    }
    my $sortname = "Title";
    if ((scalar @options > 2) && $options[2] =~ /^sort=(.*)$/i) {
    $sortname = $1;
    $sortname = undef if $sortname =~ /^nosort$/;
    }
    
    my $subjectfile = &util::filename_cat($ENV{'GSDLCOLLECTDIR'},"etc", $options[0]);
    if (!-e $subjectfile) {
    my $collfile = $subjectfile;
    $subjectfile = &util::filename_cat($ENV{'GSDLHOME'},"etc", $options[0]);
    if (!-e $subjectfile) {
        die "Hierarchy Error: Can't locate subject file $options[0]\n" .
        "This file should be in $collfile or $subjectfile\n";
    }
    }

    return bless {
    'descriptorlist'=>{}, # first field in subject file
    'locatorlist'=>{},    # second field in subject file
    'subjectfile' => $subjectfile,
    'metaname' => $options[1],
    'sortname' => $sortname
    }, $class;
}

sub init {
    my $self = shift (@_);

    # read in the subject file
    my $list = &cfgread::read_cfg_file ($self->{'subjectfile'}, undef, '^[^#]?\w');
    
    # $list is a hash that is indexed by the descriptor. The contents of this
    # hash is a list of two items. The first item is the OID and the second item
    # is the title
    foreach $descriptor (keys (%$list)) {
    $self->{'descriptorlist'}->{$descriptor} = $list->{$descriptor}->[0];
    unless (defined $self->{'locatorlist'}->{$list->{$descriptor}->[0]}) {
        $self->{'locatorlist'}->{$list->{$descriptor}->[0]}->{'title'} = $list->{$descriptor}->[1];
        $self->{'locatorlist'}->{$list->{$descriptor}->[0]}->{'contents'} = [];
    }
    }
}

sub classify {
    my $self = shift (@_);
    my ($doc_obj) = @_;

    my $doc_OID = $doc_obj->get_OID();

    my $metadata = $doc_obj->get_metadata ($doc_obj->get_top_section(),
                       $self->{'metaname'});

    foreach $metaelement (@$metadata) {
    if ((defined $self->{'descriptorlist'}->{$metaelement}) &&
        (defined $self->{'locatorlist'}->{$self->{'descriptorlist'}->{$metaelement}})) {

        my $sortmeta = "";
        if (defined $self->{'sortname'}) {
        if ($self->{'sortname'} =~ /^filename$/i) {
            $sortmeta = $doc_obj->get_source_filename();
        } else {
            $sortmeta = $doc_obj->get_metadata_element($doc_obj->get_top_section(),
                                   $self->{'sortname'});
            if ($self-{'sortname'} eq "Creator") {
            &sorttools::format_string_name_english ($sortmeta);
            } else {
            &sorttools::format_string_english ($sortmeta);
            }
        }
        $sortmeta = "" unless defined $sortmeta;
        }

        push (@{$self->{'locatorlist'}->{$self->{'descriptorlist'}->{$metaelement}}->{'contents'}}, 
          [$doc_OID, $sortmeta]);
    }
    }
}


sub get_classify_info {
    my $self = shift (@_);
    
    my $list = $self->{'locatorlist'};

    my $classifyinfo = $self->get_entry ($self->{'metaname'}, "Hierarchy");
    foreach $OID (keys (%$list)) {
    my $tempinfo = $self->get_OID_entry ($OID, $classifyinfo, $list->{$OID}->{'title'}, "Hierarchy");

    if (defined $self->{'sortname'}) {
        foreach $subOID (sort {$a->[1] cmp $b->[1];} @{$list->{$OID}->{'contents'}}) {
        push (@{$tempinfo->{'contains'}}, {'OID'=>$subOID->[0]});
        }
    } else {
        foreach $subOID (@{$list->{$OID}->{'contents'}}) {
        push (@{$tempinfo->{'contains'}}, {'OID'=>$subOID->[0]});
        }
    }
    }
    
    return $classifyinfo;
}


sub get_OID_entry {
    my $self = shift (@_);
    my ($OID, $classifyinfo, $title, $classifytype) = @_;

    $OID = "" unless defined $OID;
    $OID =~ s/^\.+//;
    
    my ($headOID, $tailOID) = $OID =~ /^(\d+)(.*)$/;
    $tailOID = "" unless defined $tailOID;


    if (!defined $headOID) {
    $classifyinfo->{'Title'} = $title;
    $classifyinfo->{'classifytype'} = $classifytype;
    return $classifyinfo;
    }

    $classifyinfo->{'contains'} = [] unless defined $classifyinfo->{'contains'};
    
    # add entries to the contains list until we have one for headOID
    while (scalar(@{$classifyinfo->{'contains'}}) < $headOID) {
    push (@{$classifyinfo->{'contains'}}, $self->get_entry("", $classifytype));
    }

    return $self->get_OID_entry ($tailOID, $classifyinfo->{'contains'}->[($headOID-1)], $title, $classifytype);
}

sub get_entry {
    my $self = shift (@_);
    my ($title, $classifytype) = @_;
    
    # organise into classification structure
    my %classifyinfo = ('classifytype'=>$classifytype,
            'Title'=>$title,
            'contains'=>[]);

    return \%classifyinfo;
}



1;