###########################################################################
#
# PowerPointPlugin.pm -- plugin for importing Microsoft PowerPoint files.
#  (currently only versions 95 and 97)
#
# A component of the Greenstone digital library software
# from the New Zealand Digital Library Project at the 
# University of Waikato, New Zealand.
#
# Copyright (C) 2002 New Zealand Digital Library Project
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
###########################################################################

package PowerPointPlugin;

use ConvertBinaryFile;

use strict;
no strict 'refs'; # allow filehandles to be variables and viceversa
no strict 'subs';
use gsprintf 'gsprintf';

# @ISA dynamically configured to be either OpenOfficeConverter or ConvertBinaryFile

# do not initialise these variables
my $openoffice_ext_installed;
my $openoffice_ext_working;
sub BEGIN {
    eval("require OpenOfficeConverter");
    if ($@) {
	# Useful debugging statement if there is a syntax error in OpenOfficeConverter	
	#print STDERR "$@\n";
	@PowerPointPlugin::ISA = ('ConvertBinaryFile');
	$openoffice_ext_installed = 0;
	$openoffice_ext_working = 0;
    }
    else {
	# Successfully found
	$openoffice_ext_installed = 1;
	# now check whether it can run soffice
	if ($OpenOfficeConverter::openoffice_conversion_available) {
	    @PowerPointPlugin::ISA = ('OpenOfficeConverter');
	    $openoffice_ext_working = 1;
	    
	} else {
	    @PowerPointPlugin::ISA = ('ConvertBinaryFile');
	    $openoffice_ext_working = 0;
	}
    }
}

my $windows_convert_to_list =
    [ {	'name' => "auto",
	'desc' => "{ConvertBinaryFile.convert_to.auto}" },
      {	'name' => "html",
	'desc' => "{ConvertBinaryFile.convert_to.html}" },
      {	'name' => "text",
	'desc' => "{ConvertBinaryFile.convert_to.text}" },
      { 'name' => "pagedimg_jpg",
	'desc' => "{ConvertBinaryFile.convert_to.pagedimg_jpg}" },
      { 'name' => "pagedimg_gif",
	'desc' => "{ConvertBinaryFile.convert_to.pagedimg_gif}" },
      { 'name' => "pagedimg_png",
	'desc' => "{ConvertBinaryFile.convert_to.pagedimg_png}" }
      ];

my $arguments = 
    [ { 'name' => "process_exp",
	'desc' => "{BasePlugin.process_exp}",
	'type' => "regexp",
	'reqd' => "no",
	'deft' => &get_default_process_exp()}
      ];

my $opt_windows_args = 
    [ { 'name' => "convert_to",
	'desc' => "{ConvertBinaryFile.convert_to}",
	'type' => "enum",
	'reqd' => "yes",
	'list' => $windows_convert_to_list, 
	'deft' => "html" },
      { 'name' => "windows_scripting",
	'desc' => "{PowerPointPlugin.windows_scripting}",
	'type' => "flag",
	'reqd' => "no" }
      ];

my $opt_openoffice_args = 
    [ { 'name' => "openoffice_scripting",
	'desc' => "{OpenOfficeConverter.openoffice_scripting}",
	'type' => "flag",
	'reqd' => "no" } ];

my $options = { 'name'     => "PowerPointPlugin",
		'desc'     => "{PowerPointPlugin.desc}",
		'abstract' => "no",
		'inherits' => "yes",
		'srcreplaceable' => "yes", # Source docs in PPT format can be replaced with GS-generated html
	        'args'     => $arguments };

sub new {
    my ($class) = shift (@_);
    my ($pluginlist,$inputargs,$hashArgOptLists) = @_;
    push(@$pluginlist, $class);

    if ($openoffice_ext_installed) {
	print STDERR "PowerPointPlugin: OpenOffice Extension to Greenstone detected\n";
	if ($openoffice_ext_working) {
	    print STDERR "... and it appears to be working\n";
	} else {
	    print STDERR "... but it appears to be broken\n";
	    &gsprintf(STDERR, "OpenOfficeConverter: {OpenOfficeConverter.noconversionavailable} ({OpenOfficeConverter.$OpenOfficeConverter::no_openoffice_conversion_reason})\n");
	}
    }

    if ($ENV{'GSDLOS'} =~ m/^windows$/i) {
	push(@$arguments,@$opt_windows_args);
    }
    if ($openoffice_ext_working) {
	push(@$arguments,@$opt_openoffice_args);
    }    

    push(@{$hashArgOptLists->{"ArgList"}},@{$arguments});
    push(@{$hashArgOptLists->{"OptList"}},$options);


    my $self = {};

    if ($openoffice_ext_working) {
	$self = new OpenOfficeConverter($pluginlist, $inputargs, $hashArgOptLists);
    }
    else {
	$self = new ConvertBinaryFile($pluginlist, $inputargs, $hashArgOptLists);
    }
 
    if ($self->{'info_only'}) {
	# don't worry about any options etc
	return bless $self, $class;
    }

    $self->{'filename_extension'} = "ppt";
    $self->{'file_type'} = "PPT";

    if ($self->{'convert_to'} eq "auto") {
	if ($self->{'windows_scripting'}) {
	    $self->{'convert_to'} = "pagedimg_jpg";
	}
	else {
	    $self->{'convert_to'} = "html";
	}
    }

   my $outhandle = $self->{'outhandle'};

    # can't have windows_scripting and openoffice_scripting at the same time
    if ($self->{'windows_scripting'} && $self->{'openoffice_scripting'}) {
	print $outhandle "Warning: Cannot have -windows_scripting and -openoffice_scripting\n";
	print $outhandle "         on at the same time.  Defaulting to -windows_scripting\n";
	$self->{'openoffice_scripting'} = 0;
    }
    
    #these are passed through to gsConvert.pl by ConvertBinaryFile.pm
    $self->{'convert_options'} = "-windows_scripting" if $self->{'windows_scripting'};
    $self->{'convert_options'} = "-openoffice_scripting" if $self->{'openoffice_scripting'};

    # set convert_to_plugin and convert_to_ext
    $self->ConvertBinaryFile::set_standard_convert_settings();

    my $secondary_plugin_name = $self->{'convert_to_plugin'};
    my $secondary_plugin_options = $self->{'secondary_plugin_options'};

    if (!defined $secondary_plugin_options->{$secondary_plugin_name}) {
	$secondary_plugin_options->{$secondary_plugin_name} = [];
    }
    my $specific_options = $secondary_plugin_options->{$secondary_plugin_name};

    push(@$specific_options, "-file_rename_method", "none");
    push(@$specific_options, "-extract_language") if $self->{'extract_language'};

    if ($secondary_plugin_name eq "HTMLPlugin") {
	push(@$specific_options, "-processing_tmp_files");
	push(@$specific_options,"-metadata_fields","Title,GENERATOR,date,author<Creator>");
    }
    elsif ($secondary_plugin_name eq "PagedImagePlugin") {
	push(@$specific_options, "-processing_tmp_files");
	#is this true??
	push(@$specific_options,"-input_encoding", "utf8");
    }

    $self = bless $self, $class;

    $self->load_secondary_plugins($class,$secondary_plugin_options,$hashArgOptLists);
    return $self;
}

sub get_default_process_exp {
    my $self = shift (@_);
    return q^(?i)\.ppt$^;
}

1;

