source: trunk/gsdl3/gs3-launch.bat@ 6439

@echo off


::  -------- Launch the Greenstone 3 Digital Library Software --------

if exist gs3-setup.bat goto start
  echo This script must be run from within the Greenstone 3 home directory
  pause
  goto exit

:start
:: ---- Run setup.bat to set the necessary environment variables ----
call gs3-setup.bat
echo.
set CATALINA_HOME=%GSDL3HOME%\comms\jakarta\tomcat
set CATALINA_OPTS="-Djava.util.prefs.syncInterval=2000000 -DGSDL3HOME=%GSDL3HOME% -DGSDLOS=%GSDLOS% -DGSDLHOME= -DPATH=%PATH%"


:findJava
:: ---- Check Java SDK exists ----
set JAVAPATH=

:: Some users may set the above line manually
if not "%JAVAPATH%" == "" goto testJava

    :: If it is set, use the JAVA_HOME environment variable
    if not "%JAVA_HOME%" == "" goto startTomcat

    :: Look in the registry for Java SDK installations
    type nul > jdk.reg
    regedit /E jdk.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit"
    type jdk.reg > jdk.txt
    del jdk.reg

    winutil\findjava.exe jdk.txt | winutil\setvar.exe JAVAPATH > setjava.bat
    del jdk.txt
    call setjava.bat
    del setjava.bat

    :: If a suitable installation was found in the registry, check it
    if not "%JAVAPATH%" == "" goto testJava

:noJava
    echo.
    echo Failed to locate an appropriate version of Java. You must install a
    echo Java Development Kit (version 1.4 or greater) before running the
    echo Greenstone 3 Digital Library Software.
    pause
    goto exit

:testJava
set JAVA_HOME=%JAVAPATH%


:startTomcat
:: ---- Start the Tomcat server ----
call "%GSDL3HOME%\comms\jakarta\tomcat\bin\startup.bat"


:: ---- Launch a web browser ----
start http://localhost:8080/gsdl3


:exit