source: trunk/gsdl/perllib/util.pm@ 14

# various useful utilities

package util;

use File::Copy;


# removes files (but not directories)
sub rm {
    my (@files) = @_;
    my @filefiles = ();

    # make sure the files we want to delete exist 
    # and are regular files
    foreach $file (@files) {
    if (!-e $file) {
        print STDERR "util::rm $file does not exist\n";
    } elsif (!-f $file) {
        print STDERR "util::rm $file is not a regular file\n";
    } else {
        push (@filefiles, $file);
    }
    }
    
    # remove the files
    my $numremoved = unlink @filefiles;

    # check to make sure all of them were removed
    if ($numremoved != scalar(@filefiles)) {
    print STDERR "util::rm Not all files were removed\n";
    }
}


# recursive removal
sub rm_r {
    my (@files) = @_;

    # recursively remove the files
    foreach $file (@files) {
    $file =~ s/[\/\\]+$//; # remove trailing slashes
    
    if (!-e $file) {
        print STDERR "util::rm_r $file does not exist\n";

    } elsif (-d $file) {
        # get the contents of this directory
        if (!opendir (INDIR, $file)) {
        print STDERR "util::rm_r could not open directory $file\n";
        } else {
        my @filedir = grep (!/^\.\.?$/, readdir (INDIR));
        closedir (INDIR);

        # remove all the files in this directory
        &rm_r (map {$_="$file/$_";} @filedir);

        # remove this directory
        if (!rmdir $file) {
            print STDERR "util::rm_r couldn't remove directory $file\n";
        }
        }

    } else {
        # remove this file
        &rm ($file);
    }
    }
}


# copies a file or a group of files
sub cp {
    my $dest = pop (@_);
    my (@srcfiles) = @_;

    # remove trailing slashes from source and destination files
    $dest =~ s/[\\\/]+$//;
    map {$_ =~ s/[\\\/]+$//;} @srcfiles;

    # a few sanity checks
    if (scalar (@srcfiles) == 0) {
    print STDERR "util::cp no destination directory given\n";
    return;
    } elsif ((scalar (@srcfiles) > 1) && (!-d $dest)) {
    print STDERR "util::cp if multiple source files are given the ".
        "destination must be a directory\n";
    return;
    }

    # copy the files
    foreach $file (@srcfiles) {
    my $tempdest = $dest;
    if (-d $tempdest) {
        my ($filename) = $file =~ /([^\\\/]+)$/;
        $tempdest .= "/$filename";
    }
    if (!-e $file) {
        print STDERR "util::cp $file does not exist\n";
    } elsif (!-f $file) {
        print STDERR "util::cp $file is not a plain file\n";
    } else {
        &File::Copy::copy ($file, $tempdest);
    }
    }
}


# recursively copies a file or group of files
# syntax: cp_r (sourcefiles, destination file or directory)
sub cp_r {
    my $dest = pop (@_);
    my (@srcfiles) = @_;

    # remove trailing slashes from source and destination files
    $dest =~ s/[\\\/]+$//;
    map {$_ =~ s/[\\\/]+$//;} @srcfiles;

    # a few sanity checks
    if (scalar (@srcfiles) == 0) {
    print STDERR "util::cp no destination directory given\n";
    return;
    } elsif ((scalar (@srcfiles) > 1) && (!-d $dest)) {
    print STDERR "util::cp if multiple source files are given the ".
        "destination must be a directory\n";
    return;
    }
    
    # copy the files
    foreach $file (@srcfiles) {
    # copy the file to within dest if dest is a directory
    # exception: if there is only one source file and that
    # source file is a directory
    my $tempdest = $dest;
    if (-d $tempdest && !(scalar(@srcfiles) == 1 && -d $file)) {
        my ($filename) = $file =~ /([^\\\/]+)$/;
        $tempdest .= "/$filename";
    }

    if (!-e $file) {
        print STDERR "util::cp $file does not exist\n";

    } elsif (-d $file) {
        # make a new directory (if needed)
        mkdir ($tempdest, 0775) unless -e $tempdest;
        
        # get the contents of this directory
        if (!opendir (INDIR, $file)) {
        print STDERR "util::cp_r could not open directory $file\n";
        } else {
        my @filedir = grep (!/^\.\.?$/, readdir (INDIR));
        closedir (INDIR);

        # copy all the files in this directory
        &cp_r (map {$_="$file/$_";} @filedir, $tempdest);
        }

    } else {
        &cp($file, $tempdest);
    }
    }
}


sub mk_all_dir {
    my ($dir) = @_;

    # use / for the directory separator, remove duplicate and
    # trailing slashes
    $dir=~s/[\\\/]+/\//g; 
    $dir=~s/[\\\/]+$//;

    # make sure the cache directory exists
    my $dirsofar = "";
    my $first = 1;
    foreach $dirname (split ("/", $dir)) {
    $dirsofar .= "/" unless $first;
    $first = 0;

    $dirsofar .= $dirname;

    next if $dirname =~ /^(|[a-z]:)$/i;
    if (!-e $dirsofar && !mkdir ($dirsofar, 0775)) {
        print STDERR "util::mk_all_dir could not create directory $dirsofar\n";
        return;
    }
    }
}


# updates a copy of a directory in some other part of the filesystem
# verbosity settings are: 0=low, 1=normal, 2=high
# both $fromdir and $todir should be absolute paths
sub cachedir {
    my ($fromdir, $todir, $verbosity) = @_;
    $verbosity = 1 unless defined $verbosity;

    # use / for the directory separator, remove duplicate and
    # trailing slashes
    $fromdir=~s/[\\\/]+/\//g; 
    $fromdir=~s/[\\\/]+$//;
    $todir=~s/[\\\/]+/\//g; 
    $todir=~s/[\\\/]+$//;

    &mk_all_dir ($todir);

    # get the directories in ascending order
    if (!opendir (FROMDIR, $fromdir)) {
    print STDERR "util::cachedir could not read directory $fromdir\n";
    return;
    }
    my @fromdir = grep (!/^\.\.?$/, sort(readdir (FROMDIR)));
    closedir (FROMDIR);

    if (!opendir (TODIR, $todir)) {
    print STDERR "util::cacedir could not read directory $todir\n";
    return;
    }
    my @todir = grep (!/^\.\.?$/, sort(readdir (TODIR)));
    closedir (TODIR);

    my $fromi = 0;
    my $toi = 0;
            
    while ($fromi < scalar(@fromdir) || $toi < scalar(@todir)) {
#   print "fromi: $fromi toi: $toi\n";

    # see if we should delete a file/directory
    # this should happen if the file/directory
    # is not in the from list or if its a different
    # size, or has an older timestamp
    if ($toi < scalar(@todir)) {
        if (($fromi >= scalar(@fromdir)) ||
        ($todir[$toi] lt $fromdir[$fromi] || 
         ($todir[$toi] eq $fromdir[$fromi] && 
          &differentfiles("$fromdir/$fromdir[$fromi]","$todir/$todir[$toi]",
                  $verbosity)))) {

        # the files are different
        &rm_r("$todir/$todir[$toi]");
        splice(@todir, $toi, 1); # $toi stays the same

        } elsif ($todir[$toi] eq $fromdir[$fromi]) {
        # the files are the same
        # if it is a directory, check its contents
        if (-d "$todir/$todir[$toi]") {
            &cachedir ("$fromdir/$fromdir[$fromi]",
                   "$todir/$todir[$toi]", $verbosity);
        }

        $toi++;
        $fromi++;
        next;
        }
    }
  
    # see if we should insert a file/directory
    # we should insert a file/directory if there
    # is no tofiles left or if the tofile does not exist
    if ($fromi < scalar(@fromdir) && ($toi >= scalar(@todir) || 
                      $todir[$toi] gt $fromdir[$fromi])) {
        &cp_r ("$fromdir/$fromdir[$fromi]", "$todir/$fromdir[$fromi]");
        splice (@todir, $toi, 0, $fromdir[$fromi]);

        $toi++;
        $fromi++;
    }
    }
}

# this function returns -1 if either file is not found
# assumes that $file1 and $file2 are absolute file names or
# in the current directory
# $file2 is allowed to be newer than $file1
sub differentfiles {
    my ($file1, $file2, $verbosity) = @_;
    $verbosity = 1 unless defined $verbosity;

    $file1 =~ s/\/+$//;
    $file2 =~ s/\/+$//;
    
    my ($file1name) = $file1 =~ /\/([^\/]*)$/;
    my ($file2name) = $file2 =~ /\/([^\/]*)$/;

    return -1 unless (-e $file1 && -e $file2);
    if ($file1name ne $file2name) {
    print STDERR "filenames are not the same\n" if ($verbosity >= 2);
    return 1;
    }

    @file1stat = stat ($file1);
    @file2stat = stat ($file2);

    if (-d $file1) {
    if (! -d $file2) {
        print STDERR "one file is a directory\n" if ($verbosity >= 2);
        return 1;
    }
    return 0;
    }

    # both must be regular files
    unless (-f $file1 && -f $file2) {
    print STDERR "one file is not a regular file\n" if ($verbosity >= 2);
    return 1;
    }

    # the size of the files must be the same
    if ($file1stat[7] != $file2stat[7]) {
    print STDERR "different sized files\n" if ($verbosity >= 2);
    return 1;
    }

    # the second file cannot be older than the first
    if ($file1stat[9] > $file2stat[9]) {
    print STDERR "file is older\n" if ($verbosity >= 2);
    return 1;
    }

    return 0;
}


sub get_tmp_filename {
    my $tmpdir = "$ENV{'GSDLHOME'}/tmp";
    &mk_all_dir ($tmpdir) unless -e $tmpdir;

    my $count = 1000;
    my $rand = int(rand $count);
    while (-e "$tmpdir/F$rand") {
    $rand = int(rand $count);
    $count++;
    }

    return "$tmpdir/F$rand";
}


sub filename_cat {
    my (@filenames) = @_;
    my $filename = join("/", @filenames);

    # remove duplicate slashes and remove the last slash
    $filename =~ s/[\\\/]+/\//g;
    $filename =~ s/\/$//;

    return $filename;
}


# if this is running on windows we want binaries to end in
# .exe, otherwise they don't have to end in any extension
sub get_os_exe {
    return ".exe" if $ENV{'GSDLOS'} =~ /^windows$/i;
    return "";
}



1;