source: trunk/gsdl3/src/java/org/greenstone/applet/phind/winMake.bat@ 3925

@echo off

set JAVALIBDIR=%GSDL3HOME%\lib\java
set JAVASRCDIR=%GSDL3HOME%\src\java

rem ---- Where to put class files ----
set JAVACLASSDIR=classes

rem ---- Where to put servlet classes ----
set JAVASERVLETCLASSDIR=%GSDL3HOME%\web\WEB-INF\classes\org\greenstone\gsdl3

rem ---- Name and location of java programs ----
set JAVAC=%JAVA_HOME%\bin\javac
set JAVAH=%JAVA_HOME%\bin\javah
set JAVA=%JAVA_HOME%\bin\java
set JAVADOC=%JAVA_HOME%\bin\javadoc
set JAR=%JAVA_HOME%\bin\jar

set JAVACOPTIONS= -deprecation -g -O

if ""%1"" == """" goto compile
if ""%1"" == ""compile"" goto compile
if ""%1"" == ""install"" goto install
if ""%1"" == ""clean"" goto clean

:unknown
    echo Error: Unrecognized argument %1.
    goto done

:compile
    if not exist %JAVACLASSDIR% mkdir %JAVACLASSDIR%
    echo Compiling...
    %JAVAC% -target 1.1 -d %JAVACLASSDIR% -sourcepath %JAVASRCDIR% %JAVACOPTIONS% *.java
    %JAR% cf phind.jar -C %JAVACLASSDIR% org
    goto done

:install
    echo Installing...
    copy phind.jar %JAVALIBDIR%
    goto done

:clean
    echo Cleaning up...
    if exist %JAVACLASSDIR% rmdir /S /Q %JAVACLASSDIR%
    del phind.jar
    goto done

:done