source: trunk/gsdl3/src/java/org/greenstone/gsdl3/winMake.bat@ 6868

@echo off

set JAVALIBDIR=%GSDL3HOME%\lib\java
set JAVASRCDIR=%GSDL3HOME%\src\java

rem ---- Where to put class files ----
set JAVACLASSDIR=classes

rem ---- Where to put servlet classes ----
set JAVASERVLETCLASSDIR=%GSDL3HOME%\web\WEB-INF\classes\org\greenstone\gsdl3

rem ---- Name and location of java programs ----
set JAVAC=%JAVA_HOME%\bin\javac
set JAVAH=%JAVA_HOME%\bin\javah
set JAVA=%JAVA_HOME%\bin\java
set JAVADOC=%JAVA_HOME%\bin\javadoc
set JAR=%JAVA_HOME%\bin\jar

set JAVACOPTIONS= -deprecation -g -O

if ""%1"" == """" goto compile
if ""%1"" == ""compile"" goto compile
if ""%1"" == ""install"" goto install
if ""%1"" == ""clean"" goto clean
if ""%1"" == ""allclean"" goto allclean

:unknown
    echo Error: Unrecognized argument %1.
    goto done

:compile
        if not exist %JAVACLASSDIR% mkdir %JAVACLASSDIR%
    echo Compiling...
    %JAVAC% -d %JAVACLASSDIR% -sourcepath %JAVASRCDIR% %JAVACOPTIONS% action\*.java
    %JAVAC% -d %JAVACLASSDIR% -sourcepath %JAVASRCDIR% %JAVACOPTIONS% build\*.java
    %JAVAC% -d %JAVACLASSDIR% -sourcepath %JAVASRCDIR% %JAVACOPTIONS% collection\*.java
    %JAVAC% -d %JAVACLASSDIR% -sourcepath %JAVASRCDIR% %JAVACOPTIONS% comms\*.java
    %JAVAC% -d %JAVACLASSDIR% -sourcepath %JAVASRCDIR% %JAVACOPTIONS% core\*.java
    %JAVAC% -d %JAVACLASSDIR% -sourcepath %JAVASRCDIR% %JAVACOPTIONS% selfContained\*.java
    %JAVAC% -d %JAVACLASSDIR% -sourcepath %JAVASRCDIR% %JAVACOPTIONS% service\*.java
    %JAVAC% -d %JAVACLASSDIR% -sourcepath %JAVASRCDIR% %JAVACOPTIONS% util\*.java
    %JAVAC% -d %JAVACLASSDIR% -sourcepath %JAVASRCDIR% %JAVACOPTIONS% *.java
    %JAR% cf gsdl3.jar -C %JAVACLASSDIR% org
    goto done

:install
    echo Installing...
    copy gsdl3.jar %JAVALIBDIR%
    if not exist %JAVASERVLETCLASSDIR% mkdir %JAVASERVLETCLASSDIR%
    copy %JAVACLASSDIR%\org\greenstone\gsdl3\LibraryServlet.class %JAVASERVLETCLASSDIR%
    goto done

:clean
    echo Cleaning up...
        if exist %JAVACLASSDIR% rmdir /S /Q %JAVACLASSDIR%
    del gsdl3.jar
    goto done

:allclean
    echo Cleaning up (everything)...
        if exist %JAVACLASSDIR% rmdir /S /Q %JAVACLASSDIR%
    del gsdl3.jar
        if exist docs rmdir /S /Q docs
    goto done

:done

rem test: compile
rem     java -classpath $(CLASSPATH) org.greenstone.gsdl3.Library1 $(GSDL3HOME) $(GSDL3HOME)/sites/localsite

rem soaptest: compile
rem     java -classpath $(SOAPCLASSPATH) org.greenstone.gsdl3.Library1 $(GSDL3HOME) $(GSDL3HOME)/sites/site1

rem unittest:
rem     java -Dclass_root=$(JAVACLASSDIR) -Dtest_type=UNIT junit.ui.TestRunner org.greenstone.testing.TestAll