@echo off

if exist gs3-setup.bat goto start
  echo This script must be run from within the Greenstone 3 home directory
  goto exit

:start
:: ---- Set the GSDL3HOME variable to the current directory ----
cd | winutil\setvar.exe GSDL3SRCHOME > setgsdl3.bat
call setgsdl3.bat
del setgsdl3.bat
echo GSDL3SRCHOME: %GSDL3SRCHOME%
set GSDL3HOME=%GSDL3SRCHOME%\web
echo GSDL3HOME: %GSDL3HOME%

:: change if using external tomcat
set TOMCAT_HOME=%GSDL3SRCHOME%\packages\tomcat

:: ---- Set other important environment variables ----
set GSDLOS=windows
set PATH=%PATH%;%GSDL3SRCHOME%\bin;%GSDL3SRCHOME%\bin\script;%GSDL3SRCHOME%\lib\jni;

:: ---- Set the CLASSPATH environment variable ----
set CLASSPATH=.;%GSDL3HOME%\WEB-INF\classes;%GSDL3SRCHOME%\resources\java;%CLASSPATH%
if exist setcp.bat del setcp.bat
for %%j in ("%GSDL3SRCHOME%"\*.jar) do echo set CLASSPATH=%%CLASSPATH%%;%%j>> setcp.bat
for %%j in ("%GSDL3HOME%"\WEB-INF\lib\*.jar) do echo set CLASSPATH=%%CLASSPATH%%;%%j>> setcp.bat
for %%j in ("%GSDL3SRCHOME%"\lib\jni\*.jar) do echo set CLASSPATH=%%CLASSPATH%%;%%j>> setcp.bat
for %%j in ("%TOMCAT_HOME%"\common\endorsed\*.jar) do echo set CLASSPATH=%%CLASSPATH%%;%%j>> setcp.bat
for %%j in ("%GSDL3SRCHOME%"\build\*.jar) do echo set CLASSPATH=%%CLASSPATH%%;%%j>> setcp.bat

call setcp.bat
del setcp.bat

echo CLASSPATH: %CLASSPATH%

::cd %GSDL3HOME%

:findJava
:: ---- Check Java SDK exists ----
set JAVAPATH=

:: Some users may set the above line manually
if not "%JAVAPATH%" == "" goto testJava
   
:: If it is set, use the JAVA_HOME environment variable
    if not "%JAVA_HOME%" == "" goto javahome

    :: Check if Java is on the search path
    echo %PATH%| winutil\which.exe java.exe | winutil\setvar.exe JAVAPATH > setjava.bat
    call setjava.bat
    del setjava.bat
    echo %JAVAPATH%
    if not "%JAVAPATH%" == "" goto testJava

    :: Still haven't found anything, so try looking in the registry (gulp!)
    type nul > jdk.reg
    regedit /E jdk.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit"
    type jdk.reg > jdk.txt
    del jdk.reg
    type nul > jre.reg
    regedit /E jre.reg "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Runtime Environment"
    type jre.reg > jre.txt
    del jre.reg

    winutil\findjava.exe jdk.txt jre.txt | winutil\setvar.exe JAVAPATH > setjava.bat
    del jdk.txt
    del jre.txt
    call setjava.bat
    del setjava.bat

    :: If nothing was found in the registry, we're stuck
    if "%JAVAPATH%" == "" goto noJava

    set JAVAPATH=%JAVAPATH%\bin
    goto testJava

:javahome
    set JAVAPATH=%JAVA_HOME%\bin

:testJava
if exist "%JAVAPATH%\java.exe" goto  exit


:noJava
    echo.
    echo Failed to locate an appropriate version of Java. You must install a
    echo Java Development Kit (version 1.4 or greater) before running the
    echo Greenstone 3 Digital Library Software.
    pause
    goto exit

:exit