source: trunk/indexers/mgpp/java/org/greenstone/mgpp/winMake.bat@ 7868

@echo off

set MGPPHOME=..\..\..\..

rem ---- Where to put class files ----
set JAVACLASSDIR=classes

rem ---- Name and location of java programs ----
set JAVAC=%JAVA_HOME%\bin\javac
set JAVAH=%JAVA_HOME%\bin\javah
set JAVA=%JAVA_HOME%\bin\java
set JAVADOC=%JAVA_HOME%\bin\javadoc
set JAR=%JAVA_HOME%\bin\jar

set JAVACOPTIONS= -deprecation -g -O


if ""%1"" == """" goto compile
if ""%1"" == ""compile"" goto compile
if ""%1"" == ""install"" goto install
if ""%1"" == ""clean"" goto clean

:unknown
    echo Error: Unrecognized argument %1.
    goto done

:compile
    if not exist %JAVACLASSDIR% mkdir %JAVACLASSDIR%
    echo Compiling...
        %JAVAC% -d %JAVACLASSDIR% %JAVACOPTIONS% *.java
        %JAVAH% -classpath %JAVACLASSDIR% -d %MGPPHOME%\jni org.greenstone.mgpp.MGPPWrapper
        %JAR% cf mgpp.jar -C %JAVACLASSDIR% org
    goto done

:install
        copy mgpp.jar %GSDL3HOME%\lib\java
    goto done

:clean
    echo Cleaning up...
    if exist %JAVACLASSDIR% rmdir /S /Q %JAVACLASSDIR%
        if exist mgpp.jar del mgpp.jar
        if exist %MGPPHOME%\jni\org_greenstone_mgpp_MGPPWrapper.h del %MGPPHOME%\jni\org_greenstone_mgpp_MGPPWrapper.h
    goto done

:done