prefix skos:   <http://www.w3.org/2004/02/skos/core#>
prefix dct:    <http://purl.org/dc/terms/>
prefix xsd:    <http://www.w3.org/2001/XMLSchema#>

PREFIX rdf:    <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:   <http://www.w3.org/2000/01/rdf-schema#>

prefix dbc:    <http://dbpedia.org/resource/Category:>
prefix dbr:    <http://dbpedia.org/resource/>
prefix dbp:    <http://dbpedia.org/property/>

PREFIX dbo:    <http://dbpedia.org/ontology/>

PREFIX prov:   <http://www.w3.org/ns/prov#>


SELECT ?countries_in_esc_by_year ?country_in_year (?year AS ?Year) (?country AS ?Country)
       ?entrant_robust (?entrant_label AS ?Creator) ?song_robust (?song_label AS ?Title) (?was_derived_from AS ?WikipediaURL)
WHERE {
  SERVICE <https://dbpedia.demo.openlinksw.com/sparql> {
    ?countries_in_esc_by_year skos:broader dbc:Countries_in_the_Eurovision_Song_Contest_by_year.

    ?country_in_year dct:subject ?countries_in_esc_by_year.
    bind( REPLACE(str(?country_in_year), ".*(\\d{4})", "$1") AS ?year).
    FILTER ( xsd:integer(?year) = 1993).

    ?country_in_year dbp:country ?country.

    ?country_in_year dbp:entrant ?entrant.
  }

  OPTIONAL {
    ?entrant_errata_uri dct:source ?entrant.
  }

  BIND (IF(isIRI(?entrant),?entrant,?entrant_errata_uri) AS ?entrant_robust)

  SERVICE <https://dbpedia.demo.openlinksw.com/sparql> {

    ?country_in_year dbp:song ?song.

  }

  OPTIONAL {
    ?song_errata_uri dct:source ?song.
  }

  BIND (IF(isIRI(?song),?song,?song_errata_uri) AS ?song_robust)

  SERVICE <https://dbpedia.demo.openlinksw.com/sparql> {

   OPTIONAL {
    ?entrant_robust rdfs:label ?entrant_label
      FILTER (lang(?entrant_label) = 'en').


    ?song_robust rdfs:label ?song_label_raw
      FILTER (lang(?song_label_raw) = 'en').
    # Create more DL friendly song-title metadata from Wikipedia song-label
    BIND(REPLACE(?song_label_raw, "\\s*\\(.*?song\\)$", "", "i") AS ?song_label).

   
      ?song_robust prov:wasDerivedFrom ?was_derived_from
    }
  }
}
ORDER BY ASC(?countries_in_esc_by_year) ?country